home *** CD-ROM | disk | FTP | other *** search
/ Frozen Fish 1: Amiga / FrozenFish-Apr94.iso / bbs / alib / d0xx / d013 / basicprogs.lha / HauntedM.bas < prev    next >
Encoding:
BASIC Source File  |  1986-02-22  |  10.6 KB  |  185 lines
  1. 5     SCREEN 1,3
  2.  
  3. 10    GOTO 5000
  4.  
  5. 20    rem COPYRIGHT (C) CLOAD 1982
  6.  
  7. 50    rem JOHN OLSON
  8.  
  9. 60    rem HOXIE, KS  67740
  10.  
  11. 70    rem FALL, 1981
  12.  
  13. 80    rem MANSION ADVENTURE
  14.  
  15. 100   REM ADAPTED FOR THE AMIGA BY GARY D. WALBORN 11/3/85
  16.  
  17. 120   DIM L$(25),A(4,25),M$(3,36),B(3,36)
  18.  
  19. 130   scnclr:GOSUB 1770:GOSUB 1130:B=1
  20.  
  21. 140   scnclr:B(1,5)=1+RND(23):B(1,6)=2+RND(22):B(1,7)=2+RND(22):PRINT"LOCATION: ";L$(B):C=0:PRINT"YOU SEE: ";:FOR A=1 TO 36
  22.  
  23. 150   IF B(1,A)=B AND B(3,A)<>0 THEN PRINT TAB(10);M$(2,A):C=1
  24.  
  25. 160   NEXT A:IF C=0 THEN PRINT "NOTHING OF INTEREST"
  26.  
  27. 170   C=0:PRINT "DIRECTIONS: ";:IF A(1,B)<>0 THEN PRINT "NOR ";:C=1
  28.  
  29. 180   IF A(2,B)<>0 THEN PRINT "SOU ";:C=1
  30.  
  31. 190   IF A(3,B)<>0 THEN PRINT "EAS ";:C=1
  32.  
  33. 200   IF A(4,B)<>0 THEN PRINT "WES";:C=1
  34.  
  35. 210   IF C=0 THEN PRINT "? ? ?";
  36.  
  37. 220   PRINT:PRINT STRING$(30,"-")
  38.  
  39. 230   INPUT"WHAT NOW . .";M$:PRINT" ";
  40.  
  41. 240   IF M$="N" THEN M$="GO NOR" ELSE IF M$="S" THEN M$="GO SOU"
  42.  
  43. 250   IF M$="E" THEN M$="GO EAS" ELSE IF M$="W" THEN M$="GO WES"
  44.  
  45. 260   IF M$="LOO" OR M$="LOOK" THEN 140
  46.  
  47. 270   IF LEN(M$)<3 THEN PRINT "?? WHAT ??":GOTO 230
  48.  
  49. 280   N$=LEFT$(M$,3):FOR A = (LEN(M$)-2) TO 1 STEP -1:IF MID$(M$,A,1)=" " THEN 290 ELSE NEXT A
  50.  
  51. 290   O$=MID$(M$,A+1,3): IF N$="INV" THEN 370 ELSE IF N$="SCO" THEN 1090
  52.  
  53. 300   IF N$="HEL" THEN 410 ELSE IF N$="GO " OR N$="WAL" THEN 470
  54.  
  55. 310   IF N$="LOO" OR N$="EXA" THEN 530 ELSE IF N$="GET" OR N$="TAK" THEN 590
  56.  
  57. 320   IF N$="DRO" OR N$="LEA" OR N$="PUT" THEN 740 ELSE IF N$="PRY" THEN 800
  58.  
  59. 330   IF N$="INS" THEN 780 ELSE IF N$="KIC" THEN 820
  60.  
  61. 340   IF N$="PUS" OR N$="PUL" OR N$="MOV" THEN 850 ELSE IF N$="OPE" OR N$="UNL" THEN 940
  62.  
  63. 350   IF N$="KIL" THEN 1050 ELSE IF N$="BRE" THEN 1060 ELSE IF N$="REA" THEN 1080
  64.  
  65. 360   PRINT"I DON'T UNDERSTAND THE VERB !":GOTO 230
  66.  
  67. 370   C=0:FOR A=1 TO 36
  68.  
  69. 380   IF B(1,A)=25 THEN PRINT TAB(2);M$(2,A):C=1
  70.  
  71. 390   NEXT A:IF C=0 THEN PRINT"YOU HAVE NOTHING !"
  72.  
  73. 400   GOTO 230
  74.  
  75. 410   IF B=1 THEN PRINT "INVENTORY AT START / SCORE AT":PRINT" THE END OF THE GAME":GOTO 230
  76.  
  77. 420   IF B=7 OR B=13 OR B=18 OR B=23 OR B=24 THEN PRINT"EXAMINE THINGS . .":GOTO 230
  78.  
  79. 430   IF B=4 THEN PRINT"YOU DESERVE A 'BREAK' TODAY !":GOTO 230
  80.  
  81. 440   IF B=2 OR B=11 THEN PRINT"MOVE THINGS !":GOTO 230
  82.  
  83. 450   IF B=5 THEN PRINT "?? EKAT ??":GOTO 230
  84.  
  85. 460   PRINT "I'M AS CONFUSED AS YOU !":GOTO 230
  86.  
  87. 470   IF O$="DOO" AND B=1 AND B(1,2)=1 THEN B=3:GOTO 140
  88.  
  89. 480   IF O$="NOR" AND A(1,B)<>0 THEN B=A(1,B):GOTO 140
  90.  
  91. 490   IF O$="SOU" AND A(2,B)<>0 THEN B=A(2,B):GOTO 140
  92.  
  93. 500   IF O$="EAS" AND A(3,B)<>0 THEN B=A(3,B):GOTO 140
  94.  
  95. 510   IF O$="WES" AND A(4,B)<>0 THEN B=A(4,B):GOTO 140
  96.  
  97. 520   PRINT"YOU'RE UNABLE TO . . .":GOTO 230
  98.  
  99. 530   FOR A=1 TO 36:IF O$=M$(1,A) THEN 550 ELSE NEXT A
  100.  
  101. 540   PRINT"I DON'T UNDERSTAND THE NOUN !":GOTO 230
  102.  
  103. 550   IF B(1,A)<>B AND B(1,A)<>25 THEN PRINT "IT ISN'T AROUND . .":GOTO 230
  104.  
  105. 560   IF B(3,A)=0 THEN PRINT "YOU CAN'T . . YET!":GOTO 230
  106.  
  107. 570   IF M$(3,A)="Z" THEN PRINT "YOU SEE NOTHING OF INTEREST!":GOTO 230
  108.  
  109. 580   PRINT M$(3,A):GOTO 230
  110.  
  111. 590   FOR A=1 TO 36:IF O$=M$(1,A) THEN 610 ELSE NEXT A
  112.  
  113. 600   GOTO 540
  114.  
  115. 610   IF B(1,A)=25 THEN PRINT "YOU ALREADY HAVE IT !":GOTO 230
  116.  
  117. 620   IF B(1,A)<>B THEN PRINT "THAT ITEM ISN'T AROUND !":GOTO 230
  118.  
  119. 630   IF B(2,A)=0 THEN PRINT "YOU'RE UNABLE TO . . .":GOTO 230
  120.  
  121. 640   C=0:FOR D=1 TO 36:IF B(1,D)=25 THEN C=C+1
  122.  
  123. 650   NEXT D:IF C>4 THEN PRINT "YOU CAN'T CARRY ANY MORE !":GOTO 230
  124.  
  125. 660   IF A=21 THEN M$(3,31)="Z"
  126.  
  127. 670   IF A=25 THEN M$(3,24)="Z"
  128.  
  129. 680   IF A=23 THEN M$(3,22)="Z"
  130.  
  131. 690   IF A=15 THEN M$(2,35)="**THE DIAMOND**"
  132.  
  133. 700   IF A=35 AND LEFT$(M$(2,35),2)="**" THEN SCNCLR:PRINT "A TRAP DOOR OPENS . . .":PRINT"YOU FIND YOURSELF FALLING . . .":PRINT"FALLING . . .":GOTO 1010
  134.  
  135. 710   PRINT "O.K.  . . YOU'VE GOT IT !":B(1,A)=25:B(3,A)=1
  136.  
  137. 720   IF A=16 AND B(3,17)=0 THEN B(3,17)=1:PRINT "A TOKEN WAS UNDER THE RUG . ."
  138.  
  139. 730   GOTO 230
  140.  
  141. 740   FOR A=1 TO 36:IF O$=M$(1,A) THEN 760 ELSE NEXT A
  142.  
  143. 750   GOTO 540
  144.  
  145. 760   IF B(1,A)<>25 THEN PRINT "YOU DON'T HAVE THAT ITEM !":GOTO 230
  146.  
  147. 770   PRINT"O.K.  . .  YOU'VE DROPPED IT !":B(1,A)=B:GOTO 230
  148.  
  149. 780   IF B=24 AND O$="KEY" AND B(1,15)=25 THEN PRINT"O.K.":B(1,15)=24:M$(2,35)=">>THE DIAMOND<<":GOTO 230
  150.  
  151. 790   PRINT"SORRY, THAT'S NOT POSSIBLE !":GOTO 230
  152.  
  153. 800   IF O$="DOO" AND B=1 AND B(1,1)=1 THEN B(1,1)=0:M$(1,1)="!":B(1,2)=1:PRINT"THE DOOR POPS OPEN . .":GOTO 230
  154.  
  155. 810   PRINT"THAT'S NOT POSSIBLE . . SORRY!":GOTO 230
  156.  
  157. 820   IF B<>12 OR O$<>"DES" THEN PRINT "NOTHING HAPPENS . .":GOTO 230
  158.  
  159. 830   PRINT"  ALL OF A SUDDEN . .":PRINT"  YOU FIND YOURSELF FALLING . .":PRINT"  THRU A SECRET ENTRANCE . ."
  160.  
  161. 840   FOR A=1 TO 1500:NEXT A:B=14:GOTO 140
  162.  
  163. 850   IF B<>11 THEN 870 ELSE IF O$="FOU" AND B(1,31)=0 THEN PRINT "A SMALL COMPARTMENT OPENS ! !":B(1,31)=11:B(1,21)=11:GOTO 230
  164.  
  165. 860   PRINT"NOTHING HAPPENS !":GOTO 230
  166.  
  167. 870   IF B=2 AND O$="CAB" AND B(1,12)=0 THEN PRINT "YOU SEE A SAFE !":B(1,12)=2:GOTO 230
  168.  
  169. 880   IF B=18 AND O$="LEV" THEN SCNCLR:PRINT"THERE IS AN EXPLOSION . . .":GOTO 1010
  170.  
  171. 890   IF B=23 AND O$="BUT" THEN SCNCLR:PRINT"THE PASSAGE BEGINS TO FLOOD . .":GOTO 1010
  172.  
  173. 900   FOR A=1 TO 36:IF O$=M$(1,A) THEN 920 ELSE NEXT A
  174.  
  175. 910   GOTO 540
  176.  
  177. 920   IF B(1,A)<>B AND B(1,A)<>25 THEN PRINT"THAT ITEM ISN'T AROUND":GOTO 230
  178.  
  179. 930   PRINT"O.K. . . NOTHING HAPPENS !":GOTO 230
  180.  
  181. 940   IF B<>2 OR O$<>"SAF" OR B(1,12)<>2 THEN 1040
  182.  
  183. 950   PRINT" TO  OPEN  THE SAFE  YOU  MUST":PRINT" USE AND ENTER A  THREE  NUMBER"
  184.  
  185. 960   PRINT" COMBINATION.   ENTER  IT  WITH":PRINT" SLASHES BETWEEN THE  THREE #'S"
  186.  
  187. 970   PRINT" YOU WISH TO USE.  FOR EXAMPLE:":PRINT" 27/14/82  . . . . IF YOU THINK"
  188.  
  189. 980   PRINT" THE COMBINATION IS 27, 14, 82."
  190.  
  191. 990   INPUT" YOUR ATTEMPT . .";M$: IF M$="13/82/30" THEN 1020
  192.  
  193. 1000  SCNCLR:PRINT"THERE IS AN EXPLOSION . .":PRINT:PRINT"THAT WAS THE WRONG COMBINATION!"
  194.  
  195. 1010  PRINT:PRINT "Y O U   A R E   D E A D !":PRINT:INPUT"HIT ENTER TO RESTART";M$
  196.  
  197. 1020  PRINT" THE SAFE POPS OPEN . . .":PRINT" TWO ITEMS FALL TO THE FLOOR !"
  198.  
  199. 1030  B(1,12)=0:B(1,13)=2:B(1,14)=2:B(1,15)=2:M$(1,12)="q":GOTO 230
  200.  
  201. 1040  PRINT"SORRY, THAT'S NOT POSSIBLE !":GOTO 230
  202.  
  203. 1050  PRINT"THOU SHALT NOT . .":GOTO 230
  204.  
  205. 1060  IF (B(1,30)=25 OR B(1,30)=B) AND O$="STA" THEN PRINT"IT BREAKS INTO 5,378 PIECES -":PRINT" REVEALING A MEDALLION !":B(1,30)=0:B(1,10)=B:GOTO 230
  206.  
  207. 1070  PRINT"SORRY, THAT'S NOT POSSIBLE !":GOTO 230
  208.  
  209. 1080  PRINT"TELL ME TO 'LOOK' OBJECT . .":PRINT"THEN YOU READ . . .":GOTO 230
  210.  
  211. 1090  IF B(1,35)=25 OR B(1,35)=1 THEN 1110
  212.  
  213. 1100  PRINT"AT THE MOMENT: SCORE OF ZERO !":GOTO 230
  214.  
  215. 1110  IF B<>1 THEN PRINT"YOU MUST BE OUTSIDE TO SCORE !":GOTO 230
  216.  
  217. 1120  SCNCLR:PRINT" C O N G R A T U L A T I O N S !":PRINT:PRINT" YOU HAVE WON !":PRINT:END
  218.  
  219. 1130  FOR A=1 TO 25:READ L$(A),A(1,A),A(2,A),A(3,A),A(4,A):NEXT A
  220.  
  221. 1140  DATA"OUTSIDE THE MANSION",0,0,0,0
  222.  
  223. 1150  DATA"A LIBRARY",0,0,3,0
  224.  
  225. 1160  DATA"AN ENTRANCE HALL",6,1,4,2
  226.  
  227. 1170  DATA"A SITTING ROOM",7,0,0,3
  228.  
  229. 1180  DATA"A SMALL BEDROOM",0,0,6,0
  230.  
  231. 1190  DATA"A CORRIDOR",9,3,0,5
  232.  
  233. 1200  DATA"A DINING ROOM",10,4,0,0
  234.  
  235. 1210  DATA"A LARGE BEDROOM",11,0,9,0
  236.  
  237. 1220  DATA"A CORRIDOR",12,6,10,8
  238.  
  239. 1230  DATA"A KITCHEN",13,7,0,9
  240.  
  241. 1240  DATA"A CLOSET",0,8,0,0
  242.  
  243. 1250  DATA"A DEN",0,9,0,0
  244.  
  245. 1260  DATA"A PANTRY",0,10,0,0
  246.  
  247. 1270  DATA"A SECRET PASSAGE",15,12,0,0
  248.  
  249. 1280  DATA"A PASSAGE",0,14,20,16
  250.  
  251. 1290  DATA"IN A PASSAGE",17,0,15,0
  252.  
  253. 1300  DATA"A PASSAGE",18,16,19,0
  254.  
  255. 1310  DATA"A SMALL ROOM",0,17,0,0
  256.  
  257. 1320  DATA"A PASSAGE TURN",0,20,21,17
  258.  
  259. 1330  DATA"A MAZE-LIKE PASSAGE",19,0,0,15
  260.  
  261. 1340  DATA"A TURN IN THE PASSAGE",0,22,0,19
  262.  
  263. 1350  DATA"LOST IN A PASSAGE",21,23,0,20
  264.  
  265. 1360  DATA"A CONFUSING PASSAGE",22,24,0,0
  266.  
  267. 1370  DATA"A TREASURE ROOM",23,0,0,0
  268.  
  269. 1380  DATA"YOU",0,0,0,0
  270.  
  271. 1390  FOR A=1 TO 36:READ M$(1,A),M$(2,A),M$(3,A),B(1,A),B(2,A),B(3,A):NEXT A
  272.  
  273. 1400  DATA"DOO","A LOCKED DOOR","IT APPEARS SOLID!",1,0,1
  274.  
  275. 1410  DATA"DOO","AN OPEN DOOR","Z",0,0,1
  276.  
  277. 1420  DATA"BAR","A METAL BAR","WRITING: 4.U.2. PRY",25,1,1
  278.  
  279. 1430  DATA"PAP","A SHEET OF PAPER","WRITING: SAFE COMBO/ATOMIC #'S",25,1,1
  280.  
  281. 1440  DATA"MOU","A MOUSE","IT IS WATCHING YOU !",3,0,1
  282.  
  283. 1450  DATA"SPI","A LARGE SPIDER","IT APPEARS DANGEROUS!",10,0,1
  284.  
  285. 1460  DATA"COB","COBWEBS . . .","Z",7,0,1
  286.  
  287. 1470  DATA"TRE","A COAT TREE","WRITING: I WAS ONCE AN OAK!",3,1,1
  288.  
  289. 1480  DATA"SOF","A SHABBY SOFA","Z",4,0,1
  290.  
  291. 1490  DATA"MED","A LEAD MEDALLION","WRITING:  LEAD A# 82",0,1,1
  292.  
  293. 1500  DATA"CAB","A DINGY CABINET","IT IS EMPTY . . .",2,0,1
  294.  
  295. 1510  DATA"SAF","A LOCKED SAFE","WRITING: VERYSTRONG CO.",0,0,1
  296.  
  297. 1520  DATA"SAF","AN OPEN SAFE","Z",0,0,1
  298.  
  299. 1530  DATA"NOT","A NOTEBOOK","WRITING:  KSED KCIK",0,1,1
  300.  
  301. 1540  DATA"KEY","A SMALL KEY","WRITING: INSERT",0,1,1
  302.  
  303. 1550  DATA"RUG","A TATTERED RUG","Z",5,1,1
  304.  
  305. 1560  DATA"TOK","A ZINC TOKEN","WRITING:  ZINC A# 30",5,1,0
  306.  
  307. 1570  DATA"TAB","AN OLD TABLE","CARVED ON IT: OTKK ENTQ",7,0,1
  308.  
  309. 1580  DATA"DRE","A RUN-DOWN DRESSER","IT IS EMPTY . .",8,0,1
  310.  
  311. 1590  DATA"HOO","WALL HOOKS (1 TO 4)","Z",11,0,1
  312.  
  313. 1600  DATA"COI","AN ALUMINUM COIN","WRITING: ALUMINUM A# 13",0,1,0
  314.  
  315. 1610  DATA"COU","A COUNTER","YOU SEE A KNIFE ON IT !",10,0,1
  316.  
  317. 1620  DATA"KNI","A KNIFE","WRITING: TV WONDERBLADE",10,1,0
  318.  
  319. 1630  DATA"SHE","A SET OF SHELVES","YOU SEE A FLASHLIGHT !",13,0,1
  320.  
  321. 1640  DATA"FLA","A FLASHLIGHT","IMPRINTED: NEVEREADY CO.",13,1,0
  322.  
  323. 1650  DATA"BUC","AN EMPTY BUCKET","WRITING: EL-CHEAPO PLASTIC CO.",13,1,1
  324.  
  325. 1660  DATA"WAT","A WATCH","WRITING: TIME FOR COFFEE !",15,1,1
  326.  
  327. 1670  DATA"FIL","A NAIL FILE","Z",20,1,1
  328.  
  329. 1680  DATA"DES","A DESK","IT IS IN POOR CONDITION !",12,0,1
  330.  
  331. 1690  DATA"STA","A CHEAP STATUE","IMPRINTED: MADE IN JAPAN",4,1,1
  332.  
  333. 1700  DATA"COM","A SMALL COMPARTMENT","YOU SEE: AN ALUMINUM COIN",0,0,1
  334.  
  335. 1710  DATA"LEV","A BLACK LEVER","WRITING: EP OPU QVMM",18,0,1
  336.  
  337. 1720  DATA"BUT","A RED BUTTON","WRITING: EFBUI !",23,0,1
  338.  
  339. 1730  DATA"SLO","A KEY SIZE SLOT","WRITING: HMRDQS JDX EHQRS",24,0,1
  340.  
  341. 1740  DATA"DIA","**A DIAMOND**","IT IS FLAWLESS . . HUGE !",24,1,1
  342.  
  343. 1750  DATA"SIG","A SIGN","ADVENTURES ARE FUN ! ?",14,0,1
  344.  
  345. 1760  INPUT" HIT ENTER TO START . . READY";M$:RETURN
  346.  
  347. 1770  PRINT "M A N S I O N":PRINT
  348.  
  349. 1780  PRINT" SOME SAY  IT'S HAUNTED . . . .":PRINT" OTHERS SAY IT'S CURSED . . . ."
  350.  
  351. 1790  PRINT" WHATEVER THE TRUTH . . . . . .":PRINT" NO ONE  HAS EVER RECOVERED THE"
  352.  
  353. 1800  PRINT" FABLED MANSION DIAMOND ! !":PRINT
  354.  
  355. 1810  PRINT" YOUR TASK IS TO ENTER THE MAN-":PRINT" SION,  FIND THE  DIAMOND,  AND":PRINT" THEN GET OUT SAFELY."
  356.  
  357. 1820  PRINT:INPUT" HIT ENTER . . . TO CONTINUE";O$
  358.  
  359. 1830  SCNCLR:PRINT:PRINT" MAKE YOUR QUEST  USING  ONE OR":PRINT" TWO WORD COMMANDS,SUCH AS:"
  360.  
  361. 1840  PRINT:PRINT" LOOK,  GO NORTH,  TAKE STATUE,":PRINT" BREAK STATUE, HELP, INVENTORY,"
  362.  
  363. 1850  PRINT" LOOK CABINET, ETC.":PRINT
  364.  
  365. 1860  PRINT" IF ONE COMMAND  DOESN'T  WORK,":PRINT" THEN TRY ANOTHER.":PRINT
  366.  
  367. 1870  PRINT"     G O O D   L U C K ! !":PRINT:RETURN
  368.  
  369. 5000  GOTO 100
  370.  
  371.  
  372.