home *** CD-ROM | disk | FTP | other *** search
/ The Fred Fish Collection 1.5 / ffcollection-1-5-1992-11.iso / ff_progs / prog-asm / assemtls.lzh / ASSEMTOOLS / INCLUDE / COM.I < prev    next >
Encoding:
Text File  |  1991-08-16  |  5.8 KB  |  312 lines
  1. ; Graphics and etc. MACRO SET
  2. ; fw 1988
  3. ; Metacomco Macro Assembler
  4. ; Needs 'jmplibs.i' included
  5. ; 
  6. ; NOTE: The "common registers" (d0-d1/a0-a1/a6-a7)
  7. ; should not be used as parameters for these macros
  8. ; to avoid confusion.
  9.  
  10. leftmouse    macro
  11.         btst    #6,$bfe001
  12.         endm
  13.  
  14. ; Usage: leftmouse [<dummy>]
  15. ; Returns the zero flag as ONE if the left mouse button was
  16. ; pressed.
  17. ; <dummy> for compatibility with former versions.
  18.  
  19.  
  20. rightmouse    macro
  21.         btst    #10,$dff016
  22.         endm
  23.  
  24. ; Usage: rightmouse
  25. ; Returns the zero flag as ONE if the right mouse button was
  26. ; pressed.
  27.  
  28.  
  29. use_text    macro
  30.         push    d0-d1/a0-a2
  31.         move.l    \1,a1
  32.         move.w    \2,d0
  33.         move.l    \4,a2
  34.         move.w    \3,d1
  35.         lib    Gfx,Move
  36.         move.l    a2,a0
  37.         moveq.l    #-1,d0
  38. use_tx\@    addq.l    #1,d0
  39.         tst.b    (a2)+
  40.         bne    use_tx\@
  41.         lib    Gfx,Text
  42.         pull    d0-d1/a0-a2
  43.         endm
  44.  
  45. ; Usage: use_text <rport>,<xco>,<yco>,<*text>
  46. ; Calculates the length of the string *text
  47. ; (until a null byte) and outputs it to po-
  48. ; sition xco,yco using Move and Text-functions
  49. ; of the Graphics library.
  50.  
  51.  
  52. alloc_mem    macro
  53.         move.l    $4,a6
  54.         move.l    \1,d0
  55.         move.l    \2,d1
  56.         jsr    _LVOAllocMem(a6)
  57.         move.l    d0,\3
  58.         endm
  59.  
  60. ; Usage: alloc_mem <size>,<type>,<*mem>
  61. ; Allocates memory and returns the pointer.
  62.  
  63.  
  64. use_setapen    macro
  65.         move.l    \1,a1
  66.         move.l    \2,d0
  67.         lib    Gfx,SetAPen
  68.         endm
  69.  
  70. use_setbpen    macro
  71.         move.l    \1,a1
  72.         move.l    \2,d0
  73.         lib    Gfx,SetBPen
  74.         endm
  75.  
  76. ;Usage:    use_setapen <rport>,<pen>
  77. ;Sets the Bg-pen (setbpen) or the Fg-pen (setapen).
  78.  
  79.  
  80. use_setmask    macro
  81.         move.l    \1,a1
  82.         move.b    \2,24(a1)
  83.         endm
  84.  
  85. ;Usage:    use_setmask <rport>,<mask>
  86. ;Sets the drawing mask for given rastport.
  87.  
  88.  
  89. use_move    macro
  90.         move.l    \1,a1
  91.         move.l    \2,d0
  92.         move.l    \3,d1
  93.         lib    Gfx,Move
  94.         endm
  95.  
  96. use_draw    macro
  97.         move.l    \1,a1
  98.         move.l    \2,d0
  99.         move.l    \3,d1
  100.         lib    Gfx,Draw
  101.         endm
  102.  
  103. ;Usage:    use_move <rport>,<xco>,<yco>
  104. ;    use_draw <rport>,<xco>,<yco>
  105. ;Moves the pixel cursor or draws a line.
  106.  
  107.  
  108. use_hrect    macro
  109.         move.l    \1,a1
  110.         move.l    \2,d0
  111.         move.l    \3,d1
  112.         lib    Gfx,Move
  113.         move.l    \2,d0
  114.         move.l    \5,d1
  115.         move.l    \1,a1
  116.         lib    Gfx,Draw
  117.         move.l    \4,d0
  118.         move.l    \5,d1
  119.         move.l    \1,a1
  120.         lib    Gfx,Draw
  121.         move.l    \4,d0
  122.         move.l    \3,d1
  123.         move.l    \1,a1
  124.         lib    Gfx,Draw
  125.         move.l    \2,d0
  126.         move.l    \3,d1
  127.         move.l    \1,a1
  128.         lib    Gfx,Draw
  129.         endm
  130.  
  131. ;Usage:    use_hrect <rport>,<xco1>,<yco1>,<xco2>,<yco2>
  132. ;Draws a hollow rectangle using Move and Draw-routines
  133.  
  134.  
  135. use_frect    macro
  136.         move.l    \1,a1
  137.         move.l    \4,d2
  138.         move.l    \5,d3
  139.         move.l    \2,d0
  140.         move.l    \3,d1
  141.         lib    Gfx,RectFill
  142.         endm
  143.  
  144. ;Usage:    use_frect <rport>,<xco1>,<yco1>,<xco2>,<yco2>
  145. ;Draws a filled rectangle using the RectFill-routine.
  146. ;NOTE: Any parameters should not be passed to this macro
  147. ;in the common registers or d2-d3 to avoid confusion.
  148.  
  149.  
  150. set_led        macro
  151.         push    d0
  152.         move.l    \1,d0
  153.         beq    \@s_led2
  154.         bpl    \@s_led1
  155.         bclr    #1,$bfe001
  156.         bra    \@s_led0
  157. \@s_led1    bset    #1,$bfe001
  158.         bra    \@s_led0
  159. \@s_led2    bchg    #1,$bfe001
  160. \@s_led0    pull    d0
  161.         endm
  162.  
  163. ;Usage:    set_led    <state>
  164. ;Sets the power indicator state. On a positive <state> the
  165. ;indicator will be turned off (A500) or dimmed (A1000/A2000).
  166. ;On a negative <state> the indicator will be brightened back.
  167. ;On a zero <state> the led will be toggled on and off.
  168.  
  169.  
  170. use_line    macro
  171.         move.l    \1,a1
  172.         move.l    \2,d0
  173.         move.l    \3,d1
  174.         lib    Gfx,Move
  175.         move.l    \1,a1
  176.         move.l    \4,d0
  177.         move.l    \5,d1
  178.         lib    Gfx,Draw
  179.         endm
  180.  
  181. ;Usage:    use_line <rport>,<x1>,<y1>,<x2>,<y2>
  182. ;Draws a straight line between points (x1,y1)
  183. ;and (x2,y2) using the routines DRAW and MOVE
  184. ;of the Gfx-library.
  185.  
  186.  
  187. use_setdrmd    macro
  188.         move.l    \1,a1
  189.         move.l    \2,d0
  190.         lib    Gfx,SetDrMd
  191.         endm
  192.  
  193. ;Usage:    use_setdrmd <rport>,<mode>
  194. ;Sets the drawing mode using the SetDrMd-routine.
  195.  
  196.  
  197. drmd_jam1    equ    0
  198. drmd_jam2    equ    1
  199. drmd_complement    equ    2
  200. drmd_inversvid    equ    4
  201.  
  202. memf_public    equ    1
  203. memf_chip    equ    2
  204. memf_fast    equ    4
  205. memf_clear    equ    1<<16
  206. memf_largest    equ    1<<17
  207.  
  208. style_bold    equ    2
  209. style_italic    equ    4
  210. style_underline    equ    1
  211.  
  212. customscreen    equ    15
  213.  
  214.  
  215. use_setrast    macro
  216.         move.l    \1,a1
  217.         move.l    \2,d0
  218.         lib    Gfx,SetRast
  219.         endm
  220.  
  221. ;Usage:    use_setrast <rport>,<color>
  222. ;Used to fill the whole rastport with any color.
  223.  
  224.  
  225. use_scrollraster macro
  226.         move.l    \1,a1
  227.         move.l    \2,d2
  228.         move.l    \3,d3
  229.         move.l    \4,d4
  230.         move.l    \5,d5
  231.         move.l    \6,d0
  232.         move.l    \7,d1
  233.         lib    Gfx,ScrollRaster
  234.         endm
  235.  
  236. ;Usage:    use_scrollraster <rport>,<x1>,<y1>,<x2>,
  237. ;    <y2>,<xd>,<yd>
  238. ;Scrolls a rectangular area of the rastport.
  239. ;Direction is specified by dx and dy. Negative
  240. ;value means down or right, positive up or left.
  241.  
  242.  
  243. use_clearvert    macro
  244.         move.l    \1,a1
  245.         move.l    4(a1),a1
  246.         move.l    (8+4*\2)(a1),a1
  247.         add.l    #\3*\5,a1
  248.         move.l    #\4*\5,d0
  249.         moveq.l    #0,d1
  250.         lib    Gfx,BltClear
  251.         endm
  252.  
  253. ;Usage:    use_clearvert <rport>,<plane#>,<ymin>,<ysiz>,<bytesperrow>
  254. ;Used to clear a vertical region of a rastport.
  255. ;plane# is the number of plane to be cleared, 
  256. ;ymin and ysiz are the utmost pixel line and number of pixel
  257. ;lines of the area to be cleared,
  258. ;bytesperrow is the number of bytes per a horizontal row
  259. ;The values plane#, ymin, ysiz and bpr must be entered as
  260. ;immediate values, but WITHOUT the hash (#) sign.
  261.  
  262.  
  263. use_loadrgb4    macro
  264.         move.l    \1,a0
  265.         move.l    \2,a1
  266.         move.l    \3,d0
  267.         lib    Gfx,LoadRGB4
  268.         endm
  269.  
  270. ;Usage:    use_loadrgb4 <vport>,<colmap>,<count>
  271. ;Loads palette for given viewport. See the
  272. ;Amiga Rom Kernel Refernce Manual: Libraries
  273. ;and Devices for further details.
  274.  
  275.  
  276. rassize        macro
  277. \1        set    \3*(((\2+15)/16)*2)
  278.         endm
  279.  
  280. ;Usage:    rassize <label>,<xsiz>,<ysiz>
  281. ;SETs the value of the label as the size of a raster
  282. ;of size (xsiz,ysiz) in words.
  283.  
  284.  
  285. use_allocraster    macro
  286.         move.l    \1,d0
  287.         move.l    \2,d1
  288.         lib    Gfx,AllocRaster
  289.         move.l    d0,\3
  290.         ifnc    '\4',''
  291.         beq    \4
  292.         endc
  293.         endm
  294.  
  295. ;Usage:    use_allocraster <wid>,<heig>,<dest>[,<cleanup>]
  296. ;Allocates a raster of size <wid>,<heig>. Pointer to
  297. ;the raster is written to the <dest>. If an error occurs,
  298. ;the program flow will be transferred to <cleanup>.
  299.  
  300.  
  301. use_freeraster    macro
  302.         move.l    \1,d0
  303.         move.l    \2,d1
  304.         move.l    \3,a0
  305.         lib    Gfx,FreeRaster
  306.         endm
  307.  
  308. ;Usage:    use_freeraster <wid>,<heig>,<pointer>
  309. ;Frees the raster allocated by the use_allocraster.
  310. ;Use the same parameters as in the use_allocraster.
  311.  
  312.