home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.robelle3000.ai 2014
/
2014.06.ftp.robelle3000.ai.tar
/
ftp.robelle3000.ai
/
papers
/
nmdebug.macros
next >
Wrap
Text File
|
1995-08-10
|
11KB
|
138 lines
wl "Robelle macros, version 07 Jun91"
/* Macro: Vfilepages
/*
/* Purpose: Display the number of pages (and corresponding
/* sectors) of a file that are actually in memory.
/*
/* Warning: Never use this macro on catalog.pub.sys.
/*
mac vfilepages (filename:str) {
map !filename;
w !filename " contains " ;
w vainfo(mapva(!filename),"pages_in_mem"):"D" ;
w " pages in memory = " ;
w vainfo(mapva(!filename),"pages_in_mem")*#16:"D" ;
w " sectors" ;
wl ;
unmap(mapindex(!filename));
}
/* Macro: show_hpfopen
/*
/* Purpose: Display the parameters to HPFopen. Only valid at
/* entry into HPFopen. Written by Stan Sieler.
macro show_hpfopen {
loc args r26;
wl "# Parameters = ", r26:"#";
wl "File# @ ", r25;
wl "Status @ ", r24;
loc itemnum r23;
loc args args - 2;
loc nth 0;
loc spminus sp-#56+8;
while args >= 0 do
{
loc nth nth + 1;
if nth > 1 then
loc itemnum [spminus];
w "Item # ", nth:"DW2", " = ", itemnum:"#W2", ' ';
if itemnum = 0 then
wl
else
{
loc itemval [spminus - 4];
w ": ", itemval;
if (itemval >= $40000000) and (itemval <= $4f000000) then
{
loc parmval [itemval];
w ' --> ', parmval;
if itemnum = #51 then
w ' = ',parmval:"A", [itemval + 4]:"A"
else
if (parmval > 9) or (parmval < -9) then
w ' (', parmval:'#', ')';
}
else
w ' (', itemval:'#', ')';
wl;
};
loc args args - 2;
loc spminus spminus - 8;
}
}
/* Macro: show_fopen
/*
/* Purpose: Display the parameters to Fopen. Only valid at
/* entry into Fopen. Patterned after Stan's
/* show_hpfopen. Written by David Greer.
mac show_fopen {
w "Filename: ";
dv r26,9,s;
wl "Foptions: ", r25:"#";
wl "Aoptions: ", r24:"#";
wl "Recsize: ", r23:"#";
wl "Userlabels: ", [sp-3a]:"#";
wl "Blk factor: ", [sp-3e]:"#";
wl "Numbuffers: ", [sp-42]:"#";
wl "Filesize: ", [sp-48]:"#";
wl "Numextents: ", [sp-4a]:"#";
wl "Initalloc: ", [sp-4e]:"#";
wl "Filecode: ", [sp-52]:"#";
}
/* Macro: show_ffileinfo
/*
/* Purpose: Display the parameters to ffileinfo. Only valid at
/* entry into Ffileinfo. Patterned after Stan's
/* show_hpfopen. Written by Neil Armstrong.
mac show_ffileinfo {
wl "Filenum : ", r26:"#";
wl "itemnum1 : ", r25:"#";
wl "itemvalue1: ", r24:"#";
wl "itemnum2 : ", r23:"#";
wl "itemvalue2: ", [sp-34]:"#";
wl "itemnum3 : ", [sp-36]:"#";
wl "itemvalue3: ", [sp-3c]:"#";
wl "itemnum4 : ", [sp-3e]:"#";
wl "itemvalue4: ", [sp-44]:"#";
wl "itemnum5 : ", [sp-46]:"#";
wl "itemvalue5: ", [sp-4c]:"#";
}
/* Macro: show_dbinfo
/*
/* Purpose: Display the parameters to DBINFO. Only valid at
/* entry into DBINFO. Patterned after Stan's
/* show_hpfopen. Written by David Greer.
mac show_dbinfo {
w "Base: "; dv r26,7,s;
w "Qualifier: "; dv r25,4,s;
w "Mode: "; dv r24,1,#,,2;
wl "@Status: ", r23:"$";
wl "@Buffer: ", [sp-34]:"$";
}
/* Macro: show_ffileinfo
/*
/* Purpose: Display the parameters to ffileinfo. Only valid at
/* entry into Ffileinfo. Patterned after Stan's
/* show_hpfopen. Written by Neil Armstrong.
mac show_flabelinfo {
w "Filename : ";
dv r26,9,s;
wl "Mode : ", r25:"#";
wl "error : ", r24:"#";
wl "itemnums : ", r23:"#";
wl "itemvalues: ", [sp-34]:"#";
wl "itemerrs : ", [sp-38]:"#";
}