ftp.robelle3000.ai 2014/2014.06.ftp.robelle3000.ai.tar/ftp.robelle3000.ai/faq/install.suprjob.robelle

Text File | 1999-05-16 | 3KB | 136 lines

!job install,mgr.robelle,pub;outclass=lp,3
!comment
!comment  setup:    03 May90 by David Greer
!comment  revised:  28 Feb96 by Neil Armstrong
!comment  revised:  10 May99 by Paul : recode renames accross groups.
!comment
!comment  purpose:  This job stream installs the latest prodution
!comment            version of SUPRTOOL into the PUB group.
!comment            This job also installs Suprlink, Speed
!comment            Demon and Stexport.
!comment
!comment  note:  This job stream will fail if anyone is using SUPRTOOL
!comment         at installation time.
!
!setjcw false = 0
!setjcw true  = 1
!
!comment
!comment
!comment  Step 1:  verify that Suprtool exists, with a valid hpsusan.
!comment
!
!run suprcm.pub,trial
!
!comment
!comment  Step 2:  Determine whether we are on MPE XL.
!comment
!setjcw cierror = 0
!continue
!setvar robelletempflag "MPE XL " + "only"
!if cierror=0 then
!   continue
!   deletevar robelletempflag
!   setjcw mpexlflag = true
!else
!   setjcw mpexlflag = false
!endif
!comment
!comment  Step 3:  Make sure none of the major programs are
!comment           allocated.
!comment
!continue
!deallocate suprtool.pub
!continue
!deallocate suprlink.pub
!continue
!deallocate demon.pub
!continue
!deallocate stexport.pub
!comment
!comment  Step 4:  purge all files from the pubold group.
!comment
!purge demon.pubold
!purge suprlink.pubold
!purge stexport.pubold
!purge suprtool.pubold
!comment
!comment  Step 5:  Verify that no one is running the production
!comment           versions of our programs.
!comment
!setjcw cierror = 0
!continue
!listf suprtool.pub;$null
!if cierror = 0 then
!   rename suprtool.pub ,suprtool.pub
!endif
!setjcw cierror = 0
!continue
!listf suprlink.pub;$null
!if cierror = 0 then
!   rename suprlink.pub ,suprlink.pub
!endif
!setjcw cierror = 0
!continue
!listf stexport.pub;$null
!if cierror = 0 then
!   rename stexport.pub ,stexport.pub
!endif
!setjcw cierror = 0
!continue
!listf demon.pub;$null
!if cierror = 0 then
!   rename demon.pub ,demon.pub
!endif
!setjcw cierror = 0
!continue
!comment
!comment  Step 6:  move files from the pub group to the
!comment           pubold group.
!comment
!if mpexlflag = true then
!   continue
!   copy   demon.pub       ,demon.pubold
!   continue
!   copy   suprlink.pub    ,suprlink.pubold
!   continue
!   copy   stexport.pub    ,stexport.pubold
!   continue
!   copy   suprtool.pub    ,suprtool.pubold
!else
!   continue
!   fcopy from= demon.pub     ;to=demon.pubold    ;new
!   continue
!   fcopy from= suprlink.pub  ;to=suprlink.pubold ;new
!   continue
!   fcopy from= stexport.pub  ;to=stexport.pubold ;new
!   continue
!   fcopy from= suprtool.pub  ;to=suprtool.pubold ;new
!endif
!continue
!purge  demon.pub
!continue
!purge  suprlink.pub
!continue
!purge  stexport.pub
!continue
!purge  suprtool.pub
!comment
!comment  Step 7:  Rename compatibility-mode or native-mode versions
!comment           of our programs as the production version.
!comment
!if mpexlflag = true then
!   rename suprnm.pub   ,suprtool.pub
!   rename linknm.pub   ,suprlink.pub
!   rename demonnm.pub  ,demon.pub
!   rename stexpnm.pub  ,stexport.pub
!else
!   rename suprcm.pub  ,suprtool.pub
!   rename linkcm.pub  ,suprlink.pub
!   rename demoncm.pub ,demon.pub
!   rename stexpcm.pub ,stexport.pub
!endif
!
!tell mgr.robelle;Install has installed a new version of SUPRTOOL!
!eoj