home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
norge.freeshell.org (192.94.73.8)
/
192.94.73.8.tar
/
192.94.73.8
/
pub
/
computers
/
pcjr
/
arc
/
FF_65A.LZH
/
PATCH_FF.BAT
< prev
Wrap
DOS Batch File
|
1989-06-25
|
2KB
|
67 lines
echo off
rem @(#)c:/usr/ff/65/ff.c:6.5a * Sun Jun 25 18:26:10 1989 * by John Lots
if "==%1" goto usage
if not exist ff.exe goto nofiles
if exist __$ff$__.scr del __$ff$__.scr
set a=fill
set opt=69
set adr=null
if not %opt%.==69. goto no_env
if not %adr%.==null. goto no_env
echo Working... please wait.....
:loop
if "==%1" goto doit
set opt=
for %%a in (A;B;C;N;V;a;b;c;n;v) do if %1==+%%a set opt=ff
for %%a in (A;B;C;N;V;a;b;c;n;v) do if %1==-%%a set opt=0
if .==%opt%. goto usage
for %%a in (N;n) do if %1==+%%a set adr=2b64
for %%a in (N;n) do if %1==-%%a set adr=2b64
for %%a in (A;a) do if %1==+%%a set adr=2b65
for %%a in (A;a) do if %1==-%%a set adr=2b65
for %%a in (C;c) do if %1==+%%a set adr=2b66
for %%a in (C;c) do if %1==-%%a set adr=2b66
for %%a in (B;b) do if %1==+%%a set adr=2b67
for %%a in (B;b) do if %1==-%%a set adr=2b67
for %%a in (V;v) do if %1==+%%a set adr=2b68
for %%a in (V;v) do if %1==-%%a set adr=2b68
echo>>__$ff$__.scr e %adr% %opt%
shift
goto loop
:doit
echo>>__$ff$__.scr w
echo>>__$ff$__.scr q
copy>nul ff.exe ff
debug<__$ff$__.scr >nul ff
copy>nul ff.exe ff.old
copy>nul ff ff.exe
del ff
echo.
echo [old file is ff.old, new file is ff.exe]
echo.
echo All done!
goto end
:nofiles
echo ff.exe not found in current directory
echo [nothing changed]
goto end
:usage
echo Usage: patch_ff {+,-}{a,b,c,n,v} [...]
echo Set defaults for the Arconly, Brief, Continuous, No_arc and Verbose options
echo to either on(+) or off (-) [standard defaults: all options except Verbose off]
echo.
echo e.g. patch_ff +n
echo to get a version that defaults to not search archives (DWC PAK ARC ZIP ZOO LZH)
echo (ofcourse, in this case you can still search archives by giving the -n option)
echo.
echo [nothing changed]
goto end
:no_env
echo Oops: your environment is too small! please enlarge it a little before running
echo patch_ff again...
echo.
:end
if exist __$ff$__.scr del __$ff$__.scr
set opt=
set adr=