home *** CD-ROM | disk | FTP | other *** search
/ ftp.update.uu.se / ftp.update.uu.se.2014.03.zip / ftp.update.uu.se / pub / pdp8 / os278-src.tar.Z / os278-src.tar / lpts.pa < prev    next >
Text File  |  1992-09-18  |  6KB  |  287 lines
  1. /LPTS SERIAL LINE PRINTER
  2. /
  3. /
  4. /
  5. / THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
  6. / AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
  7. / CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
  8. / FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
  9. /
  10. / THE SOFTWARE DESCRIBED HEREIN IS FURNISHED TO THE PURCHASER
  11. / UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
  12. / (WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
  13. / SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
  14. / 
  15. / DIGITAL EQUIPMENT ASSUMES NO RESPONSIBILITY FOR THE USE
  16. / OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED
  17. / BY DIGITAL.
  18. /
  19. /    COPYRIGHT (C) 1977,1978,1979,1981,1982, 1984
  20. /                BY
  21. /        DIGITAL EQUIPMENT CORPORATION
  22. /
  23.  
  24. PDPC=6336        /PRINT CHARACTER
  25. PDSF=6331        /SKIP ON FLAG
  26. PDBD=6333        /SET BAUD RATE
  27.  
  28. RDSKP=6321        /SKIP ON SERIAL PORT INPUT FLAG
  29. RDXF=6326        /READ SERIAL XON/OFF FLAG
  30. XON=21
  31. XOFF=23
  32.  
  33. LPVERSION="B&77^100+PATCH+60    /VERSION B
  34. PATCH=3                /PATCH LEVEL
  35.  
  36. NOCHK=    1    / 0 = Don't check for ctrl c, 1 = check for ctrl c
  37. AUTOFF= 0    / 0 = No auto FF, 1 = Auto FF
  38.  
  39. *0        /ORIGIN FOR BUILD INFO
  40.  
  41. -1        /ONE ENTRY POINT
  42. DEVICE LPTS
  43. DEVICE LPT    /DEVICE NAME
  44. 1040        /DEVICE TYPE
  45. LQP&177+4000    /ENTRY POINT + TWO-PAGE FLAG
  46. 0        /REQUIRED ZEROES
  47. 0
  48.  
  49. PAGE
  50.  
  51.  
  52. LQPORG=.
  53. STLINE,    -205        /-(WIDTH+1)  MODIFIED BY "SET LPT WIDTH NN"
  54. LINE,    0        /POINTER TO SECOND PAGE LINE COUNTER
  55. LPTSER,    DEVICE LPTS    /USED BY "SET" FOR IDENTIFICATION OF SERIAL HANDLER
  56. STBAUD,    14        /CAN BE MODIFIED BY "SET LPT BAUD NN"
  57.  
  58. LQP,    LPVERSION    /ENTRY POINT (MH)
  59.     CLL CLA
  60. LQBAUD,    TAD STBAUD    /INIT PRINTER BAUD RATE
  61.     PDBD
  62.     CLA
  63.     JMS LQPDCZ    /INIT SECOND PAGE LINK
  64.     RDF        /SAVE RETURN FIELD
  65.     TAD (CIF CDF)
  66.     DCA LQPRDF
  67.     TAD I LQP    /GET FUNCTION WORD
  68.     AND (70)
  69.     TAD (CDF)
  70.     DCA LQPBDF    /SET BUFFER CDF
  71.     TAD I LQP
  72.     AND (3700)
  73.     CMA
  74.     DCA LQPDWC    /SET DOUBLE-WORD COUNT +1
  75.     ISZ LQP
  76.     TAD I LQP
  77.     DCA LQPBUF    /SET BUFFER PTR
  78.     ISZ LQP
  79.     TAD I LQP
  80. LQPBDF,    0        /CDF TO BUFFER
  81.     SZA CLA
  82.     JMP LQPGO
  83.     TAD (15)
  84.     JMS LQPDOC    /NEW PAGE PN BLOCK 0
  85.     TAD (14)
  86.     JMS LQPDOC
  87. LQPGO,    ISZ LQPDWC
  88.     JMP LQPGO1    /LOOP IF MORE TO DO
  89. LQPCZ,    CLL CLA
  90.     JMS LQPDOC    /CLEAR SPACE ACCUMULATORS
  91. LQPRDF,    0        /THEN RETURN TO CALLER
  92.     ISZ LQP
  93.     ISZ LQP
  94.     JMP I LQP
  95.  
  96. LQPGO1,    TAD I LQPBUF    /GET NEXT WORD
  97.     AND (7400)
  98.     CLL RTR
  99.     DCA LQPCSV    /SAVE PART OF THIRD CHAR
  100.     TAD I LQPBUF
  101.     JMS LQPDOC    /OUTPUT FIRST CHAR
  102.     ISZ LQPBUF
  103.     NOP        /PATCH TO AVOID SKIP ON ZERO
  104.     TAD I LQPBUF
  105.     JMS LQPDOC    /OUTPUT SECOND CHAR
  106.     TAD I LQPBUF
  107.     AND (7400)    /PUT THIRD CHAR TOGETHER
  108.     BSW
  109.     TAD LQPCSV
  110.     CLL RTR
  111.     JMS LQPDOC    /OUTPUT THIRD CHAR
  112.     ISZ LQPBUF
  113.     NOP        /PATCH TO AVOID SKIP ON ZERO
  114.     JMP LQPGO    /LOOP FOR DONE TEST
  115.  
  116. LQPDCZ,    0        /SET UP SECOND PAGE POINTERS
  117.     TAD LQPDCZ
  118.     AND (7600)
  119.     DCA CORPAG    /SAVE CURRENT PAGE #
  120.     TAD CORPAG
  121.     TAD (LQPDCX-LQPORG)
  122.     DCA LQPDCY
  123.     RDF        /GET RETURN FIELD
  124.     TAD (CDF    /BUILD DATA FIELD INSTRUCTION
  125.     DCA RTFLD    /SAVE IT FOR LATER
  126.     CDF 0        /SET DF TO OUR FIELD
  127.     TAD (LQLINE-LQPORG
  128.     TAD CORPAG    /ADD BASE PAGE
  129.     DCA LINE    /SAVE IT AS A POINTER
  130.     TAD STLINE    /GET THE MINUS CHARACTER COUNT
  131.     IAC        /SUBTRACT ONE FROM IT, BECAUSE "SET LPT WIDTH" ADDS ONE.
  132.     DCA I LINE    /SET IT IN THE SECOND PAGE
  133. RTFLD,    CDF
  134.     JMP I LQPDCZ
  135.  
  136. LQPDOC,    0
  137.     JMS I LQPDCY
  138.     JMP LQPCZ
  139.     JMP I LQPDOC
  140.  
  141. CORPAG,    0
  142. LQPCSV,    0
  143. LQPBUF,    0
  144. LQPDWC,    0
  145. LQPDCY,    0
  146.  
  147. PAGE
  148.  
  149. LQPDCX,    0        /OUTPUT ONE CHAR
  150.     AND (177)
  151.     TAD (-40)    /TEST FOR SPECIAL OR BLANK
  152.     SPA
  153.     JMP LQPSPC    /JUMP IF SPECIAL
  154.     ISZ LQPX    /PRINTABLE CHAR; BUMP CHAR COUNTER
  155.     TAD K40        /RESTORE THE CHAR CODE
  156. LQPDC1,    DCA LQPCTM    /SAVE CHAR CODE
  157.     JMS LQPNDX    /PRINT A CHAR
  158. LQPDCR,    ISZ LQPDCX    /BUMP TO OK RETURN
  159.     JMS LQPEOL    /CHECK FOR END OF LINE
  160.     JMP I LQPDCX    /RETURN TO CALLER
  161.  
  162. LQPNDX,    0        /ROUTINE TO PRINT A CHAR
  163.     JMS XONOFF    //LOOK FOR XONOFF
  164.     TAD LQPCTM    /RETRIEVE SAVED CHAR
  165.     SNA
  166.     JMP I LQPNDX    /EXIT IF NONE
  167.     PDPC        /PRINT CHAR
  168.     PDSF
  169.     JMP .-1
  170. L7600,    7600        /SHADY CLA
  171.     JMP I LQPNDX    /XON, EXIT
  172.  
  173. XONOFF,    0
  174. IFNZRO    NOCHK < KSF >
  175. IFZERO    NOCHK < NOP >
  176.     JMP    XONOFA
  177.     KRB
  178.     TAD (-3
  179.     SNA CLA
  180.     JMP XONOF3    //EASIER THAN REWRITING FOR 2-WAY CROSS PAGE LINKAGE.
  181. XONOFA,    RDSKP
  182.     JMP XONOF1    //NO FLAG. CHECK XON STATUS.
  183.     RDXF
  184.     AND (177
  185.     TAD (-XON
  186.     SNA
  187.     JMP XONOF2    //XON. RESET OR KEEP OUTPUT GOING.
  188.     TAD (XON-XOFF
  189.     SNA CLA
  190.     JMP .+3        //XOFF. SET THE WAIT FLAG.
  191. XONOF1,    ISZ XOFLAG
  192.     JMP XONOF2    //NOTHING DOING, SO EXIT TO PRINT.
  193.     STA        //KEEP XOFF SET,
  194.     DCA XOFLAG
  195.     JMP XONOFF+1    //UNTIL WE GET XON.
  196. XONOF2,    DCA XOFLAG
  197.     JMP I XONOFF    //LEGIT XON.
  198.  
  199. XONOF3,    CDF CIF 0
  200.     JMP I L7600
  201.  
  202. XOFLAG,    0
  203.  
  204.  
  205. /CHECK FOR END OF LINE TO BE FORCED.
  206.  
  207. LQPEOL,    0
  208.     TAD LQPX    /GET AMOUNT OF CHAR SO FAR ON THIS LINE
  209.     TAD LQLINE    /ARE WE OVER THE LIMIT?
  210.     SPA CLA
  211.     JMP I LQPEOL    /OK, KEEP PRINTING ON CURRENT LINE
  212.     JMS LQCRLF    /THAT'S IT, OUTPUT CR/LF
  213.     JMP I LQPEOL
  214.  
  215. LQCRLF,    0
  216.     DCA LQPX    /CLEAR CHARACTER COUNTER
  217.     TAD (15
  218.     DCA LQPCTM    /OUTPUT CR
  219.     JMS LQPNDX
  220.     TAD (12
  221.     DCA LQPCTM    /OUTPUT LF
  222.     JMS LQPNDX
  223.     JMP I LQCRLF
  224.  
  225.  
  226. /SPECIAL CHARACTER CHECKING
  227. LQPSPC,    TAD (40-32)    /CONTROL Z?
  228.     SNA
  229.     JMP I LQPDCX    /TAKE EOF RETURN IF SO
  230.  
  231.     TAD (32-15)    /CARRIAGE RETURN?
  232.     SNA
  233.     JMP LQPCR    /JUMP IF SO
  234.  
  235.     IAC        /FORM FEED?
  236.     SNA
  237.     JMP LQPFF    /JUMP IF SO
  238.  
  239.     IAC
  240.     IAC        /LINE FEED?
  241.     SNA
  242.     JMP LQPLF    /JUMP IF SO
  243.  
  244.     IAC        /TAB?
  245.     SNA
  246.     JMP LQPTB
  247.  
  248.     TAD (11
  249.     JMP LQPDC1    /AND PRINT IT
  250.  
  251. LQPTB,    TAD LQPX    /DO TAB
  252.     AND (7        /8 COLUMNS PER TAB
  253.     TAD (-10    /SUBTRACT 8
  254.     DCA CRCNTR    /MAKE IT A COUNTER
  255. LQPTB1,    TAD K40
  256.     DCA LQPCTM
  257.     ISZ LQPX    /BUMP CHAR COUNTER
  258.     JMS LQPNDX    /PRINT A SPACE
  259.     ISZ CRCNTR
  260.     JMP LQPTB1    /KEEP GOING ROUND
  261.     JMP LQPDCR    /EXIT
  262. LQPCR,    DCA LQPX    /CLEAR CHAR COUNTER
  263.     TAD (15
  264.     JMP LQPDC1    /OUTPUT A CR
  265.  
  266. LQPLF,    ISZ LQPDY    /BUMP LINE COUNTER
  267.     TAD LQPDY    /CHECK FOR NEXT PAGE
  268.     TAD LQPAGE
  269.     SMA CLA
  270. IFNZRO AUTOFF < JMP LQPFF >    / Auto page break
  271. IFZERO AUTOFF < DCA LQPDY >    / No auto page break
  272.     TAD (12
  273.     JMP LQPDC1    /OUTPUT A LF
  274.  
  275. LQPFF,    DCA LQPDY    /CLEAR LINE COUNTER
  276.     TAD (14        /DO FORM FEED
  277.     JMP LQPDC1    /DO PAGE EJECT NOW
  278.  
  279. LQPX,    0
  280. CRCNTR,    0
  281. LQPDY,    0
  282. LQPCTM,    0
  283. LQPAGE,    -102        /-NUMBER OF LINES PER PAGE
  284. LQLINE,    -205        /-NUMBER OF CHARACTERS PER LINE
  285. K40,    0040        /EFFECTIVE NOP
  286.  
  287.