home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.update.uu.se
/
ftp.update.uu.se.2014.03.zip
/
ftp.update.uu.se
/
pub
/
pdp8
/
os278-src.tar.Z
/
os278-src.tar
/
cclmsg.ma
< prev
next >
Wrap
Text File
|
1992-09-18
|
3KB
|
188 lines
/CCLMSG CCL MESSAGE PRINTER
/
/
/
/COPYRIGHT (C) 1979 BY DIGITAL EQUIPMENT CORPORATION
/
/
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
/AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
/CORPORATION. DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
/
/THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
/UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
/(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
/SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
/
/DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
/OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
/DIGITAL.
/
/
/
/VERSION=V3A (D.H.)
/2 CCL MESSAGE PRINTER
.EXTERNAL TWAIT,BATCH
T=20
BATOUT=7400 /JMS HERE TO PRINT ON BATCH LOG
BATERR=7000 /JMP HERE TO ABORT BATCH
NAME1=23
NAME2=24
NAME3=25
NAME4=26
NAME5=27
.GLOBAL PRMESG,PRWD,PRNAME,PRINT,CRLF
.GLOBAL LEAVE
.RSECT CCLMSG
FIELD 1
PRMESG, 0
CLA
TAD I PRMESG
DCA TE2
JMS PRINT
TE2, HLT
LEAVE, JMS I (TWAIT
/V3D TCF
CIF CDF 0
TAD FATALFLG
SNA CLA
JMP I (7605
FATALFLG,0 /CIF CDF BATCH FIELD IF WANT TO ABORT
JMP I (BATERR
PRWD, 0
DCA T
TAD T
TTY212, RTR
RTR
RTR
JMS PCHAR
TAD T
JMS PCHAR
JMP I PRWD
PCHAR, 0
AND (77
TNOP, SNA
JMP I PCHAR /IGNORE NULLS
TAD (240
AND (77
TAD (240 /CAN'T USE 'TTY240'
JMS TYPE
JMP I PCHAR
TE,
PRNAME, 0
TAD NAME1
JMS PRWD
TAD NAME2
JMS PRWD
TAD NAME3
JMS PRWD
TAD NAME4
SNA CLA
JMP I PRNAME
TAD (256
JMS PCHAR
TAD NAME4
JMS PRWD
/ TAD NAME5
/ SZA
/ JMS PRWD
JMP I PRNAME
TYPE, 0
/ SNA
/ JMP I TYPE /CAN REMOVE IF NEED ROOM
DCA TE2
JMS I (BATCH
JMP TTYOUT
DCA CIFB
CIFB, HLT /REPLACED BY CIF BATCH FIELD
TAD TE2
JMS I (BATOUT
TAD TE2
TAD (-"#
SZA CLA
JMP I TYPE
TAD CIFB
IAC /CONVERT CIF TO CIF CDF
DCA FATALFLG
JMP I TYPE
TTYOUT, TAD TE2
TAD (-"# /DON'T TYPE #'S
SNA CLA
JMP I TYPE
KRB //KEYBOARD CHECKING CHANGED FOR V4 (VT278)
AND K177
TAD MINUS3
SNA
JMP LEAVE
TAD (203-217
SNA CLA
JMP I TYPE
TAD TE2
TJUMP, TLS //CHANGED FOR V4:
TSF
JMP .-1
CLA
JMP I TYPE
K177, 177
MINUS3, -3
PRINT, 0
DCA CRLF /AC NON-0 MEANS DON'T CRLF
TAD I PRINT
ISZ PRINT
DCA TE
TAD CRLF
SPA CLA
TAD (TYPE-PRWD
TAD (PRWD
DCA PROUT
1$: TAD I TE
JMS I PROUT
TAD I TE
ISZ TE
AND (77
SZA CLA
JMP 1$
CLA IAC
AND CRLF
SNA CLA
JMS CRLF
JMP I PRINT
PROUT, PRWD
CRLF, 0
TAD (215
JMS TYPE
TAD TTY212
JMS TYPE
JMP I CRLF
PAGE