home *** CD-ROM | disk | FTP | other *** search
/ ftp.ncftp.com / ftp.ncftp.com.zip / ftp.ncftp.com / ncftp / older_versions / ncftp-3.2.2-src.tar.bz2 / ncftp-3.2.2-src.tar / ncftp-3.2.2 / configure.in < prev    next >
Text File  |  2008-08-18  |  8KB  |  268 lines
  1. dnl Process this file with autoconf to produce a configure script.
  2. dnl
  3. AC_INIT(ncftp/main.c)
  4. AC_PREREQ(2.13)
  5. AC_CONFIG_HEADER(config.h)
  6. wi_ARG_DISABLE_CCDV
  7. AC_ARG_WITH(curses,[  --without-curses        do not try to find and use the curses library],nc_cv_curses=$withval,nc_cv_curses=yes)
  8. wi_ARG_ENABLE_DEBUG
  9. AC_ARG_WITH(ncurses,[  --without-ncurses       do not try to find and use the ncurses library],nc_cv_ncurses=$withval,nc_cv_ncurses=yes)
  10. wi_ARG_DISABLE_PRECOMP
  11. dnl AC_ARG_WITH(readline,[  --without-readline      do not try to find and use the readline library],nc_cv_readline=$withval,nc_cv_readline=yes)
  12. wi_ARG_WITH_SOCKS5
  13. wi_ARG_DISABLE_MACOSX_UNIVERSAL
  14.  
  15.  
  16.  
  17. dnl ---------------------------------------------------------------------------
  18. dnl Environment and compiler settings.
  19. dnl ---------------------------------------------------------------------------
  20. dnl
  21. wi_ENV_VAR_MESSAGES
  22. wi_OS_VAR
  23.  
  24. case "$os" in
  25.     linux)
  26.         OS="linux-$arch-$libc"
  27.         ;;
  28. esac
  29.  
  30. if test -f sh/install-sh ; then chmod 755 sh/*.sh sh/config.* sh/install-sh ; fi
  31. AC_CONFIG_AUX_DIR([sh])
  32. AC_PROG_CC
  33. wi_CC_PRECOMP
  34. wi_REQUEST_NO_Y2K_WARNINGS
  35. wi_CFLAGS_LFS
  36. wi_CFLAGS_REENTRANT
  37. wi_MACOSX_UNIVERSAL_CFLAGS
  38. wi_SFLAG
  39. AC_OBJEXT
  40. AC_EXEEXT
  41. wi_DEFINE_UNAME
  42. wi_EXTRA_SYSV_SUNOS_DIRS    dnl    For better curses library on SunOS 4
  43. if test "${prefix-NONE}" = "NONE" ; then
  44.     AC_DEFINE_UNQUOTED(PREFIX_BINDIR, "/usr/local/bin")
  45. else
  46.     AC_DEFINE_UNQUOTED(PREFIX_BINDIR, "$prefix/bin")
  47. fi
  48.  
  49.  
  50.  
  51. dnl ---------------------------------------------------------------------------
  52. dnl Checks for header files.
  53. dnl ---------------------------------------------------------------------------
  54. dnl
  55. AC_HEADER_STDC
  56. dnl Readline headers #ifdefs for string.h, sio needs strings.h for AIX
  57. AC_CHECK_HEADERS(arpa/nameser.h gnu/libc-version.h locale.h net/errno.h nserve.h resolv.h sgtty.h string.h strings.h sys/id.h sys/ioctl.h syslog.h sys/socket.h sys/time.h sys/types.h sys/utsname.h sys/systeminfo.h termio.h termios.h time.h utime.h unistd.h gnu/libc-version.h)
  58. AC_TIME_WITH_SYS_TIME
  59. dnl    # sio
  60. wi_UNIX_DOMAIN_SOCKETS
  61. SIO_OBJS_U=''
  62. SIO_SOBJS_U=''
  63. if test "$wi_cv_unix_domain_sockets" = yes ; then
  64.     SIO_OBJS_U='$(OBJS_U) '
  65.     SIO_SOBJS_U='$(SOBJS_U) '
  66. fi
  67. AC_SUBST(SIO_OBJS_U)
  68. AC_SUBST(SIO_SOBJS_U)
  69. dnl    # sio
  70.  
  71.  
  72.  
  73. dnl ---------------------------------------------------------------------------
  74. dnl Checks for libraries.
  75. dnl ---------------------------------------------------------------------------
  76. dnl
  77. wi_NET_LIBS
  78. wi_LIB_SOCKS5
  79.  
  80. LIBCURSES=''
  81. if test "$nc_cv_curses" = yes ; then
  82.     wi_LIB_CURSES
  83. fi
  84. dnl if test "$nc_cv_readline" = yes ; then
  85. dnl     wi_LIB_READLINE
  86. dnl fi
  87.  
  88.  
  89.  
  90. dnl ---------------------------------------------------------------------------
  91. dnl Checks for typedefs, structures, and compiler characteristics.
  92. dnl ---------------------------------------------------------------------------
  93. dnl
  94. AC_C_CONST
  95. AC_TYPE_SIZE_T
  96. AC_TYPE_OFF_T
  97. AC_TYPE_MODE_T
  98. AC_TYPE_PID_T
  99. AC_TYPE_UID_T
  100. wi_VOID_MAIN_RETURN_TYPE
  101. wi_USE_LONG_LONG
  102. wi_STRUCT_TIMEVAL_FIELD_TYPES
  103. wi_UNISTD_FUNC_PARAM_TYPES
  104. wi_FUNC_SELECT_ARGTYPES
  105. wi_STRUCT_STAT64
  106. wi_TYPE_SIG_ATOMIC_T
  107. wi_GETOPT
  108. wi__RES_DEFDNAME    dnl                # sio
  109. wi_STRUCT_CMSGHDR    dnl                # sio
  110. wi_MSGHDR_CONTROL    dnl                # sio
  111. wi_MSGHDR_ACCRIGHTS    dnl                # sio
  112. wi_HEADER_SYS_SELECT_H    dnl                # sio
  113.  
  114.  
  115.  
  116. dnl ---------------------------------------------------------------------------
  117. dnl Checks for library functions.
  118. dnl ---------------------------------------------------------------------------
  119. dnl
  120. wi_FUNC_GETCWD
  121. AC_CHECK_FUNCS(fstat64 getdomainname gethostname getpass getpassphrase gnu_get_libc_release gnu_get_libc_version inet_aton inet_ntop llseek lseek64 lstat64 memmove mktime open64 pathconf readlink res_init setlocale setpgid setpgrp setsid setvbuf sigaction sigsetjmp stat64 strcasecmp strcoll strdup strerror strncoll strstr strtoq symlink sysconf sysctl sysinfo syslog tcgetattr uname waitpid)
  122. AC_CHECK_FUNCS(gethostbyaddr_r gethostbyname_r gethostbyname2_r getlogin_r getpwnam_r _posix_getpwnam_r getpwuid_r _posix_getpwuid_r getservbyname_r getservbyport_r gmtime_r localtime_r readdir_r)
  123. wi_SNPRINTF
  124. wi_FUNC_SIGSETJMP
  125. wi_FUNC_SETPGRP
  126. wi_FUNC_SETVBUF
  127. AC_FUNC_ALLOCA    dnl Only needed for Linux, and for one function in Sio.
  128. wi_CURSES_FEATURES
  129. if test "x$LIBCURSES" = "x" ; then
  130.     VIS_DPROGS="# ../bin/ncftpbookmarks${EXEEXT}"
  131. else
  132.     VIS_DPROGS="../bin/ncftpbookmarks${EXEEXT}"
  133. fi
  134.  
  135.  
  136.  
  137. dnl ---------------------------------------------------------------------------
  138. dnl Checks for system characteristics.
  139. dnl ---------------------------------------------------------------------------
  140. dnl
  141. AC_SYS_LONG_FILE_NAMES
  142. AC_PROG_MAKE_SET
  143. wi_PROG_TAR
  144. wi_CREATE_TAR_FILES
  145. wi_PROG_RANLIB
  146. wi_PROG_AR
  147. AC_PROG_INSTALL
  148. wi_PROG_CCDV
  149. wi_MANDIR
  150. wi_SUBST_LONGEST_INT_HEADER([libncftp/ncftp.h])
  151. wi_SUBST_STAT_HEADER([libncftp/ncftp.h])
  152. wi_REMOVE_UNKNOWN_PREPROCESSING_DIRECTIVES_FROM_FILE([libncftp/ncftp.h])
  153. LIBSET='$(LIB)'
  154. Z30='#'
  155. case "$HOME" in
  156.     *lcompile*)
  157.         ;;
  158.     *)
  159.         if test -x /usr/local/bin/incrementor ; then
  160.             Z30='    -@/usr/local/bin/incrementor -b -f version.c -f version.o'
  161.         fi
  162.         ;;
  163. esac
  164. wi_RESOLVE_PATH([$srcdir], MAINDIR)
  165. wi_RESOLVE_PATH([$MAINDIR/libncftp/ncftp.h], [libncftp_h])
  166. wi_DIRNAME(libncftp_h)
  167. wi_RESOLVE_PATH([$MAINDIR/sio/sio.h], [sio_h])
  168. wi_DIRNAME(sio_h)
  169. wi_RESOLVE_PATH([$MAINDIR/Strn/Strn.h], [strn_h])
  170. wi_DIRNAME(strn_h)
  171. CPPFLAGS="-I${MAINDIR} -I${libncftp_h} -I${sio_h} -I${strn_h} $CPPFLAGS"
  172. LDFLAGS="-L${libncftp_h} -L${sio_h} -L${strn_h} $LDFLAGS"
  173. wi_BEAUTIFY_ENVIRONMENT_VARIABLES
  174.  
  175.  
  176.  
  177. dnl ---------------------------------------------------------------------------
  178. dnl Extra steps to work with precompiled headers.
  179. dnl ---------------------------------------------------------------------------
  180. dnl
  181. LIBNCFTP_PRECOMP="libncftp/pch.mk.none"
  182. SIO_PRECOMP="sio/pch.mk.none"
  183. if test "${wi_cv_cc_precomp}_${wi_cv_cc_precomp_type}" = "yes_gcc_gch_files" ; then
  184.     LIBNCFTP_PRECOMP="libncftp/pch.mk.gcc-gch"
  185.     SIO_PRECOMP="sio/pch.mk.gcc-gch"
  186. elif test "${wi_cv_cc_precomp}_${SYS}" = "yes_macosx" ; then
  187.     LIBNCFTP_PRECOMP="libncftp/pch.mk.$SYS"
  188.     SIO_PRECOMP="sio/pch.mk.$SYS"
  189. fi
  190. AC_SUBST_FILE(LIBNCFTP_PRECOMP)
  191. AC_SUBST_FILE(SIO_PRECOMP)
  192.  
  193.  
  194.  
  195. dnl ---------------------------------------------------------------------------
  196. dnl Version lookups for Makefile variables.
  197. dnl ---------------------------------------------------------------------------
  198. dnl
  199. changequote(<<, >>)dnl
  200. LIBNCFTP_VERSION=`sed -n '/kLibraryVersion/{
  201.     s/^[^0-9]*//
  202.     s/\ .*$//
  203.     p
  204.     q
  205. }' libncftp/ncftp.h`
  206.  
  207. NCFTP_VERSION=`sed -n '/gVersion\[\]/{
  208.     s/^[^0-9]*//
  209.     s/\/.*$//
  210.     p
  211.     q
  212. }' ncftp/version.c`
  213.  
  214. SIO_VERSION=`sed -n '/kSioVersion/{
  215.     s/^[^0-9]*//
  216.     s/\ .*$//
  217.     p
  218.     q
  219. }' sio/sio.h`
  220.  
  221. STRN_VERSION=`sed -n '/gStrnLibVersion\[\]/{
  222.     s/^[^0-9]*//
  223.     s/\".*$//
  224.     p
  225.     q
  226. }' Strn/Strncpy.c`
  227.  
  228. Z00="unknown_id"
  229. Z31=''
  230. if [ -x /sbin/md5 ] ; then
  231.     Z00=`hostname | tr '[A-Z]' '[a-z]' | /sbin/md5`
  232. elif [ -x /usr/bin/md5sum ] ; then
  233.     Z00=`hostname -f | tr '[A-Z]' '[a-z]' | /usr/bin/md5sum | cut -d ' ' -f1`
  234. fi
  235.  
  236. case "$Z00" in
  237.     'e85dfd19937dece65225d717f4cd5f22'|'816c501837158512dc4f606d58f4993b'|'9aa70fa2084f59bab13fe52bdfff65f4')
  238.         Z31='    scp -p "$(STGZFILE)" build@Src:src/ncftp/current/ ; mv ncftp-*-src.* /ztmp/'
  239.         ;;
  240.     
  241. esac
  242. changequote([, ])dnl
  243.  
  244. dnl ---------------------------------------------------------------------------
  245. dnl Create Makefiles and config.h files.
  246. dnl ---------------------------------------------------------------------------
  247. dnl
  248. wi_SUMMARIZE_COMPILER_FLAGS
  249. AC_SUBST(CC)
  250. AC_SUBST(CFLAGS)
  251. AC_SUBST(CPPFLAGS)
  252. AC_SUBST(LDFLAGS)
  253. AC_SUBST(LIBS)
  254. AC_SUBST(SFLAG)
  255. AC_SUBST(DEFS)
  256. AC_SUBST(MAKE)
  257. AC_SUBST(Z30)
  258. AC_SUBST(Z31)
  259. AC_SUBST(LIBSET)
  260. AC_SUBST(MAINDIR)
  261. AC_SUBST(NCFTP_VERSION)
  262. AC_SUBST(LIBNCFTP_VERSION)
  263. AC_SUBST(SIO_VERSION)
  264. AC_SUBST(STRN_VERSION)
  265. AC_SUBST(VIS_DPROGS)
  266. AC_OUTPUT_COMMANDS([/bin/rm -f ./ncftp/readln.o])
  267. AC_OUTPUT([Makefile Makefile.bin ncftp/Makefile libncftp/Makefile Strn/Makefile sio/Makefile sh_util/Makefile vis/Makefile])
  268.