home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
The First Hungarian Family
/
The_First_Hungarian_Family_CD-ROM.bin
/
internet
/
offlread
/
1stbbs
/
sparky.bbs
/
SPARKY.SCR
< prev
Wrap
Text File
|
1995-07-20
|
4KB
|
192 lines
' ┌─────────────────────────────────┐
' │ Qmail mail script for 1stReader │
' │ July 16, 1995 │
' └─────────────────────────────────┘
IF SCR_CALL THEN GOTO SETUP
KILL @API$(28)@API$(10).DL
NEWFILES ON
:SETUP
TIMEOUT 30
SET_API$(142)="PCBOARD"
LOOKFOR "Esc" "X'1BX'1B"
LOOKFOR "correct? " "^M"
LOOKFOR "elp, More? " "N^M"
LOOKFOR ") to continue?" "^M"
LOOKFOR "ll new mail? (" "N^M"
LOOKFOR "<CHAT>" "Sorry, I'm on automatic using 1stReader^M"
REQ_FILE @API$(14)@API$(10).REQ
LOCKLINE 20 30
COMMENT "@DATE@ @TIME@ Connected with @BBSNAME@"
COMMENT "@DATE@ @TIME@ Opened capture file @BBSID@.CAP"
COMMENT "@DATE@ @TIME@ Logging in to system"
SET_API(83)=OFF
WAITFOR "Language #|=no change?|color|colour|graphics (|TSX-BBS" 40
SET_API(83)=ON
LOOKFOR "Esc" ""
IF FOUND=0 THEN GOTO FNAME
IF FOUND=3 THEN GOTO GRAPHICS
IF FOUND=4 THEN GOTO GRAPHICS
IF FOUND=5 THEN GOTO GRAPHICS
IF FOUND=6 THEN GOTO TSX
TRANSMIT "@LANGUAGE@^M"
WAITFOR "Do you want|color|colour" 20
IF FOUND=0 THEN GOTO FNAME
:GRAPHICS
TRANSMIT "@GRAPHICS@ Q NS^M"
:FNAME
WAITFOR "first name" 50
IF FOUND=0 THEN EXIT
TRANSMIT "@USER@^M"
LOOKFOR "(Enter)=yes? " "N^M"
WAITFOR "last name|password|new user?" 30
LOOKFOR "correct? " ""
IF FOUND=1 THEN GOTO LOGIN
IF FOUND=2 THEN GOTO LOGIN1
IF FOUND=3 THEN GOTO NEWUSER
GOTO COMMAND
:NEWUSER
COMMENT "@DATE@ @TIME@ New user login"
LOOKFOR "(Enter)=yes? " ""
LOOKFOR ") to continue?" ""
IF NOT SWITCH 1 THEN HELP 198
TRANSMIT "^M"
WAITFOR ")=yes?" 30
TRANSMIT "Y^M"
WAITFOR "please!)?" 30
TRANSMIT "@PASSWORD@^M"
WAITFOR "verify?" 30
TRANSMIT "@PASSWORD@^M"
TERMINAL
LOOKFOR "(Enter)=yes? " "N^M"
LOOKFOR ") to continue?" "^M"
WAITFOR "Command?"
GOTO COMMAND
:LOGIN
TRANSMIT "^M"
:LOGIN1
COMMENT "@DATE@ @TIME@ Transmitting password"
TRANSMIT "@PASSWORD@^M"
IF SCR_CALL THEN GOTO SCR_CONT
WAITFOR "word has expired|Command?"
IF FOUND=2 THEN GOTO COMMAND
NEW_PASSWORD
SET_PASSWORD
PROMPT "Your password is now set to @PASSWORD@"
TRANSMIT "@PASSWORD@^M"
WAITFOR "to verify"
TRANSMIT "@PASSWORD@^M"
WAITFOR "Command?"
:COMMAND
TIMEOUT 60
IF SCR_SERVER THEN GOTO TELNET
IF SCR_MAIL THEN CALL PCB-DL.SCR
:SCR_CONT
IF NOT SCR_CALL THEN GOTO JOINCONF
TERMINAL
EXIT
:JOINCONF
COMMENT "@DATE@ @TIME@ Joining conference #@CONFERENCE@"
TRANSMIT "J @CONFERENCE@ Q - 1stReader #@API$(121)^M"
WAITFOR "=yes?|Command" 3
IF FOUND=1 THEN TRANSMIT "N^M"
:DOOR
COMMENT "@DATE@ @TIME@ Opening Qmail Door"
DOORNAME "QMAIL4"
TRANSMIT "@QMAIL@ PROMPTS^M"
LOOKFOR "<AUTOSTART>" "X'1B"
WAITFOR "Qmail Command?|<KEYFILE>"
LOOKFOR "<AUTOSTART>" ""
IF FOUND=1 THEN GOTO KEYWORDS
COMMAND "@DATE@ @TIME@ Downloading your keyfile"
DOWNLOAD @API$(28)1ST.KEY
WAITFOR "Qmail Command?" 20
:KEYWORDS
IF NOT KEYWORDS THEN GOTO REPLIES
TRANSMIT "K^M"
COMMENT "@DATE@ @TIME@ Transmitting keywords"
WAITFOR "<KEYUP>"
UPLOAD @API$(14)KEYWORDS
WAITFOR "Qmail Command?" 20
:REPLIES
IF NOT REPLIES THEN GOTO DOWNLOAD
TRANSMIT "U@API$(48)^M"
COMMENT "@DATE@ @TIME@ Uploading replies"
WAITFOR "<UPLOAD>"
UPLOAD @REPDIR@@BBSID@.REP
WAITFOR "DELETE PACKET>|DELETE NO>|BAD UPLD>|MESSAGES INSERTED>|UP ERROR>" 180
IF FOUND=1 THEN GOTO GOODUPLD
IF FOUND=4 THEN GOTO GOODUPLD
GOTO DOWNLOAD
:GOODUPLD
COMMENT "@DATE@ @TIME@ Deleting @BBSID@.REP"
KILL @REPDIR@@BBSID@.REP
COUNT REP
:DOWNLOAD
WAITFOR "Qmail Command?" 20
IF SCR_REPLY THEN GOTO GOODBYE
TRANSMIT "D@API$(48);Y;G^M"
:REPEAT
COMMENT "@DATE@ @TIME@ Scanning for new messages"
WAITFOR "<DOWNLOAD>|<NO TRANSFER>|<NO TIME>"
IF FOUND=1 THEN GOTO GETMAIL
GOTO GOODBYE
:GETMAIL
DOWNLOAD @FILEDIR@@BBSID@.QWK
WAITFOR "DL SUCCESS>|DL ERROR>"
IF FOUND=2 THEN GOTO EXIT
COUNT QWK
WAITFOR "<REPEAT>|Command?" 20
IF FOUND=1 THEN GOTO REPEAT
:GOODBYE
PAUSE 2
COMMENT "@DATE@ @TIME@ Transmitting GOODBYE command"
TRANSMIT "G^M"
:EXIT
IF SCR_TELNET THEN GOTO DONE
COMMENT "@DATE@ @TIME@ Waiting for disconnect"
LOOKFOR "<GOODBYE>" "^M"
WAITFOR "<HANGUP>" 20
PAUSE 2
:DONE
CAPTURE OFF
EXIT
:TSX
SET_API$(142)="TSX"
LOOKFOR "Esc" ""
LOOKFOR "correct? " ""
LOOKFOR "elp, More? " ""
LOOKFOR ") to continue?" ""
LOOKFOR "ll new mail? (" ""
LOOKFOR "<CHAT>" ""
RUN "TSX.SCR"
EXIT