home *** CD-ROM | disk | FTP | other *** search
/ Simtel MSDOS 1992 June / SIMTEL_0692.cdr / msdos / procomm / aaapcp31.arc / AAAPCP.ASP next >
Encoding:
Text File  |  1988-11-13  |  14.6 KB  |  416 lines
  1. ; docs?  See Bottom of file.
  2. ; NOTE:  [IR#000]'s are found throughout this file.  They are used
  3. ;        by the ACONFIG.COM configuration/optimizer.  DO NOT ALTER.
  4.  IF LINKED
  5.    MESSAGE"AAAPCP: File MUST NOT be linked with dialing directory."
  6.    MESSAGE"        Issue ALT-F5 A <ENTER> to use AAAPCP+."
  7.    HANGUP
  8.    EXIT
  9.  ENDIF
  10.  STRCPY S3"12"                   ;REPLACE w/ /baud
  11.  STRCPY S8",abc00300,abcd0300^m" ;REPLACE",id,pw^m"   [IR#001]
  12.  GOTO START:                     ;jump to start/restart
  13. C_DIAL:
  14.  FIND S9"Y"
  15.  IF FOUND                     ;  IF repeat flag is ON
  16.    ATSAY 00 23 N0" » Press SPACE to abort REPEAT « "
  17.    SET MENUMODE ON            ;   KEEP KEYSTROKES FOR ABORT OPTION
  18.  ENDIF
  19.  SWITCH S0                    ;switch user request (A/P/AREA)
  20.   CASE"A"                     ; case ADDRESS
  21.    STRCPY S7 "c "             ;  setup ADDRESS transmit string
  22.    STRCAT S7 S2               ;   address
  23.    STRCAT S7 S8               ;   id/pw
  24.    FIND S2"PURSUIT"           ;  if (SEND=PURSUIT BBS)
  25.    IF FOUND
  26.     STRCPY S7 "c "            ;   setup ADDRESS transmit string
  27.     STRCAT S7 S2              ;    address
  28.     STRCAT S7 "^m"
  29.    ENDIF 
  30.    GOSUB PCPADD               ;  gosub ADDRESS login routine
  31.   ENDCASE
  32.   DEFAULT                     ; case NON-ADDRESS (PORT)
  33.    STRCPY S7 "c d/"           ;  setup PORT transmit string
  34.    STRCAT S7 S2               ;   city
  35.    STRCAT S7 "/"
  36.    STRCAT S7 S4               ;   baud
  37.    STRCAT S7 S8               ;   id/pw
  38.    GOSUB PCP_PORT             ;  gosub PORT login routine
  39.   ENDCASE
  40.  ENDSWITCH
  41.  RETURN
  42. ;
  43. PCP_PORT:                     ;ROUTINE: c d/xxxxx/bd,id,pw
  44.  IF NOT CONNECTED  ;if(carrier lost)
  45.   MESSAGE"^MAAAPCP: Carrier Lost.  Redialing..."
  46.   GOSUB DIAL_UP
  47.  ENDIF
  48.  IF HITKEY                    ; IF KEY PRESSED(ABORT=Y)
  49.    KFLUSH
  50.    SET MENUMODE OFF           ;  ALLOW keys to go to output again
  51.    STRCPY S9"A"               ;  FLAG REPEAT ABORT
  52.  ENDIF
  53.  TRANSMIT S7                  ; TRANSMIT request
  54.  RGET S5 80 9                 ; Get line #1
  55.  RGET S1 80 9                 ; Get line #2
  56.  IF NOT SUCCESS               ; Check to make sure Telenet is alive
  57.    ALARM
  58.    MESSAGE"AAAPCP: Telenet Appears Frozen.  Disconnecting..."
  59.    MESSAGE"AAAPCP: Aborting Request to prevent loop."
  60.    SET MENUMODE OFF           ;  turn on keyboard
  61.    HANGUP
  62.    GOSUB DIAL_UP              ;  dial back into telenet
  63.    STRCPY S1"Request ABORTED due to "
  64.    STRCPY S5"Telenet Port Freeze."
  65.    RETURN
  66.  ENDIF
  67.  RGET S5                      ; Get line #3
  68.  FIND S5"CONNECT"             ; Look for connection
  69.  IF NOT FOUND                 ; IF NO CONNECTION
  70.   FIND S9"Y"
  71.   IF FOUND                    ;  IF repeat flag is ON
  72.    GOTO PCP_PORT              ;   GO BACK and try again (infinite loop)
  73.   ENDIF
  74.  ENDIF
  75.  FIND S5"CONN"                ; IF CONNECTION
  76.  IF FOUND
  77.   ALARM                       ;  sound alarm
  78.   EXIT                        ;  exit to term mode
  79.  ENDIF
  80.  RETURN
  81. ;
  82. PCPADD:                       ;ROUTINE: c xxxxx,id,pw
  83.  IF NOT CONNECTED ;if(carrier lost)
  84.   MESSAGE"^MAAAPCP: Carrier Lost.  Redialing..."
  85.   GOSUB DIAL_UP
  86.  ENDIF
  87.  IF HITKEY                    ; IF KEY PRESSED(ABORT=Y)
  88.    KFLUSH
  89.    SET MENUMODE OFF           ;  ALLOW keys to go to output again
  90.    STRCPY S9"A"               ;  FLAG REPEAT ABORT
  91.  ENDIF
  92.  TRANSMIT S7                  ; TRANSMIT request
  93.  RGET S5 80 9                 ; Get line #1
  94.  RGET S1 80 9                 ; Get line #2
  95.  IF NOT SUCCESS               ; Check to make sure Telenet is alive
  96.    ALARM
  97.    MESSAGE"AAAPCP: Telenet Appears Frozen.  Disconnecting..."
  98.    MESSAGE"AAAPCP: Aborting Request to prevent loop."
  99.    SET MENUMODE OFF           ;  turn on keyboard
  100.    HANGUP
  101.    GOSUB DIAL_UP              ;  dial back into telenet
  102.    STRCPY S1"Request ABORTED due to "
  103.    STRCPY S5"Telenet Port Freeze."
  104.    RETURN
  105.  ENDIF
  106.  RGET S5                      ; Get line #3
  107.  FIND S5"CONNECT"             ; Look for connection
  108.  IF NOT FOUND                 ; IF NO CONNECTION
  109.   FIND S9"Y"
  110.   IF FOUND                    ;  IF repeat flag is ON
  111.    GOTO PCP_PORT              ;   GO BACK and try again (infinite loop)
  112.   ENDIF
  113.  ENDIF
  114.  FIND S5"CONN"                ; IF CONNECTION
  115.  IF FOUND
  116.   ALARM                       ;  sound alarm
  117.   EXIT                        ;  exit to term mode
  118.  ENDIF
  119.  RETURN
  120. ;
  121. START:                        ;STARTUP
  122.  STRCPY S1"Restart/Connected" ; assume restart
  123.  STRCPY S2" "                 ; set last request area to nothing
  124.  INIT N0 14                   ; Color bright yellow
  125.  INIT N1 1                    ; Color dark blue
  126.  INIT N2 2                    ; Color green
  127.  INIT N3 3                    ; Color cyan
  128.  INIT N4 4                    ; Color red
  129.  INIT N5 5                    ; Color magenta
  130.  INIT N6 6                    ; Color brown
  131.  INIT N7 7         ;unused    ; Color white
  132.  INIT N8 8         ;unused    ; Color grey
  133.  INIT N9 9         ;unused    ; Color light blue
  134. MENU_A:
  135.  IF NOT CONNECTED             ; IF NO CARRIER
  136.   CLEAR                       ;  clear screen
  137.   GOSUB DIAL_UP               ;  GOSUB connect to telenet
  138.  ENDIF
  139.  CLEAR                        ; clear screen
  140.  SET DISPLAY OFF              ; turn incoming character display off
  141.  BOX 00 00 23 79 N1           ; draw box
  142.  ATSAY 01 02 N4"Cmd  ST Cty Comments"
  143.  ATSAY 00 28 N1"╣ AAAPCP+ v3.1 by Flurb ╠"
  144.  ATSAY 01 55 N4"MultiComm 815/282-1494"
  145.  ATSAY 02 02 N2"201  NJ New[         ];    312  IL Chi[1815     ];   612  MN Min[         ]:"
  146.  ATSAY 03 02 N2"202  DC Was[301;703*7];    313  MI Det[         ];   617  MA Bos[         ];"
  147.  ATSAY 04 02 N2"203  CT Har[         ].    314  MO SLo[1618     ];   619  CA SaD[         ]."
  148.  ATSAY 05 02 N2"206  WA Sea[         ];    404  GA Atl[         ];   713  TX Hou[         ];"
  149.  ATSAY 06 02 N2"212  NY NYo[1718     ];    408  CA SJo[         ].   714  CA SAn[         ]."
  150.  ATSAY 07 02 N2"213  CA LAn[         ];    414  WI Mil[         ].   7142 CA Col[         ]."
  151.  ATSAY 08 02 N2"214  TX Dal[817   *10];    415  CA SFa[         ];   801  UT SLC[         ]:"
  152.  ATSAY 09 02 N2"215  PA Phi[         ];    4152 CA Oak[         ].   813  FL Tam[         ];"
  153.  ATSAY 10 02 N2"216  OH Clv[         ]:    4153 CA PAl[         ].   816  MO KCi[1913     ];"
  154.  ATSAY 11 02 N2"303  CO Den[         ];    503  OR Por[         ]:   818  CA Gle[         ]."
  155.  ATSAY 12 02 N2"305  FL Mia[         ];    602  AZ Pho[         ]:   919  NC RTP[         ]:"
  156.  ATSAY 13 00 N1"╠═══════════════════════════════════════"
  157.  ATSAY 13 40 N1"═══════════════════════════════════════╣"
  158.  ATSAY 14 02 N6"A:   plink,pursuit,execpc, A    C aaaaaaa,id,pw      .      12"
  159.  ATSAY 15 02 N6"     portal,31256.06       P    C D/ppppp/bb,id,pw   :    3 12"
  160.  ATSAY 16 02 N6"*7   Dial 7 Digits         X    Exit/Logoff          ;    3 12 24"
  161.  ATSAY 17 00 N1"╠═══════════════════════════════════════"
  162.  ATSAY 17 40 N1"═══════════════════════════════════════╣"
  163.  FATSAY 18 02 N2"Last Port Request:  %s,%s/%s" S0 S2 S4
  164.  FATSAY 19 02 N3"Status Message   :  %-.26s%-.26s" S1 S5
  165.  FATSAY 20 02 N4"Area/A/P/X<ENTER>:  %s" S6
  166.  FATSAY 21 02 N5"Baud    (3,12,24):  %s" S3
  167.  ATSAY 22 02 N6"Repeat  (Def=n)  :"
  168. ;
  169. GET_AREA:                     ;get user request for destination
  170.  ATGET 20 22 N4 4 S0          ; Get S0 AREA
  171.  SWITCH S0
  172.   CASE "_NULL"                ; CASE: <ENTER>
  173.    STRCPY S0 S6               ;  copy last AREA into AREA
  174.   ENDCASE
  175.   CASE "X"                    ; CASE: exit
  176.    CLEAR
  177.    MESSAGE"AAAPCP: Disconnecting Telenet"
  178.    HANGUP
  179.    GOSUB INFBOX               ;  gosub aaapcp info box routine
  180.    MESSAGE "^M"               ;  move cursor below box
  181.    EXIT                       ;  exit to term
  182.   ENDCASE
  183.  ENDSWITCH
  184. ;
  185.  FATSAY 20 22 N4"%-55s" S0    ; display AREA & Clear AREA error message
  186.  STRCPY S6 S0                 ; set new last AREA
  187. ;
  188.  SWITCH S0                    ; switch AREA
  189.   CASE"201"
  190.    STRCPY S2"njnew"
  191.   ENDCASE
  192.   CASE"202"
  193.    STRCPY S2"dcwas"
  194.   ENDCASE
  195.   CASE"203"
  196.    STRCPY S2"cthar"
  197.   ENDCASE
  198.   CASE"206"
  199.    STRCPY S2"wasea"
  200.   ENDCASE
  201.   CASE"212"
  202.    STRCPY S2"nynyo"
  203.   ENDCASE
  204.   CASE"213"
  205.    STRCPY S2"calan"
  206.   ENDCASE
  207.   CASE"214"
  208.    STRCPY S2"txdal"
  209.   ENDCASE
  210.   CASE"215"
  211.    STRCPY S2"paphi"
  212.   ENDCASE
  213.   CASE"216"
  214.    STRCPY S2"ohclv"
  215.   ENDCASE
  216.   CASE"303"
  217.    STRCPY S2"coden"
  218.   ENDCASE
  219.   CASE"305"
  220.    STRCPY S2"flmia"
  221.   ENDCASE
  222.   CASE"312"
  223.    STRCPY S2"ilchi"
  224.   ENDCASE
  225.   CASE"313"
  226.    STRCPY S2"midet"
  227.   ENDCASE
  228.   CASE"314"
  229.    STRCPY S2"moslo"
  230.   ENDCASE
  231.   CASE"404"
  232.    STRCPY S2"gaatl"
  233.   ENDCASE
  234.   CASE"408"
  235.    STRCPY S2"casjo"
  236.   ENDCASE
  237.   CASE"414"
  238.    STRCPY S2"wimil"
  239.   ENDCASE
  240.   CASE"415"
  241.    STRCPY S2"casfa"
  242.   ENDCASE
  243.   CASE"4152"
  244.    STRCPY S2"caoak"
  245.   ENDCASE
  246.   CASE"4153"
  247.    STRCPY S2"capal"
  248.   ENDCASE
  249.   CASE"503"
  250.    STRCPY S2"orpor"
  251.   ENDCASE
  252.   CASE"602"
  253.    STRCPY S2"azpho"
  254.   ENDCASE
  255.   CASE"612"
  256.    STRCPY S2"mnmin"
  257.   ENDCASE
  258.   CASE"617"
  259.    STRCPY S2"mabos"
  260.   ENDCASE
  261.   CASE"619"
  262.    STRCPY S2"casad"
  263.   ENDCASE
  264.   CASE"713"
  265.    STRCPY S2"txhou"
  266.   ENDCASE
  267.   CASE"714"
  268.    STRCPY S2"casan"
  269.   ENDCASE
  270.   CASE"7142"
  271.    STRCPY S2"cacol"
  272.   ENDCASE
  273.   CASE"801"
  274.    STRCPY S2"utslc"
  275.   ENDCASE
  276.   CASE"813"
  277.    STRCPY S2"fltam"
  278.   ENDCASE
  279.   CASE"816"
  280.    STRCPY S2"mokci"
  281.   ENDCASE
  282.   CASE"818"
  283.    STRCPY S2"cagle"
  284.   ENDCASE
  285.   CASE"919"
  286.    STRCPY S2"ncrtp"
  287.   ENDCASE
  288.   CASE"A"                     ;  CASE: A)ddress
  289.    STRCPY S4" "               ;   clear transmit baud
  290.    ATSAY 21 22 N5"N/A"        ;   display the fact that baud is N/A
  291.    ATSAY 20 22 N4"Manual Address?  [__________]"
  292.    ATGET 20 40 N4 10 S2       ;   get user address to transmit
  293.    GOTO NO_BAUD               ;   skip past baud input code
  294.   ENDCASE
  295.   CASE"P"                     ;  CASE: P)ort
  296.    ATSAY 20 22 N4"Manual Port Name? >_____<"
  297.    ATGET 20 41 N4 5 S2        ;   get user port city code
  298.   ENDCASE
  299.   DEFAULT                     ;  CASE: ERROR (ie all others)
  300.    ATSAY 20 40 N4"Please Enter Area, A, P, or X"
  301.    SOUND 612 12               ;   sound an error noise
  302.    GOTO GET_AREA              ;   go back and let user try again
  303.   ENDCASE
  304.  ENDSWITCH
  305. ;
  306. GET_BAUD:                     ;GET user baud request or <ENTER>
  307.  ATGET 21 22 N5 2 S4          ; Get Baud input
  308.  ATSAY 21 40 000"                           " ;Clear Error
  309.  SWITCH S4                    ; SWITCH BAUD
  310.   CASE"3"                     ;  CASE: 3
  311.   ENDCASE
  312.   CASE"12"                    ;  CASE: 12
  313.   ENDCASE
  314.   CASE"24"                    ;  CASE: 24
  315.   ENDCASE
  316.   CASE"_NULL"                 ;  CASE: <ENTER>
  317.    STRCPY S4 S3               ;   copy last/default into current BAUD
  318.    FATSAY 21 22 N5"%s" S4     ;   display BAUD
  319.   ENDCASE
  320.   DEFAULT                     ;  CASE: NOT 3, 12, 24, or <ENTER>
  321.    ATSAY 21 40 N5"Please Enter 3, 12, or 24"
  322.    SOUND 612 12               ;   sound error noise
  323.    GOTO GET_BAUD              ;   go let user try to enter BAUD again
  324.   ENDCASE
  325.  ENDSWITCH
  326.  STRCPY S3 S4                 ; set LAST baud to CURRENT baud
  327. ;
  328. NO_BAUD:                      ;LABEL to jump to when BAUD is N/A
  329.  ATGET 22 22 N6 1 S9          ; get repeat y/N
  330.  SET DISPLAY ON               ; turn incoming character display on again
  331.  CLEAR                        ; clear screen
  332.  IF NOT CONNECTED             ; IF CARRIER LOST
  333.   GOSUB C_DIAL                ;  GOSUB Routine to switch request type
  334.  ELSE                         ; ELSE
  335.   TRANSMIT"^m" ;clear input/scan for twits
  336.   WAITFOR"?" 2                ;  handshake with telenet
  337.   IF NOT WAITFOR              ;  IF expected handshake not found
  338.    MESSAGE "^MAAAPCP: @ Not Found.  Attempting City Disconnect."
  339.    TRANSMIT "^M@^MD^M"        ;   TRANSMIT city disconnect string
  340.    PAUSE 1                    ;   pause 1 second
  341.    TRANSMIT "^M"              ;   handshake with telenet
  342.    WAITFOR"?" 3               ;   IF expected handshake not found
  343.    IF NOT WAITFOR
  344.     MESSAGE "^MAAAPCP: Attempt Failed:  Telenet Appears Frozen."
  345.     MESSAGE "AAAPCP: Disconnecting Telenet"
  346.     HANGUP                    ;    HANGUP and call back
  347.    ENDIF
  348.   ENDIF
  349.   GOSUB C_DIAL                ; GOSUB routine to switch request type
  350.  ENDIF
  351.  GOTO MENU_A                  ; GOTO menu, diplay response, & get next
  352. ;
  353. DIAL_UP:                      ;CONNECT TO TELENET
  354.  GOSUB INFBOX                 ; display aaapcp info box
  355.  SET DATABITS 8    ;REPLACE 7/8
  356.  SET BAUDRATE 2400 ;REPLACE baud   [IR#002]
  357.  SET PARITY NONE   ;REPLACE NONE/EVEN
  358.  MESSAGE"^J^MAAAPCP: Dialing Telenet..."
  359. L2:
  360.  TRANSMIT "ATDT965-0696^m"  ;REPLACE ACCESS #   [IR#003]
  361.  MLOAD"AAAPCP.KEY"          ;REPLACE MACRO file
  362.  SET TXPACE 0               ;REPLACE XMIT PACE
  363.  SET DUPLEX FULL            ;REPLACE DUPLEX
  364.  WAITFOR"CONNECT" 30        ;REPLACE the number of secounds of wait time
  365.  IF NOT WAITFOR               ; it didn't connect, assume busy
  366.   HANGUP
  367.   MESSAGE"^MAAAPCP: Busy. Redialing..."
  368.   PAUSE 2
  369.   GOTO L2                     ; go dial again
  370.  ENDIF
  371. ;
  372.  PAUSE 2
  373.  TRANSMIT"@~D~^m"           ; REPLACE with CORRECT handshake   [IR#004]
  374.  WAITFOR"=" 6                 ; Wait for 'TERMINAL=' prompt
  375.  IF NOT WAITFOR               ; IF handshake failed to wakeup Telenet
  376.   MESSAGE"AAAPCP: Telenet Not Responding to Handshake.  Redialing..."
  377.   MESSAGE"        If problem persists, see error message in docs."
  378.   HANGUP                      ;  hangup
  379.   PAUSE 1
  380.   GOTO L2                     ;   go dial again
  381.  ENDIF
  382.  TRANSMIT"A1^m"               ; REPLACE terminal type A1,D1
  383.  STRCPY S1"Initial Startup"
  384.  ALARM                        ; sound connection to telenet alarm
  385.  WAITFOR"@"                   ; Wait for Telenet prompt
  386.  RETURN
  387. ;
  388. INFBOX:                       ;DISPLAY INFO BOX
  389.  CLEAR
  390.  BOX 00 16 13 62 N1
  391.  ATSAY 00 24 N1"╣ AAAPCP+ for ProComm+ v1.1a+ ╠"
  392.  ATSAY 02 26 N0"If you find AAAPCP+ useful,"
  393.  ATSAY 03 26 N2"send $5.00 or any amount to:"
  394.  ATSAY 05 34 N5"Paul Johnson"
  395.  ATSAY 06 30 N6"401 South 2nd Street"
  396.  ATSAY 07 30 N4"Rockford, IL  61104"
  397.  ATSAY 09 28 N5"For the Latest Version:"
  398.  ATSAY 10 25 N6"Call MultiComm (815) 282-1494"
  399.  ATSAY 11 25 N4"or EXECPC   (via 'A' on menu)"
  400.  RETURN
  401. ;-----------------------------------------------------------------------
  402. ; AAAPCP+    v2.3+Written 06/15/88 by Flurb (No Public Release)
  403. ;            v3.0 Written 08/22/88 by Flurb
  404. ;                 Updated 0 /0 /88 by Flurb
  405. ;Registers:
  406. ; S0 - User Request [Area/A/P/X] for switching & display
  407. ; S1 - Current Status or Response from last request for display
  408. ; S2 - PCP city code, port code, or address being xmitted
  409. ; S3 - Last Baud Called or default
  410. ; S4 - BAUD RATE being xmitted
  411. ; S5 - used to pick up unwanted response lines
  412. ; S6 - Last Area Called
  413. ; S7 - C Space Request w/ ID/PW to be transmitted
  414. ; S8 - User account/pass being xmitted
  415. ; S9 - 'y' 'n' to repeat
  416.