Amiga Format CD 28/amigaformatcd28.iso/-seriously_amiga-/comms/www/wgetrexx/wget.rexx

OS/2 REXX Batch file | 1998-05-09 | 13.1 KB | 453 lines

/*
 * wget.rexx -- Invoke Wget from WWW browser
 *
 * $VER: wget.rexx 2.0 (8.5.1998)
 *
 * This program is copyrighted freeware. All rights reserved.
 * Copyright (C) 1998 by Thomas Aglassinger <[e-mail]>
 *
 * See http://www.giga.or.at/~agi/wgetrexx/ for more information.
 */

/* Version information */
version = "2.0 (8.5.1998)"

/* Install signal handlers */
SIGNAL ON Break_C                      /* Catch Control-C */
SIGNAL ON NoValue                      /* Catch unitinialized variables */

/* Directory to where the directory structure of the server
 * should be copied */
download_directory = 'Web:'

PARSE ARG arguments
OPTIONS RESULTS

/* Check, if wget is in search path */
ADDRESS COMMAND 'which >nil: wget'
IF RC ~= 0 THEN DO
    CALL view_error_message("Could not find wget.*NMake sure it is in the Workbench search path.")
    EXIT 10
END

/* Open rexxdossupport.library */
IF ~SHOW('L', 'rexxdossupport.library') THEN DO
    IF ~ADDLIB('rexxdossupport.library', 0, -30, 2) THEN DO
        CALL view_error_message("Library 'rexxdossupport.library' not found.*NRefer to the manual where to obtain it from.")
    END
END

/* Set default values for CLI arguments */
to       = download_directory
ask      = 0
further  = 0
continue = 0
verbose  = 0
clip     = 'wget'
port     = ''
options  = ''

/* Parse CLI options using ReadArgs() */
template = "Verbose/S,To/K,Ask/S,Further/S,Port/K,Continue/S,Clip/K,Options/F"
IF ~ReadArgs(arguments, template) THEN DO
   CALL view_error_message("Error in CLI options: " || Fault(RC) || "*NRefer to the manual about possible arguments.")
   EXIT 10
END

/* Show program header */
IF verbose THEN DO
    SAY 'wget.rexx -- Invoke Wget from WWW browser. Version ' || version
    SAY 'Copyright © 1998 Thomas Aglassinger. Freeware.'
    SAY
END

/* Check, if download directory is available */
download_directory = to
IF ~Exists(download_directory) THEN DO
    CALL view_error_message("Download directory '" || download_directory || "' not found.*NMake sure it exists and that it is accessible.")
    EXIT 10
END

/* If no browser port has been specified, find out which port to use */
IF (port = "") THEN DO
    /* Assume that current host is a browser */
    port = ADDRESS()

    IF ((LEFT(port, 4) ~= 'AWEB') ,
         | (LEFT(port, 7) ~= 'IBROWSE')) ,
    THEN DO
        /* Current host has turned out to be useless (e.g. 'REXX' if started
         * from a plain CLI), therefore try to find the default port of any
         * of the supported browsers */
        IF SHOW('P', 'AWEB.1') THEN DO
            port = 'AWEB.1'
        END
        ELSE IF SHOW('P', 'IBROWSE') THEN DO
            port = 'IBROWSE'
        END
        ELSE DO
            /* No supported browser found. Abort with error message. */
            CALL view_error_message("Could not find ARexx port of any supported browser.*NMake sure your browser is supported and running at*Nits default ARexx port or start script from browser.")
            EXIT 10
        END
    END
END

/* Assign browser port */
browser.port = port

IF verbose THEN DO
    /* Tell the user which browser we are using */
    SAY "Using browser in port '" || browser.port || "'"
    SAY
END

/* Assign browser ARexx commands */
IF LEFT(browser.port,4) = 'AWEB' THEN DO
    /* AWeb */
    browser.open = 'Open Reload'
    browser.query_uri = 'Get URL'
    browser.activate.count = 2
    browser.activate.1 = 'ActivateWindow'
    browser.activate.2 = 'WindowToFront'
END
ELSE IF LEFT(browser.port,7) = 'IBROWSE' THEN DO
    /* iBrowse */
    browser.open = 'GotoURL'
    browser.query_uri = 'Query URL'
    browser.activate.count = 2
    browser.activate.1 = 'Show'
    browser.activate.2 = 'ScreenToFront'
END

ELSE DO
    /* Unknown browser */
    CALL view_error_message("Browser at port '" || browser.port || "' is not supported*NRefer to the manual to learn which browsers are.")
    EXIT 10
END

/* Check, if browser is available */
IF ~SHOW('P', browser.port) THEN DO
    /* No; abort with error message */
    CALL view_error_message("Could not find WWW browser in port '" || browser.port || "'.*NStart browser before using this script.")
    EXIT 10
END

/*
 * Ask for additional options
 */
IF (ask) THEN DO
    /* Open rexxreqtools.library */
    IF ~SHOW('L', 'rexxreqtools.library') THEN DO
        IF ~ADDLIB('rexxreqtools.library', 0, -30, 0) THEN DO
            CALL view_error_message("Library 'rexxreqtools.library' not found.*NRefer to the manual where to obtain it from.")
        END
    END

    IF further THEN DO
        /* Only further options are asked and the options passed in the
         * command line are not displayed in the requester */
        ask_options = ''
        options = options || ' '
        further_text = ' further '
    END
    ELSE DO
        /* Display options passed in the command line in the requester
         * so that the user can edit all of them */
        ask_options = options
        options = ''
        further_text = ' '
    END

    IF continue THEN DO
        /* Obtain options used to be displayed as default in requester
         * from the clip.
         *
         * Note that this can discard all options passed in the CLI if
         * <further> was not specified.*/
        ask_options = GetClip(clip)
    END
    ELSE DO
        /* Reset the Clip and use the options already in <ask_options>
         * as default requester content */
        SetClip(clip, "")
    END

    /* Ask for additional options. If the user cancels the requester,
     * abort the whole process. */
    ok = 1
    ask_options = rtGetString(ask_options, "     Enter" || further_text || "options for Wget     ", "Wget Request",,,ok)
    IF (ok = 0) THEN DO
        EXIT 5
    END

    /* Update the clip with the options asked */
    SetClip(clip, ask_options)

    /* Append options just asked to overall options */
    options = options || ask_options
END /* ask */

/* From now on talk with the browser */
ADDRESS VALUE browser.port

/* Figure out URI to download from */
IF (POS('http://', options) = 0) THEN DO
    /* There is no URI specified in the command line, therefore use the one
     * from page currently viewed in browser */
    browser.query_uri
    uri = RESULT

END
ELSE DO
    /* Extract URI from options */
    PARSE VAR options options1 'http://' uri ' ' options2

    uri = 'http://' || uri
    options = options1 || ' ' || options2
END

/* Check, if there is another URI within the options.
 * In case, abort with error message. */
IF (POS('http://', options) > 0) THEN DO
    CALL view_error_message("Only one URI at a time allowed in options.*NRemove all other URIs from your request.")
    EXIT 10
END

/* Extract the name of the WWW-server to be downloaded from */
PARSE VAR uri 'http://' server '/' external_file

/* Validate URI */
IF server = '' THEN DO
    /* If the server name could not be extracted,
     * view error message and abort */
    CALL view_error_message(" Server name is missing in URI*Nor does not start with 'http://'")
    EXIT 10
END

/* Make sure that download_directory ends in ':' or '/' */
IF (POS(RIGHT(download_directory, 1), ':/') = 0) THEN DO
    download_directory = download_directory || '/'
END

/* Compute target directory and filename in URI-style */
target_directory = convert_amiga_path_to_uri(download_directory)
target_file = 'file://localhost/' || download_directory || server
target_file = target_file || '/' || convert_uri_to_amiga_path(external_file)

/*
 * Compute command call for wget
 */
wget = 'wget -x --directory-prefix=' || target_directory
wget = wget || ' ' || options || ' ' || uri

/*
 * Invoke Wget and lauch error requester or view downloaded page in browser
 */

/* View source and target file for users information */
IF verbose THEN DO
    SAY 'Downloading "' || uri || '"'
    SAY 'to          "' || target_file || '"'
    SAY
END

/* View the command so the user knows what is going to happen */
IF verbose THEN DO
    SAY 'Downloading "' || uri || '"'
    SAY 'to          "' || target_file || '"'
    SAY
END
SAY wget
SAY

/* Invoke the command viewed before
 * and remember its returncode */
ADDRESS COMMAND wget
wgetRC = RC

/* If wget was successful, view the copied page in browser */
IF (wgetRC = 0) THEN DO
    SAY
    SAY 'Successfully downloaded data to local web.'

    IF SHOW('P', browser.port) THEN DO
        SAY 'Viewing page in Browser'

        /* In case browser has been iconified meanwhile, pop it up again */
        DO command_index=1 FOR browser.activate.count
            browser.activate.command_index
        END

        /* View page from local web */
        browser.open target_file
    END
END
ELSE DO
    /* Inform user that something has gone wrong */
    SAY
    SAY 'Error during download. Nothing to display in Browser.'
    CALL view_error_message("Wget did return an error")
END

/* Exit with code returned by wget, multiplied by 10
 * (wget returns 1 in case of error) */
EXIT 10*wgetRC

/*
 * Signal handlers
 */

/* Handler for Control-C */
Break_C:
    SIGNAL OFF Break_C
    SAY
    SAY '*** Interrupted.'
    EXIT 5

/* Handler for unitinialized variables */
NoValue:
    SIGNAL OFF NoValue
    SAY
    SAY SIGL SourceLine(SIGL)
    SAY '*** Error: uninitialized value.'
    EXIT 20

/*
 * Subroutines
 */

/***** ugly/convert_amiga_path_to_uri **************************************
 * NAME
 *   convert_amiga_path_to_uri - Convert path from Amiga to URI style
 * FUNCTION
 *   Convert path from Amiga to URI style. The following conversion rules
 *   are applied:
 *
 *   - Device names are transformed from e.g. "ram:" to "/ram/"
 *   - Leading "/"'s replaced by "../"
 *   - All "//"'s are replaced by "/../"
 * INPUTS
 *   amiga_path - Amiga style path
 * RESULT
 *   Path in URI style
 * BUGS
 *   The input path is not validated for correctness. In such a case the
 *   result will also be invalid.
 * EXAMPLES
 *   "ram:"           -> "/ram/"
 *   "ram:sepp"       -> "/ram/sepp"
 *   "sepp//resi"     -> "sepp/../resi"
 *   "ram:sepp//resi" -> "/ram/sepp/../resi"
 *   "//resi/hugo"    -> "../../resi/hugo"
 *   "//resi//hugo"   -> "../../resi/../hugo
 **************************************************************************/
convert_amiga_path_to_uri : PROCEDURE
    PARSE ARG amiga_path

    uri = ''

    /* Extract device name from Amigapath (if there is any) */
    device = ''
    IF (POS(':', amiga_path) > 0) THEN DO
        PARSE VAR amiga_path device ':' path_part
        amiga_path = path_part
    END

    /* Convert leading "/" to "../" */
    DO WHILE (LEFT(amiga_path, 1) = '/')
        amiga_path = DELSTR(amiga_path, 1, 1)
        uri = uri || '../'
    END

    uri = uri || amiga_path

    /* Convert '//' inside string to '/../' */
    DO WHILE (POS('//', uri) > 0)
        PARSE VAR uri before '//' after
        uri = before || '/../' || after
    END

    /* Add device name in Unix-style;
     * 'ram:' becomes '/ram/' */
    IF (device ~= '') THEN DO
        uri = '/' || device || '/' || uri
    END

    RETURN uri

/***** ugly/convert_uri_to_amiga_path **************************************
 * NAME
 *   convert_uri_to_amiga_path - Convert path from URI to Amiga style
 * SYNOPSIS
 *   amiga_path = convert_uri_to_amiga_path( uri )
 * FUNCTION
 *   Convert path from URI to Amiga style. The following conversion rules
 *   are applied:
 *
 *   - Replace every leading '../' by '/'
 *   - Replace every '/../' by '//'
 *   - Replace every '~' by '%7E'
 * INPUTS
 *   uri - URI style path
 * RESULT
 *   amiga_path - Amiga style path
 * BUGS
 *   The input path is not validated for correctness. In such a case the
 *   result will also be invalid.
 *
 *   Devices in URI style are not handled.
 **************************************************************************/
convert_uri_to_amiga_path : PROCEDURE
    PARSE ARG uri

    amiga_path = ''

    /* Replace leading "../" by "/" */
    DO WHILE (LEFT(uri, 3) = '../')
        uri = DELSTR(uri, 1, 3)
        amiga_path = amiga_path || '/'
    END

    amiga_path = amiga_path || uri

    /* Replace '/../' inside string by '//' */
    DO WHILE (POS('//', uri) > 0)
        PARSE VAR uri before '/../' after
        amiga_path = before || '//' || after
    END

    /* Replace '~' by '%7E' */
    DO WHILE (POS('~', uri) > 0)
        PARSE VAR uri before '~' after
        amiga_path = before || '%7E' || after
    END

    RETURN amiga_path

/***************************************************************************
 * NAME
 *   view_error_message -- Pop-up error requester.
 * FUNCTION
 *   Pop-up error requester and wait for user to confirm it.
 *
 *   The title of the requester is "Wget Error", and the conformation button
 *   will have an "Ok".
 *
 *   This procedure simply invokes c:RequestChoice with the proper
 *   arguments.
 * INPUTS
 *   message - Message text to be in body of requester.  This text must not
 *       contain any double quotes ("), but single quotes (') are allowed.
 * RESULT
 *   The return value is the same as sent by the RequestChoice command.
 *   Normally, this is 0, as there is only one button. Other values indicate
 *   an error while invoking RequestChoice.
 **************************************************************************/
view_error_message : PROCEDURE
    PARSE ARG message
    ADDRESS COMMAND 'RequestChoice >nil: "Wget Error" "' || message || '" Ok'

    RETURN RC