home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
DP Tool Club 19
/
CD_ASCQ_19_010295.iso
/
vrac
/
icap4c.zip
/
DEMO.LI_
/
DEMO.LI
Wrap
Text File
|
1994-07-15
|
9KB
|
312 lines
*********************
*SYM=XFMR
.SUBCKT XFMR 1 2 3 4
*
* 1_______ _______3
* + ) ( +
* ) (
* V1 ) ( V2
* ) (
* - ) ( -
* 2_______) (_______4
*
* 1 : RATIO
*
RP 1 2 1MEG
E 5 4 1 2 {RATIO}
F 1 2 VM {RATIO}
RS 6 3 1U
VM 5 6
.ENDS
*****************
.MODEL DN4001 D(RS=.04 CJO=55PF IS=1.38E-09 N=1.7 VJ=.34V
+ TT=5U M=.38 BV=75V)
********************
.MODEL DN4148 D(RS=.8 CJO=4PF IS=7E-09 N=2 VJ=.6V
+ TT=6E-09 M=.45 BV=100V)
********************
.MODEL QN2222 NPN(IS=1.9E-14 BF=150 VAF=100 IKF=.175 ISE=5E-11 NE=2.5
+ BR=7.5 VAR=6.38 IKR=.012 ISC=1.9E-13 NC=1.2 RC=.4 XTB=1.5
+ CJE=26PF TF=.5E-9 CJC=11PF TR=30E-9 KF=3.2E-16 AF=1.0)
********************
.MODEL QN2907 PNP (IS=1.1E-12 BF=200 BR=6 NF=1.21
+ RC=.6 IKF=100E-3 VAF=50 XTB=1.5 NE=1.9 ISE=1.3E-11
+ CJE=23PF VJE=.85 MJE=1.25 CJC=19PF VJC=.5 MJC=.2
+ TF=5E-10 TR=34E-9)
********************
.MODEL QN3055 NPN(IS=1.5E-8 NF=1.67 BF=75 VAF=100 IKF=4
+ BR=4 RC=.06 MJC=.45 VJE=1.2 MJE=.5 XTB=1.5
+ CJE=520PF TF=40E-9 CJC=380PF TR=.8U )
********************
*SYM=SCR
.SUBCKT SN6397 1 2 3
* 2N6397 SCR...ANODE GATE CATHODE
Q1 2 4 1 QPSCR AREA=.67 OFF
Q2 4 2 3 QNSCR AREA=.67
Q3 5 4 1 QPSCR AREA=.33 OFF
Q4 4 5 3 QNSCR AREA=.33
RBN 2 5 40
.MODEL QNSCR NPN(TF=400NS TR=1.6US CJC=50PF CJE=175PF XTB=2.5
+ IS=1E-15 ISE=3E-9 NE=2 BF=100 BR=25 ISC=3E-9 NC=2 )
.MODEL QPSCR PNP(TF=90NS TR=180NS CJC=50PF CJE=80PF XTB=2.5
+ IS=1E-15 ISE=3E-9 NE=2 BF=50 BR=25 ISC=3E-9 NC=2 RE=.03)
.ENDS
*************************
.MODEL ZN750 D(RS=9.0662 BV=4.5187
+ CJO=435.15P TT=50N M=.33 VJ=.75 IS=1E-11 N=1.27 IBV=20MA)
************************
.MODEL ZN962 D(RS=5.2600 BV=10.940
+ CJO=710.46P TT=20N N=2 IS=1E-9 IBV=11.364M)
*************************
.MODEL MR751 D (IS=3.62E-08 N=1.67 BV=1.33E+02 IBV=2.50E-05
+ RS=1.84E-03 CJO=9.28E-10 VJ=.29 M=.55 TT=6.91E-06)
* Motorola 100 Volt 6.00 Amp 5.50 us Si Rectifier Diode 07-01-1990
**********
.MODEL DN5148 D(M=0.4881 VJ=.275 CJO=86.90P BV=90 IBV=10N)
* Motorola CT=47P @ 4V Si Varactor Diode 5-5-91
**********
.MODEL DN5165 D (IS=2.14N RS=9.69 N=.942 BV=43.3 IBV=350.0N
+ CJO=800F VJ=.75 M=.333 TT=36P EG=0.69 XTI=2)
* HP 5082-2301 30 Volt .05 Amp Si Schottky Diode 11-23-1990
**********
*SYM=BRIDGE
.SUBCKT MDA2500 2 3 5 4
* IN1 IN2 + -
D2 2 5 D2500
D3 3 5 D2500
D4 4 3 D2500
D1 4 2 D2500
.MODEL D2500 D (IS=1.52E-08 N=1.59 BV=5.00E+01 IBV=5.00E-06
+ RS=1.79E-03 CJO=4.69E-10 VJ=.29 M=0.4 TT=4.32E-06)
* Motorola 50 Volt 25.00 Amp 3.75 us Si Diode Bridge 07-08-1990
.ENDS
*******
.MODEL MPS3903 NPN (IS=.937F NF=1 BF=445 VAF=113 IKF=70M
+ ISE=2.71P NE=2 BR=4 NR=1 VAR=16 RE=1.81 RB=7.26 RC=.726
+ XTB=1.5 CJE=8.17P CJC=5.10P TF=636P TR=297N)
* 40 Volt .2 Amp 250 MHz SiNPN Transistor 09-22-1990
**********
.MODEL QN2904 PNP (IS=381F NF=1 BF=51.5 VAF=113 IKF=.14
+ ISE=46.1P NE=2 BR=4 NR=1 VAR=20 IKR=.21 RE=.552 RB=2.21
+ RC=.221 XTB=1.5 CJE=15.6P CJC=20.8P TF=636P TR=63.7N)
* 40 Volt .6 Amp 250 MHz SiPNP Transistor 04-11-1991
**********
*SYM=DARBJTN
.SUBCKT MJ10005 1 2 3
* TERMINALS: C B E
Q1 1 2 4 QPWR .1
Q2 1 4 3 QPWR
R1 2 4 100
R2 4 3 10
D1 3 1 DSUB
D2 4 2 DSUB .01
.MODEL QPWR NPN (IS=24P NF=1.1 BF=18.4 VAF=360 IKF=15
+ ISE=42.4P NE=2 BR=4 NR=1 VAR=32 IKR=22.5 RE=47.5M RB=.22M
+ RC=22.5M XTB=1.5 CJE=210N CJC=45900P TF=30N TR=160N)
.MODEL DSUB D (IS=24P N=1 RS=56.2M BV=400 IBV=.001
+ CJO=190P TT=360N)
.ENDS
* 400 Volt 20 Amp NPN Darlington Transistor 01-08-1991
**********
*SYM=POWBJTP
.SUBCKT MJ14003 1 2 3
* TERMINALS: C B E
* Motorola 80 Volt 60 Amp SiPNP Power Transistor 08-02-1993
Q1 1 2 3 QPWR .67
Q2 1 4 3 QPWR .33
RBS 2 4 23
.MODEL QPWR PNP (IS=2.36P NF=1 BF=195 VAF=161 IKF=15 ISE=1.25N NE=2
+ BR=4 NR=1 VAR=20 IKR=22.5 RE=13M RB=52.1M RC=5.21M XTB=1.5
+ CJE=2.81N VJE=.6 MJE=.3 CJC=1.5N VJC=.22 MJC=.2 TF=83.8N TR=2.04U)
.ENDS
**********
*SYM=RFNBJT
* MOTOROLA MRF911 10 V 10 MA
.SUBCKT MRF911 1 2 3
LC 1 4 0.112E-9
LB 2 6 1.402E-9
LE 5 3 0.884E-9
CC 4 5 0.246E-12
CB 4 6 0.225E-12
Q1 4 6 5 QR21
.MODEL QR21 NPN ( BF=99 VAF=96 VAR=9.6 RC=5.7 RB=3.39
+RE=1.085 IKF=0.28E-01 ISE=0.36E-14 TF=0.178E-10
+TR=0.13E-08 ITF=0.40E-01 VTF=0.40E+01 CJC=1.262E-12
+CJE=2.045E-12 XTI=3.0 NE=1.5 ISC=0.12E-14 EG=1.11
+XTB=1.5 BR=2.57 VJC=0.75 VJE=0.75 IS=0.40E-15
+MJC=0.33 MJE=0.33 XTF=4.0 IKR=0.28E-01 KF=0.1E-14
+NC=1.7 FC=0.50 RBM=2.4 IRB=0.40E-02 XCJC=0.5 )
.ENDS
*********
*SYM=BEAD
.SUBCKT B7741 1 2
*Fair-Rite Wound Bead 2943777741
RX 3 2 1E12
CB 3 2 29.720N
F1 1 2 VM1 1
G2 2 3 1 2 1
E1 4 2 3 2 1
VM1 4 5
RB 5 2 10.590K
RS 5 6 1.1754K
VP 7 2 300
D1 6 7 DCLAMP
VN 2 8 300
D2 8 6 DCLAMP
.MODEL DCLAMP D(CJO=1.96536P VJ=25)
* Resistor with SPICE 2G.6 Temperature syntax
*R2 1 2 1.05K TC=-.00333
* Resistor with IsSpice3 Temperature syntax
R2 1 2 1.05K RMOD
.MODEL RMOD R TC1=-.00333
C1 1 2 6.57E-13
.ENDS
**********
.MODEL J105 NJF (VTO=-7.25 BETA=5M LAMBDA=.035
+ RD=4.20E-01 RS=3.78E-01 IS=9.48E-14
+ PB=1.00 FC=.5 CGS=8.00E-11 CGD=1.40E-10 KF=3.886E-16 AF=1)
* Siliconix 25 Volt 50 mA 3.0 ohm Dep-Mode N-Channel
* Switch 07-11-1990
*********
.MODEL BSJ176 PJF (VTO=-2.10 BETA=4M LAMBDA=10.3M RD=40.8
+ RS=37.7 IS=9.22F PB=1 FC=.5 CGS=20P CGD=26.5P)
* Philips 30 Volt 35M Amp 220 ohm Dep-Mode P-Channel J-FET 05-10-1991
**********
.MODEL MN156 PMOS (LEVEL=1 VTO=-4.2 KP=2.5M GAMMA=10.3U
+ PHI=.75 LAMBDA=2.14M RD=56 RS=56 IS=10.7F PB=.8 MJ=.46
+ CBD=9.46P CBS=11.3P CGSO=11.7N CGDO=9.75N CGBO=16.0N)
* -- Assumes default L=100U W=100U --
* 35 Volt .03 Amp 400 ohm Enh-Mode P-Channel MOS-FET 04-08-1991
* Motorola
**********
.MODEL VN10LE NMOS (LEVEL=1 VTO=1.8 KP=.3 GAMMA=2.01U
+ PHI=.75 LAMBDA=1.25M RD=1.65 RS=1.35 IS=79.1F PB=.8 MJ=.46 AF=1
+ CBD=69.2P CBS=83P CGSO=36N CGDO=30N CGBO=334N)
* -- Assumes default L=100U W=100U --
* 60 Volt .38 Amp 2.5 ohm Enh-Mode N-Channel MOS-FET 02-11-1993
* Siliconix
**********
*SYM=POWMOSN
.SUBCKT IRF150 10 20 30
* TERMINALS: D G S
M1 1 2 3 3 DMOS L=1U W=1U
RG 20 2 5.35
RD 10 1 4.3M
RDS 1 3 635K
CGD 4 1 2.75N
RCG 4 1 10MEG
MCG 4 5 2 2 SW L=1U W=1U
ECG 5 2 2 1 1
DGD 2 6 DCGD
MDG 6 7 1 1 SW L=1U W=1U
EDG 7 1 1 2 1
DDS 3 1 DSUB
LS 30 3 7.5N
.MODEL DMOS NMOS (LEVEL=3 VMAX=1.6MEG THETA=265.6M VTO=3.3
+ KP=9 RS=8.12M IS=2.01P CGSO=2.65M)
.MODEL SW NMOS (LEVEL=3 VTO=0 KP=.45)
.MODEL DCGD D (CJO=2.75N M=.5 VJ=.41)
.MODEL DSUB D (IS=2.01P RS=5.20M VJ=.8 M=.4 CJO=2.60N TT=720N)
.ENDS
* IR 100 Volt 28 Amp 45M ohm N-Channel Power MOS-FET 11-20-1990
**********
*SYM=POWMOSN
.SUBCKT MTP3055E 10 20 40
* TERMINALS: D G S
* Motorola 60 Volt 12 Amp .15 ohm N-Channel Power MOSFET 06-29-1993
M1 1 2 3 3 DMOS L=1U W=1U
RD 100 1 70.2M
RS 30 3 4.75M
RG 20 2 5
CGS 2 3 400P
EGD 12 0 2 1 1
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 600P
R1 13 0 1
D1 12 13 DLIM
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 100 DSUB
LS 30 40 7.5N
LD 10 100 4.5N
.MODEL DMOS NMOS (LEVEL=3 THETA=56.2M VMAX=625K ETA=2M VTO=3.2 KP=4.83)
.MODEL DCGD D (CJO=600P VJ=.6 M=.68)
.MODEL DSUB D (IS=49.8N N=1.5 RS=79.2M BV=60 CJO=660P VJ=.8 M=.42 TT=50N)
.MODEL DLIM D (IS=100U)
.ENDS
**********
*SYM=POWMOSP
.SUBCKT IRF9530 10 20 30
* TERMINALS: D G S
M1 4 1 5 5 DMOS L=1U W=1U
RG 20 1 21.4
RD 10 4 .117
RDS 4 5 2.54MEG
CGD 7 4 787P
RCG 7 4 10MEG
MCG 7 9 1 1 SW
ECG 9 1 1 4 1
DGD 6 1 DCGD
MDG 6 8 4 4 SW
EDG 8 4 4 1 1
DDS 4 5 DSUB
LS 5 30 7.5N
.MODEL DMOS PMOS (LEVEL=3 VMAX=6.6MEG THETA=220M VTO=-3.2
+ KP=3.2 RS=8.25M IS=504F CGSO=400U)
.MODEL SW PMOS (LEVEL=3 VTO=0 KP=20)
.MODEL DCGD D (CJO=787P M=.5 VJ=.41)
.MODEL DSUB D (IS=504F RS=.513 BV=100 IBV=.001
+ VJ=.8 M=.4 CJO=802P TT=432N)
.ENDS
* IR 100 Volt 7 Amp .25 ohm P-Channel Power MOS-FET 07-26-1990
**********
*SYM=SCR
.SUBCKT SN1595 1 2 3
* TERMINALS: A G K
* Motorola 2N1595 50 Volt 1.6 Amp SCR 06-04-1993
QP 6 4 1 POUT OFF
QN 4 6 5 NOUT OFF
RF 6 4 10MEG
RR 1 4 6.66MEG
RGK 6 5 210
RG 2 6 92.9
RK 3 5 80M
DF 6 4 ZF
DR 1 4 ZR
DGK 6 5 ZGK
.MODEL ZF D (IS=.64F IBV=1U BV=50 RS=1.5MEG)
.MODEL ZR D (IS=.64F IBV=1U BV=66.6)
.MODEL ZGK D (IS=.64F IBV=1U BV=10)
.MODEL POUT PNP (IS=640F BF=1 CJE=335P)
.MODEL NOUT NPN (IS=640F BF=100 RC=.32
+ CJE=335P CJC=67P TF=143N TR=17U)
.ENDS
**********
*SYM=IGBT
.SUBCKT IRGBC40F 10 20 30
* TERMINALS: C G E
Q1 30 1 10 QOUT
M1 1 2 30 30 MFIN L=1U W=1U
RG 20 2 3.06
CGD 4 1 172P
RGD 4 1 10MEG
MGD 4 5 2 2 SW L=1U W=1U
EGD 5 2 2 1 1
DDG 2 6 DCGD
MDG 6 7 1 1 SW L=1U W=1U
EDG 7 1 1 2 1
DDS 30 1 DSUB
VEC 8 10 23.5
DEC 1 8 DBE
.MODEL QOUT PNP (IS=7.79P BF=3.08 RE=4.56M TF=6.62N TR=646N)
.MODEL MFIN NMOS (LEVEL=1 VTO=4.2
+ KP=.932 IS=7.79P RS=1.86M CGSO=1.48M)
.MODEL SW NMOS (LEVEL=1 VTO=0 KP=65.3M)
.MODEL DCGD D (CJO=172P VJ=.41 M=.5)
.MODEL DSUB D (IS=7.79P BV=599 IBV=1M CJO=114P VJ=.8 M=.4 TT=547P)
.MODEL DBE D (IS=7.79P)
* 600 Volt 49 Amp N-Channel IGBT 08-19-1991
.ENDS
**********