home *** CD-ROM | disk | FTP | other *** search
/ DP Tool Club 15 / CD_ASCQ_15_070894.iso / vrac / agt17.zip / CRUSADE.CMD < prev    next >
OS/2 REXX Batch file  |  1993-05-02  |  35KB  |  1,177 lines
  1. (***************************************************)
  2. (* Flags & Counters --- What they stand for        *)
  3. (* Flags 0   Display CMD detail as being processed *)
  4. (*           enter DEBUG to toggle ON and OFF      *)
  5. (* Flags 1   ON if player has been in cave         *)
  6. (* Flags 2   Has thrown something into chasm if ON *)
  7. (* Flags 3   Harp is in tune if ON                 *)
  8. (* Flags 5   Has met toad if ON                    *)
  9. (* Flags 6   Has met princess if ON                *)
  10. (* Flags 7   Has met horse if ON                   *)
  11. (* Counter 1 Number of turns torch has been lit    *)
  12. (* Counter 2 Number of turns player has been       *)
  13. (*           stumbling around in the dark          *)
  14. (***************************************************)
  15.  
  16. (***************************************************)
  17. (*   First -- Automatic commands executed each turn*)
  18. (*   Part     regardless of command's VERB etc     *)
  19. (***************************************************)
  20.  
  21. (***************************************************)
  22. (*  Automatic commands to control time torch is ON *)
  23. (*   -- Torch starts to flicker at 50 turns        *)
  24. (*   -- Torch goes off at 75 turns                 *)
  25. (*   -- Player dies if he stumbles around in dark  *)
  26. (*      for 5 turns                                *)
  27. (***************************************************)
  28.  
  29.  
  30. COMMAND ANY
  31. Present 210 (* Blazing torch *)
  32. CounterEquals 1 50 (* light has been on for 50 turns *)
  33. PrintMessage 74 (* light is flickering *)
  34. RoomNeedsLight (* will be dark if no light *)
  35. PrintMessage 75 (* Better get out before light goes out *)
  36. END_COMMAND
  37.  
  38. COMMAND ANY
  39. Present 210 (* Blazing torch *)
  40. CounterGT 1 50 (* light has been on for more than 50 turns *)
  41. CounterLT 1 75 (* light has been on for less than 75 turns *)
  42. PrintMessage 74 (* light is flickering *)
  43. END_COMMAND
  44.  
  45. COMMAND ANY
  46. Present 210 (* Blazing torch *)
  47. CounterEquals 1 75 (* light has been on for 75 turns *)
  48. PrintMessage 76 (* light has gone out *)
  49. SwapLocations 210 203 (* switch to unlit torch *)
  50. Destroy 207 (* dry matches *)
  51. RoomNeedsLight (* will be dark if no light *)
  52. TurnCounterON 2 (* now stumbling around in dark *)
  53. LookAtRoom
  54. END_COMMAND
  55.  
  56. COMMAND ANY
  57. RoomNeedsLight (* will be dark if no light *)
  58. NOT LightPresent (* no light in room *)
  59. CounterEquals 2 0 (* stumbling counter not currently on *)
  60. PrintMessage 77 (* stumbling is dangerous *)
  61. TurnCounterON 2 (* now start counter for stumbling around in dark *)
  62. END_COMMAND
  63.  
  64. COMMAND ANY
  65. CounterGT 2 1 (* stumbling around in dark *)
  66. RoomNeedsLight (* will be dark if no light *)
  67. NOT LightPresent (* no light in room *)
  68. PrintMessage 77 (* stumbling is dangerous *)
  69. CounterEquals 2 5
  70. KillPlayer (* Player dies *)
  71. DoneWithTurn (* no further action -- get next input *)
  72. END_COMMAND
  73.  
  74. COMMAND ANY
  75. CounterGT 2 5 (* have previously been stumbling around in dark *)
  76. RoomNeedsLight (* will be dark if no light *)
  77. NOT LightPresent (* no light in room *)
  78. TurnCounterON 2 (* re-start counter for stumbling around in dark *)
  79. END_COMMAND
  80.  
  81. (***************************************************)
  82. (*  Automatic commands to offer player hint if     *)
  83. (*  player has not been in cave by TURN 10         *)
  84. (***************************************************)
  85.  
  86. COMMAND ANY
  87. ATlocation 7 (* in cave *)
  88. TurnFlagON 1 (* has visited cave *)
  89. END_COMMAND
  90.  
  91. COMMAND ANY
  92. FlagOFF 1 (* hasn't visited cave yet *)
  93. TurnsEquals 10
  94. PrintMessage 14 (* offer player a hint for 10 points *)
  95. PromptForYes (* get player's answer *)
  96. PrintMessage 16 (* give hint *)
  97. MinusScore 10 (* subtract 10 points from score *)
  98. DoneWithTurn (* no further action -- get next input *)
  99. END_COMMAND
  100.  
  101. (***************************************************)
  102. (*  Automatic commands to control appearance and   *)
  103. (*  disappearance of guard at various locations    *)
  104. (***************************************************)
  105.  
  106. COMMAND ANY
  107. Chance 20
  108. AtLocation 24  (* Baron's private chamber *)
  109. NOT InRoom 301  (* Guard *)
  110. PutInCurrentRoom 301  (* Put guard in room *)
  111. PrintMessage 33   (* Guard suddenly appears *)
  112. BlankLine
  113. END_COMMAND
  114.  
  115. COMMAND ANY
  116. Chance 50
  117. AtLocation 17  (* Guard's quarters *)
  118. NOT InRoom 301  (* guard *)
  119. PutInCurrentRoom 301 (* angry guard *)
  120. PrintMessage 33 (* guard appears *)
  121. BlankLine
  122. END_COMMAND
  123.  
  124. COMMAND ANY
  125. Chance 50
  126. AtLocation 39 (* passage near cell *)
  127. NOT InRoom 301 (* guard *)
  128. NOT InRoom 259 (* unconscious guard *)
  129. PutInCurrentRoom 301 (* angry guard *)
  130. PrintMessage 33 (* Guard appears *)
  131. BlankLine
  132. END_COMMAND
  133.  
  134. COMMAND ANY
  135. InRoom 301 (* guard *)
  136. NOT atLocation 39 (* passage near cell *)
  137. IsWearing 230 (* Baron's Armor *)
  138. SendToRoom 301 11 (* guard leaves *)
  139. PrintMessage 45 (* Guard leaves *)
  140. AtLocation 11 (* small room in cave *)
  141. Destroy 301 (* Guard disappears *)
  142. END_COMMAND
  143.  
  144. (***************************************************)
  145. (*  Automatic commands to give and heal player     *)
  146. (*  a broken leg                                   *)
  147. (***************************************************)
  148.  
  149. COMMAND ANY
  150. IsCarrying 215 (* Broken leg *)
  151. VerbIsDirection (* Trying to move *)
  152. PrintMessage 8 (* Sorry, but you can't *)
  153. PrintMessage 43 (* with a broken leg *)
  154. DoneWithTurn (* no further action -- get next input *)
  155. END_COMMAND
  156.  
  157. COMMAND ANY
  158. Chance 20
  159. IsCarrying 215 (* Broken leg *)
  160. PrintMessage 44 (* Leg is healed *)
  161. BlankLine
  162. Destroy 215  (* get rid of broken leg *)
  163. END_COMMAND
  164.  
  165. COMMAND ANY
  166. Chance 25
  167. AtLocation 11 (* room in wall *)
  168. InRoom 301 (* Guard *)
  169. GetIt 215 (* give broken leg *)
  170. GoToRoom 10  (* guard throws you into room 10 *)
  171. PrintMessage 42
  172. PutInCurrentRoom 204 (* rope goes in to room also *)
  173. DoneWithTurn (* no further action -- get next input *)
  174. END_COMMAND
  175.  
  176. (***************************************************)
  177. (*  Automatic commands to control meeting horse    *)
  178. (*  and have horse follow player                   *)
  179. (***************************************************)
  180.  
  181. COMMAND ANY
  182. Present 303 (* horse *)
  183. FlagOFF 7 (* hasn't met horse yet *)
  184. TurnFlagON 7 (* now has met *)
  185. PrintMessage 83 (* met horse *)
  186. BlankLine
  187. END_COMMAND
  188.  
  189. COMMAND ANY
  190. FlagON 7 (* has met horse *)
  191. AtLocation 19 (* in courtyard *)
  192. PutInCurrentRoom 304 (* grazing horse *)
  193. END_COMMAND
  194.  
  195. COMMAND ANY
  196. FlagON 7 (* has met horse *)
  197. IsSomeWhere 216 (* drawbridge is down *)
  198. AtLocationGT 1 (* outside castle *)
  199. AtLocationLT 7 (* not in cave *)
  200. NOT AtLocation 3 (* not at top of tree *)
  201. PutInCurrentRoom 304 (* grazing horse *)
  202. END_COMMAND
  203.  
  204. COMMAND ANY
  205. FlagON 7 (* has met horse *)
  206. IsSomeWhere 216 (* drawbridge is down *)
  207. AtLocation 43 (* thick woods *)
  208. PutInCurrentRoom 304 (* grazing horse *)
  209. END_COMMAND
  210.  
  211. COMMAND ANY
  212. FlagON 7 (* has met horse *)
  213. IsSomeWhere 216 (* drawbridge is down *)
  214. AtLocation 12 (* top of hill *)
  215. SendToRoom 304 45 (* grazing horse goes to winning room *)
  216. END_COMMAND
  217.  
  218. (***************************************************)
  219. (*  Automatic commands to control meeting toad     *)
  220. (*  and have toad follow player and speak          *)
  221. (***************************************************)
  222.  
  223. COMMAND ANY
  224. Present 300 (* toad *)
  225. TurnFlagON 5 (* has met toad *)
  226. END_COMMAND
  227.  
  228. COMMAND ANY
  229. IsSomewhere 300 (* toad exists *)
  230. FlagON 5 (* has met toad *)
  231. PutInCurrentRoom 300 (* put toad in room *)
  232. VerbIsDirection (* moving to another location *)
  233. PrintMessage 80 (* the toad follows you *)
  234. END_COMMAND
  235.  
  236. COMMAND ANY
  237. Chance 50
  238. Present 300 (* horny toad *)
  239. PrintMessage 66 (* Toad says Rib-bit *)
  240. BlankLine
  241. END_COMMAND
  242.  
  243. (***************************************************)
  244. (*  Automatic commands to control meeting princess *)
  245. (*  and have princess follow player                *)
  246. (***************************************************)
  247.  
  248. COMMAND ANY
  249. Present 302 (* princess *)
  250. TurnFlagON 6 (* has met princess *)
  251. END_COMMAND
  252.  
  253. COMMAND ANY
  254. IsSomewhere 302 (* princess exists *)
  255. FlagON 6 (* has met princess *)
  256. PutInCurrentRoom 302 (* put princess in room *)
  257. VerbIsDirection (* moving to another location *)
  258. PrintMessage 81 (* the princess follows you *)
  259. END_COMMAND
  260.  
  261. (***************************************************)
  262. (*  Automatic commands to control skull speaking   *)
  263. (***************************************************)
  264.  
  265. COMMAND ANY
  266. Chance 10
  267. Present 245  (* Skull *)
  268. PrintMessage 57  (* Skull speaks *)
  269. PrintMessage 26  (* Baron sucks eggs *)
  270. BlankLine
  271. END_COMMAND
  272.  
  273. COMMAND ANY
  274. Present 245  (* Skull *)
  275. AtLocation 28  (* A cavern with glowing walls *)
  276. PrintMessage 57  (* Skull speaks *)
  277. PrintMessage 58  (* Beware the vampire *)
  278. BlankLine
  279. END_COMMAND
  280.  
  281. COMMAND ANY
  282. Present 245  (* Skull *)
  283. AtLocation 31 (* east end of cavern *)
  284. PrintMessage 57  (* Skull speaks *)
  285. PrintMessage 59  (* Beware the chest *)
  286. BlankLine
  287. END_COMMAND
  288.  
  289. COMMAND ANY
  290. Present 245 (* Skull *)
  291. AtLocation 40  (* A secret passageway *)
  292. PrintMessage 57  (* Skull speaks *)
  293. PrintMessage 60  (* Beware the gold bars *)
  294. BlankLine
  295. END_COMMAND
  296.  
  297. (***************************************************)
  298. (*  Automatic commands to control appearance of    *)
  299. (*  vampire bats and their biting of player        *)
  300. (***************************************************)
  301.  
  302. COMMAND ANY
  303. Chance 50
  304. InRoom 246 (* vampire bat *)
  305. NOT IsWearing 252 (* Silver cross *)
  306. PrintMessage 63  (* Bat just bit you *)
  307. GoToRoom 42  (* go limbo *)
  308. DoneWithTurn (* no further action -- get next input *)
  309. END_COMMAND
  310.  
  311. COMMAND ANY
  312. Chance 80
  313. AtLocation 29  (* room with strange smell *)
  314. NOT InRoom 246  (* vampire bat *)
  315. PutInCurrentRoom 246 (* put bat in room *)
  316. PrintMessage 65 (* you hear bat wings flapping *)
  317. LookAtRoom
  318. END_COMMAND
  319.  
  320. (***************************************************)
  321. (*  Automatic commands whenever player is swimming *)
  322. (*  -- matches get soggy                           *)
  323. (*  -- torch goes out                              *)
  324. (*  -- piranha eat player                          *)
  325. (***************************************************)
  326.  
  327. COMMAND ANY
  328. AtLocation 13  (* in water *)
  329. Present 207 (* dry matches *)
  330. SwapLocations 207 208  (* swap with wet soggy matches *)
  331. END_COMMAND
  332.  
  333. COMMAND ANY
  334. AtLocation 13  (* in water *)
  335. Present 210 (* blazing torch *)
  336. SwapLocations 210 203  (* swap with unlit torch *)
  337. TurnCounterOFF 1 (* no longer counting number of turns torch is lit *)
  338. END_COMMAND
  339.  
  340. COMMAND ANY
  341. Chance 80
  342. AtLocation 13 (* in water *)
  343. InRoom 217 (* Piranha *)
  344. PrintMessage 1 (* hear strange sound *)
  345. PrintMessage 38 (* you made as tasty meal *)
  346. KillPlayer  (* go to limbo *)
  347. DoneWithTurn (* no further action -- get next input *)
  348. END_COMMAND
  349.  
  350. (***************************************************)
  351. (*   Last   -- Specific VERB,NOUN & OBJECT commands*)
  352. (*   Part      executed only when VERB,NOUN,OBJECT *)
  353. (***************************************************)
  354.  
  355. COMMAND CLIMB ROPE
  356. Present 204 (* Rope with hook *)
  357. PrintMessage 30 (* Throw it first *)
  358. DoneWithTurn (* no further action -- get next input *)
  359. END_COMMAND
  360.  
  361. COMMAND CLIMB ROPE
  362. InRoom 229 (* Drawbridge rope *)
  363. GoToRoom 15 (* catwalk *)
  364. PrintMessage 39 (* climb up rope... *)
  365. DoneWithTurn (* no further action -- get next input *)
  366. END_COMMAND
  367.  
  368. COMMAND CLIMB ROPE
  369. InRoom 234 (* hanging rope *)
  370. AtLocation 15 (* catwalk *)
  371. GoToRoom 14 (* outer wall *)
  372. PutInCurrentRoom 234 (* hanging rope *)
  373. PrintMessage 41 (* climb down rope... *)
  374. DoneWithTurn (* no further action -- get next input *)
  375. END_COMMAND
  376.  
  377. COMMAND CLIMB ROPE
  378. InRoom 234 (* hanging rope *)
  379. AtLocation 14 (* outer wall *)
  380. GoToRoom 15 (* catwalk *)
  381. PutInCurrentRoom 234 (* hanging rope *)
  382. PrintMessage 39 (* climb up rope... *)
  383. DoneWithTurn (* no further action -- get next input *)
  384. END_COMMAND
  385.  
  386. COMMAND CLIMB ROPE
  387. InRoom 234 (* hanging rope *)
  388. AtLocation 11 (* room in wall *)
  389. GoToRoom 10 (* large cavern *)
  390. PutInCurrentRoom 234 (* hanging rope *)
  391. PrintMessage 41 (* climb down rope... *)
  392. DoneWithTurn (* no further action -- get next input *)
  393. END_COMMAND
  394.  
  395. COMMAND CLIMB ROPE
  396. InRoom 234 (* hanging rope *)
  397. AtLocation 10 (* large cavern *)
  398. GoToRoom 11 (* room in wall *)
  399. PutInCurrentRoom 234 (* hanging rope *)
  400. PrintMessage 39 (* climb up rope... *)
  401. DoneWithTurn (* no further action -- get next input *)
  402. END_COMMAND
  403.  
  404. COMMAND CLIMB WALL
  405. AtLocation 10 (* large cavern *)
  406. PrintMessage 34 (* too high to climb!! *)
  407. DoneWithTurn (* no further action -- get next input *)
  408. END_COMMAND
  409.  
  410. COMMAND CLIMB WALL
  411. AtLocation 14 (* outer wall *)
  412. PrintMessage 34 (* too high to climb!! *)
  413. DoneWithTurn (* no further action -- get next input *)
  414. END_COMMAND
  415.  
  416. COMMAND GO PASSAGE
  417. InRoom 224 (* secret passage *)
  418. GoToRoom 40 (* passageway *)
  419. PrintMessage 15 (* OK... *)
  420. DoneWithTurn (* no further action -- get next input *)
  421. END_COMMAND
  422.  
  423. COMMAND ENTER PASSAGE
  424. InRoom 224 (* secret passage *)
  425. GoToRoom 40 (* passageway *)
  426. PrintMessage 15 (* OK... *)
  427. DoneWithTurn (* no further action -- get next input *)
  428. END_COMMAND
  429.  
  430. COMMAND GO OPENING
  431. AtLocation 10 (* large cavern *)
  432. PrintMessage 34 (* too high to climb!! *)
  433. DoneWithTurn (* no further action -- get next input *)
  434. END_COMMAND
  435.  
  436. COMMAND GO DRAWBRIDGE
  437. InRoom 216 (* lowered bridge *)
  438. AtLocation 4 (* water's edge *)
  439. GoToRoom 19 (* Courtyard *)
  440. PutInCurrentRoom 216 (* lowered bridge *)
  441. PrintMessage 19 (* you walk across bridge *)
  442. DoneWithTurn (* no further action -- get next input *)
  443. END_COMMAND
  444.  
  445. COMMAND GO DRAWBRIDGE
  446. InRoom 216 (* lowered bridge *)
  447. AtLocation 19 (* Courtyard *)
  448. GoToRoom 4 (* water's edge *)
  449. PutInCurrentRoom 216 (* lowered bridge *)
  450. PrintMessage 19 (* you walk across bridge *)
  451. DoneWithTurn (* no further action -- get next input *)
  452. END_COMMAND
  453.  
  454. COMMAND GO DRAWBRIDGE
  455. InRoom 212 (* Raised bridge *)
  456. PrintMessage 8 (* Sorry, you can't *)
  457. DoneWithTurn (* no further action -- get next input *)
  458. END_COMMAND
  459.  
  460. COMMAND GO COFFIN
  461. InRoom 243 (* open coffin *)
  462. GoToRoom 28 (* cavern *)
  463. PrintMessage 15 (* OK... *)
  464. DoneWithTurn (* no further action -- get next input *)
  465. END_COMMAND
  466.  
  467. COMMAND GO LEDGE
  468. PrintMessage 8 (* Sorry, you can't *)
  469. DoneWithTurn (* no further action -- get next input *)
  470. END_COMMAND
  471.  
  472. COMMAND JUMP ANY
  473. GetIt 215 (* Broken leg *)
  474. PrintMessage 6 (* That's not safe! *)
  475. DoneWithTurn (* no further action -- get next input *)
  476. END_COMMAND
  477.  
  478. COMMAND GET ANY
  479. InRoom 301 (* angry guard *)
  480. PrintMessage 8 (* Sorry, you can't *)
  481. PrintMessage 25 (* Guard won't allow *)
  482. DoneWithTurn (* no further action -- get next input *)
  483. END_COMMAND
  484.  
  485. COMMAND GET ANY
  486. IsCarrying 215 (* Broken leg *)
  487. PrintMessage 8 (* Sorry, you can't *)
  488. PrintMessage 43 (* with broken leg *)
  489. DoneWithTurn (* no further action -- get next input *)
  490. END_COMMAND
  491.  
  492. COMMAND GET KEY
  493. InRoom 259 (* unconscious guard *)
  494. IsNowhere 253 (* guard's keys *)
  495. GetIt 253 (* get his keys *)
  496. PrintMessage 82 (* you search guard and find keys *)
  497. DoneWithTurn (* no further action -- get next input *)
  498. END_COMMAND
  499.  
  500. COMMAND GET ROPE
  501. InRoom 234 (* hanging rope *)
  502. Destroy 234 (* hanging rope *)
  503. GetIt 204 (* Rope with hook *)
  504. PrintMessage 15 (* OK... *)
  505. DoneWithTurn (* no further action -- get next input *)
  506. END_COMMAND
  507.  
  508. COMMAND GET BOOK
  509. InRoom 224 (* secret passage *)
  510. IsNowhere 232 (* Scott book *)
  511. GetIt 232 (* Scott book *)
  512. PrintMessage 15 (* OK... *)
  513. DoneWithTurn (* no further action -- get next input *)
  514. END_COMMAND
  515.  
  516. COMMAND GET BOOK
  517. AtLocation 24 (* Baron's chamber *)
  518. InRoom 223 (* Bookcase *)
  519. SwapLocations 223 224
  520. GetIt 231 (* adventure hint book *)
  521. PrintMessage 15 (* OK... *)
  522. PrintMessage 1 (* hear strange sound *)
  523. DoneWithTurn (* no further action -- get next input *)
  524. END_COMMAND
  525.  
  526. COMMAND GET CHEST
  527. AtLocation 35 (* Baron's stronghold *)
  528. Present 249 (* Chest *)
  529. SendToRoom 249 26 (* send chest to east tower room *)
  530. PrintMessage 79 (* It disappears in a puff of blue smoke *)
  531. DoneWithTurn (* no further action -- get next input *)
  532. END_COMMAND
  533.  
  534. COMMAND GET SKULL
  535. AtLocation 27 (* family crypt *)
  536. InRoom 245 (* skull *)
  537. PrintMessage 57 (* skull speaks *)
  538. PrintMessage 58 (* beware the vampire *)
  539. END_COMMAND
  540.  
  541. COMMAND GET SIGN
  542. NOUNInRoom (* any sign is here *)
  543. PrintMessage 22 (* Voice booms out *)
  544. PrintMessage 23 (* leave the sign alone *)
  545. DoneWithTurn (* no further action -- get next input *)
  546. END_COMMAND
  547.  
  548. COMMAND GET WATER
  549. PrintMessage 8 (* sorry, but you can't *)
  550. PrintMessage 11 (* you've no container *)
  551. DoneWithTurn (* no further action -- get next input *)
  552. END_COMMAND
  553.  
  554. COMMAND GET BAR
  555. InRoom 254 (* open door *)
  556. SwapLocations 254 255 (* put closed door in room *)
  557. GetIt 251 (* gold bar *)
  558. PrintMessage 15 (* OK *)
  559. BlankLine
  560. ChangePassageway 4 0 (* Close exit to west *)
  561. PrintMessage 64 (* door slams shut *)
  562. DoneWithTurn (* no further action -- get next input *)
  563. END_COMMAND
  564.  
  565. COMMAND GET COBWEB
  566. NOUNinRoom (* cobwebs are here *)
  567. PrintMessage 68 (* Spider bites you *)
  568. GoToRoom 42 (* Go to Limbo *)
  569. DoneWithTurn (* no further action -- get next input *)
  570. END_COMMAND
  571.  
  572. COMMAND LIGHT MATCHES
  573. Present 207 (* dry matches *)
  574. PrintMessage 85 (* It burns for a few minutes and then goes out *)
  575. DoneWithTurn (* no further action -- get next input *)
  576. END_COMMAND
  577.  
  578. COMMAND LIGHT MATCHES
  579. Present 208 (* soggy matches *)
  580. PrintMessage 8 (* Sorry, but you can't *)
  581. PrintMessage 31 (* matches too wet *)
  582. DoneWithTurn (* no further action -- get next input *)
  583. END_COMMAND
  584.  
  585. COMMAND LIGHT TORCH
  586. Present 203 (* torch *)
  587. Present 207 (* dry matches *)
  588. SwapLocations 203 210 (* swap to blazing torch *)
  589. PrintMessage 15 (* OK... *)
  590. TurnCounterON 1 (* start count for light being lit *)
  591. DoneWithTurn (* no further action -- get next input *)
  592. END_COMMAND
  593.  
  594. COMMAND LIGHT TORCH
  595. Present 203 (* torch *)
  596. Present 208 (* soggy matches *)
  597. PrintMessage 8 (* Sorry, but you can't *)
  598. PrintMessage 31 (* matches too wet *)
  599. DoneWithTurn (* no further action -- get next input *)
  600. END_COMMAND
  601.  
  602. COMMAND LIGHT TORCH
  603. Present 203 (* torch *)
  604. NOT Present 207 (* dry matches *)
  605. PrintMessage 8 (* Sorry, you can't *)
  606. PrintMessage 46 (* don't have resources *)
  607. DoneWithTurn (* no further action -- get next input *)
  608. END_COMMAND
  609.  
  610. COMMAND LIGHT WOOD
  611. Present 267 (* fire wood *)
  612. Present 208 (* soggy matches *)
  613. PrintMessage 31 (* matches too wet *)
  614. DoneWithTurn (* no further action -- get next input *)
  615. END_COMMAND
  616.  
  617. COMMAND LIGHT WOOD
  618. Present 267 (* fire wood *)
  619. NOT Present 207 (* dry matches *)
  620. PrintMessage 8 (* Sorry, you can't *)
  621. PrintMessage 46 (* don't have resources *)
  622. DoneWithTurn (* no further action -- get next input *)
  623. END_COMMAND
  624.  
  625. COMMAND LIGHT WOOD
  626. ATlocation 18 (* west end of great hall *)
  627. Present 267 (* fire wood *)
  628. Present 207 (* dry matches *)
  629. SwapLocations 267 273
  630. PrintMessage 37 (* that feels good!! *)
  631. InRoom 235 (* unlit fireplace *)
  632. SwapLocations 236 235 (* put blazing fireplace in room *)
  633. DoneWithTurn (* no further action -- get next input *)
  634. END_COMMAND
  635.  
  636. COMMAND LIGHT WOOD
  637. Present 267 (* fire wood *)
  638. Present 207 (* dry matches *)
  639. PutInCurrentRoom 267 (* fire wood *)
  640. SwapLocations 267 273
  641. PrintMessage 37 (* that feels good!! *)
  642. LookAtRoom
  643. DoneWithTurn (* no further action -- get next input *)
  644. END_COMMAND
  645.  
  646. COMMAND LIGHT FIRE
  647. Present 267 (* fire wood *)
  648. Present 208 (* soggy matches *)
  649. PrintMessage 31 (* matches too wet *)
  650. DoneWithTurn (* no further action -- get next input *)
  651. END_COMMAND
  652.  
  653. COMMAND LIGHT FIRE
  654. Present 267 (* fire wood *)
  655. NOT Present 207 (* dry matches *)
  656. PrintMessage 8 (* Sorry, you can't *)
  657. PrintMessage 46 (* don't have resources *)
  658. DoneWithTurn (* no further action -- get next input *)
  659. END_COMMAND
  660.  
  661. COMMAND LIGHT FIRE
  662. ATlocation 18 (* west end of great hall *)
  663. Present 267 (* fire wood *)
  664. Present 207 (* dry matches *)
  665. SwapLocations 267 273
  666. PrintMessage 37 (* that feels good!! *)
  667. InRoom 235 (* unlit fireplace *)
  668. SwapLocations 236 235 (* put blazing fireplace in room *)
  669. DoneWithTurn (* no further action -- get next input *)
  670. END_COMMAND
  671.  
  672. COMMAND LIGHT FIRE
  673. Present 267 (* fire wood *)
  674. Present 207 (* dry matches *)
  675. PutInCurrentRoom 267 (* fire wood *)
  676. SwapLocations 267 273
  677. PrintMessage 37 (* that feels good!! *)
  678. LookAtRoom
  679. DoneWithTurn (* no further action -- get next input *)
  680. END_COMMAND
  681.  
  682. COMMAND EXTINGUISH TORCH
  683. Present 210 (* blazing torch *)
  684. PrintMessage 15 (* OK... *)
  685. SwapLocations 203 210
  686. TurnCounterOFF 1 (* stop count of light being on *)
  687. DoneWithTurn (* no further action -- get next input *)
  688. END_COMMAND
  689.  
  690. COMMAND EXTINGUISH FIRE WITH WINE
  691. Present 273 (* blazing fire *)
  692. Present 226 (* fine wine *)
  693. Destroy 226 (* fine wine *)
  694. SwapLocations 273 272
  695. PrintMessage 67 (* extinguish fire with wine *)
  696. DoneWithTurn (* no further action -- get next input *)
  697. END_COMMAND
  698.  
  699. COMMAND EXTINGUISH FIRE
  700. Present 273 (* blazing fire *)
  701. PrintMessage 8 (* Sorry, you can't *)
  702. PrintMessage 72 (* Don't have water *)
  703. DoneWithTurn (* no further action -- get next input *)
  704. END_COMMAND
  705.  
  706. COMMAND DROP ANY
  707. AtLocation 12 (* Top of hill *)
  708. NOUNpresent
  709. SendNOUNToRoom 45 (* send noun to winning room *)
  710. PrintMessage 79 (* It disappears in a puff of blue smoke *)
  711. DoneWithTurn (* no further action -- get next input *)
  712. END_COMMAND
  713.  
  714. COMMAND DROP ALL
  715. AtLocation 12 (* Top of hill *)
  716. SendAllToRoom 45 (* send items being carried noun to winning room *)
  717. PrintMessage 84 (* They disappear in a puff of blue smoke *)
  718. DoneWithTurn (* no further action -- get next input *)
  719. END_COMMAND
  720.  
  721. COMMAND DROP PILLS IN WATER
  722. AtLocation 4 (* water's edge *)
  723. IsCarrying 220 (* sleeping pills *)
  724. SwapLocations 221 217
  725. Destroy 220 (* sleeping pills *)
  726. PrintMessage 15 (* OK... *)
  727. DoneWithTurn (* no further action -- get next input *)
  728. END_COMMAND
  729.  
  730. COMMAND DROP PILLS
  731. AtLocation 13 (* in water *)
  732. IsCarrying 220 (* sleeping pills *)
  733. SwapLocations 221 217
  734. Destroy 220 (* sleeping pills *)
  735. PrintMessage 15 (* OK... *)
  736. DoneWithTurn (* no further action -- get next input *)
  737. END_COMMAND
  738.  
  739. COMMAND DROP LEG
  740. IsCarrying 215 (* Broken leg *)
  741. PrintMessage 22 (* voice booms out *)
  742. PrintMessage 24 (* Don't be silly! *)
  743. DoneWithTurn (* no further action -- get next input *)
  744. END_COMMAND
  745.  
  746. COMMAND DROP WINE ON FIRE
  747. Present 273 (* blazing fire *)
  748. Present 226 (* fine wine *)
  749. Destroy 226 (* fine wine *)
  750. SwapLocations 273 272 (* swap blazing fire for soggy wood *)
  751. PrintMessage 67 (* extinguish fire with wine *)
  752. DoneWithTurn (* no further action -- get next input *)
  753. END_COMMAND
  754.  
  755. COMMAND POUR WINE ON FIRE
  756. Present 273 (* blazing fire *)
  757. Present 226 (* fine wine *)
  758. Destroy 226 (* fine wine *)
  759. SwapLocations 273 272
  760. PrintMessage 67 (* extinguish fire with wine *)
  761. DoneWithTurn (* no further action -- get next input *)
  762. END_COMMAND
  763.  
  764. COMMAND DROP WINE
  765. NOT Present 273 (* blazing fire *)
  766. Present 226 (* wine *)
  767. Destroy 226 (* wine *)
  768. PrintMessage 73 (* bottle shatters *)
  769. PrintMessage 12 (* what a waste *)
  770. DoneWithTurn (* no further action -- get next input *)
  771. END_COMMAND
  772.  
  773. COMMAND THROW WINE ON FIRE
  774. Present 273 (* blazing fire *)
  775. Present 226 (* fine wine *)
  776. Destroy 226 (* fine wine *)
  777. SwapLocations 273 272
  778. PrintMessage 67 (* extinguish fire with wine *)
  779. DoneWithTurn (* no further action -- get next input *)
  780. END_COMMAND
  781.  
  782. COMMAND THROW PILLS IN WATER
  783. AtLocation 4 (* water's edge *)
  784. IsCarrying 220 (* sleeping pills *)
  785. SwapLocations 221 217
  786. Destroy 220 (* sleeping pills *)
  787. PrintMessage 15 (* OK... *)
  788. DoneWithTurn (* no further action -- get next input *)
  789. END_COMMAND
  790.  
  791. COMMAND THROW PILLS
  792. AtLocation 13 (* in water *)
  793. IsCarrying 220 (* sleeping pills *)
  794. SwapLocations 221 217
  795. Destroy 220 (* sleeping pills *)
  796. PrintMessage 15 (* OK... *)
  797. DoneWithTurn (* no further action -- get next input *)
  798. END_COMMAND
  799.  
  800. COMMAND THROW ANY
  801. NOUNPresent (* any noun *)
  802. AtLocation 36 (* south ledge *)
  803. OR
  804. AtLocation 30 (* north ledge *)
  805. DestroyNOUN (* any noun *)
  806. TurnFlagON 2 (* has thrown something *)
  807. PrintMessage 52 (* It disappears into the chasm *)
  808. DoneWithTurn (* no further action -- get next input *)
  809. END_COMMAND
  810.  
  811. COMMAND THROW ROPE
  812. AtLocation 14 (* outer wall *)
  813. OR
  814. AtLocation 10 (* large cavern *)
  815. Present 204 (* Rope with hook *)
  816. Destroy 204 (* Rope with hook *)
  817. PutInCurrentRoom 234 (* hanging rope *)
  818. PrintMessage 29 (* rope catches *)
  819. DoneWithTurn (* no further action -- get next input *)
  820. END_COMMAND
  821.  
  822. COMMAND OPEN ANY
  823. InRoom 301 (* angry guard *)
  824. PrintMessage 25 (* Guard won't allow *)
  825. DoneWithTurn (* no further action -- get next input *)
  826. END_COMMAND
  827.  
  828. COMMAND OPEN EGG
  829. Present 274 (* golden egg *)
  830. PrintMessage 10 (* crack egg -- sparrow appears *)
  831. SwapLocations 274 279 (* replace egg with eggshell pieces *)
  832. DoneWithTurn (* no further action -- get next input *)
  833. END_COMMAND
  834.  
  835. COMMAND OPEN DOOR
  836. InRoom 213 (* closed door *)
  837. IsUnLocked 213 (* door is unlocked *)
  838. SwapLocations 213 237 (* put open door in room *)
  839. ChangePassageway 1 31 (* open passage north to room 31 *)
  840. PrintMessage 4 (* The door is now open *)
  841. DoneWithTurn (* no further action -- get next input *)
  842. END_COMMAND
  843.  
  844. COMMAND OPEN DOOR
  845. InRoom 256 (* closed door *)
  846. IsUnLocked 256 (* door is unlocked *)
  847. SwapLocations 262 256 (* put open door in room *)
  848. SwapLocations 270 271 (* put open door on other side -- also *)
  849. ChangePassageway 4 39 (* open passage west to room 39 *)
  850. PrintMessage 4 (* The door is now open *)
  851. DoneWithTurn (* no further action -- get next input *)
  852. END_COMMAND
  853.  
  854. COMMAND OPEN DOOR
  855. InRoom 270 (* closed door *)
  856. IsUnLocked 270 (* door is unlocked *)
  857. SwapLocations 270 271 (* put open door in room *)
  858. SwapLocations 262 256 (* put open door on other side -- also *)
  859. ChangePassageway 3 41 (* open passage east to room 41 *)
  860. PrintMessage 4 (* The door is now open *)
  861. DoneWithTurn (* no further action -- get next input *)
  862. END_COMMAND
  863.  
  864. COMMAND OPEN DOOR
  865. InRoom 255 (*closed door*)
  866. IsUnLocked 255 (* door is unlocked *)
  867. SwapLocations 254 255
  868. ChangePassageway 4 40 (* open passage west to room 40 *)
  869. PrintMessage 4 (* It's open *)
  870. DoneWithTurn (* no further action -- get next input *)
  871. END_COMMAND
  872.  
  873. COMMAND OPEN BOOK
  874. PrintMessage 15 (* OK... *)
  875. DoneWithTurn (* no further action -- get next input *)
  876. END_COMMAND
  877.  
  878. COMMAND OPEN CHEST
  879. NOT AtLocation 45 (* Winning room *)
  880. PrintMessage 69 (* Baron appears and kills you *)
  881. KillPlayer (* Go to Limbo *)
  882. DoneWithTurn (* no further action -- get next input *)
  883. END_COMMAND
  884.  
  885. COMMAND OPEN COFFIN
  886. InRoom 242 (* closed coffin *)
  887. SwapLocations 242 243
  888. PrintMessage 15 (* OK... *)
  889. ChangePassageway 10 28 (* open passage down to room 28 *)
  890. DoneWithTurn (* no further action -- get next input *)
  891. END_COMMAND
  892.  
  893. COMMAND ATTACK GUARD
  894. InRoom 301 (* angry guard *)
  895. AtLocation 39 (* near dungeon cell *)
  896. SwapLocations 259 301 (* put unconscious guard in room *)
  897. PrintMessage 49 (* It was a fierce fight *)
  898. PrintMessage 51 (* but you won! *)
  899. DoneWithTurn (* no further action -- get next input *)
  900. END_COMMAND
  901.  
  902. COMMAND ATTACK GUARD
  903. InRoom 301 (* angry guard *)
  904. GoToRoom 41 (* Cell *)
  905. PrintMessage 49 (* It was a fierce fight *)
  906. PrintMessage 50 (* but you lost! *)
  907. SendAllToRoom 17 (* Guard's takes stuff to his quarters *)
  908. SendtoRoom 202 41 (* Put shining lamp in dungeon cell with you *) 
  909. DoneWithTurn (* no further action -- get next input *)
  910. END_COMMAND
  911.  
  912. COMMAND SEARCH GUARD
  913. InRoom 259 (* unconscious guard *)
  914. GetIt 253 (* get his keys *)
  915. PrintMessage 82 (* you search guard and find keys *)
  916. DoneWithTurn (* no further action -- get next input *)
  917. END_COMMAND
  918.  
  919. COMMAND FIND KEY
  920. InRoom 259 (* unconscious guard *)
  921. GetIt 253 (* get his keys *)
  922. PrintMessage 82 (* you search guard and find keys *)
  923. DoneWithTurn (* no further action -- get next input *)
  924. END_COMMAND
  925.  
  926. COMMAND FIND KEY
  927. IsNowhere 259 (* unconscious guard *)
  928. PrintMessage 36 (* try the harp *)
  929. DoneWithTurn (* no further action -- get next input *)
  930. END_COMMAND
  931.  
  932. COMMAND FIND ANY
  933. PrintMessage 18 (* don't see it *)
  934. DoneWithTurn (* no further action -- get next input *)
  935. END_COMMAND
  936.  
  937. COMMAND HELP ANY
  938. RoomNeedsLight (* will be dark if no light *)
  939. NOT LightPresent (* no light in room *)
  940. PrintMessage 17 (* You are in real trouble... *)
  941. DoneWithTurn (* no further action -- get next input *)
  942. END_COMMAND
  943.  
  944. COMMAND HELP ANY
  945. AtLocation 36 (* south ledge *)
  946. OR
  947. AtLocation 30 (* north ledge *)
  948. FlagON 2 (* has thrown something *)
  949. TurnFlagOFF 2
  950. PrintMessage 56 (* Sorry about that ... *)
  951. DoneWithTurn (* no further action -- get next input *)
  952. END_COMMAND
  953.  
  954. COMMAND HELP ANY
  955. IsCarrying 215 (* Broken leg *)
  956. PrintMessage 47 (* time heals all things *)
  957. DoneWithTurn (* no further action -- get next input *)
  958. END_COMMAND
  959.  
  960. COMMAND CRACK EGG
  961. Present 274 (* golden egg *)
  962. PrintMessage 10 (* crack egg -- sparrow appears *)
  963. SwapLocations 274 279 (* replace egg with eggshell pieces *)
  964. DoneWithTurn (* no further action -- get next input *)
  965. END_COMMAND
  966.  
  967. COMMAND BREAK DOOR WITH AXE
  968. AtLocation 41 (* Cell *)
  969. IsCarrying 227 (* Axe *)
  970. SwapLocations 256 262
  971. SwapLocations 270 271
  972. PrintMessage 15 (* OK... *)
  973. PrintMessage 40 (* Timber !! *)
  974. ChangePassageway 4 39 (* open passage to room 39 *)
  975. DoneWithTurn (* no further action -- get next input *)
  976. END_COMMAND
  977.  
  978. COMMAND BREAK DOOR WITH AXE
  979. AtLocation 39 (* passage outside Cell *)
  980. IsCarrying 227 (* Axe *)
  981. SwapLocations 256 262
  982. SwapLocations 270 271
  983. PrintMessage 15 (* OK... *)
  984. PrintMessage 40 (* Timber !! *)
  985. ChangePassageway 3 41 (* open passage to room 41 *)
  986. DoneWithTurn (* no further action -- get next input *)
  987. END_COMMAND
  988.  
  989. COMMAND BREAK DOOR WITH AXE
  990. AtLocation 11 (* small room in cave *)
  991. IsCarrying 227 (* Axe *)
  992. SwapLocations 213 237
  993. PrintMessage 15 (* OK... *)
  994. PrintMessage 40 (* Timber !! *)
  995. ChangePassageway 1 31 (* open passage to room 31 *)
  996. DoneWithTurn (* no further action -- get next input *)
  997. END_COMMAND
  998.  
  999. COMMAND BREAK DOOR
  1000. PrintMessage 9 (* rush door with shoulder *)
  1001. DoneWithTurn (* no further action -- get next input *)
  1002. END_COMMAND
  1003.  
  1004. COMMAND BREAK ANY
  1005. NOT Present 227 (* axe *)
  1006. PrintMessage 8 (* Sorry, you can't *)
  1007. PrintMessage 13 (* don't have resources *)
  1008. DoneWithTurn (* no further action -- get next input *)
  1009. END_COMMAND
  1010.  
  1011. COMMAND TUNE HARP
  1012. Present 222 (* harp *)
  1013. NOT Present 233 (* harp tuning key *)
  1014. PrintMessage 8 (* Sorry, you can't *)
  1015. PrintMessage 13 (* don't have resources *)
  1016. DoneWithTurn (* no further action -- get next input *)
  1017. END_COMMAND
  1018.  
  1019. COMMAND TUNE HARP
  1020. Present 222 (* harp *)
  1021. Present 233 (* harp tuning key *)
  1022. PrintMessage 20 (* you tune the harp *)
  1023. TurnFlagON 3 (* harp has now been tuned *)
  1024. DoneWithTurn (* no further action -- get next input *)
  1025. END_COMMAND
  1026.  
  1027. COMMAND EXAMINE HARP
  1028. Present 222 (* harp *)
  1029. FlagON 3 (* harp is in tune *)
  1030. PrintMessage 48 (* harp is in tune *)
  1031. DoneWithTurn (* no further action -- get next input *)
  1032. END_COMMAND
  1033.  
  1034. COMMAND PLAY HARP
  1035. Present 222 (* harp *)
  1036. FlagON 3 (* harp is in tune *)
  1037. PrintMessage 32 (* play harp beautifully *)
  1038. DoneWithTurn (* no further action -- get next input *)
  1039. END_COMMAND
  1040.  
  1041. COMMAND PLAY HARP
  1042. Present 222 (* harp *)
  1043. IsNowhere 233 (* harp tuning key *)
  1044. PutInCurrentRoom 233 (* harp tuning key *)
  1045. PrintMessage 1 (* hear strange sound *)
  1046. LookAtRoom
  1047. END_COMMAND
  1048.  
  1049. COMMAND CUT TREE
  1050. IsCarrying 227 (* Axe *)
  1051. AtLocation 2 (* dense forest *)
  1052. OR
  1053. AtLocation 43 (* thick woods *)
  1054. PrintMessage 40 (* Timber !! *)
  1055. DoneWithTurn (* no further action -- get next input *)
  1056. END_COMMAND
  1057.  
  1058. COMMAND CUT ROPE
  1059. InRoom 229 (* Drawbridge rope *)
  1060. IsCarrying 227 (* Axe *)
  1061. SwapLocations 229 216 (* put lowered drawbridge in room *)
  1062. Destroy 212 (* Raised bridge *)
  1063. PrintMessage 78 (* Drawbridge may now be crossed *)
  1064. DoneWithTurn (* no further action -- get next input *)
  1065. END_COMMAND
  1066.  
  1067. COMMAND CUT ANY
  1068. NOT Present 227 (* axe *)
  1069. PrintMessage 8 (* Sorry, you can't *)
  1070. PrintMessage 13 (* don't have resources *)
  1071. DoneWithTurn (* no further action -- get next input *)
  1072. END_COMMAND
  1073.  
  1074. COMMAND TALK TO PRINCESS
  1075. Present 302 (* Princess *)
  1076. PrintMessage 5 (* chat with princess *)
  1077. DoneWithTurn (* no further action -- get next input *)
  1078. END_COMMAND
  1079.  
  1080. COMMAND TALK TO GUARD
  1081. Present 301 (* Guard *)
  1082. GoToRoom 41 (* Cell *)
  1083. PrintMessage 3 (* chat with guard *)
  1084. PrintMessage 49 (* It was a fierce fight *)
  1085. PrintMessage 50 (* but you lost! *)
  1086. SendAllToRoom 17 (* Guard's takes stuff to his quarters *)
  1087. SendtoRoom 202 41 (* Put shining lamp in dungeon cell with you *)
  1088. DoneWithTurn (* no further action -- get next input *)
  1089. END_COMMAND
  1090.  
  1091. COMMAND TALK TO TOAD
  1092. Present 300 (* toad *)
  1093. PrintMessage 2 (* chat with toad *)
  1094. DoneWithTurn (* no further action -- get next input *)
  1095. END_COMMAND
  1096.  
  1097. COMMAND ASK TOAD ABOUT ANY
  1098. Present 300 (* toad *)
  1099. PrintMessage 2 (* chat with toad *)
  1100. DoneWithTurn (* no further action -- get next input *)
  1101. END_COMMAND
  1102.  
  1103. COMMAND ASK GUARD ABOUT ANY
  1104. Present 301 (* Guard *)
  1105. GoToRoom 41 (* Cell *)
  1106. PrintMessage 3 (* chat with guard *)
  1107. PrintMessage 49 (* It was a fierce fight *)
  1108. PrintMessage 50 (* but you lost! *)
  1109. SendAllToRoom 17 (* Guard's takes stuff to his quarters *)
  1110. SendtoRoom 202 41 (* Put shining lamp in dungeon cell with you *)
  1111. DoneWithTurn (* no further action -- get next input *)
  1112. END_COMMAND
  1113.  
  1114. COMMAND ASK PRINCESS ABOUT ANY
  1115. Present 302 (* Princess *)
  1116. PrintMessage 7 (* ask princess *)
  1117. DoneWithTurn (* no further action -- get next input *)
  1118. END_COMMAND
  1119.  
  1120. COMMAND READ BOOK
  1121. IsCarrying 231 (* adventure hint book *)
  1122. IsNowhere 238 (* large diamond *)
  1123. PrintMessage 35 (* something fell out *)
  1124. BlankLine
  1125. PutInCurrentRoom 238 (* large diamond *)
  1126. LookAtRoom
  1127. END_COMMAND
  1128.  
  1129. COMMAND RIDE HORSE
  1130. Present 304 (* Baron's horse *)
  1131. PrintMessage 21 (* You ride the horse for a while *)
  1132. DoneWithTurn (* no further action -- get next input *)
  1133. END_COMMAND
  1134.  
  1135. COMMAND KISS TOAD
  1136. Present 300 (* toad *)
  1137. SwapLocations 300 302
  1138. PrintMessage 54 (* Toad turns into princess! *)
  1139. DoneWithTurn (* no further action -- get next input *)
  1140. END_COMMAND
  1141.  
  1142. COMMAND KISS PRINCESS
  1143. AtLocation 45 (* winning room *)
  1144. Present 302 (* princess *)
  1145. PrintMessage 61 (* last kiss for princess!! *)
  1146. PlusScore 50 (* get special BONUS for being a true romantic! *)
  1147. WinGame (* one last kiss to win *)
  1148. DoneWithTurn (* no further action -- get next input *)
  1149. END_COMMAND
  1150.  
  1151. COMMAND KISS PRINCESS
  1152. NOT AtLocation 12 (* Top of hill *)
  1153. Present 302 (* princess *)
  1154. PrintMessage 55 (* kiss princess!! *)
  1155. DoneWithTurn (* no further action -- get next input *)
  1156. END_COMMAND
  1157.  
  1158. COMMAND KISS PRINCESS
  1159. AtLocation 12 (* Top of hill *)
  1160. Present 302 (* princess *)
  1161. PrintMessage 86 (* Oh! Rapture!! *)
  1162. GoToRoom 45 (* Win Game Room *)
  1163. DoneWithTurn (* no further action -- get next input *)
  1164. END_COMMAND
  1165.  
  1166. COMMAND KISS ANY
  1167. NOT AtLocation 12 (* Top of hill *)
  1168. PrintMessage 24 (* Don't be silly! *)
  1169. DoneWithTurn (* no further action -- get next input *)
  1170. END_COMMAND
  1171.  
  1172. COMMAND DEBUG
  1173. ToggleFlag 0 (* toggle diagnostic mode *)
  1174. DoneWithTurn (* no further action -- get next input *)
  1175. END_COMMAND
  1176.  
  1177.