home *** CD-ROM | disk | FTP | other *** search
/ DP Tool Club 13 / CD_ASCQ_13_0494.iso / maj / 419 / windman.bas < prev    next >
BASIC Source File  |  1994-03-13  |  4KB  |  118 lines
  1. '   +----------------------------------------------------------------------+
  2. '   |                                                                      |
  3. '   |        PBClone  Copyright (c) 1990-1994  Thomas G. Hanlin III        |
  4. '   |                                                                      |
  5. '   +----------------------------------------------------------------------+
  6.  
  7.    DECLARE SUB CalcAttr (BYVAL Foreground%, BYVAL Background%, VAttr%)
  8.    DECLARE SUB DelayV (BYVAL MilliSeconds%)
  9.    DECLARE SUB ReColorArea (BYVAL TopRow%, BYVAL LeftCol%, BYVAL BottomRow%, BYVAL RightCol%, BYVAL VAttr%, BYVAL Page%, BYVAL Fast%)
  10.    DECLARE SUB XQPrint (St$, BYVAL Row%, BYVAL Column%, BYVAL VAttr%, BYVAL Page%, BYVAL Fast%)
  11.  
  12. SUB WindowManager (TopRow%, LeftCol%, BottomRow%, RightCol%, Frame%, Fore%, Back%, Grow%, Shade%, TitleFore%, Title$, Page%, Fast%)
  13.  
  14.    CalcAttr Fore%, Back%, VAttr%
  15.  
  16.    IF Grow% THEN
  17.       XD% = RightCol% - LeftCol% + 1
  18.       YD% = BottomRow% - TopRow% + 1
  19.       Y1% = TopRow% + YD% \ 2
  20.       X1% = LeftCol% + XD% \ 2
  21.       Y2% = BottomRow% - YD% \ 2
  22.       X2% = RightCol% - XD% \ 2
  23.       IF YD% > XD% THEN
  24.          XDelta% = 1
  25.          YDelta% = (YD% + XD% \ 2) \ XD%
  26.          IF YDelta% < 1 THEN YDelta% = 1
  27.       ELSE
  28.          YDelta% = 1
  29.          XDelta% = (XD% + YD% \ 2) \ YD%
  30.          IF XDelta% < 1 THEN XDelta% = 1
  31.       END IF
  32.       DO
  33.          Y1% = Y1% - YDelta%
  34.          IF Y1% < TopRow% THEN Y1% = TopRow%
  35.          X1% = X1% - XDelta%
  36.          IF X1% < LeftCol% THEN X1% = LeftCol%
  37.          Y2% = Y2% + YDelta%
  38.          IF Y2% > BottomRow% THEN Y2% = BottomRow%
  39.          X2% = X2% + XDelta%
  40.          IF X2% > RightCol% THEN X2% = RightCol%
  41.          GOSUB MakeWindow
  42.          IF Grow% > 0 THEN DelayV Grow%
  43.       LOOP UNTIL Y1% = TopRow% AND X1% = LeftCol% AND Y2% = BottomRow% AND X2% = RightCol%
  44.    ELSE
  45.       Y1% = TopRow%
  46.       X1% = LeftCol%
  47.       Y2% = BottomRow%
  48.       X2% = RightCol%
  49.       GOSUB MakeWindow
  50.    END IF
  51.  
  52.    EXIT SUB
  53.  
  54.  
  55.  
  56. MakeWindow:
  57.    tmp% = X2% - X1% + 1
  58.    IF Frame% = 5 THEN
  59.       TopSt$ = STRING$(tmp%, "▄")
  60.       BotSt$ = STRING$(tmp%, "▀")
  61.    ELSEIF Frame% AND 1 THEN
  62.       TopSt$ = STRING$(tmp%, "─")
  63.       BotSt$ = TopSt$
  64.    ELSE
  65.       TopSt$ = STRING$(tmp%, "═")
  66.       BotSt$ = TopSt$
  67.    END IF
  68.    MidSt$ = SPACE$(tmp%)
  69.    IF Frame% >= 1 AND Frame% <= 5 THEN
  70.       TopSt$ = MID$("┌╔╓╒▄", Frame%, 1) + TopSt$ + MID$("┐╗╖╕▄", Frame%, 1)
  71.       MidSt$ = MID$("│║║│▌", Frame%, 1) + MidSt$ + MID$("│║║│▐", Frame%, 1)
  72.       BotSt$ = MID$("└╚╙╘▀", Frame%, 1) + BotSt$ + MID$("┘╝╜╛▀", Frame%, 1)
  73.    ELSE
  74.       TopSt$ = SPACE$(tmp% + 2)
  75.       MidSt$ = TopSt$
  76.       BotSt$ = TopSt$
  77.    END IF
  78.  
  79.    Row% = Y1% - 1
  80.    Col% = X1% - 1
  81.    IF LEN(Title$) > 0 AND LEN(TopSt$) >= 4 THEN
  82.       St$ = LEFT$(Title$, LEN(TopSt$) - 4)
  83.       MID$(TopSt$, 2) = "[" + St$ + "]"
  84.       XQPrint TopSt$, Row%, Col%, VAttr%, Page%, Fast%
  85.       CalcAttr TitleFore%, Back%, TAttr%
  86.       XQPrint St$, Row%, Col% + 2, TAttr%, Page%, Fast%
  87.    ELSE
  88.       XQPrint TopSt$, Row%, Col%, VAttr%, Page%, Fast%
  89.    END IF
  90.    FOR Row% = Y1% TO Y2%
  91.       XQPrint MidSt$, Row%, Col%, VAttr%, Page%, Fast%
  92.    NEXT
  93.    XQPrint BotSt$, Y2% + 1, Col%, VAttr%, Page%, Fast%
  94.  
  95.    Col% = X1% - 3
  96.    IF Shade% < 0 THEN
  97.       IF Shade% = -1 THEN
  98.          SAttr% = 0
  99.       ELSE
  100.          SAttr% = 8
  101.       END IF
  102.       IF Shade% < -2 THEN
  103.          ReColorArea Y1%, X2% + 2, Y2% + 1, X2% + 3, SAttr%, Page%, Fast%
  104.          ReColorArea Y2% + 2, X1% + 1, Y2% + 2, X2% + 3, SAttr%, Page%, Fast%
  105.       ELSE
  106.          ReColorArea Y1%, Col%, Y2% + 1, X1% - 2, SAttr%, Page%, Fast%
  107.          ReColorArea Y2% + 2, Col%, Y2% + 2, X2% - 1, SAttr%, Page%, Fast%
  108.       END IF
  109.    ELSEIF Shade% THEN
  110.       FOR Row% = Y1% TO Y2% + 1
  111.          XQPrint "░░", Row%, Col%, Shade%, Page%, Fast%
  112.       NEXT
  113.       XQPrint STRING$(X2% - X1% + 3, "░"), Y2% + 2, Col%, Shade%, Page%, Fast%
  114.    END IF
  115.    RETURN
  116.  
  117. END SUB
  118.