home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
DP Tool Club 12
/
CD_ASCQ_12_0294.iso
/
vrac
/
dwnld15.zip
/
DWNLD.PPS
< prev
next >
Wrap
Text File
|
1994-01-21
|
9KB
|
214 lines
;*****************************************************************************
;* DWNLD.PPE v1.4 *
;* PCBOARD 15.1 Download Counter *
;* *
;* Written by Steven Hauswirth *
;* Written in PCBoard Programming Language *
;* *
;* "The Power Palace BBS" *
;* Node 1 - 312-594-0643 - [14.4 v32b] - 80386/40 *
;* *
;* This PPE is a full screen download counter that informs the user how *
;* many files, bytes, et cetera they have flagged for download. *
;*****************************************************************************
IF (!ANSION()) THEN
PRINT "Enter the filename to Download (Enter)=none"
GOTO EXIT
ENDIF
;┌───────────────────────────────────────────────────────────────────────────┐
;│ Declare Variable Types │
;└───────────────────────────────────────────────────────────────────────────┘
STRING TEMP, Y, FILE_NAME, FLAG_FILE, NO_TIME, FREE_FILE, TEMP_FILE
STRING FLIST_TIME, TEMP_TIME
DATE FILE_DATE
INTEGER COUNT, LOOP, BAT_MIN, BAT_SEC, BAT_TIME, FILE_SEC, FILE_MIN
INTEGER TEMP1, TEMP2, TEMP3, FILE_SIZE, FILE_NUM
IF (PCBNODE() = 0) THEN
LET FLAG_FILE = GETENV("PCBDRIVE")+GETENV("PCBDIR")+"\FLIST."
ELSE
LET FLAG_FILE = GETENV("PCBDRIVE")+GETENV("PCBDIR")+"\FLIST."+STRING(PCBNODE())
ENDIF
LET TEMP_FILE = GETENV("PCBDRIVE")+GETENV("PCBDIR")+"\FLIST.TMP"
LET FILE_NUM = 0
BAT_TIME = 0
TEMP1 = 0
TEMP2 = 0
TEMP3 = 0
LET Y = 1
LET LOOP = 1
;┌───────────────────────────────────────────────────────────────────────────┐
;│ Check to see if they have NOT flagged any files yet for download, or if │
;│ the user has decided not to download the flagged files. │
;└───────────────────────────────────────────────────────────────────────────┘
FOPEN 1,FLAG_FILE,O_RD,S_DN
FDEFIN 1
FSEEK 1,0,SEEK_SET(0)
FOR LOOP = 1 TO 100000
FSEEK 1,66,SEEK_CUR(1)
FDREAD FILE_NAME,13
IF (FERR(1)) BREAK
FSEEK 1,50,SEEK_CUR(1)
NEXT
IF (EXIST(TEMP_FILE)) THEN
FLIST_TIME = FILEINF(FLAG_FILE,3)
TEMP_TIME = FILEINF(TEMP_FILE,3)
IF (LEFT(TEMP_TIME,2) < LEFT(FLIST_TIME,2)) THEN
IF (MID(TEMP_TIME,4,2) < MID(FLIST_TIME,4,2)) THEN
IF (RIGHT(TEMP_TIME,2) < RIGHT(FLIST_TIME,2)) GOTO SKIP
ENDIF
ENDIF
FOPEN 2, TEMP_FILE, O_RD, S_DN
FGET 2,TEMP1
FCLOSE 2
ELSE GOTO SKIP
ENDIF
IF (LOOP=1) GOTO SKIP
IF ((TEMP1+1)!=LOOP) WAIT
:SKIP
DELETE TEMP_FILE
FOPEN 2, TEMP_FILE, O_WR, S_DN
FPUT 2, LOOP
FCLOSE 2
COUNT = LOOP
;┌───────────────────────────────────────────────────────────────────────────┐
;│ Display the header of the dispay │
;└───────────────────────────────────────────────────────────────────────────┘
TEMP1 = 0
IF (GRAFMODE()="R") THEN
PRINTLN ""
PRINTLN "!|1K|*"
ENDIF
PRINTLN "@CLS@@X0A ┌────────────────────────────────────────────────────────────────────────────┐"
PRINTLN " │ @X09░▒▓█@X1B Statistics for the last 10 files in your batch @X09█▓▒░@X0A │"
PRINTLN " │ │"
PRINTLN " │ @X0BNum Filename Size Date Transfer Time Free No Time @X0A│"
PRINTLN " │ @X0D──── ──────────── ────────── ──────── ─────────────── ──── ─────── @X0A│"
;┌───────────────────────────────────────────────────────────────────────────┐
;│ Since there are files already flagged for download. Find out how many. │
;│ If there are more then 10 then position display to only display the last │
;│ ten of them. │
;└───────────────────────────────────────────────────────────────────────────┘
FSEEK 1,0,SEEK_SET(0)
IF (COUNT>10) THEN
FOR LOOP = 1 TO (COUNT-10)
FSEEK 1,83,SEEK_CUR(1)
FDREAD TEMP,1
IF (ASC(TEMP)!=0) TEMP1 = ASC(TEMP)
FDREAD TEMP,1
IF (ASC(TEMP)!=0) TEMP2 = 256*ASC(TEMP)
FDREAD TEMP,1
IF (ASC(TEMP)!=0) TEMP3 =65536*ASC(TEMP)
BAT_TIME = BAT_TIME + TEMP1 + TEMP2 + TEMP3
FSEEK 1,43,SEEK_CUR(1)
NEXT
ELSE COUNT = 10
ENDIF
LET Y = COUNT-9
;┌───────────────────────────────────────────────────────────────────────────┐
;│ Display the file name, bytes, and transfer time for all the files flagged │
;└───────────────────────────────────────────────────────────────────────────┘
FOR LOOP= 1 TO COUNT
TEMP1 = 0
TEMP2 = 0
TEMP3 = 0
FDREAD TEMP,66
IF (FERR(1)) BREAK
TEMP = TRIM(TEMP," ")
FILE_DATE = FILEINF(TEMP,2)
FDREAD FILE_NAME,13
FDREAD TEMP,1
IF (ASC(TEMP)!=0) TEMP1 = ASC(TEMP)
FDREAD TEMP,1
IF (ASC(TEMP)!=0) TEMP2 = 256*ASC(TEMP)
FDREAD TEMP,1
IF (ASC(TEMP)!=0) TEMP3 =65536*ASC(TEMP)
FILE_SIZE = TEMP1+TEMP2+TEMP3
TEMP1 = 0
TEMP2 = 0
TEMP3 = 0
FSEEK 1,1,SEEK_CUR(1)
FDREAD TEMP,1
IF (ASC(TEMP)!=0) TEMP1 = ASC(TEMP)
FDREAD TEMP,1
IF (ASC(TEMP)!=0) TEMP2 = 256*ASC(TEMP)
FDREAD TEMP,1
IF (ASC(TEMP)!=0) TEMP3 =65536*ASC(TEMP)
FILE_SEC = TEMP1 + TEMP2 + TEMP3
BAT_TIME = BAT_TIME + FILE_SEC
FSEEK 1,9,SEEK_CUR(1)
FDREAD FREE_FILE,1
FDREAD NO_TIME,1
FSEEK 1,32,SEEK_CUR(1)
FILE_MIN = FILE_SEC/60
FILE_SEC = FILE_SEC - FILE_MIN*60
PRINT " │@X0B"+LEFT(" ",5-LEN(Y))+STRING(Y)+LEFT(" ",15-LEN(FILE_NAME))+"@X0F"
PRINT FILE_NAME+LEFT(" ",12-LEN(STRING(FILE_SIZE)))
PRINT STRING(FILE_SIZE)+" "
PRINT STRING(FILE_DATE)+LEFT(" ",6-LEN(FILE_MIN))
PRINT STRING(FILE_MIN)+" @X07min@X0F"+LEFT(" ",3-LEN(STRING(FILE_SEC)))+STRING(FILE_SEC)+" @X07sec "
IF (ASC(FREE_FILE)=1) THEN
PRINT "@X0CY"
ELSE PRINT "@X0EN"
ENDIF
IF (ASC(NO_TIME)=1) THEN
PRINT " @X0CY"
ELSE PRINT " @X0C@X0EN"
ENDIF
ANSIPOS 79,5+LOOP
PRINTLN "@X0A│"
ANSIPOS 1,6+LOOP
INC Y
NEXT
;┌────────────────────────────────────────────────────────────────────────────┐
;│ Display with blank lines to fill the screen to ten file placements listed │
;└────────────────────────────────────────────────────────────────────────────┘
:CONT
FOR LOOP = LOOP TO 10
PRINTLN " @X0A│@X0B"+LEFT(" ",5-LEN(Y))+STRING(Y)+" @X0F0 00-00-00 0 @X07min @X0F0 @X07sec @X0A│"
INC Y
NEXT
:BACK
;┌───────────────────────────────────────────────────────────────────────────┐
;│ Display the footer of the dispay │
;└───────────────────────────────────────────────────────────────────────────┘
PRINTLN " │ │"
PRINTLN " │ @X09░▒▓█@X1B Statistics for the ENTIRE batch @X09█▓▒░@X0A │"
PRINTLN " │ │"
PRINT " │ @X07Files: @X0F@FFILES:3@ @X07Size (bytes): @X0F@FBYTES:12@ @X07Estimated time: @X0F"
;┌───────────────────────────────────────────────────────────────────────────┐
;│ Calculate the BATCH transfer time from the BATCH bytes listed on screen │
;│ taking into account local logons and error correcting modems. │
;└───────────────────────────────────────────────────────────────────────────┘
LET FILE_NUM = S2I(TRIM(SCRTEXT(14,19,2,FALSE)," "),10)
BAT_MIN = BAT_TIME/60
BAT_SEC = BAT_TIME - BAT_MIN*60
PRINT STRING(BAT_MIN)+" @X07min"+" @X0F"+STRING(BAT_SEC)+" @X07sec@X0A"
ANSIPOS 79,19
PRINTLN "│"
PRINTLN " └────────────────────────────────────────────────────────────────────────────┘"
PRINTLN " @X07Enter @X0Ffilename @X07on line above, or (@X0CENTER@X07) alone to continue@X08 1.5"
;┌───────────────────────────────────────────────────────────────────────────┐
;│ Position cursor on the screen and ask for file name. Then stuff it into │
;│ keyboard buffer and exit │
;└───────────────────────────────────────────────────────────────────────────┘
IF (FILE_NUM > 9) FILE_NUM = 9
ANSIPOS 11,6+FILE_NUM
LET FILE_NAME = ""
INPUTSTR "_",file_name,@X07,12,MASK_FILE()+"*?",UPCASE
ANSIPOS 1,21
FILE_NAME=TRIM(FILE_NAME," ")
IF (LEN(file_name) = 0) file_name = CHR(13)
KBDSTUFF file_name
:EXIT
END