home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
DP Tool Club 8
/
CDASC08.ISO
/
VRAC
/
HUBRUN10.ZIP
/
HUBRUN.MAC
< prev
next >
Wrap
Text File
|
1993-06-05
|
11KB
|
244 lines
{:MAIN1} {SETE-p0 quit}
{IFEX %_hom%hubrun.ttn,,cerror}
─────────────────> DATA READ AREA <─────────────────
{ROPE %_hom%hubrun.ttn}
{READ maildir}{READ rxdir}{READ capdir}{READ hslprg}{READ tries}{RCLO}
─────────────────> SET PARMS <─────────────────
{SOUN n}{LIGH y}{PARM ,,,T}
{SETV ss_h,~h}{SETV ss_m,~m}{SETV ss_s,~s}{SETV ss_|,~|}
{SETV ss_y,~y}{SETV ss_a,~a}{SETV ss_n,~n}{SETV d_count,1}
{SETV d_rem,%tries}{DECR d_rem}{INCR %tries}
─────────────────> DIALING <─────────────────
{WOPE-A %capdir%hubrun.log}
{MARK 1.,2.,3.,4.,5.,6.,7.,8.,9.}{CLEA}
{CLEA}{DIAL-C 1,noconn,exit}
{:EXIT} {WRIT %_24h%:%_min%:%_sec -- MAILRUN COMPLETE..EXIT TO DOS}
{WRIT ----------------------------------------------------------------------------}
{WCLO}
{:QUIT} {EXIT}
─────────────────> LINKED MACRO <──────────────────
{:TT0} {CLEA}
{ROPE %_hom%%bbsid.ttn}
{READ fname}{READ lname}{READ meth}{READ mway}{READ capnum}{RCLO}
{IFEX %capdir%%bbsid.cap,,st1}
{EXEC-N del %capdir%%bbsid.cap}
{:ST1} {CAPM screen}{CALL setcap}
{CALO st1,sd2e,Press <Esc> twice}
{CALO st1,sd1e,Escape Key}
{SSLO ss_s,<S>top}
{SSLO ss_|,color graphics (y/N)}
{SSLO ss_|,key to continue}
{LOOK FIRST and LAST name:}
{SETV xfercnt,1}
{IFEX %maildir%%bbsid.re1,,st1x}
{EXEC del %maildir%%bbsid.re1}
{:ST1X} {IFEX %maildir%%bbsid.qwk,,tt1}
{SETV qcntr,0}
{:TLOOP}
{INCR qcntr}
{COMP qcntr,999}{IFCO tloop1}
{IFEX %maildir%%bbsid.%qcntr,tloop}
{EXEC ren %maildir%%bbsid.qwk %bbsid.%qcntr}
{:TLOOP1}
{WRIT %_24h%:%_min%:%_sec -- old %bbsid.qwk has been renamed}
{WRIT ** last .qwk renamed to %bbsid.%qcntr in %maildir}
{WRIT ** be sure to delete old .qwk files when no longer needed}
{SETV qcntr}
{:TT1} {WRIT %_24h%:%_min%:%_sec -- logging on to bbs as %fname %lname}
{COMP lname}{IFCO ,ST1a}
{SEND fname;%_pas}{GOTO st1b}
{:ST1A} {SEND %fname %lname%;%_pas|}
{:ST1B} {COMP mway,bypass}{IFCO mail-b}
{GOLO gdc,^jNO CARRIER^m}
{SSLO ss_s,<S>top}
{SSLO ss_|,key to continue}
{SSLO ss_|,For Main Menu}
{GOLO mail,Enter Selection}
{LOOK ]?}
{:MAIL} {CALL %meth%}
{:MAIL-B} {SETL 30,gto,,}
{SSLO ss_s,<S>top}
{SSLO ss_|,key to continue}
{:MAIL-C} {LOOK HS*^b}{CALL hsl-m}
{CALO mail-c,badxfer,Try Again (Y/n)?}
{LOOK ^jNO CARRIER^m}
{WRIT %_24h%:%_min%:%_sec -- logoff..received NO CARRIER}
{WRIT %_24h%:%_min%:%_sec -- deleting %bbsid.rep if one exists}
{IFEX %maildir%%bbsid.rep,,gby}
{EXEC ren %maildir%%bbsid.rep %bbsid.re1}
{:GBY} {SUBS temp,1,7,%bbsid}
{CALL capupdt}
{ROPE %_hom%hubrun.fon}{SETV count,0}
{:GBL2} {WRIT %_24h%:%_min%:%_sec -- unmarking all %bbsid nodes in dialing directory}
{:GBL2A} {INCR count}
{COMP count,10}{IFCO gbl_x}
{READ line%count}
{COMP line%count}{IFCO gbl_x}
{INST line%count,%bbsid}
{SETV line%count}{IFCO ,gbl2a}
{UNMA %count.}{GOTO gbl2a}
{:GBL_X} {RCLO}
{SETV fname}{SETV lname}{SETV mway}{SETV meth}{SETV capnum}
{SETV temp}{SETV count}
{:RETURN} {RETU}
{:BADXFER}
{WRIT %_24h%:%_min%:%_sec% -- TRANFER FAILED..ATTEMPT #%xfercnt}
{COMP xfercnt,3}
{IFCO bx-1}
{SEND |}{INCR xfercnt}{GOTO mail-c}
{:BX-1}
{WRIT %_24h:%_min%:%_sec% -- no additional attempts will be made..logging off}
{WRIT %_24h:%_min%:%_sec% -- your outbound .REP has been renamed to %bbsid.re1}
{WRIT %_24h:%_min%:%_sec% -- the renamed file is in %maildir}
{SEND n|}{GOTO mail-c}
────────────────> .CAP UPDATE <─────────────────
{:CAPUPDT} {HANG y}{CAPT n}{CLEA}
{WRIT %_24h%:%_min%:%_sec -- modem on-hook}
{COMP capnum,1}{IFCO return}
{SETV capcnt,%capnum}{INCR %capnum}
{IFEX %capdir%%temp%%capcnt.cap,deloc}
{:CAPLOOP} {DECR capcnt}{DECR capnum}
{COMP capcnt,0}{IFCO loopexit}
{IFEX %capdir%%temp%%capcnt.cap,,caploop}
{EXEC-N ren %capdir%%temp%%capcnt.cap %temp%%capnum.cap}
{GOTO caploop}
{:LOOPEXIT} {EXEC ren %capdir%%bbsid.cap %temp%1.cap}
{WRIT %_24h%:%_min%:%_sec -- completed renaming capture files}{RETU}
───────────────────────── Protocol Command Strings ─────────────────────────
{:HSL-M} {PAUS 1}
{WRIT %_24h%:%_min%:%_sec -- begin mail transfer with hslink}
{EXEC-d %hslprg -P%_por -U%rxdir %maildir%%bbsid%.rep}
{WRIT %_24h%:%_min%:%_sec -- finish mail transfer with hslink}{RETU}
────────────────────────── General Purpose Macros ──────────────────────────
{:DELOC} {EXEC del %capdir%%temp%%capcnt%.cap}{GOTO caploop}
{:MMENU} {SEND ~%mway}{RETU}
{:MESGM} {SEND ~m}
{SETL 45,gto,,}
{SSLO ss_s,<S>top}
{SSLO ss_|,key to continue}
{GOLO mesg1,Enter Selection}
{LOOK ]?}
{:MESG1} {SEND ~%mway}{RETU}
{:DOORM} {SEND ~d}
{SETL 45,gto,,}
{SSLO ss_s,<S>top}
{SSLO ss_|,key to continue}
{LOOK Door Number}
{SEND ~%mway|}{RETU}
{:CERROR} {CLEA}
{WRIT}
{WRIT LOG TYPE: Error Report}
{WRIT DATE: %_dat}
{WRIT BBSID: %bbsid}
{WRIT}
{WRIT TIME:}
{WRIT ─────}
{WRIT}
{WRIT %_24h%:%_min%:%_sec -- unable to run script..%_hom%hubrun.ttn file not found}
{WRIT %_24h%:%_min%:%_sec -- reinstall the script with HINSTALL}
{WRIT %_24h%:%_min%:%_sec -- EXIT TO DOS}
{WRIT ----------------------------------------------------------------------------}
{WCLO}
{EXIT}
{:SETCAP} {SETL 60,gto,,}
{SETV d_count,1}{SETV d_rem,%tries}{DECR d_rem}
{WRIT}
{WRIT LOG TYPE: New Session}
{WRIT DATE: %_dat}
{WRIT BBSID: %bbsid}
{WRIT}
{WRIT TIME:}
{WRIT ─────}
{WRIT}
{WRIT %_24h%:%_min%:%_sec -- CONNECT %_mod}
{CAPT y,%capdir%%bbsid.cap}{RETU}
{:NOCONN} {INCR d_count}{DECR d_rem}
{COMP %_dtc,3} {IFCO nc2}
{COMP %_dtc,2} {IFCO ,nocon}
{COMP %_dialrt,BUSY}{IFCO nocon}
{COMP %_dialrt,OK}{IFCO ,nc2a}
{:NOCON} {COMP d_count,%tries}{IFCO nocon_x}
{DISP 1,52,0a,╓─────────────────────────╖
{DISP 2,52,0a,║ Dial Attempt #: ║
{DISP 3,52,0a,║ Attempts Remaining: ║
{DISP 4,52,0a,╙─────────────────────────╜
{DISP 2,70,0c,%d_count}
{DISP 3,74,0c,%d_rem}{RETU}
{:NOCON_X} {ROPE %_hom%hubrun.fon}{SETV count,0}
{:NC_X1} {INCR count}
{COMP count,10}{IFCO unma-l}
{READ line%count}
{COMP line%count}{IFCO unma-l}
{INST line%count,%bbsid}
{SETV line%count}
{IFCO ,unma-L}
{UNMA %count.}{GOTO nc_x1}
{:UNMA-L} {RCLO}
{WRIT}
{WRIT LOG TYPE: Error Report}
{WRIT DATE: %_dat}
{WRIT BBSID: %bbsid}
{WRIT}
{WRIT TIME:}
{WRIT ─────}
{WRIT}
{WRIT %_24h%:%_min%:%_sec -- Unable to connect with BBS..BUSY during entire event}
{RETU}
{:NC2} {COMP %%bbsid,} {IFCO ,nc3}
{SETV %%bbsid,0}
{:NC3} {INCR %%bbsid}
{COMP %%bbsid,2} {IFCO ,return}
{UNMA-L}
{WRIT}
{WRIT LOG TYPE: Error Report}
{WRIT DATE: %_dat}
{WRIT BBSID: %bbsid}
{WRIT}
{WRIT TIME:}
{WRIT ─────}
{WRIT}
{WRIT %_24h%:%_min%:%_sec -- Could not connect..BBS appears to be "down" or "hung"}
{SETV %%bbsid,}{RETU}
{:NC2A} {COMP %%bbsid,} {IFCO ,nc3a}
{SETV %%bbsid,0}
{:NC3a} {INCR %%bbsid}
{COMP %%bbsid,1}{IFCO-G nc3b}
{WRIT}
{WRIT LOG TYPE: Error Report}
{WRIT DATE: %_dat}
{WRIT BBSID: %bbsid}
{WRIT}
{WRIT TIME:}
{WRIT ─────}
{WRIT}
{WRIT %_24h%:%_min%:%_sec -- Could not connect with this BBS..}
{WRIT I received a "NO CARRIER" failure response from the}
{WRIT modem. Compare the value of "S7" in your modem}
{WRIT setting to the value of ^(dct=?^) in your COMMO.SET}
{WRIT Be sure the "S7" value is greater than the "dct"}
{WRIT value. Otherwise, the modem will time out before}
{WRIT COMMO's dialer.}
{:NC3b} {COMP %%bbsid,5} {IFCO ,return}
{UNMA-L}
{WRIT}
{WRIT LOG TYPE: Error Report}
{WRIT DATE: %_dat}
{WRIT BBSID: %bbsid}
{WRIT}
{WRIT TIME:}
{WRIT ─────}
{WRIT}
{WRIT %_24h%:%_min%:%_sec -- Could not connect with this BBS..}
{WRIT I received 5 consecutive "NO CARRIER" responses}
{WRIT from the modem. The board with id of "%bbsid%"}
{WRIT is probably "down" or "hung"..however, there may}
{WRIT be some other problem..}
{SETV %%bbsid,}{RETU}
{:GTO} {WRIT %_24h%:%_min%:%_sec -- script timed out..dropping carrier}
{WRIT %_24h%:%_min%:%_sec -- review %bbsid.cap to see where/why script hung}
{GOTO gby}
{:GDC} {WRIT %_24h%:%_min%:%_sec -- LOST CARRIER!}
{GOTO gby}
{:SD1E} {SEND ~^[}{RETU}
{:SD2E} {SEND ~^[~^[}{RETU}