home *** CD-ROM | disk | FTP | other *** search
/ RUN Flagazine: Run 7 / run7.zip / AARDR.BAS next >
BASIC Source File  |  1992-08-30  |  3KB  |  62 lines
  1. 100 REM AARDRIJKSKUNDELES GWBASIC GEWOON
  2. 110 CLS:KEY OFF
  3. 120 REM arrays dimmen voor landen, hoofdsteden, opgavelijstje en uitslag
  4. 130 DIM LAND$(20),STAD$(20),LIJST$(5),Q(10)
  5. 140 REM LANDEN IN LAND$()
  6. 150 DATA ALGERIJE,EGYPTE,FINLAND,ZWEDEN,NOORWEGEN
  7. 160 DATA IERLAND,IJSLAND,PORTUGAL,SPANJE,CHILI
  8. 170 DATA PERU,BULGARIJE,HONGARIJE,ALBANIE,POLEN
  9. 180 DATA ARGENTINIE,NIEUW ZEELAND,DUITSLAND,CANADA,FILIPPIJNEN
  10. 190 REM HOOFDSTEDEN IN STAD$()
  11. 200 DATA ALGIERS,KAIRO,HELSINKI,STOCKHOLM,OSLO
  12. 210 DATA DUBLIN,REYKJAVIK,LISSABON,MADRID,SANTIAGO
  13. 220 DATA LIMA,SOFIA,BUDAPEST,TIRANA,WARSCHAU
  14. 230 DATA BUENOS AIRES,WELLINGTON,BONN,OTTAWA,MANILA
  15. 240 REM INLEZEN LANDEN IN LAND$() EN HOOFDSTEDEN IN STAD$()
  16. 250 FOR A=1 TO 2
  17. 260   FOR B=1 TO 20
  18. 270     IF A=1 THEN READ LAND$(B) ELSE READ STAD$(B)
  19. 280   NEXT B
  20. 290 NEXT A
  21. 300 REM RANDOMIZER AAN EN USER DEFINED FUNCTIONS VOOR RANDOM GETALLEN
  22. 310 RANDOMIZE TIMER
  23. 320 DEF FN RAND1=INT(RND*20)+1:'----------------------> GETAL ONDER DE 20
  24. 330 DEF FN RAND2=INT(RND*5)+1 :'----------------------> GETAL ONDER DE 5
  25. 340 REM HOOFDLOOP VOOR 10 VRAGEN
  26. 350 FOR A=1 TO 10
  27. 360 LOCATE 7,10:PRINT "Vraag:";A
  28. 370 LOCATE 9,10:PRINT "Wat is de hoofdstad van: ";
  29. 380   Q(A)=FN RAND1:'---------------------> VARIABELE Q(a) KIEST EEN LAND
  30. 390   PRINT LAND$(Q(A)):'-----------> PLAATS EEN WILLEKEURIG GEKOZEN LAND
  31. 400   R=FN RAND2:'--> VARIABELE R (1 - 5) KIEST PLAATS HOOFDSTAD IN LIJST
  32. 410   REM GENESTE LOOP VOOR PLAATSING HOOFDSTEDEN IN LIJST$()
  33. 420   FOR B=1 TO 5
  34. 430     LIJST$(B)=STAD$(FN RAND1)
  35. 440     IF B=R THEN LIJST$(B)=STAD$(Q(A))
  36. 450     LOCATE B+8,50:PRINT B;"- ";LIJST$(B);SPACE$(10)
  37. 460   NEXT B
  38. 470 REM GENESTE LOOP TER VOORKOMING VAN DUBBELE STEDEN IN LIJST$()
  39. 480 FOR C=1 TO 5
  40. 490   FOR D=C+1 TO 5
  41. 500     IF LIJST$(C)=LIJST$(D) THEN B=0:GOTO 420:'HETZELFDE? OVERNIEUW!
  42. 510   NEXT D
  43. 520 NEXT C
  44. 530 LOCATE 16,16:PRINT "Toets (1,2,3,4 of 5)? ";
  45. 540 I$=INKEY$:IF I$="" THEN 540
  46. 550 IF I$="" OR INSTR("12345",I$)=0 THEN BEEP:GOTO 530
  47. 560 I=VAL(I$):'-----> Numerieke variabele I nodig voor verdere verwerking
  48. 570 LOCATE 16,16:PRINT "Uw antwoord: ";LIJST$(I);
  49. 580 IF LIJST$(I)=STAD$(Q(A)) THEN S=S+1:PRINT " is correct":GOTO 600
  50. 590 SOUND 500,3:PRINT " is onjuist"
  51. 600 T=TIMER+1:WHILE T>TIMER:WEND:CLS:'----------------> Wacht een seconde
  52. 610 NEXT A
  53. 620 REM OVERZICHT VAN DE TIEN OPGAVEN - VOLGORDE IN ARRAY Q(10)
  54. 630 CLS
  55. 640 FOR A=1 TO 10
  56. 650   LOCATE A,3
  57. 660   PRINT "De hoofdstad van ";LAND$(Q(A));" is: ",STAD$(Q(A))
  58. 670 NEXT A
  59. 680 REM DE UITSLAG
  60. 690 LOCATE 12,10:PRINT "U beantwoordde";S;"van de";A-1;"vragen correct"
  61. 700 END
  62.