home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
RUN Flagazine: Run 7
/
run7.zip
/
AARDR.BAS
next >
Wrap
BASIC Source File
|
1992-08-30
|
3KB
|
62 lines
100 REM AARDRIJKSKUNDELES GWBASIC GEWOON
110 CLS:KEY OFF
120 REM arrays dimmen voor landen, hoofdsteden, opgavelijstje en uitslag
130 DIM LAND$(20),STAD$(20),LIJST$(5),Q(10)
140 REM LANDEN IN LAND$()
150 DATA ALGERIJE,EGYPTE,FINLAND,ZWEDEN,NOORWEGEN
160 DATA IERLAND,IJSLAND,PORTUGAL,SPANJE,CHILI
170 DATA PERU,BULGARIJE,HONGARIJE,ALBANIE,POLEN
180 DATA ARGENTINIE,NIEUW ZEELAND,DUITSLAND,CANADA,FILIPPIJNEN
190 REM HOOFDSTEDEN IN STAD$()
200 DATA ALGIERS,KAIRO,HELSINKI,STOCKHOLM,OSLO
210 DATA DUBLIN,REYKJAVIK,LISSABON,MADRID,SANTIAGO
220 DATA LIMA,SOFIA,BUDAPEST,TIRANA,WARSCHAU
230 DATA BUENOS AIRES,WELLINGTON,BONN,OTTAWA,MANILA
240 REM INLEZEN LANDEN IN LAND$() EN HOOFDSTEDEN IN STAD$()
250 FOR A=1 TO 2
260 FOR B=1 TO 20
270 IF A=1 THEN READ LAND$(B) ELSE READ STAD$(B)
280 NEXT B
290 NEXT A
300 REM RANDOMIZER AAN EN USER DEFINED FUNCTIONS VOOR RANDOM GETALLEN
310 RANDOMIZE TIMER
320 DEF FN RAND1=INT(RND*20)+1:'----------------------> GETAL ONDER DE 20
330 DEF FN RAND2=INT(RND*5)+1 :'----------------------> GETAL ONDER DE 5
340 REM HOOFDLOOP VOOR 10 VRAGEN
350 FOR A=1 TO 10
360 LOCATE 7,10:PRINT "Vraag:";A
370 LOCATE 9,10:PRINT "Wat is de hoofdstad van: ";
380 Q(A)=FN RAND1:'---------------------> VARIABELE Q(a) KIEST EEN LAND
390 PRINT LAND$(Q(A)):'-----------> PLAATS EEN WILLEKEURIG GEKOZEN LAND
400 R=FN RAND2:'--> VARIABELE R (1 - 5) KIEST PLAATS HOOFDSTAD IN LIJST
410 REM GENESTE LOOP VOOR PLAATSING HOOFDSTEDEN IN LIJST$()
420 FOR B=1 TO 5
430 LIJST$(B)=STAD$(FN RAND1)
440 IF B=R THEN LIJST$(B)=STAD$(Q(A))
450 LOCATE B+8,50:PRINT B;"- ";LIJST$(B);SPACE$(10)
460 NEXT B
470 REM GENESTE LOOP TER VOORKOMING VAN DUBBELE STEDEN IN LIJST$()
480 FOR C=1 TO 5
490 FOR D=C+1 TO 5
500 IF LIJST$(C)=LIJST$(D) THEN B=0:GOTO 420:'HETZELFDE? OVERNIEUW!
510 NEXT D
520 NEXT C
530 LOCATE 16,16:PRINT "Toets (1,2,3,4 of 5)? ";
540 I$=INKEY$:IF I$="" THEN 540
550 IF I$="" OR INSTR("12345",I$)=0 THEN BEEP:GOTO 530
560 I=VAL(I$):'-----> Numerieke variabele I nodig voor verdere verwerking
570 LOCATE 16,16:PRINT "Uw antwoord: ";LIJST$(I);
580 IF LIJST$(I)=STAD$(Q(A)) THEN S=S+1:PRINT " is correct":GOTO 600
590 SOUND 500,3:PRINT " is onjuist"
600 T=TIMER+1:WHILE T>TIMER:WEND:CLS:'----------------> Wacht een seconde
610 NEXT A
620 REM OVERZICHT VAN DE TIEN OPGAVEN - VOLGORDE IN ARRAY Q(10)
630 CLS
640 FOR A=1 TO 10
650 LOCATE A,3
660 PRINT "De hoofdstad van ";LAND$(Q(A));" is: ",STAD$(Q(A))
670 NEXT A
680 REM DE UITSLAG
690 LOCATE 12,10:PRINT "U beantwoordde";S;"van de";A-1;"vragen correct"
700 END