asyncmov
Inscrit le: 05 Mai 2009
Messages: 6
Localisation: France
|
 Post� le: Lun 11 Mai 2009, 9:21 Sujet du message: Re: Recherche disque image de la revue Pom's 25 |
 |
|
| Deckard a �crit: | La revue est disponible en PDF sur le net mais je souhaite avoir le source de l'�diteur de Blocks ProDOS de Marc Rogliano sans me taper la saisie manuelle.
Merci.
JM |
Salut Jean-Marc,
Ai trouv� dans mes archives et dans mon bordel ambient,ce que tu cherches peut-�tre ( ? ) :
Assemblage sous Procode
**************************
TAB 0
DSK R.S.P.D.OBJET
*
****************************
**........................**
**..UTILITAIRE..R.S.P.D...**
**..(READ.&.SAVE.PRODOS)..**
**........MARC.ROGLIANO...**
**........................**
****************************
*.Asm.Procode
*
ORG $6000
*
************************
*..ADRESSES.PAGE.ZERO..*
************************
COL EQU $06
LIG EQU $07
CAR EQU $08
ICONE EQU $09
AFFI.L EQU $1A
AFFI.H EQU $1B
SWITCH EQU $1C
CURS EQU $1E
LB EQU $EB
HB EQU $EC
LB. EQU $ED
HB. EQU $EE
INTER EQU $EF
DISK.L EQU $FA
DISK.H EQU $FB
CURS.COL EQU $FC
CURS.LIG EQU $FD
L.LB EQU $FE
L.HB EQU $FF
*
**********************
*..ADRESSES.SYSTEME..*
**********************
STO80.1 EQU $C001
STO80.0 EQU $C000
PAGE1 EQU $C054
PAGE2 EQU $C055
BUTTON0 EQU $C061; ou touche pomme-ouverte
BUTTON1 EQU $C062; " " " ferm{e
*
**************
*..ROUTINES..*
**************
HOME EQU $FC58
SETTXT EQU $FB39
COUT EQU $FDED
SPKR EQU $C030
BASCALC EQU $FBC1
PRBYTE EQU $FDDA
FRMNUM EQU $DD67
AYINT EQU $E10C
LINPTR EQU $ED24
GIVAYF EQU $E2F2
MOVAF EQU $EB63
FDIVT EQU $EA69
FADDT EQU $E7C1
OUTPRT EQU $FE95
*
*
********************
*..INITIALISATION..*
*.//c.ou.new.//e.?.*
********************
JSR SETTXT;TEXT
LDA #$FF
STA $32;NORMAL
JSR HOME
LDA $BF98;MACHID ProDOS
AND #%00000010 ;Carte 80 col. ?
BNE OLISGOUD
LDA #<MESSERR
LDY #>MESSERR
LDX #$07
STX COL
STX LIG
JSR STROUT40
JSR SOUND
JSR SOUND
JSR SOUND
RTS
OLISGOUD SEC
LDA $FBC0
BEQ IIC
CMP #$E0
BEQ NEW.IIE
CLC
NEW.IIE EQU *
IIC ROR ICONE
LDX #3
SAVEIO LDA $36,X
STA SAVE,X
DEX
BPL SAVEIO
LDA #3
JSR OUTPRT;PR#3
*
********************************
*.AFFICHAGE.DE.LA.PRESENTATION.*
********************************
DEB.80 LDA #17;Mode 40 Colonnes
JSR COUT
JSR HOME
LDA #$01
STA COL
LDA #$01
STA LIG
LDA #<PRES.0
LDY #>PRES.0
JSR STROUT40
LDA #<PRES.1
LDY #>PRES.1
JSR STROUT40
LDA #<PRES.2
LDY #>PRES.2
JSR STROUT40
LDA #<PRES.3
LDY #>PRES.3
JSR STROUT40
LDA #<PRES.4.1
LDY #>PRES.4.1
BIT ICONE
BMI PRESICON
LDA #<PRES.4.2
LDY #>PRES.4.2
PRESICON JSR STROUT40
JSR SOUND
STA $C010
W.KBD LDA $C000
BPL W.KBD
CMP #$8D
BEQ XXX
STA $C010
JSR SOUND
JMP W.KBD
*
*************************
*.CHARGEMENT.DU.BLOCK.0.*
*************************
XXX JSR HOME
LDA #18;Mode 80 Colonnes
JSR COUT
JSR HOME
LDA #$04
STA CURS
LDA #$03
STA TABLE
LDA #$60;Lecteur 1-t{gr{
STA TABLE+1
LDA #$00
STA TABLE+2
STA TABLE+4
STA TABLE+5
LDA #$40
STA TABLE+3
JSR $BF00
DFB $80;READ
DA TABLE
BCC AFF.MENU
JSR ERROR
JMP DEB.80
*
****************************
*.AFICHAGE.COMMANDES+CADRE.*
****************************
AFF.MENU LDA #$00
STA COL
LDA #$01
STA LIG
LDA #<AAA0
LDY #>AAA0
JSR STROUT80
LDA #<AAA0.1
LDY #>AAA0.1
BIT ICONE
BMI AAAI0
LDA #<AAA0.2
LDY #>AAA0.2
AAAI0 JSR STROUT80
LDA #<AAA1
LDY #>AAA1
JSR STROUT80
LDA #<AAA1.1
LDY #>AAA1.1
BIT ICONE
BMI AAAI1
LDA #<AAA1.2
LDY #>AAA1.2
AAAI1 JSR STROUT80
LDA #<AAA2
LDY #>AAA2
JSR STROUT80
LDA #<AAA2.1
LDY #>AAA2.1
BIT ICONE
BMI AAAI2
LDA #<AAA2.2
LDY #>AAA2.2
AAAI2 JSR STROUT80
LDA #<AAA3
LDY #>AAA3
JSR STROUT80
JSR CADRE
LDA #$01
STA SWITCH
LDA #$40
STA L.HB
LDA #$00
STA L.LB
STA CURS.COL
STA CURS.LIG
STA DISK.H
STA DISK.L
JSR AFF...
JSR AFF.
JSR SOUND
STA $C010
*
**************************
*.ATTENTE.D'UNE.COMMANDE.*
**************************
WAIT.KBD LDA $C000
BPL WAIT.KBD
CMP #$88
BNE XXX.0
JMP GAUCHE
XXX.0 CMP #$95
BNE XXX.1
JMP DROITE
XXX.1 CMP #$8B
BNE XXX.2
JMP HAUT
XXX.2 CMP #$8A
BNE XXX.3
JMP BAS
XXX.3 CMP #$A0
BNE XXX.4
JMP SPACE
XXX.4 CMP #$81
BNE XXX.5
JMP C.A.
XXX.5 CMP #$82
BNE XXX.6
JMP C.B.
XXX.6 CMP #$83
BNE XXX.7
JMP C.C.
XXX.7 CMP #$93
BNE XXX.8
JMP C.S.
XXX.8 CMP #$98
BNE XXX.9
JMP C.X.
XXX.9 CMP #$9B
BNE XXX.10
JMP ESC
XXX.10 JSR TEST
BCC XXX.11
JMP ENT.CAR
XXX.11 JSR SOUND
STA $C010
JMP WAIT.KBD
*
*
********************************
*.CARACTERE.ENTRE.0-9.OU.A-F.?.*
********************************
TEST CMP #$B0
BCC TEST0
CMP #$C7
BCS TEST0
CMP #$C1
BCS TEST1
CMP #$BA
BCC TEST1
TEST0 CLC
RTS
TEST1 SEC
RTS
*
****************************
*.CARACTERE.ENTRE.0.ET.9.?.*
****************************
TEST.. CMP #$8D;RET?
BEQ TEST..1
CMP #$B0
BCC TEST..2
CMP #"9"+1
BCS TEST..2
TEST..1 CLC
RTS
TEST..2 SEC
RTS
*
*
********************************
*DEPLACEMENTS.CURSEUR.SUR.ECRAN*
********************************
GAUCHE LDA BUTTON0
BPL XXX.A
JMP GAUCHE..
XXX.A LDA BUTTON1
BPL XXX.B
JMP GAUCHE.
XXX.B LDA CURS.COL
BNE GAUCHE1
JSR SOUND
STA $C010
JMP WAIT.KBD
GAUCHE1 DEC CURS.COL
JSR AFF....
STA $C010
JMP WAIT.KBD
*
DROITE LDA BUTTON0
BPL XXX.C
JMP DROITE..
XXX.C LDA BUTTON1
BPL XXX.D
JMP DROITE.
XXX.D LDA CURS.COL
CMP #$0F
BCC DROITE1
JSR SOUND
STA $C010
JMP WAIT.KBD
DROITE1 INC CURS.COL
JSR AFF....
STA $C010
JMP WAIT.KBD
*
HAUT LDA CURS.LIG
BNE HAUT1
JSR SOUND
STA $C010
JMP WAIT.KBD
HAUT1 ASL
ASL
ASL
ASL
BCS HAUT2
CMP L.LB
BNE HAUT4
SEC
SBC #$10
STA L.LB
JMP HAUT3
HAUT2 CMP L.LB
BNE HAUT4
LDA #$40
STA L.HB
LDA #$F0
STA L.LB
HAUT3 DEC CURS.LIG
JSR AFF.
STA $C010
JMP WAIT.KBD
HAUT4 DEC CURS.LIG
JSR AFF....
STA $C010
JMP WAIT.KBD
*
BAS LDA CURS.LIG
CMP #$1F
BCC BAS1
JSR SOUND
STA $C010
JMP WAIT.KBD
BAS1 INC CURS.LIG
LDA CURS.LIG
ASL
ASL
ASL
ASL
BCC BAS3
CMP L.LB
BNE BAS3
CLC
ADC #$10
STA L.LB
BNE BAS2
LDA #$41
STA L.HB
BAS2 JSR AFF.
STA $C010
JMP WAIT.KBD
BAS3 JSR AFF....
STA $C010
JMP WAIT.KBD
*
******************************
*.DEPLACEMENTS.SUR.LE.DISQUE.*
******************************
GAUCHE. LDA DISK.H
BNE GAUCHE.1
LDA DISK.L
BNE GAUCHE.1
JSR SOUND
STA $C010
JMP WAIT.KBD
GAUCHE.1 SEC
LDA DISK.L
SBC #$01
STA DISK.L
LDA DISK.H
SBC #$00
STA DISK.H
JSR AFF..
STA $C010
JMP WAIT.KBD
*
DROITE. LDA DISK.H
BEQ DROITE.1
LDA DISK.L
CMP #$17
BCC DROITE.1
JSR SOUND
STA $C010
JMP WAIT.KBD
DROITE.1 CLC
LDA DISK.L
ADC #$01
STA DISK.L
LDA DISK.H
ADC #$00
STA DISK.H
JSR AFF..
STA $C010
JMP WAIT.KBD
*
*****************************
*.DEPLACEMENTS.DISQUE.(*10).*
*****************************
GAUCHE.. LDA DISK.H
BNE GAUCHE.2
LDA DISK.L
CMP #$0A
BCS GAUCHE.2
JSR SOUND
STA $C010
JMP WAIT.KBD
GAUCHE.2 SEC
LDA DISK.L
SBC #$0A
STA DISK.L
LDA DISK.H
SBC #$00
STA DISK.H
JSR AFF..
STA $C010
JMP WAIT.KBD
*
DROITE.. LDA DISK.H
BEQ DROITE.2
LDA DISK.L
CMP #$0E
BCC DROITE.2
JSR SOUND
STA $C010
JMP WAIT.KBD
DROITE.2 CLC
LDA DISK.L
ADC #$0A
STA DISK.L
LDA DISK.H
ADC #$00
STA DISK.H
JSR AFF..
STA $C010
JMP WAIT.KBD
*
*
*******************
*.CHANGER.DE.PAGE.*
*******************
SPACE LDA L.HB
CMP #$41
BCS SPACE2
LDA #$41
STA L.HB
LDA #$00
STA L.LB
LDA CURS.LIG
CMP #$10
BCS SPACE1
CLC
LDA #$10
ADC CURS.LIG
STA CURS.LIG
SPACE1 JSR AFF.
STA $C010
JMP WAIT.KBD
SPACE2 LDA #$40
STA L.HB
LDA #$00
STA L.LB
SEC
LDA CURS.LIG
SBC #$10
STA CURS.LIG
JSR AFF.
STA $C010
JMP WAIT.KBD
*
*************************
*.ENTRER.DES.CARACTERES.*
*************************
C.A. STA $C010
C.A.0 JSR AFF.CUR
LDA CURS.COL
LDX #$03
C.A.1 DEX
BEQ C.A.2
CLC
ADC CURS.COL
JMP C.A.1
C.A.2 CLC
ADC #$09
STA COL
LDA CURS.LIG
ASL
ASL
ASL
ASL
SEC
SBC L.LB
LSR
LSR
LSR
LSR
CLC
ADC #$08
STA LIG
LDA #$3F;"?"
STA CAR
JSR COL.LIG
INC COL
JSR COL.LIG
C.A.3 LDA $C000
BPL C.A.3
STA $C010
CMP #$81;Ctr A
BEQ C.A.7
STA INTER
LDA CURS.LIG
ASL
ASL
ASL
ASL
CLC
ADC CURS.COL
SEC
SBC L.LB
TAY
LDA INTER
STA (L.LB),Y
LDA CURS.COL
CMP #$0F
BCC C.A.6
LDA #$00
STA CURS.COL
LDA CURS.LIG
CMP #$1F
BCC C.A.4
LDA #$0F
STA CURS.COL
JSR SOUND
JMP C.A.7
C.A.4 INC CURS.LIG
LDA CURS.LIG
ASL
ASL
ASL
ASL
BCC C.A.5
CMP L.LB
BNE C.A.5
CLC
ADC #$10
STA L.LB
BNE C.A.5
LDA #$41
STA L.HB
C.A.5 JSR AFF
JMP C.A.0
C.A.6 INC CURS.COL
JSR AFF
JMP C.A.0
C.A.7 JSR AFF.
STA $C010
JMP WAIT.KBD
*
*******************
*.ENTRER.UN.BLOCK.*
*******************
C.B. STA $C010
LDA #$06
STA LIG
LDA #$08
STA COL
LDA #$20;espace
STA CAR
JSR COL.LIG
LDX #$00
C.B.1 LDA $C000
BPL C.B.1
STA INTER
JSR TEST..
TXA
PHA
BCC C.B.2
JSR AFF...
JSR SOUND
PLA
STA $C010
JMP WAIT.KBD
C.B.2 PLA
TAX
LDA INTER
AND #$7F
STA $310,X
CMP #$0D
BEQ C.B.4
INX
TXA
PHA
CPX #$03
BEQ C.B.3
LDA INTER
STA CAR
JSR COL.LIG
LDA #$20
STA CAR
INC COL
JSR COL.LIG
PLA
TAX
STA $C010
JMP C.B.1
C.B.3 PLA
C.B.4 LDA #$0D
STA $310,X
CPX #$00
BEQ C.B.7
LDA #$10
STA $B8
LDA #$03
STA $B9
JSR FRMNUM
JSR AYINT
LDA $A0
CMP #$01
BCS C.B.6
STA DISK.H
C.B.5 LDA $A1
STA DISK.L
JSR AFF..
STA $C010
JMP WAIT.KBD
C.B.6 CMP #$02
BCS C.B.7
LDA $A1
CMP #$18
BCS C.B.7
LDA $A0
STA DISK.H
JMP C.B.5
C.B.7 JSR AFF...
JSR SOUND
STA $C010
JMP WAIT.KBD
*
********************
*.CHANGER.DE.DRIVE.*
********************
C.C. LDA TABLE+1
CMP #$E0
BEQ C.C.1
LDA #$E0;Lecteur 2 (= externe sur //c)
STA TABLE+1
LDA #$06
STA LIG
LDA #$1B
STA COL
LDA #$B1;"1"
STA CAR
JSR COL.LIG
INC COL
INC COL
LDA #$32;"2"
STA CAR
JSR COL.LIG
JMP C.C.2
C.C.1 LDA #$60;Lect. 1-terne
STA TABLE+1
LDA #$06
STA LIG
LDA #$1B
STA COL
LDA #$31;"1"
STA CAR
JSR COL.LIG
INC COL
INC COL
LDA #$B2;"2"
STA CAR
JSR COL.LIG
C.C.2 STA $C010
JMP WAIT.KBD
*
************************
*.SAUVER.SUR.DISQUETTE.*
************************
C.S. JSR $BF00
DFB $81;WRITE
DA TABLE
BCS ERREUR.S
STA $C010
JMP WAIT.KBD
ERREUR.S JSR ERROR
JSR AFF.
STA $C010
JMP WAIT.KBD
*
*************************
*."SWITCHER".CARACTERES.*
*************************
C.X. LDA SWITCH
BEQ C.X.1
LDA #$00
STA SWITCH
JMP C.X.2
C.X.1 LDA #$01
STA SWITCH
C.X.2 JSR AFF.
STA $C010
JMP WAIT.KBD
*
***********************
*.SORTIR.DU.PROGRAMME.*
***********************
ESC JSR SOUND
JSR SOUND
LDA #21
JSR COUT
LDX #3
RESETIO LDA SAVE,X
STA $36,X
DEX
BPL RESETIO
JSR HOME
JSR SOUND
JSR SOUND
STA $C010
RTS
*
*
**************************
*.ENTRER.UNE.VALEUR.HEXA.*
**************************
ENT.CAR STA $C010
STA CAR
LDA CURS.COL
LDX #$03
ENT.CAR1 DEX
BEQ ENT.CAR2
CLC
ADC CURS.COL
JMP ENT.CAR1
ENT.CAR2 CLC
ADC #$09
STA COL
LDA CURS.LIG
ASL
ASL
ASL
ASL
SEC
SBC L.LB
LSR
LSR
LSR
LSR
CLC
ADC #$08
STA LIG
JSR COL.LIG
LDA CAR
CMP #$C1
BCS ENT.CAR3
SEC
SBC #$B0
JMP ENT.CAR4
ENT.CAR3 SEC
SBC #$B7
ENT.CAR4 ASL
ASL
ASL
ASL
STA INTER
ENT.CAR5 LDA $C000
BPL ENT.CAR5
JSR TEST
BCS ENT.CAR6
STA $C010
JSR AFF.
JSR SOUND
JMP WAIT.KBD
ENT.CAR6 CMP #$C1
BCS ENT.CAR7
SEC
SBC #$B0
JMP ENT.CAR8
ENT.CAR7 SEC
SBC #$B7
ENT.CAR8 ORA INTER
STA INTER
LDA CURS.LIG
ASL
ASL
ASL
ASL
CLC
ADC CURS.COL
SEC
SBC L.LB
TAY
LDA INTER
STA (L.LB),Y
STA $C010
JSR AFF.
JMP WAIT.KBD
*
*
****************************
*.TRACE.DU.CADRE.ENTOURANT.*
*.LE.CONTENU.DU.BUFFER.....*
****************************
CADRE LDA #$5A;"Z"
STA CAR
JSR COL.LIG
LDA #$4C;"L"
STA CAR
INC COL
CADRE.1 JSR COL.LIG
INC COL
LDA #77
CMP COL
BNE CADRE.1
LDA #$5F;"_"
STA CAR
JSR COL.LIG
INC COL
LDA #$A0;" "
STA CAR
JSR COL.LIG
INC COL
LDA #$5A;"Z"
STA CAR
JSR COL.LIG
CADRE.2 INC LIG
LDA #$00
STA COL
LDA #$5A;"Z"
STA CAR
JSR COL.LIG
INC COL
LDA #$A0;" "
STA CAR
JSR COL.LIG
INC COL
LDA #$A4;"$"
STA CAR
JSR COL.LIG
LDA #$5F;"_"
STA CAR
LDA #77
STA COL
JSR COL.LIG
INC COL
INC COL
LDA #$5A;"Z"
STA CAR
JSR COL.LIG
LDA #23
CMP LIG
BNE CADRE.2
INC LIG
LDA #$00
STA COL
LDA #$5A;"Z"
STA CAR
JSR COL.LIG
LDA #$DF;"_"
STA CAR
INC COL
CADRE.3 JSR COL.LIG
INC COL
LDA #77
CMP COL
BNE CADRE.3
LDA #$5F;"_"
STA CAR
JSR COL.LIG
INC COL
LDA #$A0;" "
STA CAR
JSR COL.LIG
INC COL
LDA #$52;"R"
STA CAR
JSR COL.LIG
RTS
*
*
******************************
*.AFFICHER.CONTENU.DU.BUFFER.*
******************************
AFF LDA L.LB
STA AFFI.L
LDA L.HB
STA AFFI.H
LDA #$07;LIG8
AFF0 PHA
JSR BASCALC
LDA #$03;COL3
STA $24;CH
LDA AFFI.H
AND #$01
BEQ AFF1
LDA #$B1;"1"
JMP AFF2
AFF1 LDA #$B0;"0"
AFF2 JSR COUT
LDA AFFI.L
JSR PRBYTE
LDA #$A0
JSR COUT
LDA #$A0
JSR COUT
LDA #$00
AFF3 PHA
LDA #$A0
JSR COUT
PLA
PHA
TAY
LDA (AFFI.L),Y
JSR PRBYTE
PLA
TAY
INY
CPY #16
TYA
BCC AFF3
LDA #$A0
JSR COUT
LDA #$A0
JSR COUT
LDA #$BA;":"
JSR COUT
LDA #$A0
JSR COUT
LDA #60
STA COL
PLA
PHA
TAX
INX
TXA
STA LIG
LDA #$00
AFF4 PHA
TAY
LDA (AFFI.L),Y
STA INTER
LDA SWITCH
BEQ AFF6
LDA INTER
BEQ AFF5
ORA #$80
STA INTER
JMP AFF6
AFF5 LDA #"."
STA INTER
AFF6 LDA INTER
STA CAR
SEC ;++
ROR ICONE;++
JSR COL.LIG
ROL ICONE;++
INC COL
PLA
TAY
INY
TYA
CPY #16
BCC AFF4
PLA
TAY
INY
CPY #23
BCS AFF7
CLC
LDA AFFI.L
ADC #16
STA AFFI.L
LDA #$00
ADC AFFI.H
STA AFFI.H
TYA
JMP AFF0
AFF7 RTS
*
*
***************************
*.AFFICHER.BUFFER+CURSEUR.*
***************************
AFF. JSR AFF
JSR AFF.CUR
RTS
*
*
********************************
*.CHARGER.ET.AFFICHER.UN.BLOCK.*
********************************
AFF.. LDA DISK.L
STA TABLE+4
LDA DISK.H
STA TABLE+5
JSR $BF00
DFB $80;READ
DA TABLE
BCS ERREUR
JSR AFF...
JSR AFF.
RTS
ERREUR JSR EFFACAGE
JSR ERROR
JSR AFF...
JSR AFF.
RTS
*
*
****************************
*.AFFICHER.NUMERO.DU.BLOCK.*
****************************
AFF... LDA CURS
STA LIG
LDA #79
STA COL
LDA #$5A;"Z"
STA CAR
JSR COL.LIG
LDA DISK.H
LDY DISK.L
JSR GIVAYF
JSR MOVAF
LDA #$00
LDY #14
JSR GIVAYF
JSR FDIVT
JSR MOVAF
LDA #$00
LDY #4
JSR GIVAYF
JSR FADDT
JSR AYINT
LDA $A1
STA CURS
STA LIG
LDA #$20
STA CAR
JSR COL.LIG
LDA #$05;LIG6
JSR BASCALC
LDA #$08;COL8
STA $24;CH
LDX DISK.L
LDA DISK.H
JSR LINPTR
LDA DISK.H
BNE AFF...2
LDA DISK.L
CMP #$64
BCS AFF...2
CMP #$0A
BCS AFF...1
LDA #$A0
JSR COUT
AFF...1 LDA #$A0
JSR COUT
AFF...2 LDA #$0E
STA $24;CH
LDA DISK.H
BEQ AFF...3
LDA #"1"
JMP AFF...4
AFF...3 LDA #"0"
AFF...4 JSR COUT
LDA DISK.L
JSR PRBYTE
RTS
*
*
*******************************
*.EFFACER.ET.AFFICHER.CURSEUR.*
*******************************
AFF.... LDA TABLE1;COL
LDX #$03
AFF....1 DEX
BEQ AFF....2
CLC
ADC TABLE1
JMP AFF....1
AFF....2 CLC
ADC #$08
STA $24;CH
LDA TABLE1+1;LIG
ASL
ASL
ASL
ASL
SEC
SBC L.LB
LSR
LSR
LSR
LSR
CLC
ADC #$07
JSR BASCALC
LDA #$A0
JSR COUT
LDA TABLE1+1
ASL
ASL
ASL
ASL
CLC
ADC TABLE1
SEC
SBC L.LB
TAY
LDA (L.LB),Y
JSR PRBYTE
LDA #$A0
JSR COUT
JMP AFF.CUR
*
*
***********************
*.AFFICHER.LE.CURSEUR.*
***********************
AFF.CUR LDA CURS.COL
STA TABLE1
LDA CURS.LIG
STA TABLE1+1
LDA #40
STA $24;CH
LDA #$05
JSR BASCALC
LDA CURS.LIG
ASL
ASL
ASL
ASL
STA INTER
BCC AFF.X1
LDA #"1"
JMP AFF.X2
AFF.X1 LDA #"0"
AFF.X2 JSR COUT
LDA CURS.COL
ORA INTER
JSR PRBYTE
LDA CURS.COL
LDX #$03
AFF.CUR1 DEX
BEQ AFF.CUR2
CLC
ADC CURS.COL
JMP AFF.CUR1
AFF.CUR2 CLC
ADC #$08
STA $24;CH
LDA CURS.LIG
ASL
ASL
ASL
ASL
SEC
SBC L.LB
LSR
LSR
LSR
LSR
CLC
ADC #$07
JSR BASCALC
LDA #">"
JSR COUT
LDA #$3F;INVERSE
STA $32
LDA CURS.LIG
ASL
ASL
ASL
ASL
CLC
ADC CURS.COL
SEC
SBC L.LB
TAY
LDA (L.LB),Y
JSR PRBYTE
LDA #$FF;NORMAL
STA $32
LDA #"<"
JSR COUT
RTS
*
*
*********************
*.EFFACER.LE.BUFFER.*
*********************
EFFACAGE LDA #$40
STA HB
LDA #$00
STA LB
LDY #$00
EFF.1 LDA #$00
STA (LB),Y
INY
BNE EFF.1
LDA #$41
STA HB
LDY #$00
EFF.2 LDA #$00
STA (LB),Y
INY
BNE EFF.2
RTS
*
*
*****************************
*.ROUTINE.DE.TRAITEMENT.DES.*
*.ERREURS.DU.DISQUE.........*
*****************************
ERROR LDA #$08
STA LIG
JSR ERROR.
LDA #<ERROR.0
LDY #>ERROR.0
JSR STROUT80
JSR ERROR.
LDA #<ERROR.1
LDY #>ERROR.1
JSR STROUT80
JSR ERROR.
LDA #<ERROR.2
LDY #>ERROR.2
JSR STROUT80
JSR ERROR.
LDA #<ERROR.1
LDY #>ERROR.1
JSR STROUT80
JSR ERROR.
LDA #<ERROR.3
LDY #>ERROR.3
JSR STROUT80
LDA #<ERROR4.1
LDY #>ERROR4.1
BIT ICONE
BMI ERICON
LDA #<ERROR4.2
LDY #>ERROR4.2
ERICON JSR STROUT80
JSR ERROR.
LDA #<ERROR.1
LDY #>ERROR.1
JSR STROUT80
JSR ERROR.
LDA #<ERROR.5
LDY #>ERROR.5
JSR STROUT80
JSR ERROR.
JSR SOUND
JSR SOUND
STA $C010
ERROR0 LDA $C000
BPL ERROR0
CMP #$8D
BEQ ERROR1
STA $C010
JSR SOUND
JMP ERROR0
ERROR1 RTS
ERROR. LDA #27
STA COL
RTS
*
*
******************************
**..........................**
**.UTILITAIRE.LIGNE.COLONNE.**
**..........................**
******************************
*
*
COL.LIG LDA LIG
JSR CALCUL
LDA COL
LSR
BCS COLONNE
STA STO80.1
STA PAGE2
JSR COLONNE
STA PAGE1
STA STO80.0
RTS
COLONNE TAY
LDA CAR
BIT ICONE
BMI X6;Icones disponibles ?
CMP #$5A; sinon conversion
BEQ X1
CMP #$5F
BNE X2
X1 LDA #"!"
X2 CMP #$4C
BEQ X3
CMP #$DF
BNE X4
X3 LDA #"-"
X4 CMP #$51
BNE X5
LDA #"v"
X5 CMP #$52
BNE X6
LDA #$DE
X6 EQU *
STA (LB),Y
RTS
CALCUL CMP #$09
BCS CAL1
LDY #$00
STY LB
JMP SUITE
CAL1 CMP #$11
BCS CAL2
LDY #$28
STY LB
SEC
SBC #$08
JMP SUITE
CAL2 LDY #$50
STY LB
SEC
SBC #$10
SUITE LDY #$04
STY HB
TAX
DEX
BEQ END
BOUCLE CLC
LDA #$80
ADC LB
STA LB
LDA #$00
ADC HB
STA HB
DEX
BNE BOUCLE
END RTS
*
*
*************
**.........**
**..SOUND..**
**.........**
*************
*
SOUND LDX #$FF
SOUND1 LDA #$58
SOUND2 LDY #$1B
SOUND3 DEY
BNE SOUND3
BIT SPKR
TAY
SOUND4 DEY
BNE SOUND4
SBC #$01
BEQ SOUND1
BIT SPKR
DEX
BNE SOUND2
RTS
*
*
*********************
**.................**
**..STROUT.&.COUT..**
**.................**
*********************
*
STROUT40 STA LB.
STY HB.
LDY #$00
STR.40 TYA
PHA
LDA (LB.),Y
BNE STR.40.
PLA
RTS
STR.40. JSR COUT.40
PLA
TAY
INY
JMP STR.40
*
COUT.40 CMP #$8D;RETURN?
BEQ RET40
STA CAR
JSR COL.LIG
INC COL
INC COL
RTS
RET40 INC LIG
LDA #$01
STA COL
RTS
*
STROUT80 STA LB.
STY HB.
LDY #$00
STR.80 TYA
PHA
LDA (LB.),Y
BNE STR.80.
PLA
RTS
STR.80. JSR COUT.80
PLA
TAY
INY
JMP STR.80
COUT.80 CMP #$8D;RETURN?
BEQ RET80
STA CAR
JSR COL.LIG
INC COL
RTS
RET80 INC LIG
LDA #$00
STA COL
RTS
****************
**............**
**..MESSAGES..**
**............**
****************
PRES.0 DS 4,$8D
DS 8," "
DS 23,"_"
DFB $8D
DS 7," "
DFB $5A
DS 23," "
DFB $5F,$8D
DS 7," "
DFB $5A
DS 6," "
ASC "R.S.P.D.:"
DS 8," "
DFB $5F,$8D,$00
PRES.1 DS 7," "
DFB $5A
DS 6," "
DS 9,'L'
DS 8," "
DFB $5F,$8D
DS 7," "
DFB $5A
ASC " (Read & Save ProDos) "
DFB $5F,$8D
DS 7," "
DFB $5A
DS 23," "
DFB $5F,$8D,$00
PRES.2 DS 7," "
DFB $5A
ASC " Utilitaire de Lecture "
DFB $5F,$8D
DS 7," "
DFB $5A
ASC " et d'ecriture directe "
DFB $5F,$8D
DS 7," "
DFB $5A
ASC " sur Disquettes ProDOS "
DFB $5F,$8D
DS 7," "
DFB $5A
DS 23," "
DFB $5F,$8D,$00
PRES.3 DS 7," "
DFB $5A
ASC " par Marc ROGLIANO "
DFB $5F,$8D
DS 7," "
DFB $5A
DS 23," "
DFB $5F,$8D
DS 8," "
DS 23,$4C
DS 4,$8D
DS 15," "
ASC "Appuyez sur "
DFB $00
PRES.4.1 DFB $4D,$A0,$4E,$8D
DS 15," "
DS 13,$4C
DFB $8D,$00
PRES.4.2 ASC "RETURN "
DFB $20,$8D
DS 15," "
DS 18,$4C
DFB $8D,$00
AAA0 ASC "R.S.P.D.: Utilitaire de Lecture et d'Ecriture sur disks ProDOS par Marc ROGLIANO"
DFB $8D
ASC " Commandes:"
DFB $5A,$A0,$00
AAA0.1 DFB $48,$A0,$55,$A0
DFB $4B,$A0,$4A,$00
AAA0.2 ASC "fleches"
DFB $00
AAA1 ASC " : Deplacements sur l'ecran "
DFB $5F
ASC "^A : Entrer caracteres"
DS 4," "
DFB $5F,$8D
DS 2," "
DS 9,$4C
DFB $A0,$5A,$A0,$00
AAA1.1 DFB $40,$A0,$48
DFB $A0,$55
ASC " : Deplacements sur Disquette "
DFB $00
AAA1.2 ASC "Pomme fermee <- -> : `` sur Disque "
DFB $00
AAA2 DFB $5F
ASC "^B : Entrer un Block"
DS 6," "
DFB $5F,$A0
DFB $A0,$51,$8D
ASC " (ESC: "
DFB $5A,$A0,$00
AAA2.1 DFB $41,$A0
DFB $48,$A0,$55
ASC " : Deplacements (*10)"
DS 9," "
DFB $00
AAA2.2 ASC "Pomme ouverte <- -> : Depl. x 10 "
DFB $00
AAA3 DFB $5F
ASC "^C : Changer de Lecteur"
DS 3," "
DFB $5F,$A0,$A0
DFB $5A,$8D
ASC " Quitter) "
DFB $5A
ASC " ESPACE : Changer de Page"
DS 10," "
DFB $5F
ASC "^S : Sauver sur Disquette "
DFB $5F,$A0,$A0,$5A,$8D
ASC " BLOCK:"
DS 5," "
ASC "($ ) DRIVE: "
DFB $31
ASC "/2 OCTET: $"
DS 9," "
DFB $5F
ASC "^X : Switcher Caracteres "
DFB $5F,$A0,$A0
DFB $5A,$8D,$00
*
ERROR.0 ASC " "
DS 24,"_"
ASC " "
DFB $8D,$00
ERROR.1 DFB $5A
DS 24," "
DFB $5F,$8D,$00
ERROR.2 DFB $5A,$A0
ASC ">>>"
DFB $05,$72,$72,$65
DFB $75,$72,$20,$04
DFB $69,$73,$71,$75
DFB $65,$74,$74,$65
ASC "<<<"
DFB $A0,$5F,$8D,$00
ERROR.3 DFB $5A
DS 5," "
ASC "APPUYEZ SUR "
DFB $00
ERROR4.1 DFB $4D
DS 6," "
DFB $5F,$8D,$00
ERROR4.2 ASC "RETURN "
DFB $5F,$8D,$00
ERROR.5 ASC " "
DS 24,$4C
ASC " "
DFB $00
MESSERR ASC "IL FAUT UNE CARTE 80 COLONNES"
DFB $00
DFB $BF,$19,$04
SAVE DS 4
TABLE DS 7
TABLE1 EQU *
*
*
******************************************
Disque image du magazine Pom's 25 upload� pour ArBr sur l'espace d'�change il y a quelques mois ( en attendant la Maj de son site  )
@+ Philippe |
|
FAQ 
Rechercher 
Liste des Membres 
Groupes d'utilisateurs
S'enregistrer
Profil 
Se connecter pour v�rifier ses messages priv�s 
Connexion 
