CP/M/CPM_CDROM.iso/lambda/soundpot/p/sbasics.lbr/MATH.BZS/MATH.BAS

BASIC Source File | 1993-10-25 | 3.1 KB | 148 lines

$lines
var l,m,n,answer = integer
var low_lim,up_lim,tries,i = integer
var sym = char

procedure addition
     begin
    l=m+n
    print m;" + " ; n ; " = ";
     end
end

procedure subtraction
     begin
    l=m-n
    print m;" - " ; n ; " = ";
     end
end

procedure multiplication
     begin
    l=m*n
    print m;" * " ; n ; " = ";
     end
end

procedure division
     begin
    l=m/n
    print m;" / " ; n ; " = ";
     end
end


function operand=integer
     var ran_num=integer
     begin
    ran_num=int(rnd(1)*up_lim+1)
    if ran_num<low_lim then ran_num=operand
     end
end=ran_num

comment
this procedure finds 2 random numbers within the limits
and places the larger in m. it also insures that m/n
has an integer value.
end
procedure get_numbers
        m=operand
        n=operand
    if sym = '/' and int(m/n) <> (m/n) then get_numbers
    if n>m then
           begin
             l=m
             m=n
             n=l
           end

end

procedure math_time
    get_numbers
    i=0
      begin
        case sym of
                '+' : addition
                '-' : subtraction
                '*' : multiplication
                '/' : division
        end
      end
end



rem: this procedure gets your answer
procedure get_answer
        input answer
        if answer <> -1 then
          begin
            if answer = l then
              begin
                print "YOU ARE RIGHT!"
                math_time
                get_answer
              end
            else
              begin
                i=i+1
             if i<tries then
                  begin
                    print "SORRY, WRONG ANSWER ...PLEASE TRY AGAIN "
                    get_answer
                  end
                else
                  begin
                    print "THAT IS " ; i ; " TRIES"
                    print "THE CORRECT ANSWER IS ";l
                    math_time
                    get_answer
                  end
               end
           end
end


rem: the main program begins

text 0,&

****************************************************************************
                     THIS IS THE MATH QUIZ GAME
****************************************************************************


INPUT ONE OF THE FOLLOWING SYMBOLS FOR THE MATH OPERATION YOU WANT TO TRY:

INPUT "+" FOR ADDITION
INPUT "-" FOR SUBTRACTION
INPUT "*" FOR MULTIPLICATION
INPUT "/" FOR DIVISION
INPUT "Q" WHEN YOU WANT TO QUIT THIS GAME

TO CHANGE THE TYPE OF MATH OPERATION YOU WANT TO DO, TYPE -1  WHEN THE
COMPUTER GIVES YOU A NEW PROBLEM.

&

repeat
  begin
    input "INPUT MATH OPERATION SYMBOL "; sym
    if sym = '+' or sym = '-' or sym = '*' or sym = '/' then
      begin
        print "INPUT THE LOWER AND UPPER LIMITS OF YOUR NUMBERS (L,U) ";
        input low_lim,up_lim
        print "INPUT THE NUMBER OF INCORRECT ANSWERS YOU ARE ALLOWED ";
        input tries
        math_time
        get_answer
      end

  end
    until sym = 'Q' or sym = 'q'