home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Black Box 4
/
BlackBox.cdr
/
editors
/
amac41.arj
/
MACR31.QM
< prev
next >
Wrap
Text File
|
1991-08-26
|
43KB
|
876 lines
* MacroMaker MACR31.QM, v3.1b
* Written by Tom Hogshead
* With Macro Contributions By Tim Farley
* August 4, 1991
*
* @(2) - Refresh Macro Buffer With "Standard" Macfile
* @(3) - Merges Designated Txtfile With Current Macros, Reads Macfile
* @(4) - Appends Txtfile To Standard Txtfile & Macfile, Reads Macfile
* @(5) - Gets Error File In Window
* @(6) - Makes Dummy Txtfile From Current Macros
* @(7) - Makes & Reads Dummy Macfile From Txtfile
* @(t) - Makes & Reads Dummy Macfile From Txtfile, SMALL
* @(8) - Reads Macfile of Current Txtfile
* @(9) - Makes Macfile of Current Txtfile, No Macfile Read
* @(0) - Makes & Reads Macfile of Txtfile, With Error Window
* @(q) - Makes & Reads Macfile of Txtfile, SMALL
* @(f1)- Makes Single Column Macro
* @(f2)- Puts Command Key Beside A Single Command In A Macro
* @(f3)- Puts Command Key Beside ALL Commands In A Macro
* @(f4)- Gets A Single Command And It's Key On Screen
* @(f5)- Test TRUE/FALSE Results, Tim Farley, Author
* @(h) - Select Index Item With Cursor Line, Then <Enter> |chg
*
* (Index) Use - How to locate macro or item from Index using @h
* (Description) - MacroMaker Macros
* (Requirements) - and use
* (Startup) - See MACR.DOC for startup instructions
* (Macros) - MacroMaker Macros
* (Other) Macros - not included
* (Version) history
*
*-- eoi
* (Index) Use;
*
* To locate a macro or item in this file, press @h, place the cursor
* line on the desired item in the Index above, and press <enter>.
* See BOOKxx.QM for more details.
* (Description):
* (MacroMaker) MACR31.ZIP Contains QEdit macros to easily convert
* macros to & from text/binary (txtfile/macfile) using QMAC macro
* translator.
* See RFRMxx.QM for other commenting and un-commenting macros.
* (Requirements) and Use (see MACR.DOC for (startup) instructions):
*
* 1. Txtfile name extension MUST be [file].QM, Macfile [file].MAC.
* 2. Change ram disk c:\ (also in batch files) for your setup.
* Ram disk is optional but faster than a hard drive. Use any
* active drive letter to replace c:\.
* 3. Batch files must be in path or current directory. INSERT must
* be ON. Run macros and press Enter to continue when paused.
* 4. Modify "e:\qe\MACROS.xxx" in macros to your "standard" macro.
* Be careful to use or not use extension as shown, with spaces.
* 5. Be sure to change "e:\qe\qconfig.dat" in the macros @f2 -
* @f4 below to the location of your qconfig.dat in your
* setup, and convert with QMAC.
* In order for macros @f2 - @f4 to find a command in QCONFIG.DAT, there
* must be at least eight blank spaces betweeen the end of the command
* key and the beginning of the command. If your QCONFIG.DAT has fewer
* spaces, the macros must be modified in the first 'FIND' line.
* Insert must be ON.
* Replacing C:\ with a ram drive will make the macros run considerably
* faster.
* These macros require "QEdit and QMAC v2.1, February, 1990" or later.
* To BEGIN, just type "START MACR" <Enter>. All pertinent files will be
* loaded in the "Ring" for viewing, and MACR31.MAC is read.
* Alternatively, type "START MACR 0" <Enter> and the disk copies of all
* files in the "Ring" will be loaded ready for editing, saving time.
*
*┌───────────────────────────────────────────────────────────┐
*│ @(2) Refreshes macro buffer with "standard" macfile │
*└───────────────────────────────────────────────────────────┘
* Remember you MUST modify "e:\qe\macros.mac" with your "standard" macfile.
*
@2 MacroBegin
MacroRead
"e:\qe\macros.mac" *<<<<<CHANGE
Return
*
* 38 bytes Fri 09-14-1990 14:05:43
*
*┌────────────────────────────────────────────────────────────────┐
*│ @(3) Merges designated txtfile [file].qm with current macros │
*└────────────────────────────────────────────────────────────────┘
@3 macrobegin
editfile "NUL" return * load NUL file
"Merge macro ?" cursorright * query for macro name,
* no extension
markcharacter * start mark
pause cut quit * cut macro name (no extension)
* to scrap
macrowrite "dum4.mac" return return * write current macros to temp
* file
DOS "qmacM " paste return return * append designated macros to
* current macros
onewindow * close all windows
horizontalwindow *
editfile "c:!" return * open error file in window
quit * quit in case earlier error
* file loaded
editfile return * load error file in window 1
insertdate inserttime * put date in c:!
find "(" return return * find first error
jfalse NOERROR: * if no error go to NOERROR
wordright *ELSE move to error line #
unmarkblock * un-mark any marked blocks
markblockbegin wordright * mark error line #
cursorleft * move back one space to end of line #
markblockend copy * mark and copy line # to scrap
savefile * save error file
prevwindow * go back to txtfile we want to append
* to
gotoline paste return * move to line with first error
makectrofscreen * put cursor in center of screen
pause zoomwindow * zoomwindow for better viewing
jump CONTINUE: *
NOERROR: * if no errors, come here
prevwindow zoomwindow * enlarge txtfile we started in
CONTINUE:
editfile "dum4.qm" return * load txtfile with appended macro
* on bottom
splitline newfile "N" return * re-load in case previous copy is
* loaded
endfile addline * insert blank line for footing
"*...Tom Hogshead " * insert name (change to yours)
insertdate inserttime * insert date and time
"Appended " *
paste * paste file name we are appending
endline * move to end of file name
".qm to current macros" * finish message
unmarkblock * un-mark all blocks
savefile * save new txtfile with appended
* macro
macroread "dum4.mac" return * read current + appended macros
*
* 262 bytes Wed 05-01-1991 12:26:00
*
*┌───────────────────────────────────────────────────────────┐
*│ @(4) Appends txtfile [file].qm to a "standard" txtfile │
*│ named macros.qm and reads appended macfile. │
*└───────────────────────────────────────────────────────────┘
* Remember you MUST modify "e:\qe\macros" (no extension) in this
* macro to your "standard" macfile.
* Be careful that the macro size of the txtfile you are appending plus
* the size of your standard macros do not exceed 2k, the macro buffer
* limitation. If this occurs, you will get an error message, and the
* macros will not be appended.
@4 macrobegin
unmarkblock * unmarkblock
savefile * save current txtfile in case changed
DOS "qmacTA2 " * append
currentfilename * current txtfile
backspace backspace backspace * delete current txtfile extension
" " * add space
"e:\qe\macros" *<<<<<CHANGE * Standard macros name, no extension
return * start batch file
begline insertline * insert blank line
dropanchor currentfilename * put current file name on line
storescrbuff "1" return * store to scratch 1 for footing
cut * cut name to scrap which deletes line
editfile "c:!" return quit * quit error file if loaded
editfile paste return * get back to current txtfile
onewindow * close all windows
horizontalwindow * open window
editfile "c:!" return * get error file in window 2
insertdate inserttime * put date in c:!
find "(" return return * find first error
jfalse NOERROR: * if no errors, go to NOERROR
wordright *ELSE move to error line #
unmarkblock * un-mark any marked blocks
markblockbegin wordright * mark error line #
cursorleft * move back one space to end of line #
markblockend copy * mark and copy line # to scrap
savefile * save error file
prevwindow * go back to txtfile we want to append
* to
gotoline paste return * move to line with first error
makectrofscreen * put cursor in center of screen
pause zoomwindow * zoomwindow for better viewing
jump CONTINUE: *
NOERROR: *
prevwindow zoomwindow * no error, go to
CONTINUE:
editfile "c:$" return quit *
editfile return killfile * load dum3.qm
editfile "dum3.qm" return quit
editfile return * load dum3.qm
begfile cursordown endline * stamp
cursorright
"from:" cursorright
getscrbuff "1" return
unmarkblock endfile return * line on bot
"*" cursorright "Tom Hogshead"
cursorright cursorright
insertdate inserttime * - name/date bot
"Appnd:" cursorright
getscrbuff "1" return unmarkblock * - file on bot
savefile macroread currentfilename * read dum3.mac
backspace backspace "MAC" return *
*
* 229 bytes Wed 05-01-1991 12:45:43
*
*┌──────────────────────────────────────────────────────────────┐
*│ @(5) Gets error file (c:!) in window. Press ENTER to remove│
*└──────────────────────────────────────────────────────────────┘
@5 macrobegin
horizontalwindow * make window
editfile "c:!" return * load c:!
makectrofscreen pause zoomwindow * zoom on pause
quit * quit c:!
*
* 17 bytes Fri 09-14-1990 14:05:55
* ┌────────────────────────────────────────────┐
* │ @(6) Makes txtfile from current macros │
* └────────────────────────────────────────────┘
@6 macrobegin
macrowrite "c:$.mac" return return * write to c:$.mac
DOS "qmact c:$" return return * make c:$.qm
editfile "c:$.qm" return quit * quit old c:$.qm
editfile return * load new c:$.qm
killfile * kill c:$.qm
endfile * to see newest macro
*
* 61 bytes Sat 09-15-1990 14:26:40
*
*┌───────────────────────────────────────────────────────────┐
*│ @(7) Copies txtfile [file].QM to dummy txtfile. │
*│ Makes and reads macfile. │
*└───────────────────────────────────────────────────────────┘
@7 macrobegin
unmarkblock *
writeblock "c:$.qm" return * copy file.qm
begline insertline *
dropanchor currentfilename * get name
storescrbuff "1" return cut * to scratch
editfile return quit * load/quit c:$.qm |3.1
editfile return * load c:$.qm
DOS "qmacbj c:$" return * make c:$.mac
begline insertline *
dropanchor currentfilename *
cut * get name to scrap
editfile "c:!" return quit * quit error file if already loaded
editfile paste return * laod current file
onewindow * close all windows
horizontalwindow * one window
editfile "c:!" return * load error file in window 2
insertdate inserttime * put date and time
find "(" return return * find first error
jfalse NOERROR: * if no errors, go to NOERROR
wordright *ELSE move to error line #
unmarkblock * un-mark any marked blocks
markblockbegin wordright * mark error line #
cursorleft * move back one space to end of line #
markblockend copy * mark and copy line # to scrap
savefile * save error file
prevwindow * go back to txtfile we want
* to append to
gotoline paste return * move to line with first error
makectrofscreen * put cursor in center of screen
pause zoomwindow * zoomwindow for better viewing
jump CONTINUE: *
NOERROR: * if no errors, come here
prevwindow zoomwindow * enlarge txtfile we started in
CONTINUE: *
DOS "qmact c:$" return return * make c:$.qm
editfile "c:$.qm" return quit
editfile return * load c:$.qm
endfile addline *
"*" insertdate inserttime * - name/date bot
getscrbuff "1" return unmarkblock * - file on bot
killfile * kill c:$.qm
macroread currentfilename * read c:$.mac
backspace backspace "MAC" return *
*
* 185 bytes Wed 05-01-1991 13:19:11
* 173 bytes Thu 05-16-1991 11:52:26 (TH removed unnecessary c:$.qm)
*
*┌───────────────────────────────────────────────────────────┐
*│ @(8) READS macfile from txtfile [file].QM │
*└───────────────────────────────────────────────────────────┘
@8 macrobegin
macroread * start macroread
currentfilename * with current file name
backspace backspace * delete qm
"mac" * add mac
return * and do it
*
* 15 bytes Fri 09-14-1990 14:06:11
*
*┌───────────────────────────────────────────────────────────┐
*│ @(9) Makes macfile from txtfile [file].QM, NO read │
*└───────────────────────────────────────────────────────────┘
@9 macrobegin
savefile * save file
DOS "qmacb " * start batch file
currentfilename * with current file
backspace backspace backspace * delete extension
return * and do it
*
* 23 bytes Fri 09-14-1990 14:06:14
*
*┌───────────────────────────────────────────────────────────┐
*│ @(0) Makes macfile from txtfile [file].QM │
*│ Loads macfile [file].MAC, With error window. │
*└───────────────────────────────────────────────────────────┘
@0 macrobegin
savefile * save file
DOS "qmacbj " * begin batch file
currentfilename * with current file name
backspace backspace backspace * delete dot + extension
return * and do it
unmarkblock * un-mark all blocks
insertline begline * insert temp line
dropanchor currentfilename cut * cut name to scrp
editfile "c:!" return quit * quit c:!
editfile paste return * load current file
onewindow * close all windows
horizontalwindow * one window
editfile "c:!" return * load error file in window 2
insertdate inserttime * put date and time
find "(" return return * find first error
jfalse NOERROR: * if no errors, go to NOERROR
wordright *ELSE move to error line #
unmarkblock * un-mark any marked blocks
markblockbegin wordright * mark error line #
cursorleft * move back one space to end of line #
markblockend copy * mark and copy line # to scrap
savefile * save error file
prevwindow * go back to txtfile we want to append
* to
gotoline paste return * move to line with first error
makectrofscreen * put cursor in center of screen
pause zoomwindow * zoomwindow for better viewing
jump CONTINUE: *
NOERROR: * if no errors, come here
prevwindow zoomwindow * enlarge txtfile we started in
CONTINUE: *
macroread * begin macroread
currentfilename * with current file
backspace backspace * delete qm
"mac" * add mac
return * and read macfile
*
* 94 bytes Wed 05-01-1991 13:38:07
*
*┌───────────────────────────────────────────────────────────┐
*│ @(t) Copies txtfile [file].QM to dummy txtfile. │
*│ Makes and reads macfile, small version │
*└───────────────────────────────────────────────────────────┘
* This is an alternate version of @7. Errors during macro conversion are
* not saved in an error window. It is much smaller than @7.
@t MacroBegin *
unmarkblock *
WriteBlock "c:$.qm" Return * copy file/block to temp file
DOS "qmacb c:$" Return Return * make temp macfile
DOS "qmact c:$" Return Return * make temp txtfile
EditFile "c:$.qm" Return Quit * quit temp file from ring
EditFile Return * load temp txtfile
killfile * kill temp file
MacroRead "c:$.Mac" Return * read temp macfile
*
* 95 bytes Fri 09-14-1990 14:06:07
*
*┌───────────────────────────────────────────────────────────┐
*│ @(q) Makes macfile from txtfile [file].QM │
*│ Loads macfile [file].MAC, NO error window, SMALL. │
*└───────────────────────────────────────────────────────────┘
@q macrobegin
savefile * save file
DOS "qmacb " * begin batch file
currentfilename * with current file
backspace backspace backspace * delete dot+extension
return * run batch file
return
macroread * begin macroread
currentfilename * of current file
backspace backspace * delete qm
"mac" * add mac extension
return * read new macfile
*
* 35 bytes Fri 09-14-1990 14:06:22
*
* ----------------------------------------------------------------------
* @(h) Finds first word on cursor line marked in document below
* ----------------------------------------------------------------------
* See BOOKxx.QM for use of @h.
@h macrobegin
unmarkblock * Unmark any marked blocks
defaultwordset * In case altwordset on
begfile *
endpara * Move to end of Index
markline * Mark it
begfile * Move to bof
find "(" return "L" return * Locate first Index selection line
jfalse NOMARK: *
makectrofscreen * Show top of file
begfile * Move back to bof
unmarkblock markline markline * And highlight line 1
prevposition * Move back to first selection line
begline * Cursor in col 1
pause * Pause for Index selection
wordright markword * Mark first word on line
copy * Copy word to scrap
endpara * Go to end of Index
find "(" paste ")" *
return "I" return * Find first marked word in doc
jfalse NOMARK: *
begline * If mark found go to begline
maketopofscreen scrollup * Cursor on line 2
jump END: *
NOMARK: *
begfile * If no mark found go to begfile
END:
*
* 52 bytes Wed 07-31-1991 14:43:31 (TH @h, @4 in MACRxx.QM)
*
* ┌────────────────────────────────────┐
* │ @(f1) Makes single column macro │
* └────────────────────────────────────┘
* To make a single column macro with Alt_f1, place the cursor line
* anywhere in a macro txtfile (after loading the macfile) and press Alt
* and f1 at the same time. If a macro is not a marked block, the full
* txtfile is made into a single column macro.
@f1 macrobegin
writeblock "c:$.qm" return * copy block or file to c:$.qm
unmarkblock insertline begline * insert temp line
dropanchor currentfilename cut * cut currentfilename to scrap
DOS "qmacb c:$" return return * make macfile
DOS "qmact-n c:$" return return * make txtfile
editfile "c:$.qm" return quit *
editfile return * load c:$.qm
endfile addline * insert blank line at end
"* " insertdate inserttime * for date/time
paste unmarkblock * get file name on line
killfile * kill c:$.qm
*
* 98 bytes Fri 09-14-1990 14:06:30
*
*┌──────────────────────────────────────────┐
*│ @(f2) Puts key beside single command │
*└──────────────────────────────────────────┘
* To get the key for a single command in a macro, place the cursor line
* on the command in a single column macro txtfile and press Alt_f2. The
* key corresponding to the command will be listed next to the commmand.
@f2 macrobegin
unmarkblock insertline begline * insert temp line
dropanchor currentfilename *
storescrbuff "1" return * get to scrbuff
cut * delete temp line
begline wordright markword * get to command, mark it
copy * get to scrap
unmarkblock * unmark
editfile *
"e:\qe\qconfig.dat" *<<<<<CHANGE
return * load qconfig.dat
begfile * go to begin qconfig.dat
FIND " " * insert 8 spaces before find
paste * paste command for find
return "IW" return * find command in qconfig.dat
jfalse NOFIND: * mark if found, quit if not
wordright markcolumn * move cursor to command
begline * go to begline
"* " * insert asterisk space
begline markcolumn * go to begline, include key
storescrbuff "2" return * get key to scrbuff
cursordown * move down line
unmarkblock * unmark command
* quit * quit qconfig.dat
getscrbuff "1" return * get currentfilename
cut * cut currentfilename
editfile paste return * load currentfilename
markcolumn * start to mark block
gotocolumn "33" return * postition to get key
getscrbuff "2" return * get key
begline * go to begline
makectrofscreen * for better viewing
cursordown * move down to next command
jump END: * stop after getting key
NOFIND: * come here if no key for command
getscrbuff "1" return * get currentfilename
cut * cut currentfilename
editfile paste return * return to file
gotocolumn "33" return * position to get key
"* " * insert asterisk space
cursordown * move down to next command
begline *
END: *
*
* 145 bytes Mon 02-18-1991 12:32:15
*
*┌────────────────────────────────────────────────────────────────┐
*│ @(f3) Puts key beside ALL commands in single column macfile │
*└────────────────────────────────────────────────────────────────┘
* To get the keys for ALL commands in a macro, place the cursor
* line at the top of a macro txtfile and press Alt_f3. An example of
* this output is shown at the end of this macro. The keys corresponding
* to each command will be listed also in a single column next to the
* command.
@f3 macrobegin
unmarkblock insertline begline * insert temp line
dropanchor currentfilename *
storescrbuff "1" return *
cut * delete temp line
START: *
endline begline * line blank? if so end
jfalse END: *
begline wordright markword *
copy unmarkblock * get command to scrap, unmark
editfile *
"e:\qe\qconfig.dat" *<<<<<CHANGE
return * load qconfig.dat
begfile * go to begin qconfig.dat
FIND " " * insert 8 spaces before find
paste * paste command for find
return "IW" return * find command in qconfig.dat
jfalse NOFIND: * mark if found, quit if not
wordright markcolumn begline * move cursor to command
"* " begline markcolumn * insert asterisk space
storescrbuff "2" return * get key to scratch
cursordown unmarkblock * move down line, unmark command
quit * quit qconfig.dat
getscrbuff "1" return * get currentfilename
cut * cut currentfilename
editfile paste return * load currentfilename
markcolumn * start to mark block
gotocolumn "33" return * postition to get key
getscrbuff "2" return * get key
begline makectrofscreen * for better viewing
cursordown * move down to next command
jump START: * start on next command
NOFIND: * come here if no key for command
getscrbuff "1" return * get currentfilename
cut * cut currentfilename
editfile paste return * return to file
gotocolumn "33" return * position to get key
"* " * insert asterisk space
cursordown * move down to next command
begline *
jump START: * do next line till done
END: *
*
* 154 bytes Mon 02-18-1991 12:32:44
*-----------------
* Here is what the macro Alt_f1 looks like by first marking it as a
* block, then running @f1 by placing the cursor line on the line
* below @f1 in c:$.qm and running @f3. (NOTE: an asterisk and
* space have been added to column 1)
* *
* * Converted by QMAC from: c:\$.mac
* *
* @f1 Macro_Begin <- (modified for SIZE macro)
* WriteBlock * @w
* "c:$." *
* "qm" *
* Return * enter
* UnmarkBlock * @u
* InsertLine * ^n_i
* BegLine * home
* DropAnchor * @a
* CurrentFilename * ^n_n
* Cut * ^c_u
* DOS "" * ^n_o
* "qmacb " *
* "c:$" *
* Return * enter
* Return * enter
* DOS "" * ^n_o
* "qmact-" *
* "n c:$" *
* Return * enter
* Return * enter
* EditFile * f3
* "c:$." *
* "qm" *
* Return * enter
* Quit * @x
* EditFile * f3
* Return * enter
* EndFile * ^pgdn
* AddLine * ^n_j
* "* "
* InsertDate * ^d
* InsertTime * ^e
* Paste * ^c_p
* UnmarkBlock * @u
* KillFile * ^k_z
*
*
* ┌───────────────────────────────────────────────────────────────┐
* │ @(f4) Retrieves a command and it's key from QCONFIG.DAT │
* └───────────────────────────────────────────────────────────────┘
* This macro retrieves a command or all commands matching a selected
* find criteria from your QCONFIG.DAT file, displays the selected
* command(s) and it's key on the screen, and then removes the
* command(s) and it's key from the screen. For those of us who can
* never remember all the commands and can never find our reference
* sheet, this might help.
* To run, press Alt_f4, then enter the first letter (or more) of the
* command you want to know the key for, press 'Enter' to see the the
* command(s) and it's key, then press 'Enter' again to remove the
* command(s) and it's key from the screen.
* For example, to find the key for appendscrbuff, press:
* <Alt_f4>
* app
* <Enter>
* You should see the following highlighted on your screeen:
* ^b_a appendscrbuff
* Entering "b" instead shows all commands beginning with "b":
* ^h backspace
* ^home begscreen
* ^pgup begfile
* home begline
* backspace backspace *(note, at least 8 spaces required)
* Press 'Enter' to remove the command(s) and it's key from the screen,
* or press 'Esc' three times if you want to keep the command(s) on the
* screen for reference.
@f4 macrobegin
unmarkblock insertline begline * insert temp line
dropanchor currentfilename *
cut * delete temp line
editfile *
"e:\qe\qconfig.dat" *<<<<<CHANGE
return *
endline * blank to clear scratch
dropanchor * mark to clear scratch
storescrbuff "1" return * get to scratch
unmarkblock begfile * go to begin qconfig.dat
FIND " " * insert 8 spaces before find
pause * pause for command to find
return "i" return * find first command
Jfalse FAIL: * Stop macro if search fails
jump NEXT: *
START: * come here more than 1 find
find return "i" return * find next command
NEXT: *
jfalse FINISH: * mark if found, quit if not
markline begline * mark command line
"* " * insert asterisk space
appendscrbuff "1" return * append to scratch
cursordown unmarkblock * move down line, unmark command
jump START: * see if any more matches
FINISH: * come here after last find
quit * quit qconfig.dat
editfile paste return * return to file
markcolumn * start to mark block
getscrbuff "1" return * get command and key
delline begline * delete blank line, begline
maketopofscreen * for better viewing
pause * pause, then 'Enter' to..
deleteblock * clean up, remove block
Jump END: *
FAIL: *
quit * quit qconfig.dat
editfile paste return * return to file we were
END: * editing if search fails
*
* 128 bytes Fri 03-29-1991 16:43:58
*
* ----------------------------------------------------------------------
* @(F5) Test TRUE/FALSE Results, Tim Farley, author
* ----------------------------------------------------------------------
*
* Date: 07-30-90 (17:34) Number: 936 / 937
* To: KARL BRENDEL Refer#: 929
* From: TIM FARLEY Read: NO
* Subj: Testing TRUE/FALSE result Status: PUBLIC MESSAGE
* Conf: REGDOS (1) Read Type: GENERAL (A)
*
* KB>I'd suggest that when you need to know what a command returns,
* KB>and it appears not to return what you expect, that you write a
* KB>test macro which prints TRUE or FALSE according to the return,
* KB>and experiment with it.
*
* Surprising as it may seem (since I obviously have inside
* knowledge of the editor), I do just this myself! It's quicker
* for one thing....
*
* Here is the macro I use:
*
* (TH changed key from ^F10 to @F5)
@F5 MacroBegin
JTrue true:
Find ".F." Pause Escape
Jump end:
true:
Find ".T." Pause Escape
end:
*
* 28 bytes Mon 07-30-1990 19:58:27 (TH added)
* Just re-wrap this to fit on one line, then put it in your
* QCONFIG.DAT.
*
* Then, when you want to test a command, RECORD a macro that starts
* with the command you wish to test, then this macro. For
* instance, if I wanted to test BegLine <Home>, I would do this:
*
* (1) Press MacroRecord <Ctrl M>
* (2) Press the key to record. (I use <Alt F5> usually).
* (3) Press the key to test, BegLine <Home>.
* (4) Press the above macro, <Alt F5>
* (5) End macro recording <Ctrl M>.
*
* Now I can just move my cursor around, and hit <Alt F10>, to test
* the true/false result of BegLine at different positions. The
* true or false comes up in a nice little box on the screen, and
* when I press Return the box sends itself away, and does not
* damage the file I am editing or anything.
*
* Note if you run the above <Alt F5> macro by itself, it always
* returns TRUE. QEdit does not remember the True/False state of
* the last command while "idle". Thus the necessity of recording
* the above within a macro.
*
* --Tim Farley
* SemWare Technical Support
* (Other) Macros available: See ALLMACRO.INF.
* See RFRMxx.QM for other commenting and un-commenting macros.
* (Version) History:
*
* 1.0 - initial version
* 1.1 - Changed Alt-6 to keep [file].qm in ring after running.
* 1.2 - Date & time stamp put in dum.qm (Alt-6, Alt-7).
* 1.3 - Added batch files to macro13.ZIP.
* 1.4 - Changed Alt-6 & 7 to stamp [file].QM translated from.
* - Changed Alt-0 to not pause if no errors.
* - Added Alt-5 to see error files in window.
* - Changed /W60 to /W70 and removed "pause" in qmact.bat.
* 1.5 - Changed Alt-7 to not pause if no errors.
* 1.6 - Shortened Alt-6, 7 & 10. Faster & no pause now if no errors.
* 1.7 - Corrected Alt-6 to write macros first. Sorry.
* 1.8 - Added Alt-4 to append text file [file].qm macros
* to a "standard" macro and read appended macro.
* 1.9 - Added Alt-3 to merge designated macro [file].mac
* with current macros. QEdit normally overwrites
* current macros when reading a new macro.
* 2.0 - Added Alt-2 to refresh macro buffer with "standard" macro.
* - New qmacTA2.bat for Alt-4, gets "standard" name as %2.
* - Added Alt T & Alt N to select txtfile to read from
* sorted list of all avaialable txtfiles in directory.
* - New SORT-T.BAT and SORT-F.BAT for Alt T & N to sort macro list.
* - Changed Alt-4 to identify "standard" rather than batch file.
* (Modify g:\qe\macros for the name of your "standard" macro.)
* - Shortened Alt-3,7 & 0, total 91 bytes. (Important when merging
* since QEdit macro buffer is limited to 2046 bytes macros.)
* - Moved macroread to end of Alt-3. No problem, just in case.
* (Reading macros while executing can sometimes cause problems.)
* - Changed Alt-5 to refresh c:!.
* 2.1 - (Internal)
* 2.2 - Added Alt-1 to select txtfile to load from list of all txtfiles
* in directory sorted by Name. Added sort-N2.bat for this macro.
* - Changed Alt T & Alt N to select macfile, not txtfile as v2.0,
* from sorted list of all available macfiles in directory.
* - Changed sort-T.bat, sort-N.bat and sort-N1.bat for macr s.
* - Renamed MACCMTxx to MACROxx. Dropped MACCMTxx. Macros comments
* and instructions are now are in MACROxx.qm.
* - Shortened highlight bar in Alt N,t. Saves ~30 bytes/macro.
* - Changed dum.dir to $ in Alt-4 & qmacTA2.bat to shorten
* - Added killfile to Alt-3 & 4. Changed endfile display in Alt-4.
* - Replaced "j:\j" with "c:!" in macros and batch files to shorten.
* - Changed qmacTA2.bat for better display.
* - Changed select window from "c:!" to "c:$" in batch files
* - Sort batch files (sort-xx.bat) also changed.
* 2.3 - Changed @5 to keep error file c:! in ring.
* - By removing " "'s, changing file name tracking in buffers,
* and shortening header and footer labels:
* - shortened @4 28 bytes
* - shortened @5 5 "
* - shortened @6 67 "
* - shortened @7 24 "
* - shortened @9 3 "
* - Added macro size 'bytes line' at end of each macro
* 2.4 - Removed dum.qm and dum.mac from zip package
* - Shortened Alt_6 from 147 to 54 bytes
* - Shortened Alt_7 from 258 to 194 bytes
* 2.4a - Modified @6 and description
* 2.4b - Modified documentation.
* 2.4c - Changed file name from MACROxx to MACRxx.
* 2.5 - Changed j:j to c:! in macros and batch files.
* - Changed down arrow #25 to ! in ^0.
* - Changed .LST and .QL files.
* - Removed @1, @t and @n. Newer macros to do the same thing
* are in FILExx.ZIP.
* 2.6 - Added @t, smaller faster version of @7.
* - Added @q, smaller faster version of @0.
* - Added @f1, @f2, @f3 and @f4 from GETCxx.ZIP and COLxx.ZIP,
* which are no longer included as seperate files, but are now
* a part of MACRxx.ZIP.
* - Modified and shortened all but @2, @6, @8, @9 and ^1.
* - Added killfile to @6 so writeblock return works correctly.
* 2.6a - Changed ^1 help macro key to @h key.
* 2.7 - Removed [d:]\[path] for location of QMAC from QMACxxx batch
* files. QMAC can be located anywòere in path.
* 2.7a - Modified documentation and added START.BAT.
* - Change MACRO file names to MACR.
* 2.7b - Corrected @h Index Use instructions.
* 2.8 - Changed 4 to 8 spaces in Find for @f2 - @f4 to correctly
* find command and key.
* 2.9 - Corrected @f4 which had a missing return.
* 3.0 - Modified @F4 to stop on failed searches.
* 3.1 - Modified @3, @4, @7 and @0, also with more comments.
* - Added @F5 written by Tim Farley.
* - Removed unnecessary c:$.qm from @7.
* 3.1a - Changed documentation.
* - Included v3.1a in AMAC39.ZIP, July 21, 1991.
* 3.1b - Corrected @F5 documentation, key references were wrong. 7/30/91
* - Added latest version of @h from BOOKxx.QM. 7/31/91
* - MACR.DOC had old f:\. Corrected to e:\. 7/31/91
*
*
*
* error_sample, remove asterisk to test for errors