home *** CD-ROM | disk | FTP | other *** search
/ Crawly Crypt Collection 2 / crawlyvol2.bin / apps / dtp / pgsmodst / atariprt / stokic.s < prev    next >
Text File  |  1991-05-23  |  6KB  |  344 lines
  1.  include "prtequ.h"
  2.  
  3. *
  4. * Okimate Color driver
  5. *
  6. BLACK    equ    "0"
  7. CYAN    equ    "3"
  8. MAGENTA    equ    "5"
  9. YELLOW    equ    "6"
  10.  
  11. CR    equ    $d
  12. LF    equ    $a
  13. FF    equ    $c
  14. ESC    equ    $1b
  15.  
  16.  SECTION printer,CODE,PUBLIC
  17. ***************************************************************
  18. ***************************************************************
  19. ***************************************************************
  20. dumbentry:
  21.     clr.l    d0
  22.     rts
  23.  
  24.     dc.l    "PRNT"
  25.     dc.w    200
  26.  
  27. *
  28. * distribute the calls to the appropriate routines
  29. *
  30. oki:    move.l    a0,table
  31.     lsl.w    #2,d0
  32.     lea    prntbl,a1
  33.     move.l    0(a1,d0.w),a1
  34.     jmp    (a1)
  35.  
  36. *
  37. * identify who I am, and set up who I like to speak to.
  38. *
  39. p_ident:
  40.     move.l    #driver,pdrvrnm(a0)    ;pointer to string for driver name
  41.     move.w    #PARALLEL+ASCENDING,device(a0)
  42. prtok:    moveq    #1,d0
  43.     rts
  44.  
  45. *
  46. * initialize the table of printer specific routines
  47. *
  48. p_init:    clr.b    pdl(a0)            ;no page description language
  49.     clr.b    pmult(a0)        ;automatically print mulitiple copies?
  50.     clr.b    pman(a0)        ;handle manual feed?
  51.     move.b    #PRT_CMYK,ptype(a0)    ;printer type?
  52.  
  53.     move.l    sendout(a0),send+2    ;self-modifing code, tisk, tisk!
  54.  
  55. *
  56. * pminlft and pmaxw must be evenly divisible by 16
  57. * this is the part that should be worked out
  58. *
  59.  
  60.     move.w    pdensity(a0),d0
  61.     cmp.w    #7,d0
  62.     bcs    pint1
  63.     moveq    #6,d0
  64. pint1:    lsl.w    #1,d0
  65.  
  66.     lea    xdpi_tbl,a1
  67.     move.w    0(a1,d0.w),pxdpi(a0)    ;x resolution
  68.     lea    ydpi_tbl,a1
  69.     move.w    0(a1,d0.w),pydpi(a0)    ;y resolution
  70.     lea    minl_tbl,a1
  71.     move.w    0(a1,d0.w),pminlft(a0)    ;pixels from the left
  72.     lea    minr_tbl,a1
  73.     move.w    0(a1,d0.w),pminrht(a0)    ;pixels from the right
  74.     lea    mint_tbl,a1
  75.     move.w    0(a1,d0.w),pmintop(a0)    ;pixels down from top
  76.     lea    minb_tbl,a1
  77.     move.w    0(a1,d0.w),pminbot(a0)    ;pixels up from bottom
  78.     lea    xover_tbl,a1
  79.     move.w    0(a1,d0.w),pxover(a0)    ;percentage of x overlap of dots
  80.     lea    yover_tbl,a1
  81.     move.w    0(a1,d0.w),pyover(a0)    ;percentage of y overlap of dots
  82.     lea    rowht_tbl,a1
  83.     move.w    0(a1,d0.w),prowht(a0)    ;rows height modula
  84.  
  85.     move.w    0(a1,d0.w),rowht
  86.     lea    rows_tbl,a1
  87.     move.w    0(a1,d0.w),rows
  88.     lea    grmode_tbl,a1
  89.     move.w    0(a1,d0.w),grmode
  90.  
  91.     lsl.w    #1,d0
  92.     lea    maxw_tbl,a1
  93.     move.l    0(a1,d0.w),pmaxw(a0)    ;maximum # pixels across
  94.     lea    maxh_tbl,a1
  95.     move.l    0(a1,d0.w),pmaxh(a0)    ;maximum # pixels down
  96.  
  97.     bra    prtok
  98.  
  99. *
  100. * going to begin printing a document
  101. *
  102. p_bgndoc:
  103.     bra    prtok
  104.  
  105. *
  106. * about to start printing of a page
  107. *
  108. p_bgnpage:
  109.     bra    prtok
  110.  
  111. *
  112. * about to print a new tile for the page
  113. *
  114. p_bgntile:
  115.     bra    prtok
  116.  
  117. *
  118. * print a block to the printer
  119. *
  120. p_block:
  121.     move.l    table,a0
  122.     move.l    pblockplane(a0),pplane
  123.     move.l    pblockw(a0),d0
  124.     move.w    d0,width
  125.     move.l    pblockptr(a0),a1
  126.     move.l    (a1),a1
  127.     add.l    pblockoff(a0),a1
  128.     move.l    a1,v_base
  129.  
  130.     move.w    rows,count
  131. printl:    lea    setcolor,a0        ;yellow
  132.     bsr    sendline
  133.     move.b    #YELLOW,d0
  134.     bsr    send
  135.     move.l    v_base,lineptr
  136.     move.l    pplane,d0
  137.     lsl.l    #1,d0
  138.     add.l    d0,lineptr
  139.     bsr    putline
  140.     lea    setcolor,a0        ;magenta
  141.     bsr    sendline
  142.     move.b    #MAGENTA,d0
  143.     bsr    send
  144.     move.l    v_base,lineptr
  145.     move.l    pplane,d0
  146.     add.l    d0,lineptr
  147.     bsr    putline
  148.     lea    setcolor,a0        ;cyan
  149.     bsr    sendline
  150.     move.b    #CYAN,d0
  151.     bsr    send
  152.     move.l    v_base,lineptr
  153.     bsr    putline
  154.     lea    setcolor,a0        ;black
  155.     bsr    sendline
  156.     move.b    #BLACK,d0
  157.     bsr    send
  158.     move.l    v_base,lineptr
  159.     move.l    pplane,d0
  160.     lsl.l    #1,d0
  161.     add.l    pplane,d0
  162.     add.l    d0,lineptr
  163.     bsr    putline
  164.  
  165.     moveq    #0,d0
  166.     move.w    width,d0
  167.     add.l    d0,v_base
  168.     subq.w    #1,count
  169.     bne    printl
  170. *
  171.     move.b    #ESC,d0            ;line spacing to 1/144"
  172.     bsr    send
  173.     move.b    #"J",d0
  174.     bsr    send
  175.     move.b    #16,d0
  176.     bra    send
  177.  
  178.  
  179. **************************************
  180.  
  181. putline:
  182.     move.l    lineptr,a0
  183.     clr.w    twidth
  184.     move.w    #23,d1
  185. print0:    move.w    width,d0
  186. print1:    tst.b    -1(a0,d0.w)
  187.     bne    print2
  188.     subq.w    #1,d0
  189.     bne    print1
  190.  
  191. print2:    cmp.w    twidth,d0
  192.     blt    print3
  193.     move.w    d0,twidth
  194. print3:    add.w    width,a0
  195.     dbf    d1,print0
  196.  
  197.     tst.w    twidth
  198.     beq    wspace
  199.  
  200.     lea    setgr,a0
  201.     bsr    sendline
  202.     move.w    grmode,d0
  203.     bsr    send
  204.     move.w    twidth,d0        ;send number of graphic rows to follow
  205.     lsl.w    #3,d0
  206.     bsr    send
  207.     move.w    twidth,d0
  208.     lsr.w    #5,d0
  209.     bsr    send
  210.  
  211. print4:    move.w    #7,pixel
  212. print6:    move.w    #3,bytes
  213.     move.l    lineptr,a0
  214. print5:    move.w    pixel,d4
  215.     moveq    #7,d1
  216.     moveq    #0,d0
  217. s1:    btst    d4,(a0)
  218.     beq     s2
  219.     bset    d1,d0
  220. s2:    add.w    width,a0
  221.     dbf    d1,s1
  222.     move.l    a0,-(sp)
  223.     bsr    send
  224.     move.l    (sp)+,a0
  225.  
  226.     subq.w    #1,bytes
  227.     bne    print5
  228.     sub.w    #1,pixel
  229.     bcc    print6
  230.     add.l    #1,lineptr
  231.     subq.w    #1,twidth
  232.     bne    print4
  233. *
  234. wspace:    move.w    #CR,d0
  235.     bra    send
  236.  
  237. ************************************
  238. *
  239. * just finished describing current tile
  240. *
  241. p_endtile:
  242.     move.l    table,a0
  243.     move.l    pblockh(a0),d0
  244.     mulu    #216,d0
  245.     divu    pydpi(a0),d0
  246.     move.w    d0,scroll
  247. pend1:    tst.b    scroll
  248.     beq    pend2
  249.     move.b    #ESC,d0
  250.     bsr    send
  251.     move.b    #"J",d0
  252.     bsr    send
  253.     move.b    #255,d0
  254.     bsr    send
  255.     sub.w    #255,scroll
  256.     bra    pend1
  257. pend2:    tst.w    scroll
  258.     beq    prtok
  259.     move.b    #ESC,d0
  260.     bsr    send
  261.     move.b    #"J",d0
  262.     bsr    send
  263.     move.w    scroll,d0
  264.     bra    send
  265.  
  266. *
  267. * just finished describing all tiles for this page
  268. *
  269. p_endpage:
  270.     bra    prtok
  271.  
  272. *
  273. * finished printing the document
  274. *
  275. p_enddoc:
  276.     bra    prtok
  277.  
  278. *
  279. * user requested stop
  280. *
  281. p_break:
  282.     bra    p_endtile
  283.  
  284. ***************************************************
  285. ***    these are the send routines for the    ***
  286. ***    dot matrix driver.            ***
  287. ***************************************************
  288. sendline:
  289.     move.b    (a0)+,d0
  290.     beq    prtok
  291.     move.l    a0,-(sp)
  292.     bsr    send
  293.     move.l    (sp)+,a0
  294.     bra    sendline
  295.  
  296. send:    jmp    $ffffff
  297.  
  298. ***********************************
  299. ***                ***
  300. ***********************************
  301.  SECTION printer,DATA,PUBLIC
  302.  
  303. prntbl:    dc.l    prtok,prtok,prtok,prtok,p_init
  304.     dc.l    p_bgndoc,p_bgnpage,p_bgntile
  305.     dc.l    p_block
  306.     dc.l    p_endtile,p_endpage,p_enddoc
  307.     dc.l    p_break,p_ident
  308.  
  309.  
  310. xdpi_tbl:    dc.w    60,60,120,120,180,180,180
  311. ydpi_tbl:    dc.w    216,216,216,216,216,216,216
  312. minl_tbl:    dc.w    16,16,32,32,48,48,48
  313. minr_tbl:    dc.w    16,16,32,32,48,48,48
  314. mint_tbl:    dc.w    0,0,0,0,0,0,0
  315. minb_tbl:    dc.w    0,0,0,0,0,0,0
  316. maxw_tbl:    dc.l    480,480,960,960,1280,1280,1280
  317. maxh_tbl:    dc.l    0,0,0,0,0,0,0
  318. xover_tbl:    dc.w    0,0,30,30,70,70,70
  319. yover_tbl:    dc.w    33,33,33,33,33,33,33
  320. rowht_tbl:    dc.w    24,24,24,24,24,24,24
  321. rows_tbl:    dc.w    1,1,1,1,1,1,1
  322. grmode_tbl:    dc.w    32,32,33,33,34,34,34
  323.  
  324. driver:        dc.b    "ST Okimate Color v2.0 beta",0
  325. setcolor:    dc.b    ESC,"X",0
  326. setgr:        dc.b    ESC,"*",0
  327.  
  328.  SECTION printer,BSS,PUBLIC
  329. table:        ds.l    1
  330. twidth:        ds.w    1
  331. pixel:        ds.w    1
  332. v_base:        ds.l    1
  333. bytes:        ds.w    1
  334. aaa:        ds.l    1
  335. keep:        ds.w    1
  336. lineptr:    ds.l    1
  337. width:        ds.w    1
  338. pplane:        ds.l    1
  339. count:        ds.w    1
  340. grmode:        ds.w    1
  341. rows:        ds.w    1
  342. rowht:        ds.w    1
  343. scroll:        ds.w    1
  344.