home *** CD-ROM | disk | FTP | other *** search
/ Crawly Crypt Collection 2 / crawlyvol2.bin / apps / dtp / pgsmodst / atariprt / lq2550c.s < prev    next >
Text File  |  1991-05-23  |  7KB  |  379 lines
  1.  include "prtequ.h"
  2.  
  3. *
  4. * Epson LQ-2550 print driver
  5. *
  6. BLACK    equ    0
  7. CYAN    equ    2
  8. MAGENTA    equ    1
  9. YELLOW    equ    4
  10.  
  11. CR    equ    $d
  12. LF    equ    $a
  13. FF    equ    $c
  14. ESC    equ    $1b
  15. FS    equ    $1c
  16.  
  17.  SECTION printer,CODE,PUBLIC
  18. ***************************************************************
  19. ***************************************************************
  20. ***************************************************************
  21. dumbentry:
  22.     clr.l    d0
  23.     rts
  24.  
  25.     dc.l    "PRNT"
  26.     dc.w    200
  27.  
  28. *
  29. * distribute the calls to the appropriate routines
  30. *
  31. epson:    move.l    a0,table
  32.     lsl.w    #2,d0
  33.     lea    prntbl,a1
  34.     move.l    0(a1,d0.w),a1
  35.     jmp    (a1)
  36.  
  37. *
  38. * identify who I am, and set up who I like to speak to.
  39. *
  40. p_ident:
  41.     move.l    #driver,pdrvrnm(a0)    ;pointer to string for driver name
  42.     move.w    #PARALLEL+ASCENDING,device(a0)
  43. prtok:    moveq    #1,d0
  44.     rts
  45.  
  46. *
  47. * initialize the table of printer specific routines
  48. *
  49. p_init:    clr.b    pdl(a0)            ;no page description language
  50.     clr.b    pmult(a0)        ;automatically print mulitiple copies?
  51.     clr.b    pman(a0)        ;handle manual feed?
  52.     move.b    #PRT_CMYK,ptype(a0)    ;printer type?
  53.  
  54.     move.l    sendout(a0),send+2    ;self-modifing code, tisk, tisk!
  55. *
  56. * pminlft and pmaxw must be evenly divisible by 16
  57. * this is the part that should be worked out
  58. *
  59.  
  60.     move.w    pdensity(a0),d0
  61.     cmp.w    #7,d0
  62.     bcs    pint1
  63.     moveq    #6,d0
  64. pint1:    lsl.w    #1,d0
  65.  
  66.     lea    xdpi_tbl,a1
  67.     move.w    0(a1,d0.w),pxdpi(a0)    ;x resolution
  68.     lea    ydpi_tbl,a1
  69.     move.w    0(a1,d0.w),pydpi(a0)    ;y resolution
  70.     lea    minl_tbl,a1
  71.     move.w    0(a1,d0.w),pminlft(a0)    ;pixels from the left
  72.     lea    minr_tbl,a1
  73.     move.w    0(a1,d0.w),pminrht(a0)    ;pixels from the right
  74.     lea    mint_tbl,a1
  75.     move.w    0(a1,d0.w),pmintop(a0)    ;pixels down from top
  76.     lea    minb_tbl,a1
  77.     move.w    0(a1,d0.w),pminbot(a0)    ;pixels up from bottom
  78.     lea    xover_tbl,a1
  79.     move.w    0(a1,d0.w),pxover(a0)    ;percentage of x overlap of dots
  80.     lea    yover_tbl,a1
  81.     move.w    0(a1,d0.w),pyover(a0)    ;percentage of y overlap of dots
  82.     lea    rowht_tbl,a1
  83.     move.w    0(a1,d0.w),prowht(a0)    ;rows height modula
  84.  
  85.     move.w    0(a1,d0.w),rowht
  86.     lea    rows_tbl,a1
  87.     move.w    0(a1,d0.w),rows
  88.     lea    grmode_tbl,a1
  89.     move.w    0(a1,d0.w),grmode
  90.  
  91.     lsl.w    #1,d0
  92.     lea    maxw_tbl,a1
  93.     move.l    0(a1,d0.w),pmaxw(a0)    ;maximum # pixels across
  94.     lea    maxh_tbl,a1
  95.     move.l    0(a1,d0.w),pmaxh(a0)    ;maximum # pixels down
  96.     bra    prtok
  97.  
  98.  
  99. *
  100. * going to begin printing a document
  101. *
  102. p_bgndoc:
  103.     bra    prtok
  104.  
  105. *
  106. * about to start printing of a page
  107. *
  108. p_bgnpage:
  109.     bra    prtok
  110.  
  111. *
  112. * about to print a new tile for the page
  113. *
  114. p_bgntile:
  115.     bra    prtok
  116.  
  117. *
  118. * print a block to the printer
  119. *
  120. p_block:
  121.     move.l    table,a0
  122.     move.l    pblockw(a0),d0
  123.     move.l    pblockplane(a0),pplane
  124.     move.w    d0,width
  125.     move.l    pblockptr(a0),a1
  126.     move.l    (a1),a1
  127.     add.l    pblockoff(a0),a1
  128.     move.l    a1,v_base
  129.  
  130. *
  131. *print the block
  132. *
  133.     move.w    rows,count
  134. printt:
  135.     lea    setcolor,a0        ;yellow
  136.     bsr    sendline
  137.     move.b    #YELLOW,d0
  138.     bsr    send
  139.     move.l    v_base,lineptr
  140.     move.l    pplane,d0
  141.     lsl.l    #1,d0
  142.     add.l    d0,lineptr
  143.     bsr    putline
  144.     lea    setcolor,a0        ;magenta
  145.     bsr    sendline
  146.     move.b    #MAGENTA,d0
  147.     bsr    send
  148.     move.l    v_base,lineptr
  149.     move.l    pplane,d0
  150.     add.l    d0,lineptr
  151.     bsr    putline
  152.     lea    setcolor,a0        ;cyan
  153.     bsr    sendline
  154.     move.b    #CYAN,d0
  155.     bsr    send
  156.     move.l    v_base,lineptr
  157.     bsr    putline
  158.     lea    setcolor,a0        ;black
  159.     bsr    sendline
  160.     move.b    #BLACK,d0
  161.     bsr    send
  162.     move.l    v_base,lineptr
  163.     move.l    pplane,d0
  164.     lsl.l    #1,d0
  165.     add.l    pplane,d0
  166.     add.l    d0,lineptr
  167.     bsr    putline
  168.  
  169.     move.b    #ESC,d0            ;set line spacing to 1/360"
  170.     bsr    send
  171.     move.b    #"+",d0
  172.     bsr    send
  173.     move.b    #1,d0
  174.     bsr    send
  175.     move.w    #LF,d0
  176.     bsr    send
  177.  
  178.     moveq    #0,d0
  179.     move.w    width,d0
  180.     add.l    d0,v_base
  181.     subq.w    #1,count
  182.     bne    printt
  183. *
  184.     move.b    #ESC,d0            ;set line spacing to 1/360"
  185.     bsr    send
  186.     move.b    #"+",d0
  187.     bsr    send
  188.     move.w    #48,d0
  189.     sub.w    rows,d0
  190.     bsr    send
  191.  
  192.     move.b    #LF,d0
  193.     bra    send
  194.  
  195. **************************************
  196.  
  197. putline:
  198.     move.l    lineptr,a0
  199.     clr.w    twidth
  200.     move.w    #23,d1
  201. print0:    move.w    width,d0
  202. print1:    tst.b    -1(a0,d0.w)
  203.     bne    print2
  204.     subq.w    #1,d0
  205.     bne    print1
  206.  
  207. print2:    cmp.w    twidth,d0
  208.     blt    print3
  209.     move.w    d0,twidth
  210. print3:    move.w    rows,d3
  211. pri1:    add.w    width,a0
  212.     sub.w    #1,d3
  213.     bgt    pri1
  214.     dbf    d1,print0
  215. *
  216.     tst.w    twidth
  217.     beq    wspace
  218.  
  219.     lea    setgr,a0
  220.     bsr    sendline
  221.     move.w    grmode,d0
  222.     bsr    send
  223.     move.w    twidth,d0        ;send number of graphic bytes to follow
  224.     lsl.w    #3,d0
  225.     bsr    send
  226.     move.w    twidth,d0    
  227.     lsr.w    #5,d0
  228.     bsr    send
  229.  
  230.     move.w    twidth,d2                 ;length of the data in byte
  231. print4:    move.w    d2,twidth
  232.     moveq    #7,d4
  233. print6:    move.w    d4,pixel
  234.     moveq    #2,d3
  235.     move.l    lineptr,a0
  236. print5:    move.w    d3,bytes
  237.     moveq    #7,d1
  238.     moveq    #0,d0
  239. *
  240. s1:    btst    d4,(a0)
  241.     beq     s2
  242.     bset    d1,d0
  243. s2:
  244.     move.w    rows,d3
  245. pri2:
  246.     add.w    width,a0
  247.     sub.w    #1,d3
  248.     bgt    pri2
  249. *
  250.     dbf    d1,s1
  251.     move.l    a0,-(sp)
  252.     bsr    send
  253.     move.l    (sp)+,a0
  254. *
  255.     move.w    pixel,d4
  256.     move.w    bytes,d3
  257.     dbf    d3,print5
  258. *
  259.     move.w    pixel,d4
  260.     dbf    d4,print6
  261. *
  262.     add.l    #1,lineptr
  263.     move.w    twidth,d2
  264.     subq.w    #1,d2
  265.     bgt    print4
  266. *
  267. wspace:    move.w    #CR,d0
  268.     bra    send
  269.  
  270. ************************************
  271. *
  272. * just finished describing current tile
  273. *
  274. p_endtile:
  275.     move.l    table,a0
  276.     move.l    pblockh(a0),d0
  277.     mulu    #360,d0
  278.     divu    pydpi(a0),d0
  279.     move.w    d0,scroll
  280. pend1:    tst.b    scroll
  281.     beq    pend2
  282.     move.b    #ESC,d0
  283.     bsr    send
  284.     move.b    #"+",d0
  285.     bsr    send
  286.     move.b    #255,d0
  287.     bsr    send
  288.     sub.w    #255,scroll
  289.     bra    pend1
  290. pend2:    tst.w    scroll
  291.     beq    prtok
  292.     move.b    #ESC,d0
  293.     bsr    send
  294.     move.b    #"+",d0
  295.     bsr    send
  296.     move.w    scroll,d0
  297.     bra    send
  298.  
  299. *
  300. * just finished describing all tiles for this page
  301. *
  302. p_endpage:
  303.     bra    prtok
  304.  
  305. *
  306. * finished printing the document
  307. *
  308. p_enddoc:
  309.     bra    prtok
  310.  
  311. *
  312. * user requested stop
  313. *
  314. p_break:
  315.     bra    p_endtile
  316.  
  317. ***************************************************
  318. ***    these are the send routines for the    ***
  319. ***    dot matrix driver.            ***
  320. ***************************************************
  321. *
  322. *
  323. sendline:
  324.     move.b    (a0)+,d0
  325.     beq    prtok
  326.     move.l    a0,-(sp)
  327.     bsr    send
  328.     move.l    (sp)+,a0
  329.     bra    sendline
  330. *
  331. *
  332. send:    jmp    $ffffff
  333. *
  334. *
  335. ***********************************
  336. ***                ***
  337. ***********************************
  338.  SECTION printer,DATA,PUBLIC
  339.  
  340. prntbl:    dc.l    prtok,prtok,prtok,prtok,p_init
  341.     dc.l    p_bgndoc,p_bgnpage,p_bgntile
  342.     dc.l    p_block
  343.     dc.l    p_endtile,p_endpage,p_enddoc
  344.     dc.l    p_break,p_ident
  345.  
  346. xdpi_tbl:    dc.w    60,90,120,180,180,360,360
  347. ydpi_tbl:    dc.w    180,180,180,180,360,180,360
  348. minl_tbl:    dc.w    10,20,30,45,45,90,90
  349. minr_tbl:    dc.w    10,20,30,45,45,90,90
  350. mint_tbl:    dc.w    0,0,0,0,0,0,0
  351. minb_tbl:    dc.w    0,0,0,0,0,0,0
  352. maxw_tbl:    dc.l    480,760,960,1440,1440,2880,2880
  353. maxh_tbl:    dc.l    0,0,0,0,0,0,0
  354. xover_tbl:    dc.w    0,10,10,20,20,30,30
  355. yover_tbl:    dc.w    0,0,0,0,50,0,50
  356. rowht_tbl:    dc.w    24,24,24,24,48,24,48
  357. rows_tbl:    dc.w    1,1,1,1,2,1,2
  358. grmode_tbl:    dc.w    32,38,33,39,39,40,40
  359.  
  360.  
  361. driver:        dc.b    "Epson LQ-2550 v2.0 Color Beta",0
  362. setgr:        dc.b    ESC,"*",0
  363. setcolor:    dc.b    ESC,"r",0
  364.  
  365.  SECTION printer,BSS,PUBLIC
  366. table:        ds.l    1
  367. twidth:        ds.w    1
  368. pixel:        ds.w    1
  369. v_base:        ds.l    1
  370. bytes:        ds.w    1
  371. lineptr:    ds.l    1
  372. width:        ds.w    1
  373. pplane:        ds.l    1
  374. count:        ds.w    1
  375. grmode:        ds.w    1
  376. rows:        ds.w    1
  377. rowht:        ds.w    1
  378. scroll:        ds.w    1
  379.