home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / s85xx / s8507b.d64 / messboy (.txt) < prev    next >
Commodore BASIC  |  1995-03-30  |  3KB  |  112 lines
  1. 100 REM   **************************
  2. 110 REM   *                        *
  3. 120 REM   *     C/R-MESSGERAET     *
  4. 130 REM   *                        *
  5. 140 REM   *                        *
  6. 150 REM   *  VON  UWE GERLACH      *
  7. 160 REM   *       BRUEHLSTR. 23    *
  8. 170 REM   *                        *
  9. 180 REM   *       6440 BEBRA 1     *
  10. 190 REM   *                        *
  11. 200 REM   *                        *
  12. 210 REM   *       APRIL 1985       *
  13. 220 REM   *                        *
  14. 230 REM   **************************
  15. 250 :
  16. 1000 POKE53280,0: POKE53281,0: REM FARBE
  17. 1010 PRINT "[147][215]IDERSTANDS-  UND  [203]APAZITAETSMESSGERAET[152]";CHR$(14):PRINT:PRINT
  18. 1400 PRINT"":PRINT:PRINT:PRINT:PRINT,," [203]APAZITAETSMESSUNG"
  19. 1420 B=0
  20. 1430 PRINT:PRINT:PRINT,," [194]ITTE DEN [211]CHALTER"
  21. 1440 PRINT,,"  AM [205]ESSZUSATZ IN"
  22. 1450 PRINT,,"    [211]TELLUNG '[195]'"
  23. 1460 PRINT,,"      BRINGEN !"
  24. 1490 GOTO 8110
  25. 1500 PRINT"":PRINT:PRINT:PRINT:PRINT,," [215]IDERSTANDSMESSUNG"
  26. 1520 B=2
  27. 1530 PRINT:PRINT:PRINT,," [194]ITTE DEN [211]CHALTER"
  28. 1540 PRINT,,"  AM [205]ESSZUSATZ IN"
  29. 1550 PRINT,,"    [211]TELLUNG '[210]'"
  30. 1590 GOTO 1460
  31. 1592 :
  32. 1999 REM*********************
  33. 2000 REM  ANZEIGE UND MENUE
  34. 2001 REM*********************
  35. 2010 POKE211,21: POKE214,17: SYS 58732: REM  KURSORPOSITIONIERUNG
  36. 2020 PRINT"";W$;"[152]": REM AKTUELLER WERT
  37. 2030 GOSUB 9030
  38. 2998 :
  39. 2999 REM*******************************
  40. 3000 REM  I/O-BAUSTEIN INITIALISIEREN
  41. 3001 REM*******************************
  42. 3010 H=0
  43. 3060 IF B=1 THEN H=5: REM FUER > 500NF
  44. 3100 POKE 56590,193: REM KONTROLLREG. A
  45. 3110 POKE 56591,121: REM KONTROLLREG. B
  46. 3200 POKE 56580,0:   REM TIMER A LOW
  47. 3210 POKE 56581,H:   REM TIMER A HIGH
  48. 3220 POKE 56582,255: REM TIMER B LOW
  49. 3230 POKE 56583,255: REM TIMER B HIGH
  50. 3240 :
  51. 3300 POKE 56577,0: REM IMPULS AUSLOESEN
  52. 3998 :
  53. 3999 REM*******************************
  54. 4000 REM  WARTEN AUF FLAG-INTERRUPT-BIT
  55. 4001 REM*******************************
  56. 4040 IF (PEEK(56589) AND 16)>0 THEN 4090
  57. 4050 GOSUB 9030: GOTO 4040: REM  MENUE
  58. 4090 IF B=2 THEN 7000: REM WIDERSTDMSG.
  59. 4998 :
  60. 4999 REM**********************
  61. 5000 REM  KAPAZITAETSMESSUNG
  62. 5001 REM**********************
  63. 5020 W=(65535-(PEEK(56582)+PEEK(56583)*256))*1.02E-6/(.7*39000)
  64. 5030 IF W=0 AND B=0 THEN B=1: GOTO 3000
  65. 5035 IF W<3E-10 AND B=1 THEN B=0: GOTO 3000
  66. 5050 IF B=1 THEN 6000: REM MESSBEREICH
  67. 5070 IF W<1E-9 THEN W$=LEFT$(STR$(W*1E12)+"      ",6)+" [208]IKOFARAD ": GOTO 2000
  68. 5080 IF W<1E-6 THEN W$=LEFT$(STR$(W*1E9)+"       ",6)+" [206]ANOFARAD ": GOTO 2000
  69. 6000 W=(65535-(PEEK(56582)+PEEK(56583)*256))*5*256*1.02E-6/(.7*39000)
  70. 6010 W$=LEFT$(STR$(W*1E6)+"      ",6)+" [205]IKROFARAD"
  71. 6020 FOR I=0 TO W*1E6:GOSUB 9030: NEXT I
  72. 6050 GOTO 2000
  73. 6998 :
  74. 6999 REM**********************
  75. 7000 REM  WIDERSTANDSMESSUNG
  76. 7001 REM**********************
  77. 7050 W=(65535-(PEEK(56582)+PEEK(56583)*256))*1.02E-6/(.7*220E-9)
  78. 7070 W$="  "+LEFT$(STR$(INT(W))+"      ",7)+" [207]HM    "
  79. 7100 GOTO2000
  80. 7998 :
  81. 7999 REM********************
  82. 8000 REM  MESSWERTSPEICHER
  83. 8001 REM********************
  84. 8050 GET A$: IF A$="" THEN 8050
  85. 8060 IF VAL(A$)<0 OR VAL(A$)>9 THEN 8110
  86. 8070 W$(VAL(A$))=W$
  87. 8110 POKE 211,0: POKE 214,2: SYS 58732: REM  KURSORPOSITIONIERUNG
  88. 8120 FOR I=0 TO 9
  89. 8130 : PRINT I; W$(I): PRINT
  90. 8140 NEXT I
  91. 8210 PRINT "[211]PEICHERN  [204]OESCHEN  [215]IDERSTANDSMESSUNG"
  92. 8220 PRINT "[203]APAZITAETSMESSUNG [201]MPULSAUSLOESEN [209]UIT"
  93. 8490 GOTO 2000
  94. 8498 :
  95. 8499 REM**************************
  96. 8500 REM  LOESCHEN DER SPEICHER:
  97. 8501 REM**************************
  98. 8510 FOR I=0 TO 9: W$(I)="                 ": NEXT I
  99. 8520 GOTO 8110
  100. 8998 :
  101. 9000 REM****************
  102. 9010 REM   HAUPTMENUE
  103. 9020 REM****************
  104. 9030 GET A$
  105. 9040 IF A$="S" THEN 8000
  106. 9050 IF A$="L" THEN 8500
  107. 9060 IF A$="Q" THEN PRINT"[147]": END
  108. 9070 IF A$="K" OR A$="C" THEN 1400
  109. 9080 IF A$="W" OR A$="R" THEN 1500
  110. 9090 IF A$="I" THEN 2000
  111. 9095 RETURN
  112.