home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / s85xx / s8507b.d64 / aktienmanager (.txt) next >
Commodore BASIC  |  1995-03-30  |  25KB  |  684 lines
  1. 10 REM ********************************
  2. 20 REM *                              *
  3. 30 REM *     AKTIENKURS-PROGRAMM      *
  4. 40 REM *                              *
  5. 50 REM *  FUER C-64/FLOPPY/(DRUCKER)  *
  6. 60 REM *                              *
  7. 70 REM *   (C) 1984/85 BY B. FIETHE   *
  8. 80 REM *                              *
  9. 85 REM ********************************
  10. 88 REM --- STEUERZEICHEN ---
  11. 89 REM "" = CRSR DOWN
  12. 90 REM "[145]" = CRSR UP
  13. 91 REM "" = CRSR RIGHT
  14. 92 REM "[157]" = CRSR LEFT
  15. 93 REM "[147]" = CLR
  16. 94 REM "" = HOME
  17. 95 REM "" = RVS ON
  18. 96 REM "[146]" = RVS OFF
  19. 97 REM "" = CTRL 3
  20. 98 REM "[151]" = C= 4
  21. 99 REM ---------------------
  22. 100 REM --- DRUCKERSPEZIFISCHE ROUTINE              IM BEREICH $C700-$CB00
  23. 110 REM ZUM AUSDRUCK DES HGR-BILDSCHIRMS        WIRD GELADEN ---
  24. 120 IFWQ=0THENWQ=1:LOAD"DCOPY",8,1
  25. 130 REM --- GRAFIK-ERWEITERUNG LADEN ---
  26. 140 IFWQ=1THENWQ=2:LOAD"GRAFIK-E/MS",8,1
  27. 150 SYS49152:REM --- ERWEITERUNG STARTEN
  28. 155 _F4860:REM --- FEHLERBEHANDLUNG EIN
  29. 160 OPEN15,8,15:FORI=1TO32:CR$=CR$+"":NEXTI:FI$=".00"
  30. 170 DIMU(500),K(500),TA$(30),MO$(30),JA$(30)
  31. 180 CLOSE2:POKE53280,15:POKE53281,15:E8=0:ET$="":PRINT"[147]"
  32. 190 PRINT"[151]":PRINT:PRINT:PRINT"FIRMENKUERZEL (MAX.3/0=KATALOG):  "KA$
  33. 200 PRINT"[145]"CR$;:INPUTKA$:IFLEN(KA$)>3THEN190
  34. 210 IFKA$="0"THENPRINT:PRINT:GOSUB6590:GOTO190
  35. 220 PRINT"[147]      K U R S - P R O G R A M M"
  36. 230 PRINT:PRINT:PRINT"[151]              HAUPTMENUE"
  37. 240 PRINT"========================================"
  38. 250 PRINT:PRINT:PRINT"    F 1[146] = KURSE EINGEBEN/AENDERN"
  39. 260 PRINT:PRINT"    F 3[146] = TAEGL. UEBERSICHT"
  40. 270 PRINT:PRINT"    F 5[146] = UEBERSICHT"
  41. 280 PRINT:PRINT"    F 7[146] = PROGR.-ENDE"
  42. 290 GOSUB4470
  43. 300 IFF>1ANDF<4AND(AE=1ORJE=0)THENGOSUB5190
  44. 310 ONFGOTO330,900,2180,4450
  45. 320 GOTO180
  46. 330 PRINT"[147]  EINGABE/AENDERUNG":PRINT"======================================="
  47. 340 PRINT:PRINT:PRINT"    F 1[146] = NEUE KURSE EINGEBEN"
  48. 350 PRINT:PRINT"    F 3[146] = KURSE NACHTRAEGLICH AENDERN"
  49. 360 PRINT:PRINT"    F 5[146] = KURSE EINFUEGEN"
  50. 370 PRINT:PRINT"    F 7[146] = DATEI UEBERSPIELEN"
  51. 380 PRINT:PRINT"    F 6[146] = HAUPTMENUE"
  52. 390 GOSUB 4470:IF F<>1AND(AE=1ORJE=0)THENGOSUB5190
  53. 400 ON F GOTO 420,5630,5820,6030,180,330
  54. 410 GOTO 330
  55. 420 E=0:PRINT"[147]             KURSE EINGEBEN"
  56. 430 PRINT"========================================"
  57. 440 PRINT:PRINT:INPUT"[151]  TAG:";TA$:PRINT:INPUT"  MONAT:";MO$:PRINT:INPUT"  JAHR:";JA$
  58. 450 IFLEN(TA$)<>2ORLEN(MO$)<>2ORLEN(JA$)<>2THEN440
  59. 460 MO=VAL(MO$):JA=VAL(JA$):MO$(1)=STR$(MO):JA$(1)=STR$(JA)
  60. 470 IFE=1THEN580
  61. 480 PRINT:PRINT:INPUT"  KURS FRANKFURT: DM";KF
  62. 490 PRINT:INPUT"UMSATZ ''       : STUECK";UF
  63. 500 IFE=2THEN580
  64. 510 INPUT"[145][145][145]   HANNOVER ";KH
  65. 520 PRINT:PRINTLEFT$(CR$,24);:INPUTUH:IFE=3THEN580
  66. 530 INPUT"[145][145][145]   HAMBURG  ";KB
  67. 540 PRINT:PRINTLEFT$(CR$,24);:INPUTUB:IFE=4THEN580
  68. 550 INPUT"[145][145][145]   DUESSELD.";KD
  69. 560 PRINT:PRINTLEFT$(CR$,24);:INPUTUD:IFE=5THEN580
  70. 570 PRINT:PRINT:INPUT"  COMMERZBANK INDEX:";CI
  71. 580 IFAE=5THENGOSUB710:RETURN
  72. 590 AE=3:GOSUB710:AE=1:GOTO6380
  73. 600 OPEN2,8,2,KA$+"-AKTIE"+MO$(1)+JA$(1)+",S,A":GOSUB4960
  74. 610 PRINT#2,TA$:PRINT#2,MO$:PRINT#2,JA$:PRINT#2,KF:PRINT#2,UF:PRINT#2,KH
  75. 620 PRINT#2,UH:PRINT#2,KB:PRINT#2,UB:PRINT#2,KD:PRINT#2,UD:PRINT#2,CI
  76. 630 CLOSE2:OPEN2,8,2,"@:"+KA$+"-AKTIE,S,W":PRINT#2,ME:PRINT#2,JE:PRINT#2,MO$(1)
  77. 640 PRINT#2,JA$(1):PRINT#2,NA$:CLOSE2:GOTO670
  78. 650 PRINT:PRINT"DISKETTE VOLL!  BITTE NEUE DISK EINLEGEN":INPUTF$
  79. 660 GOTO600
  80. 670 OPEN2,8,2,KA$+"-AKTIE"+MO$(1)+JA$(1)+",S,R"
  81. 680 INPUT#2,TA$,MO$,JA$,KF,UF,KH,UH,KB,UB,KD,UD,CI
  82. 690 IFST<>64THEN680
  83. 700 CLOSE2
  84. 710 PRINT"[147]  DATUM: "TA$"."MO$"."JA$
  85. 720 PRINT:PRINT"  KURSE:"SPC(19)"UMSATZ:":PRINT"  ================================"
  86. 730 PRINT:PRINT"  FRANKFURT:"KF"DM"TAB(25)UF"STUECK"
  87. 740 PRINT:PRINT"  HANNOVER :"KH"DM"TAB(25)UH"STUECK"
  88. 750 PRINT:PRINT"  HAMBURG  :"KB"DM"TAB(25)UB"STUECK"
  89. 760 PRINT:PRINT"  DUESSELD :"KD"DM"TAB(25)UD"STUECK"
  90. 770 PRINT:PRINT"  COMMERZBANK INDEX:"CI
  91. 780 IFAE<3THENPRINT:INPUT"  AUF ZWEITE DISK ABSPEICHERN (J/N)";F$:IFF$="J"THEN 6380
  92. 790 IF AE<3THEN1000
  93. 800 PRINT:PRINT:INPUT"  RICHTIG (J/N) ";E$:IFE$="J"THENRETURN
  94. 810 IFE$<>"N"THENPRINT"[145][145]":GOTO800
  95. 820 PRINT"1[146][157]2[146][157]3[146][157]4";
  96. 830 PRINT"[146][157]5[146][157]6[146]"
  97. 840 Z=Z-1:PRINT"  WAS IST FALSCH (1-6)?"
  98. 850 GETE$:E=VAL(E$):IFE$=""THEN850
  99. 860 IFE>2ANDE<6THENPRINT:PRINT:PRINT"  KURS          : DM  000.00"
  100. 870 IFE>2ANDE<6THENPRINT:PRINT"UMSATZ ''       : STUECK"
  101. 880 ONEGOTO440,480,510,530,550,570,850
  102. 890 GOTO850
  103. 900 AB=30:AA=4:PRINT"[147]          TAEGLICHE UEBERSICHT"
  104. 910 PRINT"========================================"
  105. 920 PRINT:PRINT:PRINT"[151]    F 1[146] = AKTUELLE KURSE"
  106. 930 PRINT:PRINT"    F 3[146] = KURSE EINES TAGES"
  107. 940 PRINT:PRINT"    F 5[146] = KURSE EINER WOCHE"
  108. 950 PRINT:PRINT"    F 7[146] = HAUPTMENUE"
  109. 960 GOSUB4470
  110. 970 ONFGOTO990,1040,1010
  111. 980 GOTO180
  112. 990 MT$=STR$(ML):JR$=STR$(JL):TG$="":AF=5:GOSUB4580:GOTO1080
  113. 1000 CLOSE3:CLOSE2:PRINT:INPUT"[151]  WEITER";F$:GOTO180
  114. 1010 PRINT"[147]        KURSE EINER WOCHE":PRINT"==============================="
  115. 1020 PRINT"[151]  ANFANGSTAG DER WOCHE EINGEBEN"
  116. 1030 AF=1:GOTO1070
  117. 1040 PRINT"[147]             TAGESKURS"
  118. 1050 PRINT"========================================"
  119. 1060 PRINT"[151]  GEWUENSCHTEN TAG EINGEBEN:":AF=3
  120. 1070 GOSUB4520
  121. 1080 MN$=MT$:JH$=JR$:PRINT"[147]               AUSGABEFORM"
  122. 1090 PRINT"========================================"
  123. 1100 PRINT:PRINT:PRINT"[151]    F 1[146] : ZAHLENWERTE"
  124. 1110 PRINT:PRINT"    F 3[146] : GRAFIK"
  125. 1120 PRINT:PRINT"    F 5[146] : HAUPTMENUE"
  126. 1130 GOSUB4470
  127. 1140 ONFGOTO1170,1720,180
  128. 1150 GOTO1080
  129. 1160 REM --- ZAHLENWERTAUSGABE ---
  130. 1170 PRINT:PRINT:INPUT"HOECHST-TIEFSTKURS DES GANZEN JAHRES ";F$
  131. 1180 PRINT:PRINT:PRINT"[147]        "NA$"-AKTIE":GF=0:GH=0:GB=0:GD=0
  132. 1190 PRINT"========================================":MF=500:MH=500:MB=500:MD=500
  133. 1200 PRINTSPC(15)ET$:PRINTSPC(20)"[151]KASSAKURSE";:GI=0:MI=5000:A1=1
  134. 1210 PRINT:PRINT:PRINT"[151]  DATUM   FRANKF   HANN    HAMB   D'DORF";
  135. 1220 PRINT:PRINT"[192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192]";:UI=0:GR=0:KL=500:A=16
  136. 1230 PRINT:UG=0:FORI=0TOAA:INPUT#2,TA$,MO$,JA$,KF,UF,KH,UH,KB,UB,KD,UD,CI
  137. 1240 M=0:IFKF>=GFTHENGF=KF:IFKF>=GRTHENGR=KF:M=1
  138. 1250 IFKH>=GHTHENGH=KH:IFKH>=GRTHENGR=KH:M=1
  139. 1260 IFKB>=GBTHENGB=KB:IFKB>=GRTHENGR=KB:M=1
  140. 1270 IFKD>=GDTHENGD=KD:IFKD>=GRTHENGR=KD:M=1
  141. 1280 IFM=1THENTA$(1)=TA$:MO$(1)=MO$:JA$(1)=JA$:M=0
  142. 1290 IFKF=<MFANDKF>0THENMF=KF:IFKF=<KLTHENKL=KF:M=1
  143. 1300 IFKH=<MHANDKH>0THENMH=KH:IFKH=<KLTHENKL=KH:M=1
  144. 1310 IFKB=<MBANDKB>0THENMB=KB:IFKB=<KLTHENKL=KB:M=1
  145. 1320 IFKD=<MDANDKD>0THENMD=KD:IFKD=<KLTHENKL=KD:M=1
  146. 1330 IFM=1THENTA$(2)=TA$:MO$(2)=MO$:JA$(2)=JA$:M=0
  147. 1340 UF=INT(UF):UH=INT(UH):UB=INT(UB):UD=INT(UD):UG=UF+UH+UB+UD:IFCI>=GITHENGI=CI
  148. 1350 UI=UI+UG:IFCI=<MIANDCI>0THENMI=CI
  149. 1360 IFDR=1THENRETURN
  150. 1370 PRINTTA$"."MO$"."JA$;:KF$=STR$(INT(KF)):FK$=STR$(KF):LL=LEN(FK$)-LEN(KF$)
  151. 1380 IFLL>3THENLL=3
  152. 1390 PRINTSPC(5-LEN(KF$))LEFT$(FK$,LEN(KF$)+LL)RIGHT$(FI$,(3-LL));
  153. 1400 KH$=STR$(INT(KH)):HK$=STR$(KH):LL=LEN(HK$)-LEN(KH$):IFLL>3THENLL=3
  154. 1410 PRINTSPC(5-LEN(KH$))LEFT$(HK$,LEN(KH$)+LL)RIGHT$(FI$,(3-LL));
  155. 1420 KB$=STR$(INT(KB)):BK$=STR$(KB):LL=LEN(BK$)-LEN(KB$):IFLL>3THENLL=3
  156. 1430 PRINTSPC(5-LEN(KB$))LEFT$(BK$,LEN(KB$)+LL)RIGHT$(FI$,(3-LL));
  157. 1440 KD$=STR$(INT(KD)):DK$=STR$(KD):LL=LEN(DK$)-LEN(KD$):IFLL>3THENLL=3
  158. 1450 PRINTSPC(5-LEN(KD$))LEFT$(DK$,LEN(KD$)+LL)RIGHT$(FI$,(3-LL));
  159. 1460 PRINTSPC(A-LEN(STR$(UF)))UFSPC(7-LEN(STR$(UH)))UHSPC(7-LEN(STR$(UB)))UB;
  160. 1470 PRINTSPC(7-LEN(STR$(UD)))UD"[157]";
  161. 1480 IFI=INT(AA-1)THENFF=KF+KH+KB+KD
  162. 1490 IFST<>64THENNEXTI:CLOSE2:GOTO1510
  163. 1500 GOSUB4820:NEXTI:CLOSE2
  164. 1510 DF=KF+KH+KB+KD
  165. 1520 DD=(DF-FF)/4:IFDD>2.6THENPRINT:PRINT"  TENDENZ: STARK STEIGEND":GOTO1560
  166. 1530 IFDD>1.3THENPRINT:PRINT"  TENDENZ: LEICHT STEIGEND":GOTO1560
  167. 1540 IFDD<-2.6THENPRINT:PRINT"  TENDENZ: STARK FALLEND":GOTO1560
  168. 1550 IFDD<-1.3THENPRINT:PRINT"  TENDENZ: LEICHT FALLEND"
  169. 1560 IFF$="J"THENGOSUB6490
  170. 1570 GR$=STR$(INT(GR)):RG$=STR$(GR):LL=LEN(RG$)-LEN(GR$):IFLL>3THENLL=3
  171. 1580 PRINT:PRINT"  HOECHSTKURS:";
  172. 1590 PRINTSPC(5-LEN(GR$))LEFT$(RG$,LEN(GR$)+LL)RIGHT$(FI$,(3-LL));
  173. 1600 PRINT" DM AM "TA$(1)"."MO$(1)"."JA$(1)
  174. 1610 KL$=STR$(INT(KL)):LK$=STR$(KL):LL=LEN(LK$)-LEN(KL$):IFLL>3THENLL=3
  175. 1620 PRINT"  TIEFSTKURS :";
  176. 1630 PRINTSPC(5-LEN(KL$))LEFT$(LK$,LEN(KL$)+LL)RIGHT$(FI$,(3-LL));
  177. 1640 PRINT" DM AM "TA$(2)"."MO$(2)"."JA$(2)
  178. 1650 PRINT"  GESAMTUMSAETZE:"UI"STUECK"
  179. 1660 A1=0:PRINT:INPUT"  DRUCKER";F$:IFF$<>"J"THEN3350
  180. 1670 A1=1:PRINT"[145]"TAB(20)"DRUCKER AN";:INPUTF$:OPEN4,4:MT$=MN$:JR$=JH$
  181. 1680 IFMM=0THENGOSUB4740:GOTO1700
  182. 1690 GOSUB4550
  183. 1700 DR=1:GOTO5230
  184. 1710 REM --- GRAFIKAUSGABE ---
  185. 1720 AD=20:TE$="":GOSUB 3960
  186. 1730 _L20,10TO20,170:_L20,170TO150,170:_L190,10TO190,170
  187. 1740 _L190,170TO310,170:FORI=10TO170STEP(AC*(INT(9/AC)+1)):FORT=15TO150STEP5
  188. 1750 _DT,I:NEXTT,I
  189. 1760 FORI=10TO170STEP(AZ*(INT(9/AZ)+1)):FORT=185TO320STEP5:_DT,I:NEXTT,I
  190. 1770 FORI=20TO150STEPAB:FORT=10TO175STEP4:_DI,T:_D(I+170),T:NEXTT,I
  191. 1780 _P200,0JA$:_P155,170"   0"
  192. 1790 _P150,10UR$:_P20,0TE$:_P0,10GR$
  193. 1800 _P0,170KL$:GOSUB1950:AD=190:GOSUB2130:GOTO3270
  194. 1810 INPUTF$
  195. 1820 _T:PRINT"[147]  ERWEITERUNG":PRINT"===================================="
  196. 1830 PRINT:PRINT:PRINT"[151]    F 1[146] = GRAFIK AUSDRUCKEN":IFET$<>""THEN1860
  197. 1840 PRINT:PRINT"    F 3[146] = DURCHSCHNITT"
  198. 1850 PRINT:PRINT"    F 5[146] = WENDEPUNKTE"
  199. 1860 PRINT:PRINT"    F 7[146] = WEITER"
  200. 1870 GOSUB4470
  201. 1880 ONFGOTO1900,3400,3650,3330
  202. 1890 GOTO1820
  203. 1900 INPUT"[147]  DRUCKER AN";F$
  204. 1910 PRINT:INPUT"[151]  TABULATOR:";TB:IFTB<0ORTB>40THEN1910
  205. 1920 REM --- STARTEN DES AUSDRUCKS ---
  206. 1930 SYS50944,TB,14:GOTO1820
  207. 1940 REM --- LINIEN ZEICHNEN ---
  208. 1950 IFE8=3THEN2060
  209. 1960 FORI=0TOAA-1:T=1:F=0
  210. 1970 IFK(I+T)<=0THENT=T+1:F=2:IFAA-I<TTHENF=0:RETURN
  211. 1980 IFF=2THENF=0:GOTO1970
  212. 1990 IFK(I)<=0THENI=I+1
  213. 2000 IFI=AATHENRETURN
  214. 2010 IFB=5THENY=170-(LOG(K(I))-LOG(KL))*LG:Y1=170-(LOG(K(I+T))-LOG(KL))*LG
  215. 2020 IFB=5THEN:_L(AD+I*AB),YTO(AD+(I+T)*AB),Y1:GOTO2040
  216. 2030 _L(AD+I*AB),(170-(K(I)-KL)*AC)TO(AD+(I+T)*AB),(170-(K(I+T)-KL)*AC)
  217. 2040 NEXTI:RETURN
  218. 2050 REM --- HOCH-TIEF-BALKEN ---
  219. 2060 FORI=0TOAASTEP2
  220. 2070 IFB=5THENY=170-(LOG(K(I))-LOG(KL))*LG:Y1=170-(LOG(K(I+1))-LOG(KL))*LG:GOTO2090
  221. 2080 Y=170-(K(I)-KL)*AC:Y1=170-(K(I+1)-KL)*AC
  222. 2090 AJ=INT(100/AA):IFAJ>7THENAJ=7
  223. 2100 FORT=0TOAJ:_L(AD+I*AB+T),YTO(AD+I*AB+T),Y1:NEXTT
  224. 2110 NEXTI:RETURN
  225. 2120 REM --- UMSATZ ZEICHNEN ---
  226. 2130 FORI=0TOAA:HU=170-U(I)*AZ
  227. 2140 IFHU>=170THENNEXTI:RETURN
  228. 2150 IFHU<9THENHU=9
  229. 2160 AJ=INT(100/AA):IFAJ>7THENAJ=7
  230. 2170 FORT=0TOAJ:_L(AD+T+I*AB),HUTO(AD+T+I*AB),170:NEXTT,I:RETURN
  231. 2180 PRINT"[147]  UEBERSICHT":PRINT"========================================"
  232. 2190 PRINT:PRINT:PRINT"[151]    F 1[146] = FREIER ZEITRAUM"
  233. 2200 PRINT:PRINT"    F 3[146] = MONAT"
  234. 2210 PRINT:PRINT"    F 5[146] = JAHR"
  235. 2220 PRINT:PRINT"    F 7[146] = JAHRE"
  236. 2230 PRINT:PRINT"    F 8[146] = HAUPTMENUE"
  237. 2240 GOSUB4470:ONFGOTO2260,2400,2470,2480,180,180
  238. 2250 GOTO2180
  239. 2260 PRINT"[147]  FREIER ZEITRAUM":PRINT"======================================="
  240. 2270 PRINT:PRINT:PRINT"[151]    F 1[146] = ALLE GESPEICHERTEN TAGE"
  241. 2280 PRINT:PRINT"    F 3[146] = ZEITRAUMANFANG EINGEBEN"
  242. 2290 PRINT:PRINT"    F 5[146] = ZEITRAUMENDE EINGEBEN"
  243. 2300 GOSUB4470:ONFGOTO2320,2330,2370
  244. 2310 GOTO2260
  245. 2320 GOSUB4760:AB=270/AA:AD=30:MM=0:GOTO3030
  246. 2330 PRINT"[147]  ZEITRAUMANFANG EINGEBEN":PRINT"==============================="
  247. 2340 PRINT:PRINT:PRINT"[151]  ANFANGSTAG EINGEBEN":AF=1:GOSUB4520
  248. 2350 PRINT:PRINT:INPUT"  ZEITRAUMLAENGE IN TAGEN:";AA:AA=AA-1:AB=270/AA:AD=30
  249. 2360 GOTO3030
  250. 2370 PRINT"[147]  ZEITRAUMENDE EINGEBEN":PRINT"================================="
  251. 2380 PRINT:PRINT:INPUT"[151]  ZEITRAUMLAENGE IN TAGEN:";AF:AA=AF-1
  252. 2390 PRINT:PRINT:PRINT"  ENDTAG EINGEBEN:":GOSUB4520:AB=270/AA:AD=30:GOTO3030
  253. 2400 PRINT"[147]  MONAT":PRINT"======================================="
  254. 2410 PRINT:PRINT:INPUT"[151]  MONAT:";MT:PRINT:INPUT"  JAHR:";JR:MT$=STR$(MT):JR$=STR$(JR)
  255. 2420 GOSUB4740:I=0
  256. 2430 INPUT#2,A,A,A,A,A,A,A,A,A,A,A,A:I=I+1
  257. 2440 IFST<>64THEN2430
  258. 2450 CLOSE2:AA=I-1:GOSUB4740
  259. 2460 AB=270/AA:AD=30:GOTO3030
  260. 2470 EE$="1 JAHR":EE=1:GOTO2490
  261. 2480 EE$="JAHRE":EE=2
  262. 2490 PRINT"[147]  AUSGABEFORM":PRINT"======================================="
  263. 2500 PRINT:PRINT:PRINT"[151]  "EE$
  264. 2510 PRINT:PRINT"    F 1[146] = MONATS-DURCHSCHNITT"
  265. 2520 PRINT:PRINT"    F 3[146] = KONTINUIERLICH"
  266. 2530 PRINT:PRINT"    F 5[146] = MONATS-HOCH-TIEF-WERTE"
  267. 2540 GOSUB4470:ONFGOTO2570,2780,2870,2550
  268. 2550 GOTO2490
  269. 2560 REM --- DURCHSCHNITTE BERECHNEN ---
  270. 2570 IFEE=1THENPRINT:INPUT"  JAHR:";JR:JR$=STR$(JR)
  271. 2580 IFEE=2THENJR$=STR$(JE)
  272. 2590 MT$=" 1":ET$="DURCHSCHN "
  273. 2600 IFVAL(JR$)=JETHENMT$=STR$(ME)
  274. 2610 I=0:T=0:OPEN3,8,3,"@:"+KA$+"-AKTIE 13 00,S,W":GOSUB4740
  275. 2620 KF(1)=0:UF(1)=0:KH(1)=0:UH(1)=0:KB(1)=0:UB(1)=0:KD(1)=0:UD(1)=0:CI(1)=0
  276. 2630 INPUT#2,A,MO$,JA$,KF,UF,KH,UH,KB,UB,KD,UD,CI
  277. 2640 IFKF=0ORUF=0ORKH=0ORUH=0ORKB=0ORUB=0ORKD=0ORUD=0ORCI=0THEN2670
  278. 2650 KH(1)=KH(1)+KH:UH(1)=UH(1)+UH:KB(1)=KB(1)+KB:UB(1)=UB(1)+UB:KD(1)=KD(1)+KD
  279. 2660 KF(1)=KF(1)+KF:UF(1)=UF(1)+UF:UD(1)=UD(1)+UD:CI(1)=CI(1)+CI:I=I+1
  280. 2670 IFST<>64THEN2630
  281. 2680 CLOSE2:T=T+1:KF=KF(1)/I:UF=UF(1)/I:KH=KH(1)/I:UH=UH(1)/I:KB=KB(1)/I:F=0
  282. 2690 UB=UB(1)/I:KD=KD(1)/I:UD=UD(1)/I:CI=CI(1)/I:PRINT#3,MO$:PRINT#3,JA$:PRINT#3,"00"
  283. 2700 PRINT#3,KF:PRINT#3,UF:PRINT#3,KH:PRINT#3,UH:PRINT#3,KB:PRINT#3,UB:PRINT#3,KD:PRINT#3,UD:PRINT#3,CI
  284. 2710 IFVAL(JR$)=JLANDVAL(MT$)=MLTHENCLOSE3:AA=T-1:MT$=" 13":JR$=" 00":GOSUB4740:F=3
  285. 2720 IFF=3THENAB=270/AA:AD=30:F=0:MM=0:GOTO3030
  286. 2730 IFMT$=" 12"THENF=2:IFEE=1THENJR$=STR$(JL):MT$=STR$(ML):GOTO2710
  287. 2740 IFF=2ANDEE=2THENMT$=" 1":JR$=STR$(VAL(JR$)+1):GOTO2760
  288. 2750 MT$=STR$(VAL(MT$)+1)
  289. 2760 I=0:GOSUB4740:GOTO2620
  290. 2770 REM --- KONTINUIERLICH ---
  291. 2780 PRINT:INPUT"  JAHR:";JR:JR$=STR$(JR):MT$=" 1":IFJR=JETHENMT$=STR$(ME)
  292. 2790 MN$=MT$:I=0:GOSUB4740
  293. 2800 INPUT#2,A,A,A,A,A,A,A,A,A,A,A,A:I=I+1
  294. 2810 IFST<>64THEN2800
  295. 2820 CLOSE2:IFJR=JLANDVAL(MT$)=MLTHEN2850
  296. 2830 IFMT$=" 12"THEN2850
  297. 2840 MT$=STR$(VAL(MT$)+1):GOSUB4740:GOTO2800
  298. 2850 AA=I-1:MT$=MN$:GOSUB4740:AD=30:AB=270/AA:MM=0:GOTO3030
  299. 2860 REM --- HOCH-TIEF-WERTE ---
  300. 2870 E8=3:IFEE=1THENPRINT:INPUT"  JAHR:";JR:JR$=STR$(JR)
  301. 2880 IFEE=2THENJR$=STR$(JE)
  302. 2890 MT$=" 1":ET$="HOCH-TIEF ":IFVAL(JR$)=JETHENMT$=STR$(ME)
  303. 2900 I=0:OPEN3,8,3,"@:"+KA$+"-AKTIE 13 00,S,W":GOSUB4740
  304. 2910 KL=500:MF=500:MH=500:MB=500:MD=500:GR=0:GF=0:GH=0:GB=0:GD=0:UI=0:GI=0
  305. 2920 MI=5000
  306. 2930 INPUT#2,TA$,MO$,JA$,KF,UF,KH,UH,KB,UB,KD,UD,CI:DR=1:GOSUB1240:DR=0
  307. 2940 IFST<>64THEN2930
  308. 2950 CLOSE2:I=I+1:PRINT#3,MO$:PRINT#3,JA$:PRINT#3,"00":PRINT#3,MF:PRINT#3,UI:PRINT#3,MH:PRINT#3,UI
  309. 2960 PRINT#3,MB:PRINT#3,UI:PRINT#3,MD:PRINT#3,UI:PRINT#3,MI:PRINT#3,"[160][160]":PRINT#3,JA$:PRINT#3,"00":PRINT#3,GF:PRINT#3,UI
  310. 2970 PRINT#3,GH:PRINT#3,UI:PRINT#3,GB:PRINT#3,UI:PRINT#3,GD:PRINT#3,UI:PRINT#3,GI
  311. 2980 IFVAL(JR$)=JLANDVAL(MT$)=MLTHEN3020
  312. 2990 F=0:IFMT$=" 12"THENF=3:IFEE=1THEN3020
  313. 3000 IFF=3ANDEE=2THENMT$=" 1":JR$=STR$(VAL(JR$)+1):GOSUB4740:GOTO2910
  314. 3010 MT$=STR$(VAL(MT$)+1):GOSUB4740:GOTO2910
  315. 3020 CLOSE3:AA=I*2-1:MT$=" 13":JR$=" 00":GOSUB4740:AB=270/AA:AD=30:MM=0:GOTO3030
  316. 3030 PRINT"[147]  AUSGABEFORM":PRINT"======================================="
  317. 3040 B=0:PRINT:PRINT:PRINT"[151]    F 1[146] = ZAHLENWERTE":MN$=MT$:JH$=JR$:A2=0
  318. 3050 PRINT:PRINT"    F 3[146] = KURSGRAFIK"
  319. 3060 PRINT:PRINT"    F 5[146] = UMSATZGRAFIK"
  320. 3070 PRINT:PRINT"    F 7[146] = HAUPTMENUE"
  321. 3080 GOSUB4470:ONFGOTO1170,3110,3130,180
  322. 3090 GOTO3030
  323. 3100 REM --- GRAFIKAUSGABE ---
  324. 3110 INPUT"[147]  LOG. DARSTELLUNG (J/N)";F$:IFF$="J"THENB=5
  325. 3120 TE$=ET$+"KASSAKURSE ":AD=30:GOTO3140
  326. 3130 TE$="UMSATZ IN STUECK, ":AD=40
  327. 3140 E=F:GOSUB3960:_LAD,10TOAD,170:_LAD,170TO320,170
  328. 3150 IFE=3THENAC=AZ:GOTO3180
  329. 3160 IFB=5THENLG=160/(LOG(GR)-LOG(KL)):FORI=KLTOGRSTEP(INT(9/AC)+1)
  330. 3170 IFB=5THENY=170-(LOG(I)-LOG(KL))*LG:FORT=25TO320STEP5:_DT,Y:NEXTT,I:GOTO3190
  331. 3180 FORI=10TO170STEP(AC*(INT(9/AC)+1)):FORT=AD-5TO320STEP5:_DT,I:NEXTT,I
  332. 3190 FORI=ADTO320STEP(AB*(INT(AA/12)+1)):FORT=10TO175STEP4:_DI,T:NEXTT,I
  333. 3200 _P280,0;11JA$:_P40,0TE$
  334. 3210 IFE=2ANDB=5THEN:_P0,0"LOG":GOTO3230
  335. 3220 IFE=2THEN:_P0,0"NORM"
  336. 3230 IFE=2THEN:_P0,10GR$:_P0,170KL$:AD=30:GOSUB1950:GOTO1810
  337. 3240 IFE=3THEN:_P0,170"    0":_P0,10UR$
  338. 3250 IFE=3THEN:AD=40:GOSUB2130:GOTO3270
  339. 3260 GOTO3030
  340. 3270 GETF$:IFF$=""THEN3270
  341. 3280 _T:INPUT"[147]  AUSDRUCKEN";F$:IFF$<>"J"THEN3350
  342. 3290 PRINT:PRINT:INPUT"  DRUCKER AN";F$
  343. 3300 PRINT:INPUT"[151]  TABULATOR:";TB:IFTB<0ORTB>40THEN3300
  344. 3310 REM --- STARTEN DES AUSDRUCKS ---
  345. 3320 SYS50944,TB,14:GOTO3280
  346. 3330 MT$=MN$:JR$=JH$:IFMM=0THENGOSUB4740:GOTO3030
  347. 3340 GOSUB4550:GOTO3030
  348. 3350 MT$=MN$:JR$=JH$:IFMM=0THENGOSUB4740:GOTO3370
  349. 3360 GOSUB4550
  350. 3370 IFAB=30ANDAA=4THEN1080
  351. 3380 GOTO3030
  352. 3390 REM --- DURCHSCHNITTSKURVE ---
  353. 3400 IFET$<>""THEN1820
  354. 3410 IFA2=1THEN1820
  355. 3420 NN=MM:ZA=AA:AA=100:MT$=MN$:JR$=JH$:AF=100:IFTG$=""THENTG$="00"
  356. 3430 GOSUB4580
  357. 3440 ZZ=-1:FORI=0TOZA:K(I)=0:NEXTI:ZB=AA:AA=INT(ZA+ZB)-1:ZC=0:T=-1
  358. 3450 FORI=0TOAA
  359. 3460 KH=KF:ZZ=ZZ+1:IFZZ>ZATHENZZ=ZA
  360. 3470 IFI/5=INT(I/5)THENT=T+1:IFI>ZBTHENZC=ZC+5
  361. 3480 IFBB=1THENINPUT#2,A,A,A,KF,A,A,A,A,A,A,A,A:GOTO3530
  362. 3490 IFBB=2THENINPUT#2,A,A,A,A,A,KF,A,A,A,A,A,A:GOTO3530
  363. 3500 IFBB=3THENINPUT#2,A,A,A,A,A,A,A,KF,A,A,A,A:GOTO3530
  364. 3510 IFBB=5THENINPUT#2,A,A,A,A,A,A,A,A,A,KF,A,A:GOTO3530
  365. 3520 IFBB=4THENINPUT#2,A,A,A,A,A,A,A,A,A,A,A,KF
  366. 3530 IFKF<=0THENKF=KH
  367. 3540 FORQ=ZCTOZZSTEP5:K(I-T*5+Q)=K(I-T*5+Q)+KF:NEXTQ
  368. 3550 IFST=64THENGOSUB4820
  369. 3560 NEXTI:_G15:CLOSE2
  370. 3570 FORI=0TOZA:K(I)=K(I)/INT((ZB-1)/5+1):NEXTI
  371. 3580 AA=ZA:FORI=0TOAA-1
  372. 3590 IFB=5THENY=170-(LOG(K(I))-LOG(KL))*LG:Y1=170-(LOG(K(I+1))-LOG(KL))*LG:GOTO3610
  373. 3600 Y=170-(K(I)-KL)*AC:Y1=170-(K(I+1)-KL)*AC
  374. 3610 XY=(Y1-Y)/AB:FORT=(I*AB)TO((I+1)*AB)STEP2:X=XY*(T-I*AB)+Y:IFX<10ORX>170THEN3630
  375. 3620 _DAD+T,X
  376. 3630 NEXTT,I:A2=1:MM=NN:GOTO1810
  377. 3640 REM --- WENDEPUNKTE VERBINDEN ---
  378. 3650 IFET$<>""THEN1820
  379. 3660 A3=1:AI=INT(AA/3):G0=0:KO=5000:RG=0:LK=5000:IFA2=1THEN1820
  380. 3670 _G15:FORI=0TOAI-1:IFK(I)>G0THENG0=K(I):X1=I
  381. 3680 IFK(I)<KOANDK(I)>0THENKO=K(I):X3=I
  382. 3690 NEXTI
  383. 3700 FORI=AITOINT(AI*2)-1
  384. 3710 IFK(I)>RGTHENRG=K(I):X2=I
  385. 3720 IFK(I)<LKANDK(I)>0THENLK=K(I):X4=I
  386. 3730 NEXTI:WA=0:WB=X2*AB:AW=0:BW=X4*AB
  387. 3740 IFB=5THENY=170-(LOG(G0)-LOG(KL))*LG:Y1=170-(LOG(RG)-LOG(KL))*LG:GOTO3760
  388. 3750 Y=170-(G0-KL)*AC:Y1=170-(RG-KL)*AC
  389. 3760 XY=(Y1-Y)/(X2*AB-X1*AB)
  390. 3770 T=XY*(WA-X1*AB)+Y:T1=XY*(WB-X1*AB)+Y:IFT<10THENT=10:WA=(T-Y)/XY+X1*AB
  391. 3780 IFT1<10THENT1=10:WB=(T1-Y)/XY+X1*AB
  392. 3790 IFT>170THENT=170:WA=(T-Y)/XY+X1*AB
  393. 3800 IFT1>170THENT1=170:WB=(T1-Y)/XY+X1*AB
  394. 3810 _LWA+AD,TTOWB+AD,T1
  395. 3820 IFB=5THENY=170-(LOG(KO)-LOG(KL))*LG:Y1=170-(LOG(LK)-LOG(KL))*LG:GOTO3840
  396. 3830 Y=170-(KO-KL)*AC:Y1=170-(LK-KL)*AC
  397. 3840 XY=(Y1-Y)/(X4*AB-X3*AB)
  398. 3850 T=XY*(AW-X4*AB)+Y1:T1=XY*(BW-X4*AB)+Y1:IFT<10THENT=10:AW=(T-Y1)/XY+X4*AB
  399. 3860 IFT1<10THENT1=10:BW=(T1-Y1)/XY+X4*AB
  400. 3870 IFT>170THENT=170:AW=(T-Y1)/XY+X4*AB
  401. 3880 IFT1>170THENT1=170:BW=(T1-Y1)/XY+X4*AB
  402. 3890 _LAW+AD,TTOBW+AD,T1
  403. 3900 IFA3=0THEN1810
  404. 3910 G0=0:KO=5000:FORI=INT(AI*2)TOAA
  405. 3920 IFK(I)>=G0THENG0=K(I):X1=I
  406. 3930 IFK(I)=<KOANDK(I)>0THENKO=K(I):X3=I
  407. 3940 NEXTI:A3=0:WA=X2*AB:WB=290:AW=X4*AB:BW=290
  408. 3950 GOTO3740
  409. 3960 PRINT"[147]             BOERSE":UR=0
  410. 3970 PRINT"========================================"
  411. 3980 PRINT:PRINT:PRINT"[151]    F 1[146] = FRANKFURT"
  412. 3990 PRINT:PRINT"    F 3[146] = HANNOVER"
  413. 4000 PRINT:PRINT"    F 5[146] = HAMBURG"
  414. 4010 PRINT:PRINT"    F 6[146] = DUESSELDORF"
  415. 4020 PRINT:PRINT"    F 7[146] = COMMERZBANK INDEX"
  416. 4030 PRINT:PRINT"    F 8[146] = UMSAETZE INSGESAMMT"
  417. 4040 GOSUB4470:_G15:_C:_D320,200;11:AT=INT(AA/12)+1:BB=F
  418. 4050 ONFGOTO4070,4100,4130,4190,4160,4260,4060
  419. 4060 GOTO3960
  420. 4070 MO=15:KL=500:GR=0:FORI=0TOAA:INPUT#2,TA$,MO$,JA$,K(I),U(I),A$,A$,A$,A$,A$,A$,A$
  421. 4080 GOSUB4330:IFTS=64THENGOSUB4820
  422. 4090 NEXTI:CLOSE2:TE$=TE$+"FRANKFURT":GOTO4430
  423. 4100 MO=15:KL=500:GR=0:FORI=0TOAA:INPUT#2,TA$,MO$,JA$,A$,A$,K(I),U(I),A$,A$,A$,A$,A$
  424. 4110 GOSUB4330:IFTS=64THENGOSUB4820
  425. 4120 NEXTI:CLOSE2:TE$=TE$+"HANNOVER":GOTO4430
  426. 4130 MO=15:KL=500:GR=0:FORI=0TOAA:INPUT#2,TA$,MO$,JA$,A$,A$,A$,A$,K(I),U(I),A$,A$,A$
  427. 4140 GOSUB4330:IFTS=64THENGOSUB4820
  428. 4150 NEXTI:CLOSE2:TE$=TE$+"HAMBURG":GOTO4430
  429. 4160 MO=15:KL=500:GR=0:FORI=0TOAA:INPUT#2,TA$,MO$,JA$,A$,A$,A$,A$,A$,A$,K(I),U(I),A$
  430. 4170 GOSUB4330:IFTS=64THENGOSUB4820
  431. 4180 NEXTI:CLOSE2:TE$=TE$+"DUESSELDORF":GOTO4430
  432. 4190 IFE<>2ANDAA>7THEN:_T:GOTO3960
  433. 4200 MO=15:KL=5000:GR=0:FORI=0TOAA:INPUT#2,TA$,MO$,JA$,A,A,A,A,A,A,A,A,K(I)
  434. 4210 GOSUB4330:IFTS=64THENGOSUB4820
  435. 4220 NEXTI:CLOSE2:TE$=ET$+"COMMERZBANK INDEX":GR$=RIGHT$(STR$(GR),4):KL$=RIGHT$(STR$(KL),4)
  436. 4230 AC=160/(GR-KL):IFAA=4ANDAB=30THENMT$=MN$:JR$=JH$:IFMM=0THENGOSUB4740:GOTO4280
  437. 4240 IFAA=4ANDAB=30THENGOSUB4550:GOTO4280
  438. 4250 RETURN
  439. 4260 IFE<>3ANDAA<>4ANDAB<>30THEN:_T:GOTO3960
  440. 4270 IFAB=30ANDAA=4THEN4200
  441. 4280 MO=15:UR=0:FORI=0TOAA:INPUT#2,TA$,MO$,JA$,A,U1,A,U2,A,U3,A,U4,A:IFST=64THENTS=64
  442. 4290 U(I)=U1+U2+U3+U4
  443. 4300 GOSUB4330:IFTS=64THENGOSUB4820
  444. 4310 NEXTI:CLOSE2:TE$=TE$+"INSGESAMT":IFAA=4ANDAB=30THENTE$="COM-IND/GES.UM"
  445. 4320 GOTO4440
  446. 4330 IFST=64THENTS=64
  447. 4340 IFI=0THENTG$=TA$
  448. 4350 IFI/AT=INT(I/AT)THEN:_P(AD+I*AB-8),180TA$
  449. 4360 IFVAL(MO$)<>MOANDI/AT=INT(I/AT)THENMO=VAL(MO$):_P(AD+I*AB-8),190MO$
  450. 4370 IFAB=30ANDAA=4THEN:_P(190+I*AB-8),180TA$
  451. 4380 IFK(I)<=0ANDU(I)<=0THENRETURN
  452. 4390 IFK(I)>=GRTHENGR=INT(K(I))+1
  453. 4400 IFK(I)=<KLANDK(I)>0THENKL=INT(K(I))
  454. 4410 IFU(I)>=URTHENUR=INT(U(I))
  455. 4420 RETURN
  456. 4430 GR$=RIGHT$(STR$(GR),3):KL$=RIGHT$(STR$(KL),3):AC=160/(GR-KL)
  457. 4440 UR$=RIGHT$(STR$(UR),5):AZ=160/UR:RETURN
  458. 4450 PRINT"[147]      P R O G R A M M - E N D E"
  459. 4460 CLOSE2:CLOSE15:_E:PRINT"":END
  460. 4470 F=0:GETF$:IFF$=""THEN4470
  461. 4480 F=ASC(F$)-132:IFF=7ORF=8THENF=F-2
  462. 4490 IFF<1ORF>6THEN4470
  463. 4500 RETURN
  464. 4510 REM --- EINLESEN DER DATEIEN ---
  465. 4520 PRINT:INPUT"  TAG";TG$:PRINT:INPUT"  MONAT";MT:PRINT:INPUT"  JAHR";JR:MT$=STR$(MT)
  466. 4530 JR$=STR$(JR):IFAE=7THENRETURN
  467. 4540 GOTO4580
  468. 4550 GOSUB4740:IFAE=5THENRETURN
  469. 4560 FORI=1TOMM:INPUT#2,TA$,MO$,JA$,A,A,A,A,A,A,A,A,A
  470. 4570 NEXTI:RETURN
  471. 4580 I=0:GOSUB4740:IFTG$="00"THEN4620
  472. 4590 INPUT#2,TA$,A,A,A,A,A,A,A,A,A,A,A:I=I+1
  473. 4600 IFTG$=TA$THEN4620
  474. 4610 IFST<>64THEN4590
  475. 4620 CLOSE2
  476. 4630 IFI>AFTHENMM=I-AF:GOTO4550
  477. 4640 IFI=AFTHENMM=0:GOSUB4740:RETURN
  478. 4650 IFI<AFTHENMB=AF-I:IFVAL(MT$)=MEANDVAL(JR$)=JETHENAA=AA-MB:MM=0:GOSUB4740:RETURN
  479. 4660 MT$=STR$(VAL(MT$)-1):IFVAL(MT$)=0THENMT$=" 12":JR$=STR$(VAL(JR$)-1)
  480. 4670 I=0:GOSUB4740
  481. 4680 INPUT#2,TA$,A,A,A,A,A,A,A,A,A,A,A:I=I+1
  482. 4690 IFST<>64THEN4680
  483. 4700 CLOSE2:IFMB<ITHENMM=I-MB:GOTO4550
  484. 4710 IFMB=ITHENMM=0:GOSUB4740:RETURN
  485. 4720 IFMB>ITHENMB=MB-I:IFVAL(MT$)=MEANDVAL(JR$)=JETHENAA=AA-MB:MM=0:GOSUB4740:RETURN
  486. 4730 GOTO4660
  487. 4740 IFA1=0THENPRINT""SPC(33)"WARTEN[146][151]":FORA=1TO10:PRINT:PRINT:NEXTA
  488. 4750 OPEN2,8,2,KA$+"-AKTIE"+MT$+JR$+",S,R":GOSUB5070:RETURN
  489. 4760 I=0:MT$=STR$(ME):JR$=STR$(JE):GOSUB4740
  490. 4770 INPUT#2,A,A,A,A,A,A,A,A,A,A,A,A:I=I+1
  491. 4780 IFST<>64THEN4770
  492. 4790 CLOSE2:IFVAL(MT$)=MLANDVAL(JR$)=JLTHENAA=I-1:MT$=STR$(ME):JR$=STR$(JE):GOSUB4740:RETURN
  493. 4800 MT$=STR$(VAL(MT$)+1):IFMT$=" 13"THENMT$=" 1":JR$=STR$(VAL(JR$)+1)
  494. 4810 GOSUB4740:GOTO 4770
  495. 4820 TS=0:IFI=AATHENRETURN
  496. 4830 CLOSE2
  497. 4840 MT$=STR$(VAL(MT$)+1):IFVAL(MT$)=13THENMT$=" 1":JR$=STR$(VAL(JR$)+1)
  498. 4850 GOSUB4740:RETURN
  499. 4860 _T:REM --- FEHLER ---
  500. 4870 IFPEEK(52000)=4THENPRINT"NICHT MOEGLICH! (ANDERE DISK EINLEGEN!)":GOTO1000
  501. 4880 IFPEEK(52000)=20THENPRINT:PRINT"NICHT MOEGLICH!":GOTO1000
  502. 4890 IFPEEK(52000)=5THENPRINT:PRINT"DRUCKER/FLOPPY NICHT EINGESCHLATET!":GOTO1000
  503. 4900 PRINT:PRINT"FEHLER"PEEK(52000)"IN"PEEK(52001)+256*PEEK(52002):GOTO1000
  504. 4910 INPUT#15,FE,FE$
  505. 4920 IFFE=0THENRETURN
  506. 4930 IFFE=62THENME=VAL(MO$):JE=VAL(JA$):INPUT"  FIRMA:";NA$:CLOSE2:GOTO600
  507. 4940 IFFE=74THENPRINT"FLOPPY EINSCHALTEN / DISK EINLEGEN!":CLOSE2:INPUTF$:GOTO590
  508. 4950 PRINT:PRINT"DISK-FEHLER NR.:"FE": "FE$:GOTO1000
  509. 4960 INPUT#15,FE,FE$
  510. 4970 IFFE=0THENRETURN
  511. 4980 _T:CLOSE2:IFFE=62THENOPEN2,8,2,KA$+"-AKTIE"+MO$(1)+JA$(1)+",S,W":GOTO610
  512. 4990 IFFE=72THEN650
  513. 5000 IFFE=74THENPRINT:PRINT"FLOPPY EINSCHALTEN / DISK EINLEGEN!":INPUTF$:GOTO590
  514. 5010 PRINT:PRINT"DISK-FEHLER NR.:"FE": "FE$:GOTO1000
  515. 5020 INPUT#15,FE,FE$
  516. 5030 IFFE=0THENRETURN
  517. 5040 IFFE=62THENPRINT"DATEI NICHT AUF DISK! ANDERE EINLEGEN!":INPUTF$:CLOSE2:GOTO180
  518. 5050 IFFE=74THENPRINT"FLOPPY EINSCHALTEN / DISK EINLEGEN!":CLOSE2:INPUTF$:GOTO180
  519. 5060 PRINT:PRINT"DISK-FEHLER NR.:"FE": "FE$:GOTO1000
  520. 5070 INPUT#15,FE,FE$
  521. 5080 IFFE=0THENRETURN
  522. 5090 _T:IFFE=62THENPRINT:PRINT"NICHT MOEGLICH!":JE=0:GOTO1000
  523. 5100 PRINT:PRINT"DISK-FEHLER NR.:"FE": "FE$:GOTO1000
  524. 5110 INPUT#15,FE,FE$
  525. 5120 IFFE=0THENRETURN
  526. 5130 IFFE=62THENCLOSE2:GOTO600
  527. 5140 PRINT:PRINT"DISK-FEHLER NR.:"FE": "FE$:GOTO1000
  528. 5150 INPUT#15,FE,FE$
  529. 5160 IFFE=0THENRETURN
  530. 5170 IFFE=62THENCLOSE2:ME=VAL(MT$):JE=VAL(JR$):ML=ME:JL=JE:GOTO6340
  531. 5180 PRINT:PRINT"DISK-FEHLER NR.:"FE": "FE$:GOTO1000
  532. 5190 PRINT""SPC(33)"WARTEN[146][151]":FORA=1TO10:PRINT:PRINT:NEXTA:OPEN2,8,2,KA$+"-AKTIE,S,R":GOSUB5020
  533. 5200 INPUT#2,ME,JE,ML,JL,NA$
  534. 5210 Z=1:CLOSE2:AE=0:RETURN
  535. 5220 REM --- DRUCKERZAHLENAUSGABE ---
  536. 5230 PRINT#4,"                            "NA$"-AKTIE"
  537. 5240 PRINT#4,"========================================";
  538. 5250 PRINT#4,"====================================="
  539. 5260 PRINT#4,SPC(35)ET$:PRINT#4,SPC(20)"KASSAKURSE";
  540. 5270 PRINT#4,SPC(21)"UMSAETZE IN STUECK"
  541. 5280 PRINT#4:PRINT#4,"  DATUM   FRANKF   HANN    HAMB   D'DORF";
  542. 5290 PRINT#4,"    FRAN.  HANN.  HAMB.  D'DF.  INSG."
  543. 5300 PRINT#4,"[192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192]";
  544. 5310 PRINT#4,"[192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192]"
  545. 5320 FORI=0TOAA:INPUT#2,TA$,MO$,JA$,KF,UF,KH,UH,KB,UB,KD,UD,CI:IFST=64THENTS=64
  546. 5330 PRINT#4,TA$"."MO$"."JA$;:KF$=STR$(INT(KF)):FK$=STR$(KF):LL=LEN(FK$)-LEN(KF$)
  547. 5340 IFLL>3THENLL=3
  548. 5350 PRINT#4,SPC(5-LEN(KF$))LEFT$(FK$,LEN(KF$)+LL)RIGHT$(FI$,(3-LL));
  549. 5360 KH$=STR$(INT(KH)):HK$=STR$(KH):LL=LEN(HK$)-LEN(KH$):IFLL>3THENLL=3
  550. 5370 PRINT#4,SPC(5-LEN(KH$))LEFT$(HK$,LEN(KH$)+LL)RIGHT$(FI$,(3-LL));
  551. 5380 KB$=STR$(INT(KB)):BK$=STR$(KB):LL=LEN(BK$)-LEN(KB$):IFLL>3THENLL=3
  552. 5390 PRINT#4,SPC(5-LEN(KB$))LEFT$(BK$,LEN(KB$)+LL)RIGHT$(FI$,(3-LL));
  553. 5400 KD$=STR$(INT(KD)):DK$=STR$(KD):LL=LEN(DK$)-LEN(KD$):IFLL>3THENLL=3
  554. 5410 PRINT#4,SPC(5-LEN(KD$))LEFT$(DK$,LEN(KD$)+LL)RIGHT$(FI$,(3-LL));
  555. 5420 UF=INT(UF):UH=INT(UH):UB=INT(UB):UD=INT(UD):UG=UF+UH+UB+UD:A=9
  556. 5430 PRINT#4,SPC(A-LEN(STR$(UF)))UFSPC(6-LEN(STR$(UH)))UHSPC(6-LEN(STR$(UB)))UB;
  557. 5440 PRINT#4,SPC(6-LEN(STR$(UD)))UDSPC(6-LEN(STR$(UG)))UG
  558. 5450 IFTS=64THENTS=0:GOSUB4820
  559. 5460 NEXTI:CLOSE2
  560. 5470 IFDD>2.6THENPRINT#4:PRINT#4,SPC(20)"  TENDENZ: STARK STEIGEND":GOTO5510
  561. 5480 IFDD>1.3THENPRINT#4:PRINT#4,SPC(20)"  TENDENZ: LEICHT STEIGEND":GOTO5510
  562. 5490 IFDD<-2.6THENPRINT#4:PRINT#4,SPC(20)"  TENDENZ: STARK FALLEND":GOTO5510
  563. 5500 IFDD<-1.3THENPRINT#4:PRINT#4,SPC(20)"  TENDENZ: LEICHT FALLEND"
  564. 5510 PRINT#4:PRINT#4,SPC(20);
  565. 5520 GR$=STR$(INT(GR)):RG$=STR$(GR):LL=LEN(RG$)-LEN(GR$):IFLL>3THENLL=3
  566. 5530 PRINT#4,"  HOECHSTKURS:";
  567. 5540 PRINT#4,SPC(5-LEN(GR$))LEFT$(RG$,LEN(GR$)+LL)RIGHT$(FI$,(3-LL));
  568. 5550 PRINT#4," DM AM "TA$(1)"."MO$(1)"."JA$(1)
  569. 5560 PRINT#4,SPC(20);
  570. 5570 KL$=STR$(INT(KL)):LK$=STR$(KL):LL=LEN(LK$)-LEN(KL$):IFLL>3THENLL=3
  571. 5580 PRINT#4,"  TIEFSTKURS :";
  572. 5590 PRINT#4,SPC(5-LEN(KL$))LEFT$(LK$,LEN(KL$)+LL)RIGHT$(FI$,(3-LL));
  573. 5600 PRINT#4," DM AM "TA$(2)"."MO$(2)"."JA$(2)
  574. 5610 PRINT#4,SPC(20)"  GESAMTUMSAETZE:"UI"STUECK"
  575. 5620 CLOSE4:DR=0:GOTO1660
  576. 5630 PRINT"[147]  KURSE AENDERN":PRINT"======================================="
  577. 5640 PRINT:PRINT:PRINT"  DATUM DER AENDERUNG EINGEBEN:"
  578. 5650 AF=1:AE=5:GOSUB4520
  579. 5660 OPEN3,8,3,"@:AEND,S,W":IFMM=0THEN5700
  580. 5670 FORI=1TOMM:INPUT#2,TA$,MO$,JA$,KF,UF,KH,UH,KB,UB,KD,UD,CI
  581. 5680 PRINT#3,TA$:PRINT#3,MO$:PRINT#3,JA$:PRINT#3,KF:PRINT#3,UF:PRINT#3,KH
  582. 5690 PRINT#3,UH:PRINT#3,KB:PRINT#3,UB:PRINT#3,KD:PRINT#3,UD:PRINT#3,CI:NEXTI
  583. 5700 INPUT#2,TA$,MO$,JA$,KF,UF,KH,UH,KB,UB,KD,UD,CI:IFST=64THENI=2
  584. 5710 GOSUB580
  585. 5720 PRINT#3,TA$:PRINT#3,MO$:PRINT#3,JA$:PRINT#3,KF:PRINT#3,UF:PRINT#3,KH
  586. 5730 PRINT#3,UH:PRINT#3,KB:PRINT#3,UB:PRINT#3,KD:PRINT#3,UD:PRINT#3,CI
  587. 5740 IFI=2THEN5790
  588. 5750 INPUT#2,TA$,MO$,JA$,KF,UF,KH,UH,KB,UB,KD,UD,CI:IFST=64THENI=3
  589. 5760 PRINT#3,TA$:PRINT#3,MO$:PRINT#3,JA$:PRINT#3,KF:PRINT#3,UF:PRINT#3,KH
  590. 5770 PRINT#3,UH:PRINT#3,KB:PRINT#3,UB:PRINT#3,KD:PRINT#3,UD:PRINT#3,CI
  591. 5780 IFI<>3THEN5750
  592. 5790 CLOSE3:CLOSE2:I=0:AE=1:PRINT#15,"S:"+KA$+"-AKTIE"+MT$+JR$
  593. 5800 PRINT#15,"R:"+KA$+"-AKTIE"+MT$+JR$"=AEND"
  594. 5810 GOTO180
  595. 5820 PRINT"[147]  KURSE EINFUEGEN":PRINT"========================================"
  596. 5830 PRINT:PRINT"  DATUM EINGEBEN:":AE=7:GOSUB4520:MM=1
  597. 5840 GOSUB4740:I=0
  598. 5850 INPUT#2,TA$,MO$,JA$,A,A,A,A,A,A,A,A,A:I=I+1
  599. 5860 IFTG$=TA$THENCLOSE2:PRINT:PRINT"  DATUM SCHON VORHANDEN!":GOTO1000
  600. 5870 IFVAL(TA$)>VAL(TG$)THENI=I-1:GOTO5910
  601. 5880 IFST<>64THEN5850
  602. 5890 IFVAL(JR$)=JLANDVAL(MT$)=MLTHENPRINT:PRINT"  KURSE NORMAL EINGEBEN!":GOTO1000
  603. 5900 MM=0
  604. 5910 CLOSE2:OPEN3,8,3,"@:AEND,S,W":GOSUB4740:IFI=0THEN5950
  605. 5920 FORT=1TOI:INPUT#2,TA$,MO$,JA$,KF,UF,KH,UH,KB,UB,KD,UD,CI:PRINT#3,TA$
  606. 5930 PRINT#3,MO$:PRINT#3,JA$:PRINT#3,KF:PRINT#3,UF:PRINT#3,KH:PRINT#3,UH:PRINT#3,KB:PRINT#3,UB
  607. 5940 PRINT#3,KD:PRINT#3,UD:PRINT#3,CI:NEXTT
  608. 5950 TA$=TG$:AE=5:E=0:GOSUB480:I=0
  609. 5960 PRINT#3,TA$:PRINT#3,MO$:PRINT#3,JA$:PRINT#3,KF:PRINT#3,UF:PRINT#3,KH:PRINT#3,UH:PRINT#3,KB:PRINT#3,UB
  610. 5970 PRINT#3,KD:PRINT#3,UD:PRINT#3,CI:IFMM=0THEN6010
  611. 5980 INPUT#2,TA$,MO$,JA$,KF,UF,KH,UH,KB,UB,KD,UD,CI:IFST=64THENI=2
  612. 5990 PRINT#3,TA$:PRINT#3,MO$:PRINT#3,JA$:PRINT#3,KF:PRINT#3,UF:PRINT#3,KH:PRINT#3,UH:PRINT#3,KB
  613. 6000 PRINT#3,UB:PRINT#3,KD:PRINT#3,UD:PRINT#3,CI:IFI<>2THEN5980
  614. 6010 CLOSE2:CLOSE3:AE=1:I=0:PRINT#15,"S:"+KA$+"-AKTIE"+MT$+JR$:GOTO5800
  615. 6020 GOTO 180
  616. 6030 PRINT"[147]         UEBERSPIELEN":PRINT"================================="
  617. 6040 PRINT:INPUT"EIN ODER ZWEI LAUFWERKE (1/2)";F
  618. 6050 IFF<>1ANDF<>2THEN6040
  619. 6060 PRINT:PRINT"  WELCHEN MONAT UEBERSPIELEN:":PRINT:PRINT:INPUT"  MONAT:";MT
  620. 6070 PRINT:INPUT"  JAHR:";JR:MT$=STR$(MT):JR$=STR$(JR)
  621. 6080 IFF=1THEN6190
  622. 6090 PRINT:PRINT:PRINT"ZWEITE DISKETTE IN ANDERS LAUFWERK LEGEN!":INPUTF$
  623. 6100 GOSUB4740:OPEN3,9,3,KA$+"-AKTIE"+MT$+JR$+",S,W"
  624. 6110 INPUT#2,TA$,MO$,JA$,KF,UF,KH,UH,KB,UB,KD,UD,CI
  625. 6120 PRINT#3,TA$:PRINT#3,MO$:PRINT#3,JA$:PRINT#3,KF:PRINT#3,UF:PRINT#3,KH
  626. 6130 PRINT#3,UH:PRINT#3,KB:PRINT#3,UB:PRINT#3,KD:PRINT#3,UD:PRINT#3,CI
  627. 6140 IFST<>64THEN6110
  628. 6150 CLOSE3:CLOSE2:OPEN3,9,3,KA$+"-AKTIE,S,R":GOSUB5150
  629. 6160 INPUT#3,ME,JE,ML,JL,NA$:CLOSE3:GOTO6310
  630. 6170 OPEN3,9,3,"@:"+KA$+"-AKTIE,S,W":PRINT#3,ME:PRINT#3,JE:PRINT#3,ML
  631. 6180 PRINT#3,JL:PRINT#3,NA$:CLOSE3:GOTO180
  632. 6190 GOSUB4740:I=0
  633. 6200 INPUT#2,TA$(I),MO$(I),JA$(I),K(I),U(I),K(I+50),U(I+50),K(I+100),U(I+100)
  634. 6210 INPUT#2,K(I+150),U(I+150),K(I+200)
  635. 6220 I=I+1:IFST<>64THEN6200
  636. 6230 CLOSE2:PRINT:PRINT"ZWEITE DISK EINLEGEN!":INPUTF$
  637. 6240 OPEN2,8,2,KA$+"-AKTIE"+MT$+JR$+",S,W"
  638. 6250 FORT=0TOI-1:PRINT#2,TA$(T):PRINT#2,MO$(T):PRINT#2,JA$(T):PRINT#2,K(T)
  639. 6260 PRINT#2,U(T):PRINT#2,K(T+50):PRINT#2,U(T+50):PRINT#2,K(T+100):PRINT#2,U(T+100)
  640. 6270 PRINT#2,K(T+150):PRINT#2,U(T+150):PRINT#2,K(T+200)
  641. 6280 NEXTT:CLOSE2
  642. 6290 OPEN2,8,2,KA$+"-AKTIE,S,R":GOSUB5150
  643. 6300 INPUT#2,ME,JE,ML,JL,NA$:CLOSE2
  644. 6310 IF(VAL(JR$)=JEANDVAL(MT$)<ME)ORVAL(JR$)<JETHENME=VAL(MT$):JE=VAL(JR$):GOTO6340
  645. 6320 IF(VAL(JR$)=JLANDVAL(MT$)>ML)ORVAL(JR$)>JLTHENML=VAL(MT$):JL=VAL(JR$):GOTO6340
  646. 6330 GOTO180
  647. 6340 IFF=2THEN6170
  648. 6350 OPEN2,8,2,"@:"+KA$+"-AKTIE,S,W":PRINT#2,ME:PRINT#2,JE:PRINT#2,ML
  649. 6360 PRINT#2,JL:PRINT#2,NA$:CLOSE2:GOTO180
  650. 6370 REM --- DATEI PRUEFEN ---
  651. 6380 OPEN2,8,2,KA$+"-AKTIE":GOSUB4910
  652. 6390 INPUT#2,ME,JE,ML,JL,NA$:CLOSE2
  653. 6400 IFVAL(JA$(1))<JLOR(VAL(JA$(1))=JLANDVAL(MO$(1))<ML)THEN6470
  654. 6410 OPEN2,8,2,KA$+"-AKTIE"+MO$(1)+JA$(1)+",S,R":GOSUB5110
  655. 6420 INPUT#2,TG$,MT$,JR$,A,A,A,A,A,A,A,A,A
  656. 6430 IFTG$=TA$THENCLOSE2:PRINT:PRINT"DATUM VORHANDEN!":GOTO780
  657. 6440 IFVAL(TG$)>VAL(TA$)THENCLOSE2:GOTO6470
  658. 6450 IFST<>64THEN6420
  659. 6460 CLOSE2:GOTO600
  660. 6470 PRINT:PRINT"  SPAETERES DATUM SCHON VORHANDEN! KURSE EINFUEGEN!":GOTO780
  661. 6480 REM --- HOECHST-TIEFST-KURSE ---
  662. 6490 KL=500:GR=0:UI=0:GF=0:GH=0:GB=0:GD=0:MF=500:MH=500:MB=500:MD=500
  663. 6500 IFVAL(JR$)=JETHENMT$=STR$(ME):GOSUB4740:GOTO6520
  664. 6510 MT$=" 1":GOSUB4740
  665. 6520 INPUT#2,TA$,MO$,JA$,KF,UF,KH,UH,KB,UB,KD,UD,A$
  666. 6530 DR=1:GOSUB1240:DR=0
  667. 6540 IFST<>64THEN6520
  668. 6550 CLOSE2:IFVAL(JR$)=JLTHENIFVAL(MT$)=MLTHENRETURN
  669. 6560 IFMT$=" 12"THENRETURN
  670. 6570 MT$=STR$(VAL(MT$)+1):GOSUB4740:GOTO6520
  671. 6580 REM --- DIRECTORY ---
  672. 6590 OPEN1,8,4,"#":NT=18:NS=1
  673. 6600 PRINT#15,"B-R:";4;0;NT;NS:PRINT#15,"B-P:";4;0
  674. 6610 GET#1,NT$,NS$:IFNT$=""THEN6630
  675. 6620 NT=ASC(NT$):NS=ASC(NS$)
  676. 6630 FORT=0TO7:PRINT#15,"B-P:";4;T*32+2:GET#1,FT$:IFFT$=""ANDNT$=""THENCLOSE1:RETURN
  677. 6640 IFFT$=""THENNEXTT:GOTO6600
  678. 6650 IFASC(FT$)<>129THENNEXTT:GOTO6600
  679. 6660 GET#1,A$,A$
  680. 6670 A$="":FORTT=3TO19:GET#1,B$:IFB$="[160]"THEN6690
  681. 6680 A$=A$+B$:NEXTTT
  682. 6690 IFRIGHT$(A$,6)<>"-AKTIE"THENNEXTT:GOTO6600
  683. 6700 PRINT"  "A$:NEXTT:GOTO6600
  684.