home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol2
/
basic
/
mhbb.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
19KB
|
384 lines
1 CLS
2 ON ERROR GOTO 60000
10 DIM F(10), RR(10), XR(10), ZR(10), SW(10)
20 PRINT " **************************************************************"
30 PRINT " * BROAD-BAND MF/HF DIPOLES *"
40 PRINT " * REFERENCE-WITT, QST OCTOBER 1986 *"
50 PRINT " * JASIK, ANTENNA HANDBOOK *"
60 PRINT " * SCHELKUNOFF, ELECTROMAGNETIC WAVES 1985 *"
70 PRINT " * PROGRAM COPYRIGHT, 1991 *"
80 PRINT " * MINILAB BOOKS, DAYTONA BEACH,FL 32121-1086 *"
90 PRINT " **************************************************************"
100 PRINT
110 DEF FNP (X) = INT(100 * X + .5) / 100
120 DEF FNASIN (X) = ATN(X / SQR(1 - X * X))
130 PI = 3.141593
140 DEF FNACOS (X) = PI / 2 - ATN(X / SQR(1 - X * X))
150 INPUT " ENTER Y FOR PRINTED COPY"; P$: IF P$ = "y" THEN P$ = "Y"
160 IF P$ = "Y" THEN LPRINT " BROADBAND ANTENNA": LPRINT
200 INPUT " ENTER DESIGN FREQUENCY, MHZ"; FO: IF FO < 1 OR FO > 30 THEN 200
210 INPUT " ENTER BASIC CONDUCTOR DIAMETER, INCHES"; DIAC
220 PRINT : PRINT "ENTER TYPE OF BROADBANDING"
230 PRINT " 1= NONE"
240 PRINT " 2= QUARTER WAVE SHORT/OPEN COAX RESONATOR"
250 PRINT " 3= HALF WAVE OPEN COAX RESONATOR"
260 PRINT " 4= HALF WAVE SHORTED COAX RESONATOR"
270 PRINT " 5= DOUBLE BAZOOKA (2 HALF-WAVE RESONATORS)"
280 PRINT " 6= LC NETWORK"
290 INPUT TYR: IF TYR < 1 OR TYR > 6 THEN 220
300 INPUT " ENTER FEED-LINE COAX IMPEDANCE, OHMS"; FZO
310 IF TYR = 6 OR TYR = 1 THEN 360
320 INPUT " ENTER RESONATOR COAX SHIELD DIAMETER,INCHES"; CSDIA
330 INPUT " ENTER RESONATOR COAX VELOCITY FACTOR"; CVF
340 INPUT " ENTER RESONATOR COAX LOSS, DB/100 FEET"; CLOSS
350 INPUT " ENTER RESONATOR COAX IMPEDANCE, OHMS"; ZS
360 PRINT " THE BASIC DIPOLE CHARACTERISTICS ARE;": PRINT
370 IF P$ = "Y" THEN LPRINT " THE BASIC DIPOLE CHARACTERISTICS ARE;"
400 LAM = 984 / FO
410 LD = LAM / 2
420 DEFF = DIAC
430 IF TYR = 5 THEN 450
440 LCX = LD * CVF: IF TYR = 2 THEN LCX = LCX / 2
450 DEFF = (LCX * CSDIA + DIAC * (LD - LCX)) / LD
460 KR = 12 * LD / DEFF
470 LR = 1 - 1 / (4.6719 * LOG(KR) - 8)
480 TV = LAM * LR / 2
490 IF ABS(LD - TV) > .00001 THEN LD = TV: GOTO 420
500 PRINT : PRINT " THE FREE-SPACE WAVELENGTH="; FNP(LAM); "FEET"
510 IF P$ = "Y" THEN LPRINT : LPRINT " THE FREE -SPACE WAVELENGTH="; FNP(LAM); "FEET"
520 PRINT " THE AVERAGE DIAMETER IS"; DEFF; "INCHES"
530 IF P$ = "Y" THEN LPRINT " THE AVERAGE DIAMETER IS"; DEFF; "INCHES"
540 PRINT " THE LENGTH-DIAMETER RATIO IS"; FNP(KR)
550 PRINT
560 PRINT " ANTENNA LENGTH="; FNP(.95 * LD); "FEET"
570 IF P$ = "Y" THEN LPRINT " THE LENGTH-DIAMETER RATIO IS"; FNP(KR)
580 IF P$ = "Y" THEN LPRINT : LPRINT " ANTENNA LENGTH="; FNP(.95 * LD); "FEET"
590 INPUT "PRESS RETURN FOR MORE"; T$
700 PRINT : PRINT " UNCOMPENSATED FEED VALUES AND FEED LINE SWR ARE"
710 PRINT : PRINT " FREQUENCY RESISTANCE REACTANCE SWR"
720 IF P$ = "Y" THEN LPRINT : LPRINT " UNCOMPENSATED FEED VALUES AND FEED LINE SWR ARE"
730 IF P$ = "Y" THEN LPRINT " FREQUENCY RESISTANCE REACTANCE SWR"
740 LSF = 0: USF = 0
750 FOR N = .9 TO 1.1 STEP .02
760 M = 50 * (N - .9)
770 F(M) = N * FO
780 RR = 17.32 + 30 * LOG(2 * PI * LR * N): RR(M) = RR
790 XR = (18.6777 * LOG(KR) + 32) * (N - 1) / .1: XR(M) = XR
800 ZR = SQR(RR * RR + XR * XR): ZR(M) = ZR
820 RC = SQR(((RR - FZO) * (RR - FZO) + XR * XR) / ((RR + FZO) * (RR + FZO) + XR * XR))
830 SW = (1 + RC) / (1 - RC): SW(M) = SW
840 IF N < 1 AND LSF = 0 THEN IF SW < 2 THEN LSF = (SW(M - 1) - 2) / (SW(M - 1) - SW(M)) * .02 * FO + F(M - 1)
850 IF N > 1 AND USF = 0 THEN IF SW > 2 THEN USF = (2 - SW(M - 1)) / (SW(M) - SW(M - 1)) * .02 * FO + F(M - 1)
860 PRINT FNP(N * FO), FNP(RR), FNP(XR), FNP(SW)
870 IF P$ = "Y" THEN LPRINT FNP(N * FO), FNP(RR), FNP(XR), FNP(SW)
880 NEXT N
890 QA = FO / ABS(USF - LSF)
900 PRINT " 2:1 SWR BANDWIDTH LIMITS ="; FNP(LSF); "AND"; FNP(USF); "MHZ"
910 IF P$ = "Y" THEN LPRINT " 2:1 SWR BANDWIDTH LIMITS="; FNP(LSF), FNP(USF); "MHZ"
920 BWD = USF - LSF
930 PRINT " BANDWIDTH OF SIMPLE DIPOLE="; INT(BWD * 1000); "KHZ"
940 IF P$ = "Y" THEN LPRINT " BANDWIDTH OF SIMPLE DIPOLE="; INT(BWD * 1000); "KHZ"
950 PRINT " ANTENNA Q FOR 2:1 BANDWIDTH="; INT(QA)
960 IF P$ = "Y" THEN LPRINT " ANTENNA Q FOR 2:1 BANDWIDTH="; INT(QA)
970 PRINT
980 INPUT " PRESS RETURN FOR MORE"; T$
990 ON TYR GOTO 1000, 2000, 3000, 4000, 5000, 6000
1000 CLS 'RERUNS
1010 PRINT " ENTER 1= SET PRINTER OUTPUT AND REPEAT OUTPUT"
1020 PRINT " 2= CHANGE FREQUENCY (RERUN)"
1030 PRINT " 3= CHANGE BROAD-BANDING TYPE"
1040 PRINT " 4= CHANGE FEED COAX IMPEDANCE"
1050 PRINT " 5= CHANGE RESONATOR COAX DIAMETER"
1060 PRINT " 6= SEE ANTENNA SCHEMATICS, SCREEN ONLY"
1070 PRINT " 7= QUIT"
1100 INPUT TEM: IF TEM < 1 OR TEM > 7 THEN 1000
1110 ON TEM GOTO 1200, 200, 220, 300, 320, 7000, 1999
1200 P$ = "Y"
1210 GOTO 500
1999 STOP
2000 CLS 'QUARTER WAVE
2010 GOSUB 8000
2020 X = SQR(PI * ZN / 4 / ZS)
2030 IF X = 0 THEN X = .0000001
2040 L2 = 492 * CVF / PI / FO * FNASIN(X)
2050 L1 = 246 * CVF / FO - L2
2060 PRINT " FOR THE OPEN END SECTION, COAX LENGTH L1="; FNP(L1); "FEET"
2070 PRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L1; "FEET"
2080 PRINT " FOR THE SHORTED END SECTION, COAX LENGTH L2="; FNP(L2); "FEET"
2090 PRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L2; "FEET"
2100 IF P$ <> "Y" THEN 2800
2200 LPRINT " FOR THE OPEN END SECTION, COAX LENGTH L1="; FNP(L1); "FEET"
2210 LPRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L1; "FEET"
2220 LPRINT " FOR THE SHORTED END SECTION, COAX LENGTH L2="; FNP(L2); "FEET"
2230 LPRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L2; "FEET"
2800 GOSUB 9000
2990 INPUT " PRESS RETURN TO CONTINUE"; T$
2999 GOTO 1000
3000 CLS 'HALF WAVE SHORTED
3010 GOSUB 8000
3020 X = SQR(PI * ZN / 2 / ZS)
3030 IF X = 0 THEN X = .0000001
3040 L1 = 492 * CVF / PI / FO * FNACOS(X)
3050 L2 = 492 * CVF / FO - L1
3060 PRINT " FOR THE SHORTER SECTION, COAX LENGTH L1="; FNP(L1); "FEET"
3070 PRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L1; "FEET"
3080 PRINT " FOR THE LONGER SECTION, COAX LENGTH L2="; FNP(L2); "FEET"
3090 PRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L2; "FEET"
3100 IF P$ <> "Y" THEN 3800
3200 LPRINT " FOR THE SHORTER SECTION, COAX LENGTH L1="; FNP(L1); "FEET"
3210 LPRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L1; "FEET"
3220 LPRINT " FOR THE LONGER SECTION, COAX LENGTH L2="; FNP(L2); "FEET"
3230 LPRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L2; "FEET"
3800 GOSUB 9000
3990 INPUT " PRESS RETURN TO CONTINUE"; T$
3999 GOTO 1000
4000 CLS 'HALF WAVE OPEN
4010 GOSUB 8000
4020 X = SQR(PI * ZN / 2 / ZS)
4030 IF X = 0 THEN X = .0000001
4040 L2 = 492 * CVF / PI / FO * FNACOS(X)
4050 L1 = 492 * CVF / FO - L1
4060 PRINT " FOR THE OPEN END SECTION, COAX LENGTH L1="; FNP(L1); "FEET"
4070 PRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L1; "FEET"
4080 PRINT " FOR THE SHORTED END SECTION, COAX LENGTH L2="; FNP(L2); "FEET"
4090 PRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L2; "FEET"
4100 IF P$ <> "Y" THEN 4800
4200 LPRINT " FOR THE OPEN END SECTION, COAX LENGTH L1="; FNP(L1); "FEET"
4210 LPRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L1; "FEET"
4220 LPRINT " FOR THE SHORTED END SECTION, COAX LENGTH L2="; FNP(L2); "FEET"
4230 LPRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L2; "FEET"
4800 GOSUB 9000
4990 INPUT " PRESS RETURN TO CONTINUE"; T$
4999 GOTO 1000
5000 CLS 'BAZOOKAS
5010 PRINT " WITH COAX SECTIONS IN SERIES"
5020 ZS = 2 * ZS
5030 GOSUB 8000
5040 L2 = LD * CVF / 2
5050 L1 = L2
5060 PRINT " FOR THE RIGHT END SECTION, LENGTH L1="; FNP(L1); "FEET"
5070 PRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L1; "FEET"
5080 PRINT " FOR THE LEFT END SECTION, LENGTH L2="; FNP(L2); "FEET"
5090 PRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L1; "FEET"
5100 IF P$ <> "Y" THEN 5300
5110 LPRINT " WITH COAX SECTIONS IN SERIES"
5200 LPRINT " FOR THE RIGHT END SECTION, LENGTH L1="; FNP(L1); "FEET"
5210 LPRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L1; "FEET"
5220 LPRINT " FOR THE LEFT END SECTION, LENGTH L2="; FNP(L2); "FEET"
5230 LPRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L1; "FEET"
5300 GOSUB 9000
5310 INPUT " PRESS RETURN TO CONTINUE"; T$
5400 PRINT " WITH COAX SECTIONS IN PARALLEL"
5410 ZS = ZS / 2
5420 GOSUB 8000
5430 L2 = LD * CVF / 2
5440 L1 = L2
5450 PRINT " FOR THE RIGHT END SECTION, LENGTH L1="; FNP(L1); "FEET"
5460 PRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L1; "FEET"
5470 PRINT " FOR THE LEFT END SECTION, LENGTH L2="; FNP(L2); "FEET"
5480 PRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L2; "FEET"
5500 IF P$ <> "Y" THEN 5800
5510 LPRINT " WITH COAX SECTIONS IN SERIES"
5600 LPRINT " FOR THE RIGHT END SECTION, LENGTH L1="; FNP(L1); "FEET"
5610 LPRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L1; "FEET"
5620 LPRINT " FOR THE LEFT END SECTION, LENGTH L2="; FNP(L2); "FEET"
5630 LPRINT " REMAINING CONDUCTOR LENGTH="; .475 * LD - L2; "FEET"
5800 GOSUB 9000
5810 INPUT " PRESS RETURN TO CONTINUE"; T$
5820 ZS = 2 * ZS
5999 GOTO 1000
6000 CLS 'LC
6010 GOSUB 8000
6020 LN = ZN / 2 / PI / FO
6030 CN = 1000000! / 2 / PI / FO / ZN
6040 FM = FO / 2 / QA * SQR((SM - 1) * (1 + QA / QN))
6050 FL = SQR(FO * FO + FM * FM) - FM
6060 FH = FO * FO / FL
6100 PRINT
6110 PRINT " RESONATOR INDUCTANCE="; FNP(LN); "MICROHENRIES"
6120 PRINT " CAPACITANCE="; FNP(CN); "PICOFARADS"
6130 PRINT
6200 PRINT " COIL IMPEDANCE="; FNP(ZN); "OHMS"
6210 PRINT " IMPEDANCE RATIO, ANTENNA TAPS TO COIL="; FNP(ZR / ZN); ":1"
6220 PRINT " IMPEDANCE RATIO, LINE TAP TO ANTENNA TAPS ="; FNP(NZ); ":1"
6230 PRINT " LOWER MATCH FREQUENCY="; FNP(FL); "MHZ"
6240 PRINT " UPPER MATCH FREQUENCY="; FNP(FH); "MHZ"
6250 PRINT
6300 IF P$ <> "Y" THEN 6800
6400 LPRINT
6410 LPRINT " RESONATOR INDUCTANCE="; FNP(LN); "MICROHENRIES"
6420 LPRINT " CAPACITANCE="; FNP(CN); "PICOFARADS"
6430 LPRINT
6500 LPRINT " COIL IMPEDANCE="; FNP(ZN); "OHMS"
6510 LPRINT " IMPEDANCE RATIO, ANTENNA TAPS TO COIL="; FNP(ZR / ZN); ":1"
6520 LPRINT " IMPEDANCE RATIO, LINE TAP TO ANTENNA TAPS ="; FNP(NZ); ":1"
6530 LPRINT " LOWER MATCH FREQUENCY="; FNP(FL); "MHZ"
6540 LPRINT " UPPER MATCH FREQUENCY="; FNP(FH); "MHZ"
6550 LPRINT
6800 GOSUB 9000
6810 INPUT " PRESS RETURN TO CONTINUE"; T$
6820 ZS = 2 * ZS
6999 GOTO 1000
7000 CLS 'SCHEMATICS
7010 PRINT " SIMPLE DIPOLE"
7020 PRINT " R-RADIATOR WIRE"
7030 PRINT " RRRRRRRRRRRRRRRRRRRR RRRRRRRRRRRRRRRRRRRRR OR COAX CENTER"
7040 PRINT " F F F-FEED COAX"
7050 PRINT
7100 PRINT " TWO QUARTER-WAVE RESONATORS IN SERIES"
7110 PRINT
7120 PRINT " CCCCCCCCCCCCCC CCCCCCCCCCCCCCC C-COAX SHIELD"
7130 PRINT " RRRRRRSRRRRRRRRRRRRR RRRRRRRRRRRRRRSRRRRRR S-SHORT"
7140 PRINT " CCCCCCCCCCCCCC CCCCCCCCCCCCCCC"
7150 PRINT " F F"
7160 PRINT
7200 PRINT " TWO QUARTER-WAVE RESONATORS IN PARALLEL"
7210 PRINT
7220 PRINT " CCCCCCCCCCCCCC CCCCCCCCCCCCCCC "
7230 PRINT " RRRRRRSRRRRRRRRRRRRRXRRRRRRRRRRRRRRSRRRRRR X- SHIELD-CENTER"
7240 PRINT " CCCCCCCCCCCCCCXCCCCCCCCCCCCCCC CROSS CONNECTED"
7250 PRINT " F F"
7260 PRINT
7270 INPUT " PRESS RETURN TO CONTINUE"; T$
7280 CLS
7300 PRINT " ASSYMETRIC QUARTER-WAVE RESONATOR"
7310 PRINT " F-FEED"
7320 PRINT " CCCCCCCCCCCCCC CCCCCCO C-COAX SHIELD"
7330 PRINT " RRRRRRSRRRRRRRRRRRRRXRRRRRRRRRRRRRRRRRRRRR S-SHIELD-CENTER"
7340 PRINT " CCCCCCCCCCCCCCXCCCCCCO SHORT"
7350 PRINT " F F O- NO SHORT"
7360 PRINT
7400 PRINT " SHORTED ASSYMETRIC HALF-WAVE RESONATOR R-RADIATOR WIRE"; ""
7410 PRINT " F-FEED"
7420 PRINT " CCCCCC CCCCCCCCCCCCCCCCCCCC"
7430 PRINT " RRRRRRRRRRRRRRSRRRRRXRRRRRRRRRRRRRRRRRRRSR X- SHIELD-CENTER"
7440 PRINT " CCCCCCXCCCCCCCCCCCCCCCCCCCC CROSS CONNECTED"
7450 PRINT " F F"
7460 PRINT " NOTE"
7500 PRINT " OPEN ASSYMETRIC HALF-WAVE RESONATOR FOR SIMPLICITY"
7510 PRINT " R SECTIONS ARE"
7520 PRINT " OCCCCC CCCCCCCCCCCCCCCCCCCO ASSUMED TO BE"
7530 PRINT " RRRRRRRRRRRRRRRRRRRRXRRRRRRRRRRRRRRRRRRRRR SAME DIAMETER AS"
7540 PRINT " OCCCCCXCCCCCCCCCCCCCCCCCCCO C SECTIONS. THIS"
7550 PRINT " F F CAUSES A SMALL"
7560 PRINT " ERROR IN BANDWIDTH"
7570 INPUT " PRESS RETURN TO CONTINUE"; T$
7580 CLS
7600 PRINT " LC MATCHING NETWORK"
7610 PRINT
7620 PRINT " D D D- TAPS TO DIPOLE"
7630 PRINT " LLLLLLLLLLLLLLLLLLLLL L- COIL ON FERRITE"
7640 PRINT " W T T W T- TAPS TO TRANSMISSION LINE"
7650 PRINT " W W W- CONNECTING WIRE"
7660 PRINT " W W CCC- CAPACITOR"
7670 PRINT " WWWWWWWWWCCCWWWWWWWWW "
7680 PRINT ""
7690 INPUT " PAPER COPY OF SCHEMATICS, Y/N"; T$
7800 IF T$ = "Y" THEN GOSUB 10000
7700 GOTO 1000
8000 PRINT
8010 INPUT " ENTER MAXIMUM ALLOWED SWR, NULL=2"; SM
8020 IF SM = 0 THEN SM = 2
8030 IF TYR < 6 THEN 8060
8040 INPUT " ENTER ESTIMATED Q OF LC RESONATOR, 0=200"; QN
8050 IF QN = 0 THEN QN = 200: GOTO 8070
8060 QN = 2.78 * FO / CLOSS / CVF
8070 ZN = RR(5) * SM / QA + RR(5) * (SM - 1) / QN
8080 NZ = RR(5) / FZO * (SM - QA / (QN + QA))
8100 IF TYR = 6 THEN 8990
8110 PRINT " BALUN TRANSFORMER RATIO="; FNP(NZ); ":1 IMPEDANCE RATIO"
8120 PRINT " ="; FNP(SQR(NZ)); ":1 TURNS RATIO"
8200 IF P$ = "Y" THEN LPRINT " BALUN TRANSFORMER RATIO="; FNP(NZ); ":1 IMPEDANCE RATIO"
8210 IF P$ = "Y" THEN LPRINT " ="; FNP(SQR(NZ)); ":1 TURNS RATIO"
8990 RETURN
9000 PRINT
9010 PRINT " WITH BROADBANDING OF TYPE"
9020 IF TYR = 2 THEN PRINT " QUARTER WAVE TWO-PART OPEN/SHORTED COAX RESONATOR"
9030 IF TYR = 3 THEN PRINT " HALF WAVE TWO-PART OPEN COAX RESONATOR"
9040 IF TYR = 4 THEN PRINT " HALF WAVE TWO-PART SHORTED COAX RESONATOR"
9050 IF TYR = 5 THEN PRINT " 2 QUARTER-WAVE COAX RESONATORS"
9060 IF TYR = 6 THEN PRINT " TAPPED COIL-CAPACITOR RESONATOR"
9100 PRINT
9110 BW = FO / QN / QA / SQR(SM) * SQR((QN + QA) * ((2 * QN + QA) * SM - QA) * (SM - 1))
9120 BWIF = BW / BWD
9130 EFC = 100 * (1 - QA / SM / (QN + QA))
9140 EFE = 100 * SM * QN * QN / ((QN + QA) * (SM * (QN + QA) - QA))
9150 PRINT " COMPENSATED BANDWIDTH="; INT(1000 * BW); "KHZ"
9160 PRINT " BANDWIDTH IMPROVEMENT="; FNP(BWIF); ":1"
9170 PRINT " EFFICIENCY AT BAND CENTER= "; INT(EFC); " PERCENT"
9180 PRINT " AT SWR="; SM; " BAND EDGES"
9190 PRINT " EFFICIENCY= "; INT(EFE); " PERCENT"
9200 PRINT
9210 IF P$ <> "Y" THEN 9990
9300 LPRINT
9310 LPRINT " WITH BROADBANDING OF TYPE"
9320 IF TYR = 2 THEN LPRINT " QUARTER WAVE TWO-PART OPEN/SHORTED COAX RESONATOR"
9330 IF TYR = 3 THEN LPRINT " HALF WAVE TWO-PART OPEN COAX RESONATOR"
9340 IF TYR = 4 THEN LPRINT " HALF WAVE TWO-PART SHORTED COAX RESONATOR"
9350 IF TYR = 5 THEN LPRINT " 2 HALF WAVE COAX RESONATORS"
9360 IF TYR = 6 THEN LPRINT " TAPPED COIL-CAPACITOR RESONATOR"
9400 LPRINT
9410 LPRINT " COMPENSATED BANDWIDTH="; INT(1000 * BW); "KHZ"
9420 LPRINT " BANDWIDTH IMPROVEMENT="; FNP(BWIF); ":1"
9430 LPRINT " EFFICIENCY AT BAND CENTER= "; INT(EFC); " PERCENT"
9440 LPRINT " AT SWR="; SM; " BAND EDGES"
9450 LPRINT " EFFICIENCY= "; INT(EFE); " PERCENT"
9460 LPRINT
9990 RETURN
10000 CLS ' PRINT SCHEMATICS
10010 LPRINT " SIMPLE DIPOLE"
10020 LPRINT " R-RADIATOR WIRE"
10030 LPRINT " RRRRRRRRRRRRRRRRRRRR RRRRRRRRRRRRRRRRRRRRR OR COAX CENTER"
10040 LPRINT " F F F-FEED COAX"
10050 LPRINT
10100 LPRINT " TWO QUARTER-WAVE RESONATORS IN SERIES"
10101 LPRINT
10120 LPRINT " CCCCCCCCCCCCCC CCCCCCCCCCCCCCC C-COAX SHIELD"
10130 LPRINT " RRRRRRSRRRRRRRRRRRRR RRRRRRRRRRRRRRSRRRRRR S-SHORT"
10140 LPRINT " CCCCCCCCCCCCCC CCCCCCCCCCCCCCC"
10150 LPRINT " F F"
10160 LPRINT
10200 LPRINT " TWO QUARTER-WAVE RESONATORS IN PARALLEL"
10210 LPRINT
10220 LPRINT " CCCCCCCCCCCCCC CCCCCCCCCCCCCCC "
10230 LPRINT " RRRRRRSRRRRRRRRRRRRRXRRRRRRRRRRRRRRSRRRRRR X- SHIELD-CENTER"
10240 LPRINT " CCCCCCCCCCCCCCXCCCCCCCCCCCCCCC CROSS CONNECTED"
10250 LPRINT " F F"
10260 LPRINT
10300 LPRINT " ASSYMETRIC QUARTER-WAVE RESONATOR"
10310 LPRINT " F-FEED"
10320 LPRINT " CCCCCCCCCCCCCC CCCCCCO C-COAX SHIELD"
10330 LPRINT " RRRRRRSRRRRRRRRRRRRRXRRRRRRRRRRRRRRRRRRRRR S-SHIELD-CENTER"
10340 LPRINT " CCCCCCCCCCCCCCXCCCCCCO SHORT"
10350 LPRINT " F F O- NO SHORT"
10360 LPRINT
10400 LPRINT " SHORTED ASSYMETRIC HALF-WAVE RESONATOR R-RADIATOR WIRE"; ""
10410 LPRINT " F-FEED"
10420 LPRINT " CCCCCC CCCCCCCCCCCCCCCCCCCC"
10430 LPRINT " RRRRRRRRRRRRRRSRRRRRXRRRRRRRRRRRRRRRRRRRSR X- SHIELD-CENTER"
10440 LPRINT " CCCCCCXCCCCCCCCCCCCCCCCCCCC CROSS CONNECTED"
10450 LPRINT " F F"
10460 LPRINT " NOTE"
10500 LPRINT " OPEN ASSYMETRIC HALF-WAVE RESONATOR FOR SIMPLICITY"
10510 LPRINT " R SECTIONS ARE"
10520 LPRINT " OCCCCC CCCCCCCCCCCCCCCCCCCO ASSUMED TO BE"
10530 LPRINT " RRRRRRRRRRRRRRRRRRRRXRRRRRRRRRRRRRRRRRRRRR SAME DIAMETER AS"
10540 LPRINT " OCCCCCXCCCCCCCCCCCCCCCCCCCO C SECTIONS. THIS"
10550 LPRINT " F F CAUSES A SMALL"
10560 LPRINT " ERROR IN BANDWIDTH"
10600 LPRINT " LC MATCHING NETWORK"
10610 LPRINT
10620 LPRINT " D D D- TAPS TO DIPOLE"
10630 LPRINT " LLLLLLLLLLLLLLLLLLLLL L- COIL ON FERRITE"
10640 LPRINT " W T T W T- TAPS TO TRANSMISSION LINE"
10650 LPRINT " W W W- CONNECTING WIRE"
10660 LPRINT " W W CCC- CAPACITOR"
10670 LPRINT " WWWWWWWWWCCCWWWWWWWWW "
10680 LPRINT ""
10990 RETURN
11000 END
60000 PRINT " ERROR"; ERR; "AT LINE"; ERL
60010 INPUT "PRESS RETURN TO ATTAMPT RECOVERY FROM ERROR"; T$
60020 GOTO 1000