home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol2 / basic / isod.asc < prev    next >
Text File  |  1996-06-30  |  3KB  |  62 lines
  1. 2 ON ERROR GOTO 60000
  2. 3 CLS
  3. 10 PRINT "   **************************************************************"
  4. 20 PRINT "   *                      ANTENNA ISOLATION                     *"
  5. 30 PRINT "   *  REFERENCE- JOHNSON & JASIK, ANTENNA ENGINEERING HANDBOOK  *"
  6. 40 PRINT "   *           -  THE ARRL ANTENNA BOOK                         *"
  7. 50 PRINT "   *                PROGRAM BY  R.P. HAVILAND, W4MB             *"
  8. 60 PRINT "   *                       COPYRGHT 1990                        *"
  9. 70 PRINT "   *          MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086       *"
  10. 80 PRINT "   **************************************************************"
  11. 90 DEF FNP(X)=INT(10*X+.5)/10
  12. 100 PRINT " THIS PROGRAM ESTIMATES THE ISOLATION BETWEEN VERTICAL DIPOLES,"
  13. 110 PRINT "  AND THE REQUIRED ISOLATION BETWEEN TRANSMITTER AND RECEIVER"
  14. 120 PRINT "   AT THE SAME LOCATION, SPECIFICALLY FOR VHF/UHF FOR REPEATERS."
  15. 130 PRINT " RESULTS ARE APPROXIMATELY CORRECT FOR HORIZONTAL DIPOLES"
  16. 140 PRINT "  WHICH ARE WELL ABOVE EARTH."
  17. 150 PRINT " USE NEC OR MININEC ANALYSIS FOR EVALUATION OF OTHER ANTENNA TYPES."
  18. 200 PRINT 
  19. 210 INPUT " ENTER OPERATING FREQUENCY, MHZ.";FO
  20. 220 IF FO<=0 THEN 210
  21. 230 LAM=299.8/FO
  22. 240 LAMFT=LAM*3.2808
  23. 250 PRINT " WAVELENGTH=";FNP(LAM);"METERS"
  24. 260 PRINT "           =";FNP(LAMFT);"FEET"
  25. 300 PRINT 
  26. 310 INPUT " ENTER THE SEPARATION BETWEEN ANTENNAS, FEET";SEPFT
  27. 320 IF SEPFT=<0 THEN 310
  28. 330 INPUT " ENTER SEPARATION DIRECTION, H=HORIZONTAL, V=VERTIAL";SD$
  29. 340 IF SD$<>"H" AND SD$<>"V" THEN 320
  30. 400 PRINT 
  31. 410 SEPWL=SEPFT/LAMFT
  32. 420 PRINT " SEPARATION IS";FNP(SEPWL);"WAVELENGTHS"
  33. 500 IF SD$="H" THEN ISO=18+20/2.3*LOG(SEPWL)
  34. 510 IF SD$="V" THEN ISO=34+20/2.3*LOG(SEPWL)
  35. 520 PRINT "  THE ISOLATION IS";FNP(ISO);"DB"
  36. 600 PRINT 
  37. 610 INPUT " ENTER R= REVISE, S= ANOTHER SEPARATION, OTHER= CONTINUE";T$
  38. 620 IF T$="R" THEN 200
  39. 630 IF T$="S" THEN 300
  40. 700 PRINT 
  41. 710 INPUT " ENTER FREQUENCY OFFSET, TRANSMITTER TO RECEIVER, MHZ";FS
  42. 720 IF FS<.3 THEN PRINT "  NOT A REALISTIC VALUE FOR REPEATERS":GOTO 610
  43. 730 RI144=85-45/2.3*LOG(FS)
  44. 740 RI450=100-52/2.3*LOG(FS)
  45. 750 PRINT
  46. 800 PRINT " WITH 100 WATTS TRANSMITTER OUTPUT"
  47. 810 PRINT "  TYPICAL REQUIRED ISOLATION AT 144 MHZ=";FNP(RI144);"DB"
  48. 820 PRINT "                             AT 450 MHZ=";FNP(RI450);"DB"
  49. 830 PRINT " REQUIRED ISOLATION VARIES WITH TRANSMITTER SIGNAL PURITY AND RECEIVER DESIGN"
  50. 840 PRINT "  FOR BEST DESIGN, USE VARIABLE ATTENUATOR IN TRANSMITTER LINE,"
  51. 850 PRINT "   AND MEASURE LOSS WHICH GIVES 1 DB CHANGE IN RECEIVER SENSIVITY"
  52. 860 PRINT "    BETWEEN TRANSMITTER OFF AND ON."
  53. 870 PRINT " USE CAVITIES TO PROVIDE ADDED ATTENUATION IF SEPARATION ISOLATION"
  54. 880 PRINT "  IS LESS THAN REQUIRED TO PREVENT LOSS OF SENSITIVITY.
  55. 1000 PRINT 
  56. 1010 INPUT " ENTER R= RERUN, O= ANOTHER OFFSET, OTHER= QUIT";T$
  57. 1020 IF T$="R" THEN 200
  58. 1030 IF T$="O" THEN 700
  59. 1040 END
  60. 60000 PRINT " ERROR";ERR;"AT LINE";ERL
  61. 60010 STOP
  62.