home *** CD-ROM | disk | FTP | other *** search
/ ftp.cs.arizona.edu / ftp.cs.arizona.edu.tar / ftp.cs.arizona.edu / icon / historic / v941.tgz / icon.v941src.tar / icon.v941src / ipl / progs / setmerge.icn < prev    next >
Text File  |  2000-07-29  |  2KB  |  71 lines
  1. ############################################################################
  2. #
  3. #    File:     setmerge.icn
  4. #
  5. #    Subject:  Program to combine sets of text items
  6. #
  7. #    Author:   Gregg M. Townsend
  8. #
  9. #    Date:     May 31, 1994
  10. #
  11. ############################################################################
  12. #
  13. #   This file is in the public domain.
  14. #
  15. ############################################################################
  16. #
  17. #  Setmerge combines sets of items according to the specified operators.
  18. #  Sets are read from files, one entry per line.  Operation is from left
  19. #  to right without any precedence rules.  After all operations are
  20. #  complete the resulting set is sorted and written to standard output.
  21. # 
  22. #  Usage:  setmerge file [[op] file]...
  23. #
  24. #  Operations:
  25. #    +  add contents to set
  26. #    -  subtract contents from set
  27. #    *  intersect contents with set
  28. #
  29. #  Note that operators must be separate command options, and that some
  30. #  shells my require some of them to be quoted.
  31. #
  32. #  Example 1: combine files, sorting and eliminating duplicates:
  33. #
  34. #    setmerge file1 + file2 + file3 + file4
  35. #
  36. #  Example 2: print lines common to three files
  37. #
  38. #    setmerge file1 '*' file2 '*' file3
  39. #
  40. #  Example 3: print lines in file1 or file2 but not in file3
  41. #
  42. #    setmerge file1 + file2 - file3
  43. #
  44. ############################################################################
  45.  
  46.  
  47. procedure main(args)
  48.    local items, a, op, f, s
  49.  
  50.    items := set()
  51.    op := "+"
  52.    every a := !args do {
  53.       if *a = 1 & any('+-*', a) then {
  54.          op := a
  55.          }
  56.       else {
  57.          f := open(a) | stop("can't open ", a)
  58.          case op of {
  59.             "+": every insert(items, !f)
  60.             "-": every delete(items, !f)
  61.             "*": {
  62.                s := set()
  63.                every insert(s, member(items, !f))
  64.                items := s
  65.                }
  66.          }
  67.       }
  68.    }
  69.    every write(!sort(items))
  70. end
  71.