home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG091.ARK / DISKIO.BAS < prev    next >
BASIC Source File  |  1984-04-29  |  1KB  |  36 lines
  1. 10 ' These programs are examples of how to read and write the
  2. 20 ' spectrum analysis data files with Microsoft BASIC ver. 5.2.
  3. 30 ' Each file consists of 1024 complex values. These are stored as
  4. 40 ' 1024 8 byte records, each consisting of a real and imaginary part.
  5. 50 '
  6. 60 ' PROGRAM WHICH WRITES 1024 COMPLEX NUMBERS TO
  7. 70 ' A RANDOM DISK FILE.
  8. 80 OPEN "R", #1, "SINEWAVE.DAT", 8
  9. 90 FIELD #1, 4 AS REAL$, 4 AS IMAG$
  10. 100 ' Generate a sinewave and put it in the real part.
  11. 110 ' The imaginary part will be zero.
  12. 120 CYCLES = 20
  13. 130 M = CYCLES * 2 * 3.14159 / 1024
  14. 140 FOR N=0 TO 1023
  15. 150 S = COS( M * N )
  16. 160 LSET REAL$ = MKS$( S )
  17. 170 LSET IMAG$ = MKS$( 0 )
  18. 180 PUT #1, N+1
  19. 190 NEXT
  20. 200 CLOSE
  21. 210 END
  22. 220 REM
  23. 500 ' THIS PROGRAM READS 1024 COMPLEX NUMBERS FROM
  24. 510 ' FROM A RANDOM DISK FILE
  25. 520 INPUT "What filename (1-8 characters)"; FILE$
  26. 530 OPEN "R", #1, FILE$ + ".DAT", 8
  27. 540 FIELD #1, 4 AS REAL$, 4 AS IMAG$
  28. 550 ' Read and display the real & imaginary parts.
  29. 560 PRINT "Point", "Real", "Imaginary"
  30. 570 FOR P=0 TO 1023
  31. 580 GET #1, P+1
  32. 590 PRINT P, CVS( REAL$ ), CVS( IMAG$ )
  33. 600 NEXT
  34. 610 CLOSE
  35. 620 END
  36.