home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
SIMTEL
/
CPMUG
/
CPMUG091.ARK
/
DISKIO.BAS
< prev
next >
Wrap
BASIC Source File
|
1984-04-29
|
1KB
|
36 lines
10 ' These programs are examples of how to read and write the
20 ' spectrum analysis data files with Microsoft BASIC ver. 5.2.
30 ' Each file consists of 1024 complex values. These are stored as
40 ' 1024 8 byte records, each consisting of a real and imaginary part.
50 '
60 ' PROGRAM WHICH WRITES 1024 COMPLEX NUMBERS TO
70 ' A RANDOM DISK FILE.
80 OPEN "R", #1, "SINEWAVE.DAT", 8
90 FIELD #1, 4 AS REAL$, 4 AS IMAG$
100 ' Generate a sinewave and put it in the real part.
110 ' The imaginary part will be zero.
120 CYCLES = 20
130 M = CYCLES * 2 * 3.14159 / 1024
140 FOR N=0 TO 1023
150 S = COS( M * N )
160 LSET REAL$ = MKS$( S )
170 LSET IMAG$ = MKS$( 0 )
180 PUT #1, N+1
190 NEXT
200 CLOSE
210 END
220 REM
500 ' THIS PROGRAM READS 1024 COMPLEX NUMBERS FROM
510 ' FROM A RANDOM DISK FILE
520 INPUT "What filename (1-8 characters)"; FILE$
530 OPEN "R", #1, FILE$ + ".DAT", 8
540 FIELD #1, 4 AS REAL$, 4 AS IMAG$
550 ' Read and display the real & imaginary parts.
560 PRINT "Point", "Real", "Imaginary"
570 FOR P=0 TO 1023
580 GET #1, P+1
590 PRINT P, CVS( REAL$ ), CVS( IMAG$ )
600 NEXT
610 CLOSE
620 END