home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG054.ARK / WUGWMP.BAS < prev   
BASIC Source File  |  1984-04-29  |  2KB  |  57 lines
  1. 1 REM  COURTESY OF PEOPLE'S COMPUTER COMPANY
  2. 2 REM  MUGWMP
  3. 3 REM *** CONVERTED TO RSTS/E BY DAVID AHL, DIGITAL
  4. 5 RANDOMIZE
  5. 10 DIM P(4,2)
  6. 20  PRINT "THE OBJECT OF THIS GAME IS TO FIND FOUR MUGWUMPS"
  7. 30  PRINT "HIDDEN ON A 10 BY 10 GRID. HOMEBASE IS POSITION 0,0"
  8. 40  PRINT "ANY GUESS YOU MAKE MUST BE TWO NUMBERS WITH EACH"
  9. 50  PRINT "NUMBER BETWEEN 0 AND 9, INCLUSIVE. FIRST NUMBER"
  10. 60  PRINT "IS DISTANCE TO RIGHT OF HOMEBASE AND SECOND NUMBER"
  11. 70  PRINT "IS DISTANCE ABOVE HOMEBASE."
  12. 80  PRINT
  13. 90  PRINT "YOU GET 10 TRIES. AFTER EACH TRY, I WILL TELL"
  14. 100  PRINT "YOU HOW FAR YOU ARE FROM EACH MUGWUMP."
  15. 110  PRINT
  16. 240  GOSUB 1000
  17. 250  T=0
  18. 260  T=T+1
  19. 270  PRINT
  20. 275  PRINT
  21. 290  PRINT "TURN NO."T;"WHAT IS YOUR GUESS";
  22. 300  INPUT M,N
  23. 310  FOR I=1 TO 4
  24. 320 IF P(I,1)=-1 THEN 400
  25. 330 IF P(I,1)<>M THEN 380
  26. 340 IF P(I,2)<>N THEN 380
  27. 350 P(I,1)=-1
  28. 360  PRINT "YOU HAVE FOUND MUGWUMP";I
  29. 370  GOTO 400
  30. 380 D=SQR((P(I,1)-M)^2+(P(I,2)-N)^2)
  31. 390 PRINT "YOU ARE"INT(D*10)/10"UNITS FROM MUGWUMP"I
  32. 400  NEXT I
  33. 410  FOR J=1 TO 4
  34. 420 IF P(J,1)<>-1 THEN 470
  35. 430  NEXT J
  36. 440  PRINT
  37. 450  PRINT "YOU GOT THEM ALL IN";T;"TURNS!"
  38. 460  GOTO 580
  39. 470  IF T<10 THEN 260
  40. 480  PRINT
  41. 490  PRINT "SORRY, THAT'S 10 TRIES. HERE IS WHERE THEY'RE HIDING"
  42. 540  FOR I=1 TO 4
  43. 550 IF P(I,1)=-1 THEN 570
  44. 560 PRINT "MUGWUMP";I;"IS AT (";P(I,1);",";P(I,2);")"
  45. 570  NEXT I
  46. 580  PRINT
  47. 600 PRINT "THAT WAS FUN!  LET'S PLAY AGAIN....."
  48. 610 PRINT "FOUR MORE MUGMUMPS ARE NOW IN HIDING."
  49. 630  GOTO 240
  50. 1000  FOR J=1 TO 2
  51. 1010  FOR I=1 TO 4
  52. 1020 P(I,J)=INT(10*RND(1))
  53. 1030  NEXT I
  54. 1040  NEXT J
  55. 1050  RETURN
  56. 1099 END
  57.