home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG042.ARK / CT82.Z80 < prev    next >
Text File  |  1984-04-29  |  6KB  |  220 lines
  1.     TITLE    "A 'STAT' LIKE ROUTINE TO CHANGE MODE OF THE CT-82"
  2. ; 
  3. ;    WRITTEN 4 FEBRUARY, 1979 BY KEN TALBOTT
  4. ;    COPYRIGHT WAIVED FOR NON-COMMERCIAL, HOBBYIST USE.
  5. ; 
  6. ; 
  7. ;    THIS PROGRAM ALLOWS CHANGING THE CONFIGURATION
  8. ;    OF THE CT-82 BY SWTPC WITHOUT LEAVING THE CP/M
  9. ;    OPERATING SYSTEM.
  10. ; 
  11. ;    THE SOURCE CODE IS FOR CROMEMCO'S Z80 ASSEMBLER
  12. ;    AND WILL REQUIRE MODIFICATION FOR 8080 SYSTEMS.
  13. ; 
  14. ;    TO CALL THE ROUTINE, TYPE:
  15. ; 
  16. ;        'CT82 {C1: C2: C3: .... CN:}'
  17. ; 
  18. ;    WHERE {C1: C2: C3: .... CN:} IS A NON-EMPTY
  19. ;    STRING OF VALID ASSIGNMENTS AS DEFINED BELOW
  20. ;    IN THE LOOK-UP TABLE.
  21. ; 
  22. ;    IF YOU DON'T HAVE THE OPTIONAL CHARACTER OR
  23. ;    GRAPHICS ROM USE OF THE RELATED COMMANDS WILL
  24. ;    RESULT IN UNPREDICTABLE RESULTS (USUALLY A
  25. ;    SCREEN FULL OF VERTICAL WHITE LINES).
  26. ; 
  27. ;    NOTE THAT ON MY CT-82 THE DISPLAY CURSOR (^^ ^E)
  28. ;    AND SUPPRESS CURSOR DISPLAY (^^ ^U) FUNCTIONS
  29. ;    ARE REVERSED.
  30. ; 
  31. ;    ORG    0100H    DON'T SET ORIGIN IN SOURCE FILE
  32. ;            USE 'HEX = ' OPTION WHEN CALLING ASSM
  33. ; 
  34. TBUFF    EQU    0080H    ; THIS IS WHERE WE WILL FIND THE
  35.             ; COMMAND STRING.  LOC 80H WILL
  36.             ; CONTAIN THE LENGTH OF THE STRING
  37. ; 
  38. BEGIN:    LD    (SAVSP),SP    ; SAVE CCP'S STACK
  39.     LD    SP,STACK    ; SET ONE FOR US
  40.     LD    A,(TBUFF)
  41.     LD    C,A        ; GET NUMBER CHARS IN C
  42.     LD    HL,TBUFF+1    ; POINT TO CMND STRING
  43. ; 
  44. ;    THIS IS THE MAIN WORK LOOP.  FIRST WE FIND THE NEXT
  45. ;    COMMAND (TERMINATED BY A ':').  IF NO COLON IS FOUND,
  46. ;    WE EXIT BACK TO THE CCP
  47. ; 
  48. WORK:    LD    A,':'
  49.     CPIR
  50.     JR    NZ,FINIS    ; NO COLON, THEN FINISHED
  51. ; 
  52. ;    WE HAVE A COLON, SO NOW PUT A $ THERE IN CASE WE
  53. ;    NEED TO PRINT IT AND DECREMENT HL TO POINT TO THE
  54. ;    FIRST CHAR OF THE COMMAND
  55. ; 
  56.     DEC    HL        ; BACK UP TO ':'
  57.     LD    (HL),'?'    ; CHANGE IT FOR ERROR
  58.     DEC    HL
  59.     DEC    HL
  60.     DEC    HL
  61. ; 
  62. ;    NOW GO LOOK IN THE TABLE FOR THE THREE CHARACTER
  63. ;    STRING POINTED TO BY HL
  64. ; 
  65.     CALL    LOOK
  66. ; 
  67. ;    IF NOT FOUND, TELL THE FOLKS, DISPLAYING THE
  68. ;    INVALID COMMAND
  69. ; 
  70.     CALL    NZ,ERROR
  71. ; 
  72. ;    IF IT WAS A VALID COMMAND, OUTPUT THE CONTROL CHAR'S
  73. ; 
  74.     CALL    Z,COUT
  75. ; 
  76. ;    NOW LOOP AND DO IT ALL AGAIN
  77. ; 
  78.     LD    A,C        ; WE COULD BE AGAINST THE END
  79.     AND    A
  80.     JR    NZ,WORK
  81. ; 
  82. ;    THIS IS THE POINT AT WHICH WE EXIT BACK TO CP/M
  83. ; 
  84. FINIS:    LD    SP,(SAVSP)    ; GET CCP'S STACK
  85.     RET            ; TO CCP
  86. ; 
  87. ;    THIS IS THE LOOK-UP ROUTINE FOR VALID COMMANDS.
  88. ;    HL POINTS TO THE FIRST BYTE OF THE THREE BYTE
  89. ;    STRING SOUGHT.  REG'S BC (NUMBER OF CHARACTERS
  90. ;    LEFT IN THE COMMAND STRING) MUST BE PRESERVED
  91. ;    AND HL MUST BE INCREMENTED A TOTAL OF FOUR TIMES
  92. ;    TO KEEP IT IN SYNC WITH BC FOR SEARCHES FOR
  93. ;    SUBSEQUENT COLONS.  IF FOUND, RETURN ZERO SET.
  94. ; 
  95. LOOK:    PUSH    BC        ; SAVE CMND STRING POINTER
  96.     LD    BC,TBLLEN    ; LENGTH TO SEARCH
  97.     LD    DE,TABLE    ; POINT TO TABLE
  98.     EX    DE,HL
  99. LOOP:    LD    A,(DE)    ; 1ST CHAR OF COMMAND STRING
  100.     CPIR        ; LOOK FOR 1ST CHAR IN TABLE
  101.     JR    NZ,EXIT1    ; IT'S NOT THERE
  102.     INC    DE    ; 2ND CHAR OF COMMAND STRING
  103.     LD    A,(DE)    ; ...INTO THE ACC
  104.     CP    (HL)    ; EQUAL 2ND CHAR OF TABLE?
  105.     DEC    DE    ; IN CASE NOT EQUAL
  106.     JR    NZ,LOOP    ; CONTINUE LOOK FOR 1ST CHAR
  107.     INC    DE    ; NOW POINT TO....
  108.     INC    DE    ; ....3RD CHAR OF COMMAND
  109.     LD    A,(DE)    ; GET IT IN ACC
  110.     INC    HL    ; 3RD CHAR OF TABLE
  111.     CP    (HL)    ; ARE THEY EQUAL?
  112.     DEC    DE
  113.     DEC    DE    ; BACK TO COMMAND CHAR1
  114.     DEC    HL    ; BACK TO TABLE CHAR2
  115.     JR    NZ,LOOP    ; ....AND CONTINUE LOOK
  116. ; 
  117. ;    MAYBE WE HAVE A MATCH, MAYBE NOT.  REGARDLESS
  118. ;    RESET HL TO CONTINUE SEARCH FOR COLON AND RET.
  119. ; 
  120. EXIT1:    INC    DE
  121.     INC    DE
  122.     INC    DE
  123.     INC    DE
  124.     EX    DE,HL
  125.     POP    BC    ; GET BACK REMAINING COMMAND LENGTH
  126.     RET
  127. ; 
  128. ;    THIS IS THE ERROR ROUTINE.  IT PRINTS THE
  129. ;    UNDEFINED COMMAND AT THE CONSOLE FOLLOWED
  130. ;    BY A '?'.
  131. ; 
  132. ERROR:    DEC    HL
  133.     DEC    HL
  134.     DEC    HL
  135.     DEC    HL
  136.     PUSH    BC
  137.     PUSH    DE
  138.     LD    A,4        ; NUMBER TO PRINT
  139.     CALL    LOOP1
  140.     POP    DE
  141.     POP    BC
  142.     INC    A
  143.     RET
  144. LOOP1:    LD    E,(HL)
  145.     PUSH    HL
  146.     LD    C,02    ; CP/M CONSOLE OUT COMMAND
  147.     PUSH    AF    ; SAVE COUNT & STATUS
  148.     CALL    5    ; BDOS ENTRY
  149.     POP    AF    ; GET BACK COUNT
  150.     DEC    A
  151.     POP    HL
  152.     INC    HL        ; POINT TO NEXT CHAR
  153.     JR    NZ,LOOP1    ; DO IT AGAIN
  154.     RET
  155. ; 
  156. ;    THIS IS THE ROUTINE WHICH OUTPUTS THE CONTROL CHAR'S
  157. ;    TO THE CT-82.
  158. ; 
  159. COUT:    EX    DE,HL        ; TABLE POINTER TO HL
  160.     INC    HL
  161.     INC    HL        ; POINT TO CONTROL CHAR
  162.     PUSH    BC
  163.     PUSH    DE
  164.     LD    A,02
  165.     CALL    LOOP1
  166.     POP    DE
  167.     POP    BC
  168.     EX    DE,HL
  169.     RET
  170. ; 
  171. ;    THIS IS THE TABLE OF VALID COMMANDS.  THE COLON (:)
  172. ;    IS NOT PART OF THE TABLE BUT IS USED AS THE DELIMITER
  173. ;    IN THE COMMAND STRING.  EACH COMMAND IS FOLLOWED BY
  174. ;    A TWO CHARACTER STRING TO BE OUTPUT TO THE CT-82
  175. ;    (STRING IS PADDED WITH NULLS AS REQUIRED).
  176. ; 
  177. TABLE:    DB    'CES',1EH,01H    ; CLEAR ESCAPE DATA MODE
  178.     DB    'KOF',00H,05H    ; CURSOR OFF
  179.     DB    'KON',00H,15H    ; CURSOR ON
  180.     DB    'DLF',1EH,09H    ; DISABLE AUTO LF ON CR
  181.     DB    'DNL',1EH,1AH    ; DISABLE AUTO NEW LINE ON OVFL
  182.     DB    'DES',1EH,00H    ; DISABLE ESCAPE CHAR
  183.     DB    'DRO',1EH,1BH    ; DISABLE RUBOUT AS DATA
  184.     DB    'DSC',1EH,18H    ; DISABLE SCROLL ON LF
  185.     DB    'DSH',1EH,1DH    ; DISABLE SHIFT INVERT
  186.     DB    'DPR',1DH,07H    ; DISABLE PRINTER PASS THRU
  187.     DB    'DCN',1CH,00H    ; DISPLAY CONTROL CHAR
  188.     DB    'ELF',1EH,19H    ; ENABLE AUTO LF ON CR
  189.     DB    'ENL',1EH,0AH    ; ENABLE AUTO NL ON OVFL
  190.     DB    'EES',1EH,10H    ; ENABLE ESCAPE CHAR
  191.     DB    'ERO',1EH,0BH    ; ENABLE RUB AS DATA
  192.     DB    'ESC',1EH,08H    ; ENABLE SCROLL ON LF
  193.     DB    'ESH',1EH,0DH    ; ENABLE SHIFT INVERT
  194.     DB    'EPR',1DH,0BH    ; ENABLE PRINTER PASS THRU
  195.     DB    'EUL',1EH,0CH    ; ENABLE UPPER & LOWER CASE
  196.     DB    'POF',00H,14H    ; PUNCH OFF
  197.     DB    'PON',00H,12H    ; PUNCH ON
  198.     DB    'ROF',00H,13H    ; READER OFF
  199.     DB    'RON',00H,11H    ; READER ON
  200.     DB    'KBK',1EH,03H    ; SET BLINKING CURSOR
  201.     DB    'BKK',1EH,04H    ; SET BLOCK CURSOR
  202.     DB    '16L',1CH,11H    ; SET CRT FORMAT I
  203.     DB    '20L',1CH,12H    ; SET CRT FORMAT II
  204.     DB    '16A',1CH,13H    ; SET CRT FORMAT III
  205.     DB    '20A',1CH,14H    ; SET CRT FORMAT IV
  206.     DB    'CON',1EH,0FH    ; SET CONVERSATIONAL
  207.     DB    'FUL',1EH,0EH    ; SET FULL DUPLEX
  208.     DB    'SES',1EH,11H    ; SET ESCAPE DATA MODE
  209.     DB    'GRA',1DH,16H    ; SET GRAPHICS DISPLAY
  210.     DB    'HAF',1EH,1EH    ; SET HALF DUPLEX
  211.     DB    'NBK',1EH,13H    ; SET NON-BLINKING CURSOR
  212.     DB    'PED',1EH,1FH    ; SET PAGE EDIT MODE
  213.     DB    'ULK',1EH,14H    ; SET UNDERLINE CURSOR
  214.     DB    'UCO',1EH,1CH    ; SET UPPER CASE ONLY
  215. TBLLEN    EQU    $-TABLE
  216.     DS    16
  217. STACK    EQU    $
  218. SAVSP:    DS    2
  219.     END    BEGIN
  220.