home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG035.ARK / PARM.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  11KB  |  476 lines
  1. ; 7 SEPT,NIGHT.I RE-REPAIR CHARIN...
  2. ;
  3. ; FIX TO INCORPORATE TYPE 4 AND TYPE 7
  4. ; BY CHANDRA AND MCCHAREN ON AUGUST 25 '79
  5. ;
  6. ; PARM: INPARM & OUTPARM BY WITTENBERG. SOME
  7. ; FIXES (INCLUDING THE 'RESCALE' OP IMBEDDED) BY
  8. ; MOSHELL.
  9. ;
  10. ; INPUT CONDITIONS:
  11. ;
  12. ; PGMCTR ( OR FPC ) POINTS TO THE 'TYPE' BYTE OF THE PARAMETER.
  13. ;
  14. ; OUTPUT CONDITIONS:
  15. ;
  16. ; INPAR RETURNS THE VALUE OF THE PARAMETER IN D-E.
  17. ;
  18. PGMCTR    EQU    110H
  19. TYPBITS    EQU    0E0H
  20. DATA5    EQU    01FH
  21. CONSTAT    EQU    503FH
  22. CPM    EQU    0H
  23. DISPOFF    EQU    5057H
  24. CHAR    EQU    5094H
  25. CO    EQU    502AH
  26. CI    EQU    5027H
  27. CRLF    EQU    5024H
  28. PRINT    EQU    502DH
  29. HEXPRT    EQU    5042H
  30. DISPHL    EQU    5045H
  31. RANGTABL EQU    2F70H
  32. STOP    EQU    '$'
  33. INREG   EQU     4C06H
  34. OUTREG   EQU     4D66H
  35. *
  36.     ORG    5700H
  37. INPAR:    PUSH    H ! PUSH PSW
  38.     LHLD    PGMCTR    ;LOOK AT FIRST (TYPE) BYTE OF CURRENT PARM
  39.     MOV    A,M
  40.     ANI    TYPBITS    ;REMOVE ALL BUT TYPE CODE BITS
  41.     ADD    A    ;ADJUST SO THAT TYPE BITS SET CY,SIGN,& PPARITY FLAGS
  42.     JNC    ILESS4    ;IF CY NOT SET, TYPE # < 4
  43.     JP    ILESS6    ;IF SIGN NOT SET, TYPE 4 OR 5
  44.     ORA    A    ;SET PARITY FLAG
  45.     JPO    ITYPE6    ;IF PARITY ODD, TYPE IS 6
  46. *
  47. *  TYPE4 IS ARRAY, INDEXED BY ONE OF THE REGISTER CONTENTS
  48. * TYPE 7 REFERS TO REGISTER CONTENTS
  49. * INPAR CALLS OUTREG WITH THE PARMETER HEADER IN REG C
  50. * OUTREG RETURNS THE PARAMETER VALUE AS FOLLOWS:
  51. * REG A - LOW ORDER BYTE
  52. * REG B - HIGH ORDER BYTE
  53. *
  54. ITYPE47:   PUSH    B!    PUSH    H
  55.        MOV   C,M     ; PICK UP PARAMETER -HEADER.
  56.            CALL  OUTREG  ; OUTREG RETURNS THE PARM-VALUE IN 
  57.            MOV   E,A     ; A ( LOW ORDER BYTE ) & B ( HIGH ORDER BYTE )
  58.            MOV   D,B
  59.        POP    H    !POP    B
  60.        INX    H
  61.        SHLD PGMCTR
  62.            POP   PSW
  63.            POP   H
  64.            RET
  65. * 
  66. * TYPE 6 PARM IS A 16 BIT VARIABLE
  67. ITYPE6:    INX    H    ;GET ADDR. OF WORD WANTED TO RETURN
  68.     MOV    E,M
  69.     INX    H
  70.     MOV    D,M
  71.     INX    H    ;SAVE NEW PROGRAM COUNTER
  72.     SHLD    PGMCTR
  73.     XCHG        ;GET ADDRESS OF WANTED WORD INTO HL
  74.     MOV    E,M    ;GET WORD INNTO DE
  75.     INX    H
  76.     MOV    D,M
  77.     POP    PSW    ;RESTORE REGS AND RETURN
  78.     STC        ;TELL CALLER THAT VALUE IS 16 BITS
  79.     POP    H
  80.     RET
  81. *
  82. *  TYPE IS EITHER 4 OR 5
  83. * 
  84. ILESS6: ORA     A       ; SET THE PARITY FLAG
  85.         JPE     ITYPE47 ; IF THE PARITY IS EVEN,TYPE 4.
  86. *
  87. * TYPE 5 IS 16 BIT CONSTANT.
  88. *
  89. ITYPE5: INX     H       ; GET NEXT 16 BITS INTO D-E
  90.     MOV    E,M
  91.     INX    H
  92.     MOV    D,M
  93.     INX    H    ;UPDATE PROGRAM COUNTER
  94.     SHLD    PGMCTR
  95.     POP    PSW
  96.     STC        ;TELL CALLER THAT PPARM IS 16 BIT VALUE
  97.     POP    H
  98.     RET
  99. *
  100. * TYPE IS 0, 1, 2, OR 3
  101. *
  102. ILESS4:    JP    ILESS2    ;IF SIGN NOT SET, MUST BE 0 OR 1
  103.     ORA    A    ;SET PARITY FLAG
  104.     JPO    ITYPE2    ;IF PARITY ODD, TYPE MUST BE 2
  105. * TYPE 3 IS AN INPUT PORT
  106. * THESE ARE "STANDARDIZED" AS BELOW IN ORDER TO ACCESS
  107. * PORT INPUTS IN A MACHINE INDEPENDENT FASHION
  108. *    0  CONSOLE CTRL & STATUS: BIT 0=1 IF IN-DATA IS READY, 0 ELSE
  109. *    1  CONSOLE DATA (WAIT-LOOP AND ECHO BUILT IN)
  110. *    8  X1 \
  111. *    9  Y1  \
  112. *    A  X2   A/D CONVERTER (JOYSTICKS)
  113. *    B  Y2  /
  114. *    C  Z1  (EXTRA A/D CHANNEL ON JS-1...UNUSED NOW)
  115. *    D  Z2  ('POT' ON JS-2;USED FOR 'THETA')
  116. *    E  AUXILIARY SWITCH REG. (E.G. ON JOYSTICKS)
  117. *    F  SWITCH REGISTER
  118. ITYPE3:    PUSH    H    ;GET PROGRAM COUNTER OUT OF THE 0T OF FIRE
  119.     MOV    A,M    ;GET PORT NUMBER INTO A
  120.     ANI    DATA5
  121.     CALL    INPORT    ;CALL PROPER INPUT ROUTINE
  122.     POP    H    ;GET PROGRAM COUNTER BACK
  123.     INX    H    ;UPDATE IT AND STORE IT
  124.     SHLD    PGMCTR
  125.     MOV    E,A    ;PUUT RETURN VALUE INTO E
  126.     MVI    D,0    ;ZERO OUT HI-BYTE OF RESULT
  127.     POP    PSW
  128.     ORA    A    ;TELL CALLER RETURNN VALUE IS 8 BITS
  129.     POP    H
  130.     RET
  131. * TYPE 2 IS AN 8 BIT VARIABLE
  132. ITYPE2:    INX    H    ;GET ADDRESS OF BYTE WANTED INTO DE
  133.     MOV    E,M
  134.     INX    H
  135.     MOV    D,M
  136.     INX    H    ;UPDATE AND SAVE PROGRAM COUNTER
  137.     SHLD    PGMCTR
  138.     XCHG        ;GET BYTE'S ADDRESS INTO HL
  139.     MOV    E,M    ;GET BYTE INTO RETURN REG
  140.     MVI    D,0
  141.     POP    PSW
  142.     ORA    A    ;RETURN VALUE IS 8 BITS
  143.     POP    H
  144.     RET
  145. *
  146. *TYPE IS 0 OR 1
  147. *
  148. ILESS2:    ORA    A    ;SET PARITY FLAG
  149.     JPE    ITYPE0    ;IF PARITY IS EVEN, TYPE IS 0
  150. *TYPE 1 IS 8 BIT CONSTANT
  151. ITYPE1:    INX    H
  152.     MOV    E,M    ;GET BYTE RIGHT AWAY
  153.     MVI    D,0
  154.     INX    H    ;UPDATE AND STORE PROGRAM COUNTER
  155.     SHLD    PGMCTR
  156.     POP    PSW
  157.     ORA    A    ;RETURN VALUE IS 8 BITS; TELL CALLER
  158.     POP    H
  159.     RET
  160. * TYPE 0 IS A 5 BIT CONSTANT
  161. ITYPE0:    MOV    E,M    ;GET CONSTANT
  162.     MVI    D,0
  163.     INX    H        ;UPDATE AND SAVE PROGRAM COUNTER
  164.     SHLD    PGMCTR
  165.     POP    PSW
  166.     ORA    A        ;TELL CALLER THAT RETURN VALUE IS 8 BITS
  167.     POP    H
  168.     RET
  169. *
  170. * THIS ROUTINE TAKES A "STANDARD" PORT NUMBER IN A AND READS A BYTE
  171. * FROM THAT PORT INTO A.
  172. *
  173. INPORT:    MOV    L,A    ;MAKE HL A DISPLACEMENT VALUE
  174.     STA    SELECT    ;USED AT 'FIXRANGE' TIME .
  175.     MVI    H,0
  176.     DAD    H
  177.     LXI    D,IPORTAB ;GET BASE ADDRESS
  178.     DAD    D    ;ADD BASE TO DISP
  179.     MOV    E,M    ;GET ROUTINE @ FROM TABLE
  180.     INX    H
  181.     MOV    D,M
  182.     XCHG        ;INTO HL
  183.     PCHL        ;JUMP TO DESIGNATED ROUTINE
  184. * TABLE OF INPUT PORT ROUTINES
  185. IPORTAB    EQU    $
  186.     DW    CONSTAT,CHARIN,NOPORT,NOPORT
  187.     DW    NOPORT,NOPORT,NOPORT,NOPORT
  188.     DW    IJOY1X,IJOY1Y,IJOY2X,IJOY2Y
  189.     DW    INJOY1Z,INJOY2Z,IAUXSW,ISWREG
  190.     DW    NOPORT,NOPORT,NOPORT,NOPORT
  191.     DW    NOPORT,NOPORT,NOPORT,NOPORT
  192.     DW    NOPORT,NOPORT,NOPORT,NOPORT
  193.     DW    NOPORT,NOPORT,NOPORT,NOPORT
  194. * THIS ROUTINE IS CALLED WHEN A PORT IS ASKED FOR THAT DOESN'T
  195. * EXIST.  A NICE ERROR MESSAGE IS PRINTED AND THE INPUT IS IGNORED
  196. NOPORT:    LHLD    PGMCTR    ;DISPLAY THE CCURRENT PROGRAM COUNTER
  197.     CALL    DISPHL
  198.     MOV    A,M    ;GET PORT NUMBER
  199.     ANI    DATA5
  200.     PUSH    PSW    ;SAVE IT
  201.     LXI    H,PCEQ
  202.     CALL    PRINT    ;PRINT "=PC"
  203.     LXI    H,PORMES
  204.     CALL    PRINT    ;PRINT "ILLEGAL USE OF PORT"
  205.     POP    PSW    ;RESTORE PORT NUMMBER
  206.     CALL    HEXPRT    ;PRINT PORT NUMMBER
  207.     CALL    CRLF
  208.     RET
  209. PCEQ    DB    '=PC ',STOP
  210. INMESS1    DB    '<--PARAMETER TYPE ',STOP
  211. INMESS2    DB    ' IS NOT YET IMPLEMENTED',STOP
  212. PORMES    DB    '<--ILLEGAL USE OF PORT ',STOP
  213. * THE FOLLOWING ROUTINES READ BYTES FROM DEVICES WHICH DO NOT
  214. * ALREADY HAVE CP/M ROUTINES ASSIGNED TO THEM
  215. *
  216. X1    EQU    19H
  217. Y1    EQU    1AH
  218. X2    EQU    1BH
  219. Y2    EQU    1CH
  220. Z1    EQU    1DH
  221. Z2    EQU    1EH
  222. BUTTONS    EQU    18H
  223. SWITCH    EQU    0FFH
  224. CHARIN:    LDA    CHAR    ;LOOK AT EXEC-TRAPPED CHARACTER.
  225.     ORA    A    ;IS IT ZERO?
  226.     JZ    GETACHAR
  227.     PUSH    PSW
  228.     XRA    A    ;SHOW WE GOT IT.
  229.     STA    CHAR
  230.     POP    PSW
  231.     RET
  232. GETACHAR:CALL    CI    ;GET ONE
  233.     CPI    03H    ;CTRL/C?
  234.     RNZ
  235.     CALL    DISPOFF
  236.     JMP    CPM
  237. *
  238. * GET THE X COORDINATE FROM JOYSTICK 1
  239. *
  240. IJOY1X:    IN    X1
  241.     JMP    FIXRANGE
  242. *
  243. * GET THE Y COORDINATE FROM JOYSTICK 1
  244. *
  245. IJOY1Y:    IN    Y1
  246.     JMP    FIXRANGE
  247. *
  248. * GET THE X COORDINATE FROM JOYSTICK 2
  249. *
  250. IJOY2X:    IN    X2
  251.     JMP    FIXRANGE
  252. *
  253. * GET THE Y COORDINATE FROM JOYSTICK 2
  254. *
  255. IJOY2Y:    IN    Y2
  256.     JMP    FIXRANGE
  257. *
  258. *
  259. * GET THE Z COORDINATE FROM JS 1
  260. INJOY1Z:IN    Z1
  261.     JMP    FIXRANGE
  262. * GET THE Z ('THETA')COORD FROM JS 2
  263. INJOY2Z:IN    Z2
  264.     JMP    FIXRANGE
  265. * GET THE BYTE CORRESPONDING TO INPUT FROM THE JOYSTICK BUTTONS
  266. *
  267. IAUXSW:    IN    BUTTONS
  268.     CMA        ;"NORMALIZE" IT
  269.     RET
  270. *
  271. * GET A BYTE FROM THE SWITCH REGISTER
  272. *
  273. ISWREG:    IN    SWITCH
  274.     RET
  275. ; THIS 'RANGE' SET SYSTEM SCALES THE VARIOUS ANALOG (OR ANY OTHER)
  276. ; INPUTS IN THIS WAY: IF RANGE IS 0,NO SCALE;RANGE=1,DIVIDE BY
  277. ; 2 (SO MAX VAL. IS +-64)...UP TO RANGE=7,MAXVAL=+-1. THE
  278. ; RANGE IS SET BY THE 'RESCALE' OP,
  279. ;
  280. FIXRANGE:PUSH    D
  281.     LHLD    SELECT    ;WHICH DEVICE'S SCALE-FACTOR?
  282.     LXI    D,RANGTABL
  283.     DAD    D    ;HL POINTS INTO RANGE-TABLE.
  284.     MOV    E,M    ;E HAS RANGE(0-7)
  285. ;
  286. DIVLOOP:DCR    E
  287.     JM    GOTIT    ;ENOUGH ALREADY
  288.     ORA    A    ;SIGN OF A?
  289.     JM    NEGCASE
  290. ;POSCASE:
  291.     ANA    A    ;CLEAR CARRY
  292.     RAR        ;DIV BY 2
  293.     JMP    DIVLOOP
  294. NEGCASE:STC        ;SIGN EXTENSION
  295.     RAR
  296.     JMP    DIVLOOP
  297. GOTIT:    POP    D
  298.     RET
  299. SELECT    DB    0,0    ;SELECTOR FOR WHICH DEVICE.
  300. ;
  301. *
  302. * <OUTPAR>
  303. *
  304. * INPUT CONDITIONS:
  305. * 
  306. * THE FPC POINTS TO THE TYPE BYTE OF THE PARAMETER
  307. * THE VALUE TO BE ASSIGNED TO THE PARAMETER IS IN THE D-E PAIR
  308. *
  309.     ORG    58B0H
  310. OUTPAR:    PUSH    H ! PUSH PSW
  311.     LHLD    PGMCTR    ;LOOK AT TYPE BYTE OF CURRENT PARMM
  312.     MOV    A,M
  313.     ANI    TYPBITS    ;REMOVE ALL BUT TYPE CODE BITS
  314.     ADD    A    ;ADJUST AS IN "INPAR"
  315.     JNC    OLESS4
  316.     JP    OLESS6
  317.     ORA    A    ;SET PARITY
  318.     JPO    OTYPE6
  319. *
  320. * TYPE 7 PARM REFERS TO REGISTER CONTENTS
  321. * TYPE 4 IS A 16 BIT ARRAY, INDEXED BY THE REGISTER CONTENTS
  322. * OUTPAR CALLS INREG, WHICH INSERTS THE CONTENTS OF THE D-E PAIR 
  323. * INTO THE APPROPRIATE MEMORY LOCATION/REGISTER
  324. *
  325. OTYPE47: PUSH    B!    PUSH    H
  326.      MOV C,M      ; C HAS 'TYPE' BYTE.
  327.          CALL INREG
  328.      POP    H!    POP    B
  329.      INX    H
  330.      SHLD    PGMCTR
  331.          POP  PSW
  332.          POP  H
  333.          RET
  334. *
  335. * TYPE 6 IS A 16 BIT VARIABLE
  336. OTYPE6:    PUSH    D    ;SAVE VALUE
  337.     INX    H    ;GET ADDRESS OF WORD WANTED IN DE
  338.     MOV    E,M
  339.     INX    H
  340.     MOV    D,M
  341.     INX    H    ;UPDATE AND SAVE PROGRAM COUNTER
  342.     SHLD    PGMCTR
  343.     XCHG        ;GET WORD @ INTO HL
  344.     POP    D    ;GET VALUE BACK
  345.     MOV    M,E    ;STORE DE VALUE INTO SPECIFIED WORD
  346.     INX    H
  347.     MOV    M,D
  348.     POP    PSW
  349.     POP    H
  350.     RET
  351. *
  352. * TYPE IS EITHER 4 OR 5
  353. *
  354. OLESS6:    ORA    A    ;SET PARITY
  355.     JPE    OTYPE47
  356. * TYPE 5 IS A 16 BIT CONSTANT (ILLEGAL)
  357. OTYPE5:    CALL    NOCONS
  358.     INX    H    ;UPDATE AND STORE THE PROGRAM COUNTER
  359.     INX    H
  360.     INX    H
  361.     SHLD    PGMCTR
  362.     POP    PSW
  363.     POP    H
  364.     RET
  365. *
  366. * TYPE IS 0, 1, 2, OR 3
  367. *
  368. OLESS4:    JP    OLESS2
  369.     ORA    A    ;SET PARITY
  370.     JPO    OTYPE2
  371. * TYPE 3 IS OUTPUT PORT
  372. * THESE ARE "STANDARDIZED" AS BELOW IN ORDER TO ACCESS
  373. * I/O PORTS IN A MACHINE INDEPENDENT FASHION
  374. *    1  PRINT A CHARACTER ON THE CONSOLE
  375. *    8  SPEAKER ON JOYSTICK 1
  376. *    A  SPEAKER ON JOYSTICK 1
  377. *    F  PANEL LIGHTS
  378. OTYPE3:    PUSH    H    ;GET PROGRAM COUNTER OUT OF WAY
  379.     MOV    A,M    ;GET PORT # INTO A
  380.     ANI    DATA5
  381.     CALL    OUTPORT    ;CALL PROPER OUTPUT ROUTINE
  382.     POP    H    ;RETRIEVE PROGRAM COUNTER
  383.     INX    H    ;UPDATE AND STORE IT
  384.     SHLD    PGMCTR
  385.     POP    PSW
  386.     POP    H
  387.     RET
  388. * TYPE 2 IS AN 8 BIT VARIABLE
  389. OTYPE2:    PUSH    D    ;SAVE VALUE
  390.     INX    H    ;GET ADDRESS OF WANTED BYTE INTO DE
  391.     MOV    E,M
  392.     INX    H
  393.     MOV    D,M
  394.     INX    H    ;UPDATE AND SAVE PC
  395.     SHLD    PGMCTR
  396.     XCHG        ;GET ADDRESS INTO HL
  397.     POP    D    ;GET VALUE BACK
  398.     MOV    M,E    ;PUT BYTE WHER IT BELONGS
  399.     POP    PSW
  400.     POP    H
  401.     RET
  402. *
  403. * TYPE IS EITHER 1 OR 0
  404. *
  405. OLESS2:    ORA    A    ;SET PARITY
  406.     JPE    OTYPE0
  407. * TYPE 1 IS AN 8 BIT CONSTANT (ILLEGAL)
  408. OTYPE1:    CALL    NOCONS
  409.     INX    H
  410.     INX    H
  411.     SHLD    PGMCTR
  412.     POP    PSW
  413.     POP    H
  414.     RET
  415. OTYPE0:    CALL    NOCONS
  416.     INX    H
  417.     SHLD    PGMCTR
  418.     POP    PSW
  419.     POP    H
  420.     RET
  421. *THIS ROUTINE HANDLES ILLEGAL "OUTS" (I.E. TO CONSTANTS)
  422. NOCONS:    PUSH    H
  423.     MOV    A,M    ;GET FRESH COPY
  424.     ANI    TYPBITS
  425.     RLC    ! RLC    ! RLC    ;GET TYPE CODE # INTO LO BITS OF A
  426.     PUSH    PSW    ;SAVE IT
  427.     CALL    DISPHL    ;PRINT THE PROGRAM COUNTER
  428.     LXI    H,PCEQ
  429.     CALL    PRINT    ;PRINT "=PC"
  430.     LXI    H,INMESS1
  431.     CALL    PRINT    ;PRINT "PARM TYPE"
  432.     POP    PSW    ;RETRIEVE PARM TYPE
  433.     CALL    HEXPRT    ;PRINT THE PARM TYPE #
  434.     LXI    H,CONMES
  435.     CALL    PRINT    ;PRINT "IS A CONSTANT...ILLEGAL"
  436.     XCHG
  437.     CALL    DISPHL    ;DISPLAY VALUE WANTING STORAGE
  438.     XCHG
  439.     LXI    H,CONMES2
  440.     CALL    PRINT
  441.     CALL    CRLF
  442.     POP    H
  443.     RET
  444. CONMES    DB    ' IS A CONSTANT.  ATTEMPT TO STORE VALUE ',STOP
  445. CONMES2    DB    ' ABORTED',STOP
  446. * THIS ROUTINE TAKES A "STANDARD" OUTPUT PORT NUMBER IN A AND 
  447. * WRITES THE BYTE IN E TO THE GIVEN DEVICE
  448. OUTPORT: MOV    L,A    ;MMAKE HL A DISPLACEMENT VALUE
  449.     MVI    H,0
  450.     DAD    H
  451.     MOV    A,E    ;GET OUTPUT VALUE INTO A
  452.     LXI    D,OPORTAB ;GET BASE ADDRESS
  453.     DAD    D    ;ADD BASE TO DISP
  454.     MOV    E,M    ;GGET ROUTINE @ FROM TABLE
  455.     INX    H
  456.     MOV    D,M
  457.     XCHG        ;INTO HL
  458.     PCHL        ;JUMP TO PROPER ROUTINE
  459. OPORTAB    EQU    $
  460.     DW    NOPORT,CO,NOPORT,NOPORT
  461.     DW    NOPORT,NOPORT,NOPORT,NOPORT
  462.     DW    SPEAKR1,NOPORT,SPEAKR2,NOPORT
  463.     DW    NOPORT,NOPORT,NOPORT,LIGHTS
  464.     DW    NOPORT,NOPORT,NOPORT,NOPORT
  465.     DW    NOPORT,NOPORT,NOPORT,NOPORT
  466.     DW    NOPORT,NOPORT,NOPORT,NOPORT
  467.     DW    NOPORT,NOPORT,NOPORT,NOPORT
  468. SPEAKR1: OUT    X1
  469.     RET
  470. SPEAKR2: OUT    X2
  471.     RET
  472. PANEL    EQU    0FFH
  473. LIGHTS:    CMA
  474.     OUT    PANEL
  475.     RET
  476.