home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG008.ARK / MAC4.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  9KB  |  465 lines
  1.     TITLE    MACADPT
  2. ;
  3. ; VERSION 1.2   11 APR 77
  4. ; VERSION 1.3   20 SEP 77
  5. ; VERSION 1.4   17 OCT 77
  6. ;
  7. ; BY JEFFREY W. SHOOK
  8. ; PO BOX 185
  9. ; ROCKY POINT, NY 11778
  10. ;
  11. ; THIS PROGRAM ADAPTS THE TDL MACROASSEMBLER
  12. ; TO WORK UNDER CP/M.
  13. ;
  14. ;***********************************;
  15. ;         CP/M STANDARD EQUATES     ;
  16. ;***********************************;
  17.  
  18. BOOT    EQU    0000H    ;WARM START ADDRESS
  19. TFCB    EQU    005CH    ;DEFAULT FCB ADDRESS
  20. TBUF    EQU    0080H    ;DEFAULT BUFFER ADDRESS
  21. TBASE    EQU    0100H    ;TRANSIENT PROGRAM BASE
  22. CBASE    EQU    2900H    ;CCP BASE ADDRESS
  23. BDOS    EQU    0005H    ;BDOS ENTRY POINT
  24. CONIN    EQU    03E09H    ;CONSOLE INPUT SUBROUTINE
  25. CONOUT    EQU    03E0CH    ;CONSOLE OUTPUT ROUTINE
  26.  
  27. ;***********************************;
  28. ;       CP/M FUNCTION CODES         ;
  29. ;***********************************;
  30.  
  31. SRSET    EQU    00    ;SYSTEM RESET
  32. RCON    EQU    01    ;READ CONSOLE
  33. WCON    EQU    02    ;WRITE CONSOLE
  34. RRDR    EQU    03    ;READ READER
  35. WPUN    EQU    04    ;WRITE PUNCH
  36. WLST    EQU    05    ;WRITE LIST
  37. ISTAT    EQU    07    ;GET IOSTATUS
  38. SSTAT    EQU    08    ;SET IOSTATUS
  39. WCONB    EQU    09    ;WRITE CONSOLE BUFFER
  40. RCONB    EQU    10    ;READ CONSOLE BUFFER
  41. CSTAT    EQU    11    ;CHECK CONSOLE STATUS
  42. LHEAD    EQU    12    ;LIFT DISK HEAD
  43. RSDSK    EQU    13    ;RESET DISK SYSTEM
  44. SDISK    EQU    14    ;SELECT DISK
  45. OPEN    EQU    15    ;OPEN FILE
  46. CLOSE    EQU    16    ;CLOSE FILE
  47. SFRST    EQU    17    ;SEARCH FIRST
  48. SNEXT    EQU    18    ;SEARCH NEXT
  49. FDELT    EQU    19    ;DELETE FILE
  50. READ    EQU    20    ;READ RECORD
  51. WRITE    EQU    21    ;WRITE RECORD
  52. CREATE    EQU    22    ;CREATE FILE
  53. RENAM    EQU    23    ;RENAME FILE
  54. LOGIN    EQU    24    ;GET LOGIN
  55. IDISK    EQU    25    ;GET DISK NUMBER
  56. SDMA    EQU    26    ;SET DMA VECTOR
  57. IALLOC    EQU    27    ;GET ALLOCATION VECTOR
  58. ;
  59. ;
  60. EOF:    EQU    1AH    ; CP/M END OF FILE CHAR
  61. ;
  62. ;
  63.     ORG    100H    ; LET CP/M FIND US
  64.     JMP    MACAD
  65. ;
  66. ;
  67. ; TRANSIENT PROGRAM STORAGE
  68. ; DEFINITIONS
  69. ;
  70. ;
  71. ;
  72. CSTSF:    DS    1    ; CONSOLE STATUS FLAG
  73. PASSP:    DS    2    ; PASS TABLE POINTER
  74. SRCPTR:    DS    2    ; SOURCE BUFFER POINTER
  75. LSTPTR:    DS    2    ; LISTING BUFFER POINTER
  76. HEXPTR:    DS    2    ; HEX OBJECT FILE POINTER
  77. SRCFCB:    DS    36    ; SOURCE FILE CONTROL BLOCK
  78. SRCBUF:    DS    128    ; SOURCE FILE BUFFER
  79. LSTFCB:    DS    36    ; LISTING FILE CONTROL BLOCK
  80. LSTBUF:    DS    128    ; LISTING FILE BUFFER
  81. HEXFCB:    DS    36    ; OBJECT FILE CONTROL BLOCK
  82. HEXBUF:    DS    128    ; OBJECT FILE BUFFER
  83. ;
  84. ;
  85. ;
  86. ;
  87. MACAD:    LXI    SP,MACRX+16EH    ; SET TEMP STACK
  88.     LXI    H,AZM    ; INSERT FILETYPE
  89.     LXI    D,TFCB+9
  90.     LXI    B,3    ; IN TRANSIENT FCB
  91.     CALL    LDIR    ; MOVE FILETYPE
  92.     LXI    D,TFCB; CHECK DIRECTORY
  93.     MVI    C,SFRST    ; TO SEE IF FILE EXISTS
  94.     CALL    BDOS
  95.     CPI    0FFH
  96.     CZ    ERROR
  97.     LXI    H,TFCB    ; MOVE FILE NAME TO SRCFCB
  98.     LXI    D,SRCFCB
  99.     LXI    B,12
  100.     CALL    LDIR    ; MOVE BLOCK
  101.     MVI    C,OPEN    ; OPEN SOURCE FILE
  102.     LXI    D,SRCFCB
  103.     CALL    BDOS
  104.     CPI    0FFH
  105.     CZ    ERROR
  106.     LXI    D,LSTFCB; CREATE LISTING FILE
  107.     LXI    B,PRN
  108.     CALL    MAKEF
  109.     LXI    D,HEXFCB; CREATE OBJECT FILE
  110.     LXI    B,HXR
  111.     CALL    MAKEF
  112.     LXI    H,PASST    ; INITIALZE PASS COUNT
  113.     SHLD    PASSP
  114.     LXI    H,LSTBUF; INITALIZE LISTING POINTER
  115.     SHLD    LSTPTR
  116.     LXI    H,HEXBUF; INITIALIZE HEX POINTER
  117.     SHLD     HEXPTR
  118.     MVI    A,0    ; INITIALIZE CONSOLE STATUS FLAG
  119.     STA    CSTSF
  120.     JMP    MACRX    ; GO ASSEMBLE
  121. ;
  122. ; TABLE OF FILETYPES
  123. ;
  124. AZM:    DB 'AZM'
  125. PRN:    DB 'PRN'
  126. HXR:    DB 'HXR'
  127. ;
  128. ;
  129. ; END OF ASSEMBLY
  130. ;
  131. TRPSIM:    MVI    C,EOF    ; EMPTY LIST BUFFER
  132.     CALL    LOSIM
  133.     JNC    TRPSIM
  134. TRPS1:    CALL    POSIM    ; EMPTY HEX BUFFER
  135.     JNC    TRPS1
  136. CLOSAL: MVI    C,CLOSE    ; CLOSE ALL FILES
  137.      LXI    D,LSTFCB
  138.     CALL    BDOS
  139.     MVI    C,CLOSE
  140.     LXI    D,HEXFCB
  141.     CALL    BDOS
  142.     JMP    BOOT
  143. ;
  144. ;
  145. ;
  146. ; SIMULATE CONSOLE INPUT FOR PASS
  147. ; CONTROL OF ASSEMBLER.
  148. ; PASS 1 = SYMBOL TABLE
  149. ; PASS 2 = LISTING
  150. ; PASS 3 = HEX OBJECT FILE
  151. ;
  152. CISIM:    PUSH    H    ; SAVE ASSEMBLER REGISTERS
  153.     PUSH    D
  154.     PUSH    B
  155.     MVI    A,0    ; SET NEXT RECORD POINTER TO ZERO
  156.     STA    SRCFCB+32
  157.     STA    CSTSF    ; CLEAR CONSOLE STATUS FLAG
  158.     LXI    H,SRCBUF+128
  159.     SHLD    SRCPTR    ; SET SRC PTR TO END OF BUFFER
  160.     POP    B    ; RESTORE ASM REGISTERS
  161.     POP    D
  162.     LHLD    PASSP    ; LOAD POINTER TO PASS #
  163.     MOV    A,M    ; GET PASS
  164.     INX    H
  165.     SHLD    PASSP
  166.     POP    H
  167.     RET
  168. ;
  169. ;
  170. ; TABLE OF PASS NUMBERS
  171. ;
  172. PASST:    DB '1230'
  173. ;
  174. ; CHARACTER INPUT SUBROUTINE
  175. ;
  176. ; CREATE A SOURCE BUFFER AND LOAD
  177. ; IT FROM THE DISK. AT EACH CALL
  178. ; SUPPLY ONE CHARCTER IN A REG.
  179. ; IF BUFFER EMPTY, CALL BDOS TO
  180. ; FILL IT. SET CARRY IF EOF IS
  181. ; FOUND IN FILE.
  182. ;
  183. RISIM:    PUSH    H    ; SAVE ASSM HL,DE
  184.     PUSH    D
  185.     LXI    D,SRCFCB; GET FCB ADDRESS
  186.     LHLD    SRCPTR    ; GET BUFFER POINTER
  187.     CALL    BUFIN    ; READ A BYTE
  188.     SHLD    SRCPTR    ; SAVE BUFFER POINTER
  189.     POP    D    ; RESTORE HL,DE
  190.     POP    H
  191.     CPI    EOF    ; CHECK FOR EOF CHAR
  192.     STC        ; SET EOF FLAG IN CARRY
  193.     RZ
  194.     CMC        ; NOT EOF, ERASE MARK
  195.     RET
  196. ;
  197. ; LIST CHARACTER OUTPUT
  198. ;
  199. ; CREATE AN OUTPUT BUFFER AND
  200. ; PUT EACH CHAR IN UNTIL FULL.
  201. ; THEN WRITE CONTENTS TO DISK
  202. ; FILE AND RESET POINTER.
  203. ;
  204. LOSIM:    PUSH    D
  205.     PUSH    H
  206.     LHLD    LSTPTR
  207.     LXI    D,LSTFCB
  208.     CALL    BUFOUT
  209.     SHLD    LSTPTR
  210.     POP    H
  211.     POP    D
  212.     MOV    A,C
  213.     RET
  214. ;
  215. ;
  216. ; PUNCH CHARACTER OUTPUT
  217. ;
  218. ; SIMILAR TO LIST OUTPUT
  219. ;
  220. POSIM:    PUSH    D
  221.     PUSH    H
  222.     LHLD    HEXPTR
  223.     LXI    D,HEXFCB
  224.     CALL    BUFOUT
  225.     SHLD    HEXPTR
  226.     POP    H
  227.     POP    D
  228.     MOV    A,C
  229.     RET
  230. ;
  231. ;
  232. ; SOURCE BUFFER CONTROL
  233. ;
  234. ; REFILL BUFFER IF EMPTY, PUT NEXT CHARACTER IN A
  235. ;
  236. ; ENTER WITH FCB ADDRESS IN DE, BUFFER POINTER IN HL
  237. ; 
  238. ; SAVES BC, RETURNS WITH CHAR IN A, BUFFER POINTER IN HL
  239. ;
  240. BUFIN:    MOV    A,E    ; COMPUTE END OF BUFFER
  241.     ADI    SRCBUF+128-SRCFCB
  242.     CMP    L
  243.     JNZ    SRCB1
  244.     PUSH    B
  245.     MVI    C,READ
  246.     CALL    REFILL
  247.     ANI    0FEH    ; CHECK FOR GOOD READ
  248.     CPI    0
  249.     POP    B
  250.     CNZ    ERROR
  251. SRCB1:    MOV    A,M
  252.     INX    H
  253.     RET
  254. ;
  255. ;
  256. ; OUTPUT BUFFER CONTROL
  257. ;
  258. ; IF BUFFER FULL, WRITE CONTENTS TO DISK,
  259. ; PUT CHAR FROM C IN BUFFER.
  260. ;
  261. ; ENTER WITH FCB ADDR IN DE, BUFFER PTR IN HL,
  262. ; AND CHAR IN C.
  263. ; RETURN WITH BUFFER PTR IN HL,SAVE BC,SET CARRY AFTER
  264. ; BUFFER REFILL.
  265. ;
  266. BUFOUT:    MOV    A,E    ; COMPUTE END OF BUFFER
  267.     ADI    164
  268.     CMP    L    ; FULL?
  269.     STC        ; CLEAR CARRY
  270.     CMC
  271.     JNZ    BUFOU1    ; NOT FULL, STORE CHAR
  272.     PUSH    B    ; FULL, SAVE CHAR
  273.     MVI    C,WRITE
  274.     CALL    REFILL
  275.     CPI    0    ; GOOD WRITE?
  276.     POP    B
  277.     CNZ    ERROR
  278.     STC        ; MARK REFILL
  279. BUFOU1:    MOV    M,C    ; STORE CHAR IN BUFFER
  280.     INX    H    ; MOVE PTR TO NEXT CHAR
  281.     RET
  282. ;
  283. ;
  284. ; BUFFER I/O ROUTINE
  285. ;
  286. ; ENTER WITH CP/M READ OR WRITE CODE
  287. ; IN BC AND FCB ADDRESS IN DE.
  288. ; RETURN WITH INITIALIZED BUFFER
  289. ; POINTER IN HL.
  290. ;
  291. REFILL:    LXI    H,36    ; CALC START OF BUFFER
  292.     DAD    D
  293.     PUSH    H    ; SAVE START OF BUFFER
  294.     PUSH    D    ; SAVE FCB ADDRESS
  295.     XCHG
  296.     PUSH    B    ; SAVE CP/M CODE
  297.     MVI    C,SDMA
  298.     CALL    BDOS    ; SET DMA ADDRESS
  299.     POP    B    ; GET CP/M CODE
  300.     POP    D    ; GET FCB ADDRESS
  301.     CALL    BDOS    ; READ OR WRITE BUFFER
  302.     POP    H    ; SET PTR TO START OF BUFFER
  303.     RET
  304. ;
  305. ;
  306. ; CREATE AND OPEN A FILE WITH SAME NAME AS DEFAULT FCB
  307. ;
  308. ; ENTER WITH ADDRESS OF FCB IN DE, AND
  309. ; ADDRESS OF FILETYPE STRING IN BC.
  310. ;
  311. MAKEF:    LXI    H,TFCB
  312.     PUSH    D
  313.     PUSH    B
  314.     LXI    B,9
  315.     CALL    LDIR    ; MOVE FILENAME
  316.     POP    H
  317.     LXI    B,3
  318.     CALL    LDIR    ; MOVE FILETYPE
  319.     MVI    C,FDELT
  320.     POP    D
  321.     PUSH    D
  322.     CALL    BDOS    ; DELETE FILE
  323.     MVI    C,CREATE
  324.     POP    D
  325.     PUSH    D
  326.     CALL    BDOS    ; CREATE FILE
  327.     CPI    0FFH
  328.     CZ    ERROR
  329.     MVI    C,OPEN
  330.     POP    D
  331.     PUSH    D
  332.     CALL    BDOS    ; OPEN FILE
  333.     CPI    0FFH
  334.     CZ    ERROR
  335.     POP    D    ; SET NEXT RECORD PTR IN FCB TO ZERO
  336.     LXI    H,33
  337.     DAD    D
  338.     MVI    M,0
  339.     RET
  340. ;
  341. ;
  342. ; BLOCK MOVE (Z-80 LDIR INST)
  343. ;
  344. LDIR:    MOV    A,M
  345.     STAX    D
  346.     INX    H
  347.     INX    D
  348.     DCX    B
  349.     XRA    A
  350.     CMP    C
  351.     JNZ    LDIR
  352.     CMP    B
  353.     JNZ    LDIR
  354.     RET
  355. ;
  356. ; MEMORY SIZE TEST
  357. ;
  358. MEMSIM:    PUSH    H
  359.     LHLD    BDOS+1
  360.     MOV    A,L
  361.     MOV    B,H
  362.     POP    H
  363.     RET
  364. ;
  365. ;
  366. ; CONSOLE STATUS CHECK
  367.  
  368. CSTSIM:    LDA    CSTSF    ; CHECK CONSOLE STATUS
  369.     RET
  370.  
  371. ; IOCHECK
  372. ;
  373. IOSIM:    MVI    A,0A8H
  374.     RET
  375. ;
  376. ;
  377. ; ERROR HANDLER
  378. ;
  379. ERROR:    PUSH    PSW
  380.     LXI    D,ERRMES
  381.     MVI    C,WCONB
  382.     CALL    BDOS    ; WRITE ERROR MESS
  383.     POP    PSW
  384.     POP    H    ; GET ADDRESS OF CALLER
  385.     PUSH    PSW
  386.     CALL    OUTHHL    ; GOTO CP/M AND PRINT IT
  387.     MVI    C,'.'
  388.     CALL    CO
  389.     POP    PSW
  390.     CALL    OUT2H    ; PRINT ERROR TYPE
  391.     JMP    CLOSAL    ; CLEAN UP THE MESS
  392. ;
  393. ERRMES:    DB 'MACROASSEMBLER ERROR $'
  394. ;
  395. ;++++++++++++++++++++++++++++++++++++++++++++++
  396. ;
  397. ; HEXIDECIMAL REGISTER OUTPUT
  398. ;
  399. ; HEXOUT.LIB  -  VERSION 0.2  -  12 SEP 77
  400. ;
  401. ;++++++++++++++++++++++++++++++++++++++++++++++
  402.  
  403. ; FUNCTIONS AVAILABLE:
  404. ;
  405. ;    OUT2H    PRINT 2 HEX DIGITS FROM A
  406. ;    OUTHHL    PRINT HL
  407.  
  408. OUTHHL:    MOV    A,H    ; PRINT HL
  409.     CALL    OUT2H
  410.     MOV    A,L
  411.  
  412. OUT2H:    PUSH    PSW
  413.     CALL    OUTHL
  414.     POP    PSW
  415.     JMP    OUTHR
  416.  
  417. OUTHL:    RRC
  418.     RRC
  419.     RRC
  420.     RRC
  421. OUTHR:    ANI    0FH
  422.     ADI    '0'
  423.     CPI    '9'+1
  424.     JC    OUTHR1
  425.     ADI    '@'-'9'
  426. OUTHR1:    JMP    OUTCH
  427.  
  428. CO:    MOV    A,C    ; CHECK FOR PASS REQUEST
  429.     CPI    '='
  430.     JNZ    CO1
  431.     MVI    A,0FFH    ; SET CONSOLE STATUS
  432.     STA    CSTSF
  433. CO1:    MOV    A,C    ; SIMULATE TDL CO
  434. OUTCH:    PUSH    PSW    ; CONSOLE OUTPUT
  435.     PUSH    B
  436.     PUSH    D
  437.     PUSH    H
  438.     MVI    C,WCON
  439.     MOV    E,A
  440.     CALL    BDOS
  441.     POP    H
  442.     POP    D
  443.     POP    B
  444.     POP    PSW
  445.     RET
  446.  
  447.  
  448. ; NEW MACROASSEMBLER I/O VECTOR TABLE
  449. ; TO OVERWRITE PRESENT ASSEMBLER VECTOR TABLE
  450.  
  451.     ORG    0800H
  452.  
  453. MACRX:    DS    6
  454.     JMP    CISIM
  455.     JMP    RISIM
  456.     JMP    CO
  457.     JMP    POSIM
  458.     JMP    LOSIM
  459.     JMP    CSTSIM
  460.     JMP    IOSIM
  461.     JMP    MEMSIM
  462.     JMP    TRPSIM
  463.  
  464.     END
  465.