home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG008.ARK / DSKDIR.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  17KB  |  845 lines
  1. ;-------------------------------------------------------
  2. ;
  3. ; CP/M DISK DIRECTORY UTILITY
  4. ;
  5. ; VERSION 1.3 - 5 NOV 77
  6. ;
  7. ; WRITTEN IN TLC
  8. ; 
  9. ; COPYRIGHT 1977, BY
  10. ;
  11. ; JEFFREY W. SHOOK
  12. ; P. O. BOX 185
  13. ; ROCKY POINT, NEW YORK
  14. ; 11778
  15. ;
  16. ;---------------------------------------------------
  17.     ORG    100H    ; CP/M STARTS EXECUTION HERE
  18.     JMP    START    ;
  19.     DB 'DSKDIR VERSION 1.1',CR,LF
  20.     DB CR,LF
  21.     DB 'COPYRIGHT 1977',CR,LF
  22.     DB CR,LF
  23.     DB 'JEFFREY W. SHOOK',CR,LF
  24.     DB 'PO BOX 185',CR,LF
  25.     DB 'ROCKY POINT, NEW YORK',CR,LF
  26.     DB '11778',CR,LF,0
  27.             ;
  28.             ; $DECLARE.CONSTANT
  29.             ;
  30. BDOS:    EQU    5    !
  31. CR:    EQU    0DH    !
  32. LF:    EQU    0AH    !
  33.             !
  34.             ; * FILE CONTROL BLOCK OFFSET VALUES
  35.             ;
  36. ENTRYP:    EQU    0    ; ENTRY.TYPE = 0
  37. FILNAM:    EQU    1    ; FILE.NAME = 1
  38. FILTYP:    EQU    9    ; FILE.TYPE = 9
  39. EXTNT:    EQU    12    ; EXTENT = 12
  40. RECCNT:    EQU    15    ; RECORD.COUNT = 15
  41. DSKMAP:    EQU    16    ; DISK.MAP = 16
  42. NXTREC:    EQU    32    ; NEXT.RECORD = 32
  43.             ;
  44. SECSIZ:    EQU    128    ; SECTOR.SIZE(2) = 128
  45. DIRSEC:    EQU    16    ; DIRECT.SECTORS(1) = 16
  46. MAXENT:    EQU    64    ; MAX.ENTRY(1) = 64
  47. FALSE:    EQU    0    ; FALSE(1) = 0
  48. TRUE:    EQU    0FFH    ; TRUE(1) = 0FFH
  49. TFCB:    EQU    05CH    ; TFCB(2) = 05CH
  50. NAMLEN:    EQU    11    ; NAME.LENGTH(1) = 11
  51. ENTLEN:    EQU    32    ; ENTRY.LENGTH(1) = 32
  52.             ;
  53.             ; $DECLARE.LOGICAL
  54.             ;
  55. REDERR:    DS    1    ; READ.ERROR(1)
  56. ENTUSD:    DS    MAXENT    ; ENTRY.USED(MAX.ENTRY)
  57. NAMEOK:    DS    1    ; NAME.OK(1)
  58. SAMNAM:    DS    1    ; SAME.NAME(1)
  59. BLNKNM:    DS    1    ; BLANK.NAME(1)
  60.             ;
  61.             ; $DECLARE.VARIABLE
  62.             ;
  63. ENTRY:    DS    1    ; ENTRY(1)
  64. ENTNUM:    DS    1    ; ENTRY.NUM(1)
  65. ENTPTR:    DS    2    ; ENTRY.POINTER(2)
  66. TENPTR:    DS    2    ; TEMP.ENTRY.PTR(2)
  67. PRONAM:    DS    11    ; PROTO.NAME(11)
  68. CHRCNT:    DS    1    ; CHAR.COUNT(1)
  69.             ; BUFFER(DIRECT.SECTORS * SECTOR.SIZE)
  70. BUFFER:    DS    DIRSEC * SECSIZ
  71. DMADDR:    DS    2    ; DMA.ADDRESS(2)
  72. TRACK:    DS    1    ; TRACK(1)
  73. RECORD:    DS    1    ; RECORD(1)
  74. FILSIZ:    DS    2    ; FILE.SIZE(2)
  75. FILEXT:    DS    2    ; FILE.EXTENTS(2)
  76. TMPENT:    DS    1    ; TEMP.ENTRY(1)
  77. TOTSIZ    DS    2    ; TOTAL.SIZE(2)
  78. TOTEXT:    DS    2    ; TOTAL.EXTENTS(2)
  79. NAMEA:    DS    2    ; NAME.A(2)
  80. NAMEB:    DS    2    ; NAME.B(2)
  81. USDPTR:    DS    2    ; USED.POINTER(2)
  82. LZRO:    DS    1    ; LEAD.ZERO.SUPRESS(1)
  83. STPSAV:    DS    2    ; CP/M.STACK.PTR(2)
  84.     DS    248    ; STACK.AREA(248)
  85. STACK:    DS    2    ; STACK.START(2)
  86.             ;
  87.             ; $DECLARE.END
  88.             ;
  89.             ;--------------------------------------
  90.             ;
  91. START:            ; * DISK DIRECTORY UTILITY
  92.             ;
  93.     LXI    SP,STACK; INITIALIZE.STACK.POINTER
  94.     CALL    GPFNFT    ; GET.PROTOTYPE.FILE.NAME.FROM.TFCB
  95.     CALL    RDFDIB    ; READ.DIRECTORY.FROM.DISK.INTO.BUFFER
  96.     LDA    REDERR    ; IF  READ.ERROR
  97.     CPI    FALSE    !
  98.     JZ    ELSE01    !
  99.     CALL    PREM    ;    PRINT.READ.ERROR.MESSAGE
  100.     JMP    FI01    ; ELSE
  101. ELSE01:            !
  102.     LXI    H,0    ;    TOTAL.SIZE = 0
  103.     SHLD    TOTSIZ    !
  104.     LXI    H,0    ;    TOTAL.EXTENTS = 0
  105.     SHLD    TOTEXT    !
  106.     CALL    IEUF    ;    INITIALIZE.ENTRY.USED.FLAGS
  107.     CALL    PDH    ;    PRINT.DIRECTORY.HEADING
  108.     MVI    A,0    ;    ENTRY = 0
  109.     STA    ENTRY    !
  110. LOOP01:            ;    LOOP
  111.     LXI    D,ENTUSD;    .  IF  (ADDR[ENTRY.USED] + ENTRY) = FALSE
  112.     LXI    H,ENTRY    !
  113.     MOV    L,M    !
  114.     MVI    H,0    !
  115.     DAD    D    !
  116.     MOV    A,M    !
  117.     CPI    FALSE    !
  118.     JNZ    FI02    !
  119.     CALL    CETPN    ;    .  .  COMPARE.ENTRY.TO.PROTOTYPE.NAME
  120.     LXI    H,NAMEOK;    .  .  IF  NAME.OK
  121.     MOV    A,M    !
  122.     CPI    TRUE    !
  123.     JNZ    FI03    !
  124.     CALL    PEWSFN    ;    .  .  .  PROCESS.ENTRYS.WITH.SAME.FILE.NAME
  125.     CALL    PFIL    ;    .  .  .  PRINT.FILE.INFORMATION.LISTING
  126. FI03:            ;    .  .  FI
  127. FI02:            ;    .  FI
  128.     LXI    H,ENTRY    ;    .  ENTRY = ENTRY + 1
  129.     INR    M    !
  130.     LXI    H,ENTRY    ;    .  EXIT.IF  ENTRY >= MAX.ENTRY
  131.     MOV    A,M    !
  132.     CPI    MAXENT    !
  133.     JP    POOL01    !
  134.     JMP    LOOP01    ;    POOL
  135. POOL01:            !
  136.     CALL    PTL    ;    PRINT.TOTALS.LISTING
  137. FI01:            ; FI
  138.     JMP    WBOOT    ; RETURN.TO.CP/M
  139.             ;
  140.             ;
  141.             ;--------------------------------------
  142.             ;
  143. GPFNFT:            ; $ GET.PROTOTYPE.FILE.NAME.FROM.TFCB
  144.             ;
  145.     LXI    H,CHRCNT; CHAR.COUNT = NAME.LENGTH
  146.     MVI    M,NAMLEN!
  147.     LXI    H,PRONAM; NAME.A = ADDR[PROTOTYPE.NAME]
  148.     SHLD    NAMEA    !
  149.             ; NAME.B = TFCB + FILE.NAME
  150.     LXI H,TFCB+FILNAM
  151.     SHLD    NAMEB    !
  152.     LXI    H,BLNKNM; BLANK.NAME = TRUE
  153.     MVI    M,TRUE    !
  154. LOOP02:            ; LOOP
  155.     LHLD    NAMEB    ;    IF  (NAME.B <> " "
  156.     MOV    A,M    !    
  157.     CPI    ' '    !
  158.     JZ    FI09    !
  159.     LXI    H,BLNKNM;       BLANK.NAME = FALSE
  160.     MVI    M,FALSE    !
  161. FI09:            ;    FI
  162.     LHLD    NAMEB    ;    (NAME.A) = (NAME.B)
  163.     MOV    A,M    !
  164.     LHLD    NAMEA    !
  165.     MOV    M,A    !
  166.     LHLD    NAMEA    ;    NAME.A = NAME.A + 1
  167.     INX    H    !
  168.     SHLD    NAMEA    !
  169.     LHLD    NAMEB    ;    NAME.B = NAME.B + 1
  170.     INX    H    !
  171.     SHLD    NAMEB    !
  172.     LXI    H,CHRCNT;    CHAR.COUNT = CHAR.COUNT - 1
  173.     DCR    M    !
  174.     LXI    H,CHRCNT;    EXIT.IF  CHAR.COUNT <= 0
  175.     MOV    A,M    !
  176.     CPI    0    !
  177.     JZ    POOL02    !
  178.     JMP    LOOP02    ; POOL
  179. POOL02:            !
  180. IF10:    LXI    H,BLNKNM; IF  BLANK.NAME = TRUE
  181.     MOV    A,M
  182.     CPI    TRUE    !
  183.     JNZ    FI10    !
  184.     LXI    H,PRONAM;    NAME.A = PROTOTYPE.NAME
  185.     SHLD    NAMEA    !
  186.     LXI    H,CHRCNT;    CHAR.COUNT = NAME.LENGTH
  187.     MVI    M,NAMLEN!
  188. LOOP07:            ;    LOOP
  189.     LHLD    NAMEA    ;       (NAME.A) = "?"
  190.     MVI    M,'?'    !
  191.     LHLD    NAMEA    ;       NAME.A = NAME.A + 1
  192.     INX    H    !
  193.     SHLD    NAMEA    !
  194.     LXI    H,CHRCNT;       CHAR.COUNT = CHAR.COUNT - 1
  195.     DCR    M    !
  196.     LXI    H,CHRCNT;       EXIT.IF  CHAR.COUNT <= 0
  197.     MOV    A,M    !
  198.     CPI    0    !
  199.     JZ    POOL07    !
  200.     JMP    LOOP07    ;    LOOP
  201. POOL07:            !
  202. FI10:            ; FI
  203.     RET        ; RETURN
  204.             ;
  205.             ;
  206.             ;--------------------------------------
  207.             ;
  208. RDFDIB:            ; $ READ.DIRECTORY.FROM.DISK.INTO.BUFFER
  209.             ;
  210.     LXI    H,TFCB    ; SELECT.DISK.FROM.TFCB.ENTRY
  211.     MOV    A,M    !
  212.     ORA    A    !
  213.     JZ    TXXX    !
  214.     DCR    A    !
  215.     MOV    C,A    !
  216.     MVI    B,0    !
  217.     MVI    A,24    !
  218.     CALL    FBIOS    !
  219. TXXX:    LXI    H,BUFFER; DMA.ADDRESS = ADDR[BUFFER]
  220.     SHLD    DMADDR    !
  221.     LXI    H,TRACK    ; TRACK = 2
  222.     MVI    M,2    !
  223.     LXI    H,RECORD; RECORD = 1
  224.     MVI    M,1    !
  225.     MVI    A,27    ; SET.DISK.TRACK
  226.     LXI    H,TRACK    !
  227.     MOV    C,M    !
  228.     MVI    B,0    !
  229.     CALL    FBIOS    !
  230. LOOP03:            ; LOOP
  231.     MVI    A,33    ;    SET.DMA.ADDRESS
  232.     LHLD    DMADDR    !
  233.     MOV    B,H    !
  234.     MOV    C,L    !
  235.     CALL    FBIOS    !
  236.     LXI    H,RECORD;    SET.NEXT.SECTOR
  237.     MOV    C,M    !
  238.     CALL    RECSEC    !
  239.     MVI    A,30    !
  240.     CALL    FBIOS    !
  241.     MVI    A,36    ;    READ.ONE.RECORD
  242.     CALL    FBIOS    !
  243.     CPI    FALSE    ;    SET.READ.ERROR.FLAG
  244.     JZ    RDFDI1    !
  245.     MVI    A,TRUE    !
  246. RDFDI1:    LXI    H,REDERR!
  247.     MOV    M,A    !
  248.     LXI    H,REDERR;    EXIT.IF  READ.ERROR
  249.     MOV    A,M    !
  250.     CPI    TRUE    !
  251.     JZ    POOL03    !
  252.     LXI    D,SECSIZ;    DMA.ADDRESS = DMA.ADDRESS + SECTOR.SIZE
  253.     LHLD    DMADDR    !
  254.     DAD    D    !
  255.     SHLD    DMADDR    !
  256.     LXI    H,RECORD;    RECORD = RECORD + 1
  257.     INR    M    !
  258.     LXI    H,RECORD;    EXIT.IF  RECORD > DIRECT.SECTORS
  259.     MOV    A,M    !
  260.     CPI    DIRSEC+1!
  261.     JP    POOL03    !
  262.     JMP    LOOP03    ; POOL
  263. POOL03:            !
  264.     RET        ; RETURN
  265.             ;
  266.             ;
  267.             ;--------------------------------------
  268.             ;
  269. PREM:            ; $ PRINT.READ.ERROR.MESSAGE
  270.             ;
  271.     RET        ; RETURN
  272.             ;
  273.             ;
  274.             ;--------------------------------------
  275.             ;
  276. IEUF:            ; $ INITIALIZE.ENTRY.USED.FLAGS
  277.             ;
  278.     LXI    H,ENTNUM; ENTRY.NUM = 0
  279.     MVI    M,0    !
  280.     LXI    H,BUFFER; ENTRY.PTR = ADDR[BUFFER]
  281.     SHLD    ENTPTR    !
  282. LOOP04:            ; LOOP
  283.     LHLD    ENTPTR;    IF  (ENTRY.PTR) = 0
  284.     MOV    A,M    !
  285.     CPI    0    !
  286.     JNZ    ELSE04    !
  287.     LXI    H,ENTNUM;       (ADDR[ENTRY.USED] + ENTRY.NUM) = FALSE
  288.     MOV    E,M    !
  289.     MVI    D,0    !
  290.     LXI    H,ENTUSD!
  291.     DAD    D    !
  292.     MVI    M,FALSE    !
  293.     JMP    FI04    ;    ELSE
  294. ELSE04:            !
  295.     LXI    H,ENTNUM;       (ADDR[ENTRY.USED] + ENTRY.NUM) = TRUE
  296.     MOV    E,M    !
  297.     MVI    D,0    !
  298.     LXI    H,ENTUSD!
  299.     DAD    D    !
  300.     MVI    M,TRUE    !
  301. FI04:            ;    FI
  302.     LXI    H,ENTNUM;    ENTRY.NUM = ENTRY.NUM + 1
  303.     INR    M    !
  304.     LXI    D,ENTLEN;    ENTRY.PTR = ENTRY.PTR + ENTRY.LENGTH
  305.     LHLD    ENTPTR    !
  306.     DAD    D    !
  307.     SHLD    ENTPTR    !
  308.     LXI    H,ENTNUM;    EXIT.IF  ENTRY.NUM >= MAX.ENTRY
  309.     MOV    A,M    !
  310.     CPI    MAXENT    !
  311.     JP    POOL04    !
  312.     JMP    LOOP04    ; POOL
  313. POOL04:            !
  314.     RET        ; RETURN
  315.             ;
  316.             ;
  317.             ;
  318.             ;--------------------------------------
  319.             ;
  320. PDH:            ; PRINT.DIRECTORY.HEADING
  321.             ;
  322.     MVI    C,9    ; PRINT "FILE.NAME     SIZE  SECTORS   EXTS"
  323.     LXI    D,MSG1    !
  324.     CALL    BDOS    !
  325.     RET        ; RETURN
  326. MSG1:    DB 'FILE.NAME       BYTES  SCTRS   EXTS'
  327.     DB 0DH,0AH,0DH,0AH,'$'
  328.             ;
  329.             ;
  330.             ;--------------------------------------
  331.             ;
  332. CETPN:            ; $ COMPARE.ENTRY.TO.PROTOTYPE.NAME
  333.             ;
  334.     LXI    H,PRONAM; NAME.A = ADDR[PROTO.NAME]
  335.     SHLD    NAMEA    !
  336.     LDA    ENTRY    ; NAME.B = ADDR[BUFFER] + ENTRY.LENGTH * ENTRY + FILE.NAME
  337.     LXI    D,ENTLEN!
  338.     CALL    MULT8    !
  339.     LXI    D,BUFFER+FILNAM!
  340.     DAD    D
  341.     SHLD    NAMEB    !
  342.     CALL    CFN    ; COMPARE.FILE.NAMES
  343.     RET        ; RETURN
  344.             ;
  345.             ;
  346.             ;--------------------------------------
  347.             ;
  348. CTNTEN:            ; $ COMPARE.TEMP.NAME.TO.ENTRY.NAME
  349.             ;
  350.     LDA    TMPENT    ; NAME.A = ADDR[BUFFER] + ENTRY.LENGTH * TEMP.ENTRY + FILE.NAME
  351.     LXI    D,ENTLEN!
  352.     CALL    MULT8    !
  353.     LXI    D,BUFFER+FILNAM!
  354.     DAD    D        
  355.     SHLD    NAMEA
  356.     LDA    ENTRY    ; NAME.B = ADDR[BUFFER] + ENTRY.LENGTH * ENTRY + FILE.NAME
  357.     LXI    D,ENTLEN!
  358.     CALL    MULT8    !
  359.     LXI    D,BUFFER+FILNAM!
  360.     DAD    D
  361.     SHLD    NAMEB    !
  362.     CALL    CFN    ; COMPARE.FILE.NAMES
  363.     RET        ; RETURN
  364.             ;
  365.             ;
  366.             ;--------------------------------------
  367.             ;
  368. CFN:            ; $ COMPARE.FILE.NAMES
  369.             ;
  370.     LXI    H,CHRCNT; CHAR.COUNT = NAME.LENGTH
  371.     MVI    M,NAMLEN!
  372.     LXI    H,NAMEOK; NAME.OK = TRUE
  373.     MVI    M,TRUE    !
  374. LOOP05:            ; LOOP
  375.     LHLD    NAMEA    ;    IF  (NAME.A) <> "?"
  376.     MOV    A,M    !
  377.     CPI    '?'    !
  378.     JZ    FI05    !
  379.     LHLD    NAMEA    ;    .  IF  (NAME.A) <> (NAME.B)
  380.     MOV    A,M    !
  381.     LHLD    NAMEB    !
  382.     CMP    M    !
  383.     NOP
  384.     JZ    FI06    !
  385.     LXI    H,NAMEOK;    .  .  NAME.OK = FALSE
  386.     MVI    M,FALSE    !
  387. FI06:            ;    .  FI
  388. LXI    H,NAMEOK;    .  EXIT.IF  NAME.OK = FALSE
  389.     MOV    A,M    !
  390.     CPI    FALSE    !
  391.     JZ    POOL05    !
  392. FI05:    ;    FI
  393.     LXI    H,CHRCNT;    CHAR.COUNT = CHAR.COUNT - 1
  394.     DCR    M    !
  395.     LDA    CHRCNT    ;    EXIT.IF  CHAR.COUNT = 0
  396.     CPI    0    !
  397.     JZ    POOL05    !
  398.     LHLD    NAMEA    ;    NAME.A = NAME.A + 1
  399.     INX    H    !
  400.     SHLD    NAMEA    !
  401.     LHLD    NAMEB    ;    NAME.B = NAME.B + 1
  402.     INX    H    !
  403.     SHLD    NAMEB    !
  404.     JMP    LOOP05    ; POOL
  405. POOL05:            !
  406.     RET        ; RETURN
  407.             ;
  408.             ;
  409.             ;--------------------------------------
  410.             ;
  411. PEWSFN:            ; $ PROCESS.ENTRYS.WITH.SAME.FILE.NAME
  412.             ;
  413.     LXI    H,0    ; FILE.SIZE = 0
  414.     SHLD    FILSIZ    !
  415.     LXI    H,0    ; FILE.EXTENTS = 0
  416.     SHLD    FILEXT    !
  417.     LDA    ENTRY    ; TEMP.ENTRY = ENTRY
  418.     STA    TMPENT    !
  419.     LDA    ENTRY    ; ENTRY.POINTER = ADDR[BUFFER] + ENTRY * ENTRY.LENGTH
  420.     LXI    D,ENTLEN!
  421.     CALL    MULT8    !
  422.     LXI    D,BUFFER
  423.     DAD    D    !
  424.     SHLD    ENTPTR    !
  425.     LHLD    ENTPTR    ; TEMP.ENTRY.PTR = ENTRY.POINTER
  426.     SHLD    TENPTR    !
  427.     LXI    H,ENTRY; USED.POINTER = ADDR[ENTRY.USED] + ENTRY
  428.     MOV    L,M    !
  429.     MVI    H,0    !
  430.     LXI    D,ENTUSD!
  431.     DAD    D    !
  432.     SHLD    USDPTR    !
  433. LOOP06:            ; LOOP
  434.     LHLD    USDPTR    ;    IF  (USED.POINTER) = FALSE
  435.     MOV    A,M    !
  436.     CPI    FALSE    !
  437.     JNZ    FI07    !
  438.     CALL    CTNTEN    ;    .  COMPARE.TEMP.NAME.TO.ENTRY.NAME
  439.     LDA    NAMEOK    ;    .  IF  NAME.OK
  440.     CPI    TRUE    !
  441.     JNZ    FI08    !
  442.     LXI    D,RECCNT;    .  .  FILE.SIZE = FILE.SIZE + (TEMP.ENTRY.PTR + RECORD.COUNT)
  443.     LHLD    ENTPTR    !
  444.     DAD    D    !
  445.     MOV    E,M    !
  446.     MVI    D,0    !
  447.     LHLD    FILSIZ    !
  448.     DAD    D    !
  449.     SHLD    FILSIZ    !
  450.     LHLD    FILEXT    ;    .  .  FILE.EXTENTS = FILE.EXTENTS + 1
  451.     INX    H    !
  452.     SHLD    FILEXT    !
  453.     LHLD    USDPTR;    .  .  (USED.POINTER) = TRUE
  454.     MVI    M,TRUE    !
  455. FI08:            ;    .  FI
  456. FI07:            ;    FI
  457.     LXI    H,TMPENT;    TEMP.ENTRY = TEMP.ENTRY + 1
  458.     INR    M    !
  459.     LXI    H,TMPENT;    EXIT.IF  TEMP.ENTRY >= MAX.ENTRY
  460.     MOV    A,M    !
  461.     CPI    MAXENT    !
  462.     JP    POOL06    !
  463.     LXI    D,ENTLEN;    TEMP.ENTRY.PTR = TEMP.ENTRY.PTR + ENTRY.LENGTH
  464.     LHLD    TENPTR    !
  465.     DAD    D    !
  466.     SHLD    TENPTR    !
  467.     LHLD    USDPTR    ;    USED.POINTER = USED.POINTER + 1
  468.     INX    H    !
  469.     SHLD    USDPTR    !
  470.     JMP    LOOP06    ; POOL
  471. POOL06:            !
  472.     LHLD    FILSIZ    ; TOTAL.SIZE = TOTAL.SIZE + FILE.SIZE
  473.     XCHG        !
  474.     LHLD    TOTSIZ    !
  475.     DAD    D    !
  476.     SHLD    TOTSIZ    !
  477.     LHLD    FILEXT    ; TOTAL.EXTENTS = TOTAL.EXTENTS + FILE.EXTENTS
  478.     XCHG        !
  479.     LHLD    TOTEXT    !
  480.     DAD    D    !
  481.     SHLD    TOTEXT    !
  482.     RET        ; RETURN
  483.             ;
  484.             ;
  485.             ;
  486.             ;--------------------------------------
  487.             ;
  488. PFIL:            ; $ PRINT.FILE.INFORMATION.LISTING
  489.             ;
  490.     LHLD    ENTPTR    ; PRINT  FILE.NAME(11)
  491.     INX    H    !
  492.     MVI    B,8    !
  493.     CALL    PRNC    !
  494.     CALL    PRS    !
  495.     MVI    B,3    !
  496.     CALL    PRNC    !
  497.     CALL    PRS    !
  498.     CALL    PRS    !
  499.     CALL    PRS    !
  500.     LXI    H,DATA    ; PRINT FILE.SIZE * SECTOR.SIZE
  501.     CALL    CLEAR    !
  502.     LHLD    FILSIZ    !
  503.     SHLD    DATA+1    !
  504.     LXI    H,DATA    !
  505.     CALL    SHIFTR    !
  506.     CALL    BINBCD    !
  507.     LXI    H,RESULT+2
  508.     CALL    PR6HXD    !
  509.     CALL    PRS    !
  510.     CALL    PRS    !
  511.     CALL    PRS    !
  512.     LXI    H,DATA    ; PRINT  FILE.SIZE
  513.     CALL    CLEAR    !
  514.     LHLD    FILSIZ    !
  515.     SHLD    DATA    !
  516.     CALL    BINBCD    !
  517.     LHLD    RESULT    !
  518.     CALL    PRADDR    !
  519.     CALL    PRS    !
  520.     CALL    PRS    !
  521.     CALL    PRS    !
  522.     LXI    H,DATA    ; PRINT  FILE.EXTENTS
  523.     CALL    CLEAR    !
  524.     LHLD    FILEXT    !
  525.     SHLD    DATA    !
  526.     CALL    BINBCD    !
  527.     LHLD    RESULT    !
  528.     CALL    PRADDR    !
  529.     CALL    PRCRLF    !
  530.     RET        ; RETURN
  531.             ;
  532.             ;
  533.             ;
  534.             ;--------------------------------------
  535.             ;
  536. PTL:            ; $ PRINT.TOTALS.LISTING
  537.             ;
  538.     CALL    PRCRLF    !
  539.     MVI    C,9    ;PRINT "TOTAL.SIZE      "
  540.     LXI    D,MSG2    !
  541.     CALL    BDOS    !
  542.     LXI    H,DATA    ; PRINT  TOTAL.SIZE * SECTOR.SIZE
  543.     CALL    CLEAR    !
  544.     LHLD    TOTSIZ    !
  545.     SHLD    DATA+1    !
  546.     LXI    H,DATA    !
  547.     CALL    SHIFTR    !
  548.     CALL    BINBCD    !
  549.     LXI    H,RESULT+2
  550.     CALL    PR6HXD    !
  551.     CALL    PRS    !
  552.     CALL    PRS    !
  553.     CALL    PRS    !
  554.     LXI    H,DATA    ; PRINT TOTAL.SIZE
  555.     CALL    CLEAR    !
  556.     LHLD    TOTSIZ    !
  557.     SHLD    DATA    !
  558.     CALL    BINBCD    !
  559.     LHLD    RESULT    !
  560.     CALL    PRADDR    !
  561.     CALL    PRS    !
  562.     CALL    PRS    !
  563.     CALL    PRS    !
  564.     LXI    H,DATA    ; PRINT  TOTAL.EXTENTS
  565.     LHLD    TOTEXT    !
  566.     SHLD    DATA    !
  567.     CALL    BINBCD    !
  568.     LHLD    RESULT    !
  569.     CALL    PRADDR    !
  570.     CALL    PRCRLF    !
  571.     RET        ; RETURN
  572. MSG2:    DB 'TOTAL.SIZE     ','$'
  573.             ;
  574.             ;
  575. ;-----------------------------------------------
  576. ;
  577. ; BINARY TO BCD CONVERSION
  578. ;
  579. ;-----------------------------------------------
  580.  
  581. ; ASSUMES THREE REGISTERS IN MEMORY:
  582. ; 1) DATA - CONTAINS UNSIGNED BINARY NUMBER
  583. ; 2) PARTIAL - PACKED BCD NUMBER = 2**N
  584. ; 3) RESULT - PACKED BCD NUMBER = SUM OF PARTIAL VALUES
  585.  
  586. NBYTES: EQU    3    ; REGISTER LENGTH
  587. NBITS:    EQU    NBYTES*8; NUMBER OF BITS CONVERTED
  588.  
  589.  
  590. BITCNT:    DS    1    ; BITS REMAINING TO BE CONVERTED
  591. RESULT:    DS    NBYTES    ; RESULT REGISTER
  592. PARTL:    DS    NBYTES    ; PARTIAL REGISTER
  593. DATA:    DS    NBYTES    ; BINARY DATA REGISTER
  594.  
  595.  
  596. BINBCD:    LXI    H,BITCNT; SET BIT COUNT
  597.     MVI    M,NBITS
  598.     LXI    H,RESULT; CLEAR RESULT REGISTER
  599.     CALL    CLEAR
  600.     LXI    H,PARTL    ; CLEAR PARTIAL SUM REG
  601.     CALL    CLEAR
  602.     LXI    H,PARTL    ; SET PARTIAL = 1
  603.     MVI    M,1
  604. BINBC1:    ORA    A    ; CLEAR CARRY
  605.     LXI    H,DATA    ; SHIFT DATA RIGHT
  606.     CALL    SHIFTR
  607.     JNC    BINBC2    ; SKIP ADD IF BIT WAS 0
  608.     LXI    H,PARTL    ; ADD POWER OF 2 TO RESULT
  609.     LXI    D,RESULT
  610.     CALL    BCDADD
  611. BINBC2:    LXI    H,PARTL    ; DOUBLE PARTIAL
  612.     LXI    D,PARTL
  613.     CALL    BCDADD
  614.     LXI    H,BITCNT; CHECK BIT COUNT
  615.     DCR    M
  616.     JNZ    BINBC1    ; DONE?
  617.     RET
  618.  
  619.  
  620. ; CLEAR A REGISTER
  621. ; ADDR IN HL
  622.  
  623. CLEAR:    MVI    B,NBYTES; CLEAR A REGISTER
  624. CLEAR1:    MVI    M,0
  625.     INX    H
  626.     DCR    B
  627.     JNZ    CLEAR1
  628.     RET
  629.  
  630.  
  631. ; SHIFT RIGHT WITH CARRY
  632. ; ADDR IN HL
  633.  
  634. SHIFTR:    RAL        ; SAVE CARRY IN A
  635.     MVI    B,NBYTES; CALCULATE ADDR OF LAST BYTE
  636.     MOV    E,B
  637.     DCR    E
  638.     MVI    D,0
  639.     DAD    D
  640. SHIFR1:    RAR    ; RESTORE SAVED CARRY
  641.     MOV    A,M
  642.     RAR        ; SHIFT DATA
  643.     MOV    M,A
  644.     RAL        ; SAVE CARRY
  645.     DCX    H    ; MOVE TO NEXT BYTE
  646.     DCR    B    ; CHECK BYTE COUNT
  647.     JNZ    SHIFR1    ; DONE?
  648.     RAR        ; RESTORE CARRY
  649.     RET
  650.  
  651.  
  652. ; BCD ADDITION
  653. ; ADDS REGISTER AT ADDR IN HL
  654. ; TO CONTENTS OF REGISTER AT ADDR DE
  655.  
  656. BCDADD:    MVI    B,NBYTES
  657.     XRA    A    ; CARRY = 0
  658. BCDAD1:    RAR        ; RESTORE CARRY
  659.     LDAX    D
  660.     ADC    M
  661.     DAA
  662.     STAX    D
  663.     RAL        ; SAVE CARRY
  664.     INX    D
  665.     INX    H
  666.     DCR    B
  667.     JNZ    BCDAD1
  668.     RAR        ; RESTORE CARRY
  669.     RET
  670.  
  671. ;***********************************************
  672. ;
  673. ; CONVERT CP/M RECORD NUMBER TO DISK SECTOR
  674. ;
  675. ; ENTER WITH RECORD IN C, AND
  676. ; RETURN WITH SECTOR IN C.
  677. ; DESTROY CONTENTS OF B,HL
  678. ;
  679. ;**********************************************
  680.  
  681. ; COMPUTE TABLE ADDRESS OF SECTOR
  682.  
  683. RECSEC:    LXI    H,SECTBL-1
  684.     MVI    B,0
  685.     DAD    B
  686.     MOV    C,M
  687.     RET
  688.  
  689. ; RECORD TO SECTOR CONVERSION TABLE
  690.  
  691. SECTBL:    DB    1,7,13,19,25,5,11,17
  692.     DB    23,3,9,15,21,2,8,14
  693.     DB    20,26,6,12,18,24,4,10
  694.     DB    16,22
  695.  
  696. ;******************************************
  697. ;*  HEXIDECIMAL CHARACTER OUTPUT LIBRARY  *
  698. ;******************************************
  699. ;
  700. ; VERSION 0.2   19 APR 77
  701. ;
  702. PRHL:    MOV    A,C
  703.     RAR
  704.     RAR
  705.     RAR
  706.     RAR
  707.     JMP    PRHR1
  708. PRHR:    MOV    A,C
  709. PRHR1:    ANI    0FH
  710.     ADI    '0'
  711.     CPI    '9'+1
  712.     JM    PRA
  713.     ADI    '@'-'9'
  714. PRA:    PUSH    B
  715.     MOV    B,A
  716.     LDA    LZRO
  717.     ORA    A
  718.     JZ    PRA1
  719.     MOV    A,B
  720.     CPI    '0'
  721.     JNZ    PRA1
  722.     MVI    B,20H
  723.     JMP    PRA2
  724. PRA1:    MVI    A,0
  725.     STA    LZRO
  726. PRA2:    MOV    A,B
  727.     POP    B
  728.     PUSH H ! PUSH D ! PUSH B
  729.     MOV    E,A
  730.     MVI    C,2
  731.     CALL    BDOS
  732.     POP B ! POP D  ! POP H
  733.     RET
  734. ;
  735. ;
  736. PR2HX:    MOV    C,M
  737.     INX    H
  738. PR2H:    CALL    PRHL
  739.     JMP    PRHR
  740. ;
  741. ;
  742. PR2HXS:    CALL    PR2HX
  743. PRS:    MVI    A,' '
  744.     JMP    PRA
  745. ;
  746. ;
  747. PRADDR:    MVI    A,TRUE
  748.     STA    LZRO
  749.     MOV    C,H
  750.     CALL    PR2H
  751.     MOV    C,L
  752.     JMP    PR2H
  753. ;
  754. ;
  755. PR6HXD:    MVI    A,TRUE
  756.     STA    LZRO
  757.     CALL    PR2HXD
  758.     CALL    PR2HXD
  759.     CALL    PR2HXD
  760.     RET
  761.  
  762. PR2HXD:    MOV    C,M
  763.     DCX    H
  764.     JMP    PR2H
  765.  
  766. PRNC:    MOV    A,M
  767.     CALL    PRA
  768.     INX    H
  769.     DCR    B
  770.     JNZ    PRNC
  771.     RET
  772.  
  773. PRCRLF:    PUSH H ! PUSH D ! PUSH B
  774.     LXI    D,CRSTRG
  775.     MVI    C,9
  776.     CALL    BDOS
  777.     POP B ! POP D ! POP H
  778.     RET
  779. ;
  780. ;
  781. CRSTRG:    DB    0DH,0AH,0,0,'$'
  782. ;
  783. ;******************************************
  784. ;----------------------------------------------
  785. ;
  786. ; UNSIGNED 8 BIT MULTIPLY
  787. ;
  788. ;-----------------------------------------------
  789.  
  790. ; ENTER WITH:
  791. ;    MULTIPLIER IN A
  792. ;    MULTIPLICAND IN DE
  793. ; RETURN WITH:
  794. ;    PRODUCT IN HL
  795. ; DESTROYS:
  796. ;    A, DE
  797.  
  798. MULT8:    LXI    H,0    ; CLEAR PARTIAL PRODUCT
  799. MULT1:    ORA    A    ; CLEAR CARRY
  800.     RAR        ; SHIFT MULTPLR RIGHT
  801.     JNC    MULT2    ; SKIP IF ZERO
  802.     DAD    D    ; ADD MPLCND TO PARTIAL
  803. MULT2:    XCHG        ;
  804.     DAD    H    ; SHIFT MLTPCND LEFT
  805.     XCHG        ;
  806.     ORA    A    ; SET FLAGS
  807.     JNZ    MULT1    ; LOOP UNTIL DONE
  808.     RET        ;
  809. ;******************************************
  810. ;* BIOS FUNCTION CALLING PROCEDURE        *
  811. ;******************************************
  812. ;
  813. ; THIS PROCEDURE ALLOWS CALLING BIOS
  814. ; FUNCTIONS WITHOUT PRIOR KNOWLEDGE OF THE
  815. ; SIZE OF THE CP/M SYSTEM.
  816. ;
  817. ; CALL FBIOS WITH THE FUNCTION IN A
  818. ; AND THE PARAMETER IN BC.
  819. ;
  820. FBIOS:    MOV    E,A    ; GET ENTRY OFFSET
  821.     MVI    D,0    ; IN DE
  822.     LHLD    1    ; GET BIOS ENTRY + 3
  823.     DAD    D    ; ADD ENTRY TO OFFSET
  824.     PCHL        ; JUMP TO BIOS
  825. ;
  826. ; BIOS ENTRY CODE NAMES
  827. ;
  828. WBOOT:    EQU    0    ; WARM BOOT
  829. CONST:    EQU    3    ; TEST CONSOLE STATUS
  830. CONIN:    EQU    6    ; CONSOLE INPUT
  831. CONOUT:    EQU    9    ; CONSOLE OUTPUT
  832. LIST:    EQU    12    ; LIST OUTPUT
  833. PUNCH:    EQU    15    ; PUNCH OUTPUT
  834. READER:    EQU    18    ; READER INPUT
  835. HOME:    EQU    21    ; HEAD TO TRACK 0
  836. SELDSK:    EQU    24    ; SELECT DRIVE
  837. SETTRK:    EQU    27    ; SET NEXT TRACK
  838. SETSEC:    EQU    30    ; SET NEXT SECTOR
  839. SETDMA:    EQU    33    ; SET DMA ADDRESS
  840. READS:    EQU    36    ; READ SECTOR
  841. WRITES:    EQU    39    ; WRITE SECTOR
  842. ;
  843. ;
  844.     END        ; END
  845.