10 REM  ********************************
20 REM  *   INSTALLATION PROGRAM FOR   *
30 REM  *         AUTOBOOT 128         *
40 REM  *                              *
50 REM  * CDU TECHNO INFO - J.R. FINCH *
60 REM  ********************************
70 :
100 POKE53280,14:POKE53281,6:PRINT"[147]INSERT CDU DISK (VOLUME 3, NUMBER 11)"
110 PRINT"INTO DRIVE WITH DEVICE NUMBER EIGHT,"
120 PRINT"AND THEN PRESS 'RETURN' TO CONTINUE.":POKE198,0
130 GETA$:IFA$<>CHR$(13)THEN130
140 PRINT"SEARCHING FOR AUTOBOOT FILE...":OPEN15,8,15,"I0":OPEN2,8,0,"AUTOBOOT 128"
150 INPUT#15,E,E$:IFETHENPRINT"DISK ERROR:":PRINTE$:CLOSE2:CLOSE15:END
160 PRINT"[145]AUTOBOOT FILE FOUND. READING INFO...":GET#2,A$,A$:FORI=0TO253:GET#2,A$
170 POKE49152+I,ASC(A$+CHR$(0)):NEXT:CLOSE2:INPUT#15,E,E$
180 IFETHENPRINT"DISK ERROR:":PRINTE$:CLOSE15:END
190 PRINT"[145]ALL INFORMATION READ.                  "
200 PRINT"PLEASE INSERT DISK ONTO WHICH YOU WANT"
210 PRINT"THE AUTOBOOT BLOCK TO BE WRITTEN, AND"
220 PRINT"PRESS 'RETURN' TO CHECK BLOCK STATUS.":POKE198,0
230 GETA$:IFA$<>CHR$(13)THEN230
240 PRINT#15,"I0":PRINT#15,"B-A:8 1 0":INPUT#15,E,E$:IFE=0THEN280
250 IFE<>65THENPRINT"DISK ERROR:":PRINTE$:CLOSE15:END
260 PRINT"SORRY, CAN'T CONTINUE!!":PRINT"THE AUTOBOOT BLOCK ON THIS DISK HAS"
270 PRINT"ALREADY BEEN WRITTEN ON BY ANOTHER":PRINT"PROGRAM!!!":CLOSE15:END
280 PRINT"AUTOBOOT BLOCK IS FREE. WRITING INFO...":OPEN8,8,8,"#"
290 PRINT#15,"B-P:8 0":FORI=0TO253:PRINT#8,CHR$(PEEK(49152+I));:NEXT:CLOSE8
300 INPUT#15,E,E$:IFE<>0THENPRINT"DISK ERROR:":PRINTE$:CLOSE15:END
310 PRINT"SUCCESS!!![146] - BUT DON'T VALIDATE THE DISK"
320 PRINT"IF YOU DO THEN THE D.O.S. WILL THINK"
330 PRINT"THAT THE AUTOBOOT BLOCK CAN BE USED AND"
340 PRINT"IT MAY WRITE ANOTHER FILE OVER THE INFO!":END