10 REM ENIAC=================C64/C128
20 REM (P) COMMODORE DISC
30 REM ==============================
40 REM (C) BY CHRISTIAN NIEDERLE V3.5
50 REM (V) A.M.                  V2.0
60 REM
70 REM BASIC V2.0/V7.0
80 REM C64/C128
90 REM ==============================
100 GOSUB 1090:PRINTCHR$(147);
110 DIM A$(40):DIM B$(40)
120 DIM KL(40):R=1:REM *** R KANN WERTE VON 0 BIS 5 ANNEHMEN
130 GOSUB 910
140 XK=5:YK=10:GOSUB1061:PRINT"TEXT CODIEREN.........(C)";
150 XK=5:YK=15:GOSUB1061:PRINT"TEXT ENTSCHLUESSELN...(E)";
160 XK=5:YK=20:GOSUB1061:PRINT"ENIAC SPIELEN.........(S)";
170 GETC$:IFC$=""THEN170
180 IFC$="C"THEN200
181 IFC$="E"THEN390
182 IFC$="S"THEN540
190 GOTO 170
200 PRINTCHR$(147);
210 GOSUB 910
220 X=0:PRINT:PRINT:INPUT"EIGENER CODE(1-15 OD.NUR RETURN)";X
230 IF X>0 THEN GOTO 250
240 X=INT(RND(1)*11)+1
250 PRINT:PRINT
260 FOR I=0 TO 39
270 GETA$(I):IFA$(I)=""THEN270
280 IF A$(I)=CHR$(13) THEN A=I-1:I=39:GOTO 320
290 T=ASC(A$(I))
300 B$(I)=CHR$(T+X+R):A=I
310 XK=I:YK=15:GOSUB1061:PRINTB$(I);
320 NEXT I
330 X$=STR$(X):XK=10:YK=20:GOSUB1061:PRINTX$;
340 XK=0:YK=22:GOSUB1061:PRINT"TEXT AUF DRUCKER(J/N)";
345 GETS$:IFS$=""THEN345
350 IF S$="J" THEN GOSUB 970
360 XK=0:YK=24:GOSUB1061:PRINT"ZURUECK ZUM MENUE(J/N)";
365 GETS$:IFS$=""THEN365
370 IF S$="J" THEN RUN
380 GOTO 200
390 PRINTCHR$(147);
400 GOSUB 910
410 PRINT:PRINT:INPUT"GEBE DEN CODE EIN";X
420 FOR I=0 TO 39
430 GETB$(I):IFB$(I)=""THEN430
440 IF B$(I)=CHR$(13) THEN A=I-1:I=39:GOTO 480
450 T=ASC(B$(I))
460 A$(I)=CHR$(T-X-R)
470 XK=I:YK=15:GOSUB1061:PRINTA$(I);
480 NEXT I
490 PRINT:PRINT:PRINT"SOLL TEXT AUF DRUCKER(J/N)"
495 GETS$:IFS$=""THEN495
500 IF S$="J" THEN GOSUB 970
510 PRINT:PRINT:PRINT"ZURUECK ZU MENUE(J/N)"
515 GETS$:IFS$=""THEN515
520 IF S$="J" THENRUN
530 GOTO 390
540 PRINTCHR$(147);
550 GOSUB 910
560 X=INT(RND(1)*11)+1
570 REM *** CODIEREN ***
580 FOR I=0 TO 39
590 GETA$(I):IFA$(I)=""THEN590
600 IF A$(I)=CHR$(13) THEN A=I:I=39:GOTO 640
610 T=ASC(A$(I))
620 B$(I)=CHR$(T+X+R):A=I
630 XK=I:YK=10:GOSUB1061:PRINTB$(I);
640 NEXT I
650 PRINTCHR$(147);
660 GOSUB 910
670 FOR I=0 TO A-1
680 XK=I:YK=15:GOSUB1061:PRINT".";
690 NEXT I
700 XK=0:YK=24:GOSUB1061:PRINT"OK!";
701 GETD$:IFD$=""THEN701
702 L=L+1:L$=STR$(L):XK=15:YK=24:GOSUB1061:PRINTL$;
720 Y=A+3:Y$=STR$(Y):XK=10:YK=24:GOSUB1061:PRINTY$;
730 FOR I=0 TO A
740 GOSUB 810
750 NEXT I
760 IF L=Y THEN GOTO 860
770 IF SR=1 THEN XK=0:YK=20:GOSUB1061:PRINT"GRATULIERE, DU HAST DEN CODE GEKNACKT!";
790 IF SR=1 THEN 901
800 GOTO 700
810 XK=0:YK=24:GOSUB1061:PRINT"   ";
820 IF A$(I)=D$ THEN XK=I:YK=15:GOSUB1061:PRINTD$;:KL(I)=KL(I)+1
830 IF KL(I)=1 AND A$(I)=D$ THEN U=U+1
840 IF U=A THEN SR=1:I=A
850 RETURN
860 XK=0:YK=20:GOSUB1061:PRINT"PECH GEHABT! RICHTIG HEISST ES:";
870 FOR I=0 TO A
880 XK=I:YK=15:GOSUB1061:PRINTA$(I);
890 NEXT I
901 GETTX$:IFTX$=""THEN901
902 RUN
910 PRINTTAB(4)"[213][195][195][195][213][201][213] [209] [213][195][195][201] [213][195][195]  [195]"ZH$"[195] [195]"ZH$"[195]"
920 PRINTTAB(4)"[194]   [194][194][194]   [194]  [194] [194]     [194]   [194] "
930 PRINTTAB(4)ZA$"[195][195] [194][194][194] [194] "ZA$"[195][195]"ZI$"[213]"ZI$"     [194]   [194] "
940 PRINTTAB(4)"[194]   [194][194]"ZA$"[201]"ZA$"[201][194]  [194][194][194]     [194]   [194] "
950 PRINTTAB(4)"[202][195][195][195][203][202][203][202][203][202][203]  [202][203][202][195][195]  [195]"ZG$"[195] [195]"ZG$"[195] [209]"
960 RETURN
970 OPEN4,4
980 PRINT#4
990 PRINT#4,"   ";X;"   "
1000 FOR I=0 TO A
1010 IF C$="C" THEN PRINT#4,B$(I);
1020 IF C$="E" THEN PRINT#4,A$(I);
1030 NEXT
1040 PRINT#4
1050 CLOSE 4
1060 RETURN
1061 POKEXR,YK:POKEYR,XK:SYS65520:RETURN
1070 REM NACHSPANN ===========
1080 REM ZEICHENSATZ/GRAPHIK *
1090 ZA$=CHR$(171):ZG$=CHR$(177)
1100 ZH$=CHR$(178):ZI$=CHR$(179)
1101 XR=7:YR=8:IFPEEK(772)=124THENXR=781:YR=782
1110 RETURN
1120 REM =ENIAC==========ENDE=
1130 REM =====================