100 REM       FOX-TEXTO
110 REM
120 REM  01.03.87  BY P.ENGELS
130 REM  ---------------------
140 REM
150 PRINTCHR$(14)"[147][208]RINT[198]OX -> [212]EXTOMAT"CHR$(13)"  [212]EXTKONVERTER"
160 INPUT"[209]UELL-[212]EXT: ";QF$:QF$=QF$+",P,R"
170 INPUT" [218]IEL-[212]EXT: ";ZF$:ZF$=ZF$+",P,W"
180 OPEN1,8,3,QF$
190 OPEN2,8,4,ZF$
200 PRINT:PRINT:GET#1,A$:REM TEXTKENNUNG
210 GET#1,A$:IFA$=""THENA$=CHR$(0)
220 A=ASC(A$):B=0
230 IF(A>96)AND(A<123)THENB=A-32:GOTO370:REM KLEIN
240 IF(A>64)AND(A<91)THENB=A+128:GOTO370:REM GROSS
250 IF(A>31)AND(A<65)THENB=A:GOTO370:REM ZIFFERN & ZEICHEN
260 IFA=2THENGOTO470:REM FORMATZEILE IGNORIEREN
270 IFA=160THENB=127:REM SHIFT SPACE
280 IFA=13THENB=95:REM ABSATZ
290 IFA=91THENB=169:REM AE
300 IFA=92THENB=168:REM OE
310 IFA=93THENB=170:REM UE
320 IFA=123THENB=165:REM AE
330 IFA=124THENB=161:REM OE
340 IFA=125THENB=166:REM UE
350 IFA=126THENB=167:REM SZ
360 :
370 IF(A>31)THEN PRINTCHR$(A);
380 IFA=13THEN PRINTCHR$(A);
390 IFST=2GOTO430:REM FILE-ENDE
400 IF B=0GOTO210
410 PRINT#2,CHR$(B);:GOTO210
420 :
430 PRINT#2
440 CLOSE1:CLOSE2
450 PRINT:PRINT:PRINT"[212]EXT IST KONVERTIERT !![146]":END
460 :
470 GET#1,A$:IFASC(A$)<>13GOTO470:ZEILE UEBERLESEN
480 GOTO210