100 REM****  MUSIK-KURS   (TEIL 7)
101 REM****  5-VOICE-PLAYER
102 REM****
103 REM****  BY A.& F.HUGENROTH
104 REM****
105 :
106 SYS9*4096:.OPT OO:S = 54272
107 :
108 INITIRQ SEI
109 LDA #<NEWIRQ:STA $314
110 LDA #>NEWIRQ:STA $315
111 LDA #4:STA COUNT
112 LDA FSTEP:STA CSTEP
113 LDA #0:STA CNOTE
114 LDY #31:IIRQ2 STA SNSP1,Y
115 STA SNSP2,Y:STA SNSP3,Y
116 DEY:BPL IIRQ2
117 LDA #<NMI1:STA $318
118 LDA #>NMI1:STA $319
119 LDA #$81:STA $DD0D:LDA #1:STA $DD0E
120 LDA #128:STA $DD04:STA $DD05
121 LDA #$C8:STA $A6:STA $A9
122 LDA #$C7:STA $A5:STA $A8
123 LDA #$FF:STA $A4:STA $A7
124 LDA #$44:STA $C800
125 CLI
126 RTS
127 :
128 NMI1 STA $9B:STY $9E:LDY #0:CLC
129 LDA ($A4),Y:ADC ($A7),Y:STA $9F
130 AND #15:ORA $AA:STA $D418
131 LDA $A6:CMP $A5:BEQ NMI1B
132 INC $A4:BNE NMI1B:INC $A5
133 NMI1B LDA #<NMI2:STA $318
134 LDA $DD0D:LDY $9E:LDA $9B:RTI
135 NMI2 STA $9B:LDA $9F
136 LSR:LSR:LSR:LSR:ORA $AA:STA $D418
137 LDA #<NMI1:STA $318
138 LDA $A9:CMP $A8:BEQ NMI2B
139 INC $A7:BNE NMI2B:INC $A8
140 NMI2B LDA $DD0D:LDA $9B:RTI
141 :
142 NEWIRQ LDA 1:PHA:LDA #54:STA 1
143 JSR PLAY:JSR SOUND
144 PLA:STA 1:JMP $EA31
145 :
146 PLAY DEC COUNT:BMI PLAY2:RTS
147 PLAY2 LDA #4:STA COUNT
148 LDX CSTEP
149 LDA $A000,X:STA TKT1
150 LDA $A100,X:STA TSP1
151 LDA $A200,X:STA TKT2
152 LDA $A300,X:STA TSP2
153 LDA $A400,X:STA TKT3
154 LDA $A500,X:STA TSP3
155 LDA $A600,X:STA $B0
156 LDA $A700,X:STA $B1
157 LDA $A800,X:STA $B2
158 LDA $A900,X:STA $B3
159 LDA TKT1:AND #3:TAX
160 LDA TKTADRLO,X:STA $F7
161 LDA TKT1:LSR:LSR:TAX
162 LDA TKTADRHI,X:STA $F8
163 LDA TKT2:AND #3:TAX
164 LDA TKTADRLO,X:STA $F9
165 LDA TKT2:LSR:LSR:TAX
166 LDA TKTADRHI,X:STA $FA
167 LDA TKT3:AND #3:TAX
168 LDA TKTADRLO,X:STA $FB
169 LDA TKT3:LSR:LSR:TAX
170 LDA TKTADRHI,X:STA $FC
171 LDY CNOTE
172 LDA ($F7),Y:STA NOTE1
173 LDA ($F9),Y:STA NOTE2
174 LDA ($FB),Y:STA NOTE3
175 LDA ($B0),Y:STA DIGI1
176 LDA ($B2),Y:STA DIGI2
177 TYA:CLC:ADC #32:TAY
178 LDA ($F7),Y:STA SND1
179 LDA ($F9),Y:STA SND2
180 LDA ($FB),Y:STA SND3
181 LDX #2
182 PLAY3 LDA NOTE1,X:AND #127
183 CMP #96:BEQ PLAY5
184 CMP #95:BEQ PLAY4
185 CLC:ADC TSP1,X:LDY SND1,X
186 BPL PLAY11:STA GLIDETO,X:LDA #1
187 STA GLIDEON,X:JMP PLAY10
188 PLAY11 STA AKTNOTE1,X
189 PLAY10 LDA NOTE1,X:BMI PLAY0
190 LDA #1:STA ON1,X
191 PLAY0 JSR RESETFX
192 STX $F9:LDA SND1,X:AND #7:TAX
193 LDA SNDADRL,X:STA $F7:LDA SND1,X
194 AND #127
195 LSR:LSR:LSR:TAX:LDA SNDADRH,X
196 STA $F8:LDA $F9:ASL:ASL:ASL:ASL:ASL
197 TAX:LDY #0
198 PLAY6 LDA ($F7),Y:STA SNSP1,X
199 INX:INY:CPY #32:BCC PLAY6
200 LDX $F9:JSR FXINIT
201 JMP PLAY5
202 PLAY4 LDA #0:STA ON1,X
203 PLAY5 DEX:BMI PLAY9:JMP PLAY3
204 PLAY9 LDX DIGI1:BEQ PLAY12
205 LDA $AE00,X:STA $A4
206 LDA $AE40,X:STA $A5
207 LDA $AE80,X:STA $A6
208 LDA $AEC0,X:STA $DD04
209 LDA $AF00,X:STA $DD05
210 PLAY12 LDX DIGI2:BEQ PLAY13
211 LDA $AE00,X:STA $A7
212 LDA $AE40,X:STA $A8
213 LDA $AE80,X:STA $A9
214 PLAY13 LDA CNOTE
215 LDA CNOTE
216 CLC:ADC #1
217 CMP #32:BCC PLAY7
218 INC CSTEP:LDA CSTEP
219 CMP LSTEP:BEQ PLAY8:BCC PLAY8
220 LDA FSTEP:STA CSTEP
221 PLAY8 LDA #0
222 PLAY7 STA CNOTE
223 RTS
224 :
225 RESETFX LDA #0:STA ARPCOUNT,X
226 STA VIBLO,X
227 STA VIBHI,X:STA PULSRI,X
228 STA PORTLO,X:STA PORTHI,X
229 STA GLIDLO,X:STA GLIDHI,X
230 RTS
231 :
232 FXINIT LDY #24
233 LDA ($F7),Y:STA ARPSPEED,X
234 LDY #9:LDA ($F7),Y:LSR:STA VIBLEV,X
235 LDY #3:LDA ($F7),Y:STA PCOUNT,X
236 DEY:LDA ($F7),Y:PHA:ASL:ASL:ASL:ASL
237 STA PULSLO,X:PLA:LSR:LSR:LSR:LSR
238 STA PULSHI,X:LDY #16
239 LDA ($F7),Y:BEQ FXINIT2:STX TRIGGER
240 LDA #0:STA FRICHT,X:INY:LDA ($F7),Y
241 STA FTIME1,X:INY:LDA ($F7),Y
242 STA FTIME2,X
243 FXINIT2 RTS
244 :
245 SETSID LDA SNSP1+10:STA S+5
246 LDA SNSP1+11:STA S+6
247 LDA SNSP2+10:STA S+5+7
248 LDA SNSP2+11:STA S+6+7
249 LDA SNSP3+10:STA S+5+14
250 LDA SNSP3+11:STA S+6+14
251 LDY #0:CLC
252 LDA AKTNOTE1:ADC ARPNOTE:STA $F7
253 LDA AKTNOTE2:ADC ARPNOTE+1:STA $F8
254 LDA AKTNOTE3:ADC ARPNOTE+2:STA $F9
255 LDX SNSP1+29:BEQ SSID1A
256 DEC SNSP1+31:BPL SSID1B
257 STY SNSP1+29:SSID1B LDA SNSP1+30
258 STA $F7:JMP SSID2
259 SSID1A LDX SNSP1
260 LDA ON1:BNE SSID2
261 LDX SNSP1+1
262 SSID2 STX S+4
263 LDX SNSP2+29:BEQ SSID2A
264 DEC SNSP2+31:BPL SSID2B
265 STY SNSP2+29:SSID2B LDA SNSP2+30
266 STA $F8:JMP SSID3
267 SSID2A LDX SNSP2
268 LDA ON2:BNE SSID3
269 LDX SNSP2+1
270 SSID3 STX S+4+7
271 LDX SNSP3+29:BEQ SSID3A
272 DEC SNSP3+31:BPL SSID3B
273 STY SNSP3+29:SSID3B LDA SNSP3+30
274 STA $F9:JMP SSID4
275 SSID3A LDX SNSP3
276 LDA ON3:BNE SSID4
277 LDX SNSP3+1
278 SSID4 STX S+4+14
279 LDX $F7:CLC
280 LDA NOTELO,X:ADC TLO+0:STA S
281 LDA NOTEHI,X:ADC THI+0:STA S+1
282 LDX $F8:CLC
283 LDA NOTELO,X:ADC TLO+1:STA S+7
284 LDA NOTEHI,X:ADC THI+1:STA S+1+7
285 LDX $F9:CLC
286 LDA NOTELO,X:ADC TLO+2:STA S+14
287 LDA NOTEHI,X:ADC THI+2:STA S+1+14
288 LDA PULSLO+0:STA S+2
289 LDA PULSHI+0:STA S+3
290 LDA PULSLO+1:STA S+2+7
291 LDA PULSHI+1:STA S+3+7
292 LDA PULSLO+2:STA S+2+14
293 LDA PULSHI+2:STA S+3+14
294 LDA TRIGGER:ASL:ASL:ASL:ASL:ASL
295 CLC:ADC #<SNSP1:STA $F7
296 LDA #>SNSP1:ADC #0:STA $F8
297 LDY #22:LDA ($F7),Y
298 ASL:ASL:ASL:ASL:STA $F9:LDY #16
299 LDA ($F7),Y:BEQ SSIDEND:AND #15
300 ORA $F9:STA S+23:LDA ($F7),Y
301 AND #240:STA $AA:LDA #0:STA S+21
302 LDY #23:LDA ($F7),Y:STA S+22
303 SSIDEND LDA TIMERL:STA $DC04
304 LDA TIMERH:STA $DC05:RTS
305 :
306 SOUND LDX #0:LDA #<SNSP1
307 STA $F7:LDA #>SNSP1:STA $F8
308 ;**
309 ;** ARPEGGIO
310 ;**
311 SOUND1 LDA #25:CLC
312 ADC ARPCOUNT,X:TAY:LDA ($F7),Y
313 STA ARPNOTE,X
314 DEC ARPSPEED,X:BPL SOUND2
315 LDY #24:LDA ($F7),Y:STA ARPSPEED,X
316 LDA ARPCOUNT,X:CLC:ADC #1
317 AND #3:STA ARPCOUNT,X
318 ;**
319 ;** VIBRATO
320 ;**
321 SOUND2 LDY #7:LDA ($F7),Y
322 BEQ SOUND2B:SEC:SBC #1:STA ($F7),Y
323 JMP SOUND3
324 SOUND2B DEC VIBLEV,X:BPL SOUND2C
325 LDY #8:LDA ($F7),Y:EOR #255
326 STA ($F7),Y:INY:LDA ($F7),Y
327 STA VIBLEV,X:SOUND2C LDY #8
328 LDA ($F7),Y:BMI SOUND2D:CLC
329 ADC VIBLO,X:STA VIBLO,X:LDA VIBHI,X
330 ADC #0:STA VIBHI,X:JMP SOUND3
331 SOUND2D EOR #255:STA $F9:SEC
332 LDA VIBLO,X:SBC $F9:STA VIBLO,X
333 LDA VIBHI,X:SBC #0:STA VIBHI,X
334 ;**
335 ;** PULSE
336 ;**
337 SOUND3 LDY #5:LDA ($F7),Y:STA $F9
338 LDA PULSRI,X:BMI SOUND3A
339 LDA PULSLO,X:CLC:ADC $F9
340 STA PULSLO,X:LDA PULSHI,X:ADC #0
341 STA PULSHI,X
342 DEC PCOUNT,X:BPL SOUND4
343 LDY #4:LDA ($F7),Y:STA PCOUNT,X
344 LDA #128:STA PULSRI,X:JMP SOUND4
345 SOUND3A LDA PULSLO,X:SEC:SBC $F9
346 STA PULSLO,X:LDA PULSHI,X:SBC #0
347 STA PULSHI,X:DEC PCOUNT,X
348 BPL SOUND4:LDY #3:LDA ($F7),Y
349 STA PCOUNT,X:LDA #0:STA PULSRI,X
350 LDY #6:LDA ($F7),Y:AND #16
351 BNE SOUND4:DEY:LDA #0:STA ($F7),Y
352 ;**
353 ;** PORTAMENTO
354 ;**
355 SOUND4 LDY #6:LDA ($F7),Y:AND #15
356 BEQ SOUND5:AND #3:CMP #1
357 BEQ SOUND4A:LDY #12:LDA PORTLO,X
358 CLC:ADC ($F7),Y:STA PORTLO,X
359 INY:LDA PORTHI,X:ADC ($F7),Y
360 STA PORTHI,X:INY:CMP ($F7),Y
361 BCC SOUND5:JMP SOUND4B
362 SOUND4A LDY #12:LDA PORTLO,X:SEC
363 SBC ($F7),Y:STA PORTLO,X
364 INY:LDA PORTHI,X:SBC ($F7),Y
365 STA PORTHI,X:INY:CMP ($F7),Y
366 BCS SOUND5:SOUND4B LDY #6
367 LDA ($F7),Y:AND #4:BEQ SOUND4C
368 LDA #0:STA PORTLO,X:STA PORTHI,X
369 JMP SOUND5:SOUND4C LDA ($F7),Y
370 AND #240:STA ($F7),Y
371 ;**
372 ;** FILTER
373 ;**
374 SOUND5 CPX TRIGGER:BNE SOUND6
375 LDA FRICHT,X:BMI SOUND5A
376 DEC FTIME1,X:BPL SOUND5B:LDA #255
377 STA FRICHT,X:STA FTIME1,X
378 JMP SOUND6:SOUND5B LDY #19
379 LDA ($F7),Y:LDY #23:CLC:ADC ($F7),Y
380 STA ($F7),Y:JMP SOUND6
381 SOUND5A DEC FTIME2,X
382 BPL SOUND5D:LDA #0:STA FRICHT,X
383 LDA #255:STA FTIME2,X
384 LDY #21:LDA ($F7),Y:BEQ SOUND6
385 LDY #17:LDA ($F7),Y:STA FTIME1,X
386 INY:LDA ($F7),Y:STA FTIME2,X
387 JMP SOUND6:SOUND5D LDY #20
388 LDA ($F7),Y:LDY #23:CLC:ADC ($F7),Y
389 STA ($F7),Y
390 ;**
391 ;** GLIDE
392 ;**
393 SOUND6 LDA GLIDEON,X:BNE SOUND6D
394 JMP SOUND7:SOUND6D LDY AKTNOTE1,X
395 LDA NOTELO,Y:CLC
396 ADC TLO,X:STA $F9:LDA NOTEHI,Y
397 ADC THI,X:STA $FA
398 LDA GLIDETO,X:CMP AKTNOTE1,X
399 BCC SOUND6A:LDY #12:LDA GLIDLO,X
400 CLC:ADC ($F7),Y:STA GLIDLO,X:INY
401 LDA GLIDHI,X:ADC ($F7),Y
402 STA GLIDHI,X:LDY GLIDETO,X
403 LDA $FA:CMP NOTEHI,Y
404 BCC SOUND7:BNE SOUND6B
405 LDA $F9:CMP NOTELO,Y:BCC SOUND7
406 JMP SOUND6B
407 SOUND6A LDY #12:LDA GLIDLO,X
408 SEC:SBC ($F7),Y:STA GLIDLO,X:INY
409 LDA GLIDHI,X:SBC ($F7),Y
410 STA GLIDHI,X:LDY GLIDETO,X
411 LDA NOTEHI,Y:CMP $FA:BCC SOUND7
412 BNE SOUND6B:LDA NOTELO,Y
413 CMP $F9:BCC SOUND7
414 SOUND6B LDA #0:STA GLIDEON,X
415 STA GLIDLO,X:STA GLIDHI,X
416 LDA GLIDETO,X:STA AKTNOTE1,X
417 ;**
418 ;** SOUNDENDE
419 ;**
420 SOUND7 LDA VIBLO,X:CLC
421 ADC PORTLO,X:STA TLO,X:LDA TLO,X
422 CLC:ADC GLIDLO,X:STA TLO,X
423 LDA VIBHI,X:ADC PORTHI,X:STA THI,X
424 LDA THI,X:CLC:ADC GLIDHI,X
425 STA THI,X:LDA TLO,X:CLC:LDY #15
426 ADC ($F7),Y:STA TLO,X
427 LDA THI,X:ADC #0:STA THI,X
428 LDA $F7:CLC:ADC #32:STA $F7
429 LDA $F8:ADC #0:STA $F8
430 INX:CPX #3:BCS SOUNDE:JMP SOUND1
431 SOUNDE JMP SETSID
432 :
433 :
434 :
435 TKTADRLO .BYT $00,$40,$80,$C0
436 TKTADRHI .BYT $B0,$B1,$B2,$B3
437 :        .BYT $B4,$B5,$B6,$B7
438 :        .BYT $B8,$B9,$BA,$BB
439 :        .BYT $BC,$BD,$BE,$BF
440 NOTE1 .BYT 0
441 NOTE2 .BYT 0
442 NOTE3 .BYT 0
443 TKT1 .BYT 0
444 TKT2 .BYT 0
445 TKT3 .BYT 0
446 TSP1 .BYT 0
447 TSP2 .BYT 0
448 TSP3 .BYT 0
449 SND1 .BYT 0
450 SND2 .BYT 0
451 SND3 .BYT 0
452 ON1 .BYT 0
453 ON2 .BYT 0
454 ON3 .BYT 0
455 TLO .BYT 0,0,0
456 THI .BYT 0,0,0
457 PULSRI .BYT 0,0,0
458 PCOUNT .BYT 0,0,0
459 PULSLO .BYT 0,0,0
460 PULSHI .BYT 0,0,0
461 ARPCOUNT .BYT 0,0,0
462 ARPNOTE .BYT 0,0,0
463 ARPSPEED .BYT 0,0,0
464 VIBLEV .BYT 0,0,0
465 VIBLO .BYT 0,0,0
466 VIBHI .BYT 0,0,0
467 PORTLO .BYT 0,0,0
468 PORTHI .BYT 0,0,0
469 FRICHT .BYT 0,0,0
470 FTIME1 .BYT 0,0,0
471 FTIME2 .BYT 0,0,0
472 GLIDEON .BYT 0,0,0
473 GLIDETO .BYT 0,0,0
474 GLIDLO .BYT 0,0,0
475 GLIDHI .BYT 0,0,0
476 TRIGGER .BYT 0
477 CNOTE .BYT 0
478 CSTEP .BYT 0
479 FSTEP .BYT 0
480 LSTEP .BYT 3
481 COUNT .BYT 0
482 SPEED .BYT 0
483 TIMERL .BYT 0
484 TIMERH .BYT $39
485 DIGI1 .BYT 0
486 DIGI2 .BYT 0
487 SNSP1 .ASC "********************************"
488 SNSP2 .ASC "********************************"
489 SNSP3 .ASC "********************************"
490 AKTNOTE1 .BYT 0
491 AKTNOTE2 .BYT 0
492 AKTNOTE3 .BYT 0
493 NOTELO .BYT 22,39,57,75,95,116,138
494 :      .BYT 161,186,212,240,14,45
495 :      .BYT 78,113,150,190,231,20
496 :      .BYT 66,116,169,224,27,90
497 :      .BYT 156,226,45,123,207,39
498 :      .BYT 133,232,81,193,55,180
499 :      .BYT 56,196,89,247,158,78
500 :      .BYT 10,208,162,129,109,103
501 :      .BYT 112,137,178,237,59,157
502 :      .BYT 20,160,69,3,219,207
503 :      .BYT 225,18,101,219,118,58
504 :      .BYT 39,65,138,5,181,157
505 :      .BYT 193,36,201,182,237,115
506 :      .BYT 78,130,20,10,106,59
507 :      .BYT 130,72,147,107,218,231
508 :      .BYT 156,4,40,20
509 NOTEHI .BYT 1,1,1,1,1,1,1,1,1,1,1
510 :      .BYT 2,2,2,2,2,2,2,3,3,3,3
511 :      .BYT 3,4,4,4,4,5,5,5,6,6,6
512 :      .BYT 7,7,8,8,9,9,10,10,11
513 :      .BYT 12,13,13,14,15,16,17
514 :      .BYT 18,19,20,21,23,24,26
515 :      .BYT 27,29,31,32,34,36,39
516 :      .BYT 41,43,46,49,52,55,58
517 :      .BYT 62,65,69,73,78,82,87
518 :      .BYT 92,98,104,110,117,124
519 :      .BYT 131,139,147,156,165
520 :      .BYT 175,185,196,208,221
521 :      .BYT 234,248
522 SNDADRL .BYT $00,$20,$40,$60
523 :       .BYT $80,$A0,$C0,$E0
524 SNDADRH .BYT $AA,$AB,$AC,$AD