10 REM *******************************
20 REM *  JULIA-MENGEN VON Z=Z^2+C   *
30 REM *  1987 BY STEFAN VILSMEIER   *
40 REM *******************************
50 :
60 IF A=0 THEN A=1:LOAD "FRACTAL.OBJ",8,1
70 OPEN 1,8,15,"U9":CLOSE1:REM DIESE ZEILE KANN BEI PROBLEMEN MIT DEM
80 REM FLOPPYSPEEDER WEGGELASSEN WERDEN!
90 POKE53280,0:POKE53281,0:SYS50194
100 DIMF(320),F2(320),G(320),G2(320),Z(320),Z2(320)
110 :
120 :
130 REM ********** EINGABEN *******
140 :
150 INPUT"[147]ANFANG REALTEIL         ";X1
160 INPUT"ENDE REALTEIL           ";X2
170 INPUT"ANFANG IMAGINAERTEIL    ";Y1
180 INPUT"ENDE IMAGINAERTEIL      ";Y2
190 INPUT"REALTEIL VON C          ";CR
200 INPUT"IMAGINAERTEIL VON C     ";CR
210 INPUT"ANZAHL DER ITERATIONEN  ";Z
220 INPUT"TOLERANZ                ";MX
230 :
240 :
250 REM ******************************
260 REM *      HAUPTSCHLEIFE         *
270 REM ******************************
280 :
290 DX=(X2-X1)/320:DY=(Y1-Y2)/200
300 SYS50176,14,0:SYS50179,1
310 R=2:V=4:H=A:EF=S/8:GH=T/8:SW=.2
320 :
330 FORYY=199TO199
340 :FORXX=0TO319
350 : ZZ=0
360 : X=X1+XX*DX
370 : Y=Y2+YY*DY
380 : GOSUB680:REM ** 'ITERATION' ***
390 : IF ZZ<Z AND RA<4 THEN GOTO 380
400 : F2(XX)=X:G2(XX)=Y:Z2(XX)=ZZ
410 :
420 :
430 : REM ***** 'TOLERANZ' *********
440 :
450 : IFYY=0ORXX=0GOTO540
460 :   IF Z(XX-1)<Z AND Z(XX)<Z AND Z2(XX-1)<Z AND Z2(XX)<Z GOTO 540
470 :   P1=F(XX-1):P2=F(XX):P3=F2(XX):P4=F2(XX-1)
480 :   Q1=G(XX-1):Q2=G(XX):Q3=G2(XX):Q4=G2(XX-1)
490 :   D1=ABS(P1-P2)^2+ABS(Q1-Q2)^2
500 :   D2=ABS(P2-P3)^2+ABS(Q2-Q3)^2
510 :   D3=ABS(P3-P4)^2+ABS(Q3-Q4)^2
520 :   D4=ABS(P4-P1)^2+ABS(Q4-Q1)^2
530 : IF D1>MX OR D2>MX OR D3>MX OR D4>MX THEN SYS 50182,XX,YY,1
540 :NEXTXX
550 :FORSE=0TO320:F(SE)=F2(SE):G(SE)=G2(SE):Z(SE)=Z2(SE):NEXT
560 NEXTYY
570 :
580 :
590 GETA$:IFA$=""GOTO590
600 SYS50179,0:IF A$="S" THEN GOSUB 810:REM 'GRAFIK SPEICHERN'
610 GOTO 70:REM NEUSTART
620 :
630 :
640 REM ******************************
650 REM *        'ITERATION'         *
660 REM ******************************
670 :
680 XQ=X*X
690 YQ=Y*Y
700 Y=2*X*Y+CI
710 X=XQ-YQ+CR
720 ZZ=ZZ+1
730 RA=XQ+YQ
740 RETURN
750 :
760 :
770 REM ***************************
780 REM *   'GRAFIK SPEICHERN'    *
790 REM ***************************
800 :
810 INPUT "GRAFIK-NAME ";N$
820 OPEN 2,8,2,"PI."+N$+",P,W":SYS 50191:CLOSE 2
830 RETURN