100 SYS9*4096
110 .OPT OO
120 ;
130 ;
140 ; TAKTZYKLEN EINES
150 ; MASCHINENPROGRAMMS MESSEN
160 ;
170 ;
180 ; VON  MARK RICHTERS
190 ;      ALLERSTR.4
200 ;      2806 OYTEN
210 ;      TEL. 04207/1870
220 ;
230 ;
240 *=$C000
250 ;
260 FAC      =$62   ;FLIESSKOMMA-AKKU
270 FRMNUM   =$AD8A ;AUSDRUCK HOLEN
280 CHKCOM   =$AEFD ;AUF KOMMA PRUEFEN
290 GETADR   =$B7F7 ;2-BYTE INTEGER
300 VICCTRL  =$D011 ;REG. FUER BS AUS
310 RASTER   =$D012 ;RASTER-ZEILE
320 TIMER    =$DD04 ;TIMER A LO-BYTE
330 CRA      =$DD0E ;TIMER A CONTROL
340 CRB      =$DD0F ;TIMER B CONTROL
350 ;---------------
360 JSR CHKCOM      ;STARTADRESSE DER
370 JSR FRMNUM      ;ZU MESSENDEN
380 JSR GETADR      ;ROUTINE HOLEN
390 STY JSUBR+1     ;UND ALS SPRUNG-
400 STA JSUBR+2     ;ADRESSE SPEICHERN
410 ;
420 SEI             ;IRQ SPERREN
430 LDA #%00001011  ;BILDSCHIRM AUS
440 STA VICCTRL
450 WAIT LDA RASTER ;WARTEN BIS BILD-
460 BNE WAIT        ;SCHIRM GANZ AUS
470 ;
480 LDX #3          ;BEIDE TIMER AUF
490 LDA #$FF        ;MAXIMALWERT
500 SETTIMER STA TIMER,X
510 DEX
520 BPL SETTIMER
530 ;
540 LDA #%00010001  ;TIMER KOPPELN,
550 LDX #%01010001  ;LADEN UND STARTEN
560 STX CRB
570 STA CRA
580 ;---------------
590 JSUBR JSR $FFFF ;SPRUNG AUF ROUTINE
600 ;---------------
610 LDY #0          ;BEIDE TIMER STOP
620 STY CRA
630 STY CRB
640 LDA #%00011011  ;BILDSCHIRM WIEDER
650 STA VICCTRL     ;AN
660 CLI             ;IRQ WIEDER FREI-
670 ;
680 SEC             ;4 TIMER-BYTES
690 LDA TIMER       ;UMRECHNEN
700 EOR #$FF        ;FUER AUFRUF BE-
710 SBC #11         ;NOETIGTE ZYKLEN
720 STA FAC+3       ;ABZIEHEN
730 LDX #3          ;UND DIE RESTLICHEN
740 ;
750 L1 LDA TIMER+1,Y;3 TIMER-WERTE
760 EOR #$FF        ;ANPASSEN
770 SBC #0
780 STA FAC-1,X
790 INY
800 DEX
810 BNE L1
820 ;
830 SEC
840 TXA             ;4 BYTE WERTEN
850 LDX #$A0        ;OHNE VORZEICHEN
860 JSR $BC4F       ;IN FLIESSKOMMAZAHL
870 JMP $BDD7       ;FAC AUSGEBEN/RTS