10 REM COPYRIGHT 1987 COMPUTE! PUBLICATIONS, INC. - ALL RIGHTS RESERVED
20 POKE 53280,0:POKE 53281,0:POKE 646,5:PRINT"[147]"
30 FORI=1TO10:PRINT"":NEXT
40 PRINTTAB(5)"[151][213][196][201] COPYRIGHT 1987"
50 PRINTTAB(5)"[199]C[200] COMPUTE! PUBLICATIONS INC."
60 PRINTTAB(5)"[202][198][203] ALL RIGHTS RESERVED"
70 PRINT"[155]GEOCONVERTER[146]"
80 INPUT"FILE TO CONVERT";GF$
90 PRINT"SEARCHING FOR "GF$
100 HD$="":FOR I=1 TO 4:READ HE:HD$=HD$+CHR$(HE):NEXT
110 FOR I=1TO5:READIE:ID$=ID$+CHR$(IE):NEXT
120 NL$="":T$=CHR$(18):S$=CHR$(1):OPEN 15,8,15,"I0:":OPEN 2,8,2,"#"
130 GOSUB360:GET #2,NT$,NS$
140 FOR E=0 TO 7
150 D$=NL$:GET#2,B$:I=1:IFB$=NL$ THEN210
160 IF ASC(B$)<>130 THEN210
170 GET#2,HT$,HS$:I=3
180 GET#2,B$:I=I+1
190 IF ASC(B$)=160 THEN210
200 D$=D$+B$:GOTO180
210 FOR I=I TO 31:GET#2,B$:NEXT
220 IF D$=GF$ THEN250
230 NEXT E:IF NT$=NL$ THEN250
240 T$=NT$:S$=NS$:GOTO130
250 IF D$=NL$ THENPRINT"FILE NOT FOUND[146]":GOTO350
260 PRINT"CONVERTING "GF$
270 DT$=T$:DS$=S$:T$=HT$:S$=HS$:GOSUB360
280 GET#2,MT$,MS$
290 FOR I=0 TO 65:GET #2,B$:NEXT
300 GET#2,CT$,GT$:GOSUB360:PRINT#2,HD$;:GOSUB370:T$=DT$:S$=DS$:GOSUB360
310 FOR I=0 TO 32*E+2:GET#2,B$:NEXT
320 PRINT#2,MT$;MS$;:FORI=0 TO 15:GET#2,B$:NEXT
330 PRINT#2,HT$;HS$;CHR$(0);GT$;
340 PRINT#2,ID$;:GOSUB370:PRINT:PRINTGF$" CONVERTED"
350 CLOSE2:CLOSE15:END
360 U$="U1":GOTO380
370 U$="U2"
380 PRINT#15,U$;2;0;ASC(T$+"0");ASC(S$+"0")
390 RETURN
400 DATA 0,255,3,21,87,10,1,0,0