10 DV=PEEK(186):POKE53265,11:GOSUB8000:GOSUB8100:PRINT"[147]"
52 OPEN1,DV,1,"CH7":POKE780,0:SYS65493:CLOSE1
54 OPEN1,DV,1,"CHSET2":POKE780,0:SYS65493:CLOSE1
55 OPEN1,DV,1,"7SPRITES":POKE780,0:SYS65493:CLOSE1
56 POKE53265,PEEK(53265)AND239
57 OPEN1,DV,1,"INTRO":POKE780,0:SYS65493:CLOSE1
58 OPEN1,DV,1,"INTRO.CL":POKE780,0:SYS65493:CLOSE1
59 POKE53281,0:POKE53280,0:POKE53265,PEEK(53265)OR16
60 POKE198,0:WAIT198,1:PRINT"[147]":GOTO555
62 REM
200 C$=CHR$(34):POKE198,4:DV=PEEK(186)
210 PRINT"[147]LOAD";C$;B$;C$;",DV";
230 POKE631,13:POKE632,82:POKE633,117:POKE634,13:END
500 REM*INFO
502 PRINT"[147][158]":POKE53280,0:POKE53281,0:PRINT"QUICK START INFORMATION"
503 PRINT:PRINT"[159]YOU CAN USE JOYSTICK OR KEYBOARD."
504 PRINT:PRINT"[159]JOYSTICK USE JS IN PORT 2. UP/DOWN FOR"
506 PRINT"MENU CHOICES, LEFT RIGHT FOR STEERING"
508 PRINT"CHOICES, FIREBUTTON TO CHOOSE OPTION."
510 PRINT"SOME KEYBOARD INPUT ALSO REQUIRED."
512 PRINT:PRINT"[159]KEYBOARD USE I,K FOR UP/DOWN, J,L FOR"
514 PRINT"LEFT/RIGHT, SPACEBAR TO CHOOSE OPTION."
516 PRINT:PRINT"[159]LANDING ONLY AT A SPACE STATION (I.E."
518 PRINT"WHEN LARGE S AT TOP OF SCREEN IS WHITE).";
520 PRINT"SHIP MUST DECELERATE BEFORE LANDING."
530 PRINT:PRINT"[159]TAVERNS VARY FROM PLANET TO PLANET."
532 PRINT:PRINT"[159]ACADEMIES VARY FROM SYSTEM TO SYSTEM"
533 PRINT:PRINT"[155]PRESS SPACEBAR TO CONTINUE...";
534 POKE198,0:WAIT198,1:PRINT"[147]"
535 PRINT:PRINT"[159]CODE NUMBER AS YOUR TOTAL WORTH GROWS"
536 PRINT"CODE NUMBERS BECOME AVAILABLE ENABLING"
538 PRINT"YOU TO START WITH A BONUS NEXT GAME."
544 PRINT:PRINT"[159]TRAVELLING YOU START IN SECTOR 3 OF "
545 PRINT"STAR SYSTEM K-OO1. GO TO THE TOP OR THE"
546 PRINT"FAR RIGHT OF THE SCREEN TO ENTER A NEW "
547 PRINT"SECTOR. TO GET TO A NEW SYSTEM YOU"
548 PRINT"NEED A HYPERSPACE DRIVE IN YOUR SHIP,"
549 PRINT:PRINT"[155]PLEASE NOTE:"
550 PRINT:PRINT"[159]THIS QUICK START INFO IS BRIEF. READ"
551 PRINT"THE INSTRUCTION FILE FOR MORE DETAILS."
552 PRINT:PRINT:PRINT"[155]PRESS SPACEBAR TO CONTINUE...";
553 POKE198,0:WAIT198,1:PRINT"[147]"
555 PRINT:PRINT"[159]---------------------------------------"
556 PRINT"[155]L  LOAD THE GAME"
558 PRINT:PRINT"R  READ FULL INSTRUCTION FILE"
559 PRINT:PRINT"Q  READ QUICKSTART INFO"
561 PRINT"[159]---------------------------------------"
562 PRINT:PRINT"[159]PLEASE CHOOSE L, R OR Q"
563 PRINT:PRINT:PRINT"[155]LEAVE DISK IN DRIVE DURING GAME "
570 POKE198,0:WAIT198,1:GETX$
574 IFX$="L"THENB$="GT1":GOTO200
576 IFX$="R"THENB$="INFO":GOTO200
577 IFX$="Q"THEN500
578 GOTO570
4999 END
5000 REM*MVR
5010 EA=EA+1:L=EA-SA:NE=L+NS
5020 X=INT(L/256):Y=L-256*X
5030 A=INT((NE-Y)/256):B=NE-256*A-Y
5040 C=INT((EA-Y)/256):D=EA-256*C-Y
5050 POKE 781,X+1:POKE782,Y
5060 POKE 88,B+1:POKE 89,A
5070 POKE90,D+1:POKE 91,C
5080 SYS41964:POKE NS,PEEK(SA)
5085 RETURN
7999 REMREC3
8000 SC=50176
8002 RM=INT(SC/16384)
8004 POKE56334,PEEK(56334)AND254
8006 POKE1,PEEK(1)AND251:SA=53248
8008 EA=55295:NS=51200:GOSUB5000
8010 POKE1,PEEK(1)OR4
8012 POKE56334,PEEK(56334)OR1
8014 POKE56578,PEEK(56578)OR3
8016 POKE56576,(PEEK(56576)AND252)OR(3-RM):POKE53272,18:POKE648,SC/256
8018 RETURN:REMPK55,0:56,160BSTOP40960
8099 REM**SPR
8100 V=53248:POKEV,84:POKEV+1,101:POKEV+39,1:POKEV+21,0:POKE51192,0
8102 FORP=49152TO49215:POKEP,0:NEXT
8104 POKE49152,3:POKE49153,192
8106 POKE49155,3:POKE49156,192:RETURN