10 PRINTCHR$(147);CHR$(14);:POKE53280,0:POKE53281,0
15 GOSUB 61000
20 NR=11:NV=33:NN=6:NO=6:RM=1:M=0:V4=100
30 DIMMP(NR,7),VB$(NV),NN$(NN),NO$(NO,1),RN$(NR),OP(NO)
40 FORI=1TONV:READVB$(I):NEXT:FORI=1TONN:READNN$(I):NEXT
50 FORI=1TONR:FORJ=1TO6:READMP(I,J):NEXT:READRN$(I):NEXT
60 FORI=1TONO:READOB$(I,0),OB$(I,1),OP(I):NEXT
70 MP(1,7)=1:PRINT"[200][197][204][208] IS AVAILABLE.":GOTO640
80 IF(INT(RND(1)*100)+1<10)ORM=0THENA$="[217]PV GFBQ FWOKPTJPMT!":GOSUB880
90 IFM>60THEN1750
100 IFRM=10ANDOP(3)=0THEN1660
110 IFRM=10ANDV2=1THEN1700
120 IFV4<MTHENPRINT"[212]HE LIFEBOAT HAS LAUNCHED WITHOUT YOU!":GOTO800
130 IFV5=1THENPRINTV4-M+1"MOVES TO LAUNCH."
140 A1=0:PRINT"[215]HAT NOW? ";:LIMIT=25:GOSUB50000:PRINT:IFLEN(AM$)>20THEN80
150 FORI=1TOLEN(AM$):IFMID$(AM$,I,1)<>" "THENNEXT:W1$=AM$:W2$="":GOTO170
160 W1$=LEFT$(AM$,I-1):W2$=MID$(AM$,I+1,15)
170 FORI=1TONV
175 IFVB$(I)<>LEFT$(W1$,3)THENNEXT:PRINT"[201] DON'T KNOW "W1$:GOTO80
180 W1=I:IFW2$=""THENW2=0:GOTO220
190 FORI=1TONN:IFNN$(I)=LEFT$(W2$,3)THENW2=I:GOTO220
200 NEXT:FORI=1TONO:IFLEFT$(W2$,3)=OB$(I,1)THENW2=I:A1=1:GOTO220
210 NEXT:W2=100
220 M=M+1:IFW1=1THENPRINTM"MOVES.":PRINT:GOTO80
230 IFW1<12THEN360
240 IFW1<14THEN560
250 IFW1<16THEN610
260 IFW1<19THEN640
270 IFW1<24THEN690
280 IFW1<26THEN730
290 IFW1<28THEN760
300 IFW1<30THEN800
310 IFW1<32THEN920
320 IFW1=32ANDW2$="SOMETHING"ANDRM=7THEN1580
330 IFW1=32ANDW2$="SOMETHING"THENA$="[206]P LFZAPBQC!":GOSUB880:GOTO80
340 IFW1=33THENPRINT"TYPE SOMETHING":IFRM=7THENPRINT"HERE!"
350 IFW1=33THEN80
360 IFRM=4AND(W1=3ORW2=2)ANDV1=0THEN390
370 IFRM=6AND(W1=2ORW2=1)ANDV1=0THEN390
380 GOTO400
390 A$="[195]BQHP JT MPS OQFTTVQJYFC.":GOSUB880:GOTO80
400 IFW1>8ANDW2$="HATCH"AND(RM=3ORRM=7)THENPRINT"[201]T'S LOCKED!":GOTO80
410 IFW1>8ANDW2$="HATCH"THENPRINT"[215]HAT HATCH?":GOTO80
420 IFW1<8OR(W1>7ANDW2<7)THEN440
430 PRINT"[196]O WHAT?":GOTO80
440 IFW1<8THENW2=W1-1
450 IFMP(RM,W2)>0THEN500
460 IFMP(RM,W2)<0THENPRINT"[212]HE DOOR IS LOCKED!":GOTO80
470 IFW2<5THENPRINT"[211]OMETHING SOLID HITS YOU IN THE FACE!":GOTO80
480 IFW2=5THENPRINT"[217]OU CAN'T CLIMB AIR!":GOTO80
490 PRINT"[217]OU FALL ON YOUR FACE.":GOTO80
500 RM=MP(RM,W2):PRINT:PRINT""RN$(RM):IFMP(RM,7)=1THENGOSUB840:GOTO80
510 MP(RM,7)=1
520 DE=0:ONRMGOSUB1160,1200,1280,1240,1320,1350,1380,1430,1470,1510,1540
530 GOSUB840
540 IFDE=1THEN800
550 GOTO80
560 IFW2=2THENA1=0
570 IFW2=1THENA1=0
580 IFA1=0THENPRINT"[217]OU CAN'T TAKE THAT.":GOTO80
590 IFOP(W2)<>RMTHENPRINT"[217]OU DON'T SEE IT.":GOTO80
600 OP(W2)=0:PRINTCHR$(ASC(LEFT$(W2$,1))+32);MID$(W2$,2,10);" TAKEN."
605 GOTO80
610 IFA1=0OROP(W2)<>0THENPRINT"[217]OU DON'T HAVE IT.":GOTO80
620 OP(W2)=RM:PRINTCHR$(ASC(LEFT$(W2$,1))+32);MID$(W2$,2,10);" DROPPED."
630 GOTO80
640 IFW2=5ANDRM=1THENPRINT"[212]HERE IS SOMETHING UNDER IT!":GOTO80
650 IFW1=18ANDW2=1ANDRM=5ANDOP(3)=11THENGOSUB1800:GOTO80
660 IFW1=18ANDW2=1ANDRM=5THENPRINT"[201]T IS EMPTY.":GOTO80
670 IFW1=18THENPRINT"[217]OU SEE NOTHING SPECIAL.":GOTO80
680 PRINT""RN$(RM):GOTO520
690 IFRM=1ANDW2=5ANDOP(6)=11THENPRINT"[217]OU FIND "OB$(6,0)".":OP(6)=1:GOTO80
700 IFW2=5ANDOP(6)<>11THENPRINT"[217]OU ALREADY DID THAT!":GOTO80
710 IFRM<>1ANDW2=5THENPRINT"[196]ON'T SEE IT!":GOTO80
720 PRINT"[215]HY?":GOTO80
730 IFW1=24ANDRM=5ANDW2=1ANDOP(3)=11ANDOP(4)=0THENGOSUB1810
740 IFV3=1THENGOSUB880:V3=0:OP(3)=5:GOTO530
750 PRINT"[217]OU CAN'T DO THAT.":GOTO80
760 IFOP(6)<>0THENPRINT"[217]OU HAVE NO KEY.":GOTO80
770 IFRM>2THENPRINT"[212]HAT DOOR DOESN'T LOCK."
780 IFW1=26THENMP(1,3)=-2:MP(2,4)=-1:PRINT"[207]K.":GOTO80
790 MP(1,3)=2:MP(2,4)=1:PRINT"[207]K.":GOTO80
800 PRINT:PRINT"[194]ETTER LUCK NEXT TIME."
810 PRINT"[212]RY AGAIN? (Y/N)"
815 GETY$:IFY$<>"Y"ANDY$<>"N"THEN815
820 IFY$="Y"THENRUN
830 PRINT"[147]":GOTO 60000
840 AM=0:FORI=1TONO:IFRM=OP(I)ANDAM=0THENAM=1:PRINT"[217]OU SEE ";
850 IFRM=OP(I)THENPRINTOB$(I,0)", ";
860 NEXT:IFAM>0THENPRINT"[157][157]."
870 RETURN
880 FORI=1TOLEN(A$):A=1:B=ASC(MID$(A$,I,1))
890 IFB<65ORB>90THENPRINTCHR$(B);:NEXTI:PRINT:RETURN
900 IFB/2=INT(B/2)THENA=-1
910 PRINTCHR$(B+A);:NEXTI:PRINT:RETURN
920 PRINT"[217]OU ARE CARRYING:"
930 AM=0:FORI=1TONO:IFOP(I)=0THENAM=1:PRINTOB$(I,0)
940 NEXT:IFAM=0THENPRINT"[206][207][212][200][201][206][199]!"
950 GOTO80
960 DATATIM,N,S,E,W,U,D,GO,ENT,WAL,RUN,TAK,GET,DRO,LEA,L,LOO,EXA
970 DATAMOV,PUS,PUL,SHO,HIT,OPE,CLO,LOC,UNL,QUI,END,I,INV,TYP,HEL
980 DATANOR,SOU,EAS,WES,UP,DOW
990 DATA0,0,-2,0,0,0,"[217]OUR CABIN"
1000 DATA4,6,0,-1,0,0,"[200]ALLWAY"
1010 DATA11,4,0,0,0,0,"[197]NGINE ROOM"
1020 DATA3,5,9,2,0,0,"[208]ASSAGEWAY"
1030 DATA4,6,0,0,0,0,"[195]ARGO"
1040 DATA5,7,9,2,0,0,"[208]ASSAGEWAY"
1050 DATA6,8,0,0,0,0,"[195]OMPUTER ROOM"
1060 DATA7,0,0,0,0,0,"[194]RIDGE"
1070 DATA4,6,10,0,0,0,"[204]IFEBOAT BAY"
1080 DATA9,9,9,9,0,0,"[204]IFEBOAT"
1090 DATA0,0,0,0,0,0,"[197]NGINES"
1100 DATA"A LARGE CRATE",CRA,5
1110 DATA"A HATCH IN THE FLOOR",HAT,3
1120 DATA"A SMALL DEVICE",DEV,11
1130 DATA"A BENT CROWBAR",CRO,8
1140 DATA"A LARGE BED",BED,1
1150 DATA"A KEYCARD",KEY,11
1160 A$="[217]PV TJS XJSGJM ZPVQ QPPN, DPMSFNOKBSJMH":GOSUB880
1170 A$="XGBS SP CP MFWS.  [212]GF CPPQXBZ JT JM SGF":GOSUB880
1180 A$="FBTS XBKK, AVS SGF EVQMJTGJMHT BQF SPP":GOSUB880
1190 A$="FMSJDJMH SP KFBUF.":GOSUB880:RETURN
1200 A$="[217]PV TSBMC IVTS PVSTJCF ZPVQ FWOFMTJUF":GOSUB880
1210 A$="DBAJM PM SGF KVWVQZ KJMFQ.  [212]GF GBKKXBZ":GOSUB880
1220 A$="QVMT MPQSG-TPVSG XJSG ZPVQ DBAJM SP SGF":GOSUB880
1230 A$="XFTS.  [211]JQFMT XBJK XJSGJM SGF TGJO.":GOSUB880:RETURN
1240 A$="[198]QPN GFQF JS JT OPTTJAKF SP HP MPQSG,":GOSUB880
1250 A$="TPVSG, FBTS, PQ XFTS.  [212]P SGF TPVSG JT":GOSUB880
1260 A$="SGF DBQHP ABZ, XGJDG JT MPQNBKKZ MPS":GOSUB880
1270 A$="OQFTTVQJYFC.":GOSUB880:RETURN
1280 A$="[212]GJT JT SGF NBTSFQ FMHJMF QPPN. [193]":GOSUB880
1290 A$="TGQJKK TPVMC FDGPFT EQPN SGF MPQSGFQM":GOSUB880
1300 A$="DQBXKXBZ.  [193] QVTSFC CPPQ FWJST SP SGF":GOSUB880
1310 A$="TPVSG.":GOSUB880:RETURN
1320 A$="[193]KK PE SGFTF DQBSFT DPMSBJM DBQHP SP AF":GOSUB880
1330 A$="SBLFM SP ZPVQ CFTSJMBSJPM.  [193] EFX NJHGS":GOSUB880
1340 A$="DPMSBJM TOBQF OBQST.  [196]PPQT KFBC MPQSG  BMC TPVSG."
1345 GOSUB880:RETURN
1350 A$="[207]MF PE SGF NBMZ OBTTBHFXBZT PM SGF":GOSUB880
1360 A$="TGJO, EQPN GFQF JS JT OPTTJAKF SP HP":GOSUB880
1370 A$="MPQSG, TPVSG, FBTS, BMC XFTS.":GOSUB880:RETURN
1380 A$="[211]SQFXM BAPVS SGF EKPPQ PE SGJT DPNOVSFQ":GOSUB880
1390 A$="QPPN BQF AQPLFM NFNPQZ DQZTSBKT,":GOSUB880
1400 A$="BOOBQFMSKZ EQPN SGF TGJO'T NBJM":GOSUB880
1410 A$="DPNOVSFQ.  [193] KPDLFC GBSDG JT JM SGF":GOSUB880
1420 A$="EKPPQ, BMC FWJST BQF MPQSG BMC TPVSG.":GOSUB880:RETURN
1430 A$="[212]GF AQJCHF JT JM TGBNAKFT!  [211]PNFPMF GBT":GOSUB880
1440 A$="CFEJMBSFKZ TBAPSBHFC SGF TGJO.  [193]QF":GOSUB880
1450 A$="ZPV HFSSJMH XPQQJFC ZFS?  [207]MF FWJS":GOSUB880
1460 A$="KFBCT MPQSG.":GOSUB880:RETURN
1470 A$="[212]XP PE SGF SGQFF KJEFAPBST BQF NJTTJMH;":GOSUB880
1480 A$="SGF KBTS KJEFAPBS JT SP SGF FBTS.  [212]XP":GOSUB880
1490 A$="DVQUJMH OBTTBHFXBZT FWJS EQPN GFQF, PMF":GOSUB880
1500 A$="MPQSG BMC PMF TPVSG.":GOSUB880:RETURN
1510 A$="[212]GF KJEFAPBS JT B KJSSKF ABMHFC-VO.":GOSUB880
1520 A$="[211]PNF OBQST TFFN SP AF NJTTJMH.  [201]S JT":GOSUB880
1530 A$="BT JE ZPV BQF MPS XBMSFC SP KFBUF!":GOSUB880:RETURN
1540 A$="[215]GZ CJC ZPV CP SGBS?  [215]BT JS MPS":GOSUB880
1550 A$="PAUJPVT SGBS SGFTF BQF SGF FMHJMFT?":GOSUB880
1560 A$="[217]PV GBUF DPMTFRVFMSKZ JMDFMFQBSFC":GOSUB880
1570 A$="ZPVQTFKE.  [193]QF ZPV GBOOZ MPX?":GOSUB880:GOTO800
1580 PRINT"[212]HE SCREEN REPLIES:"
1590 A$="[197]MSFQ 1 SP OQFTTVQJYF DBQHP.":GOSUB880
1600 A$="[197]MSFQ 2 SP BDSJUBSF [204]JEF[194]PBS.":GOSUB880
1610 PRINT"[197]NTER YOUR CHOICE NOW->  [146]"
1615 POKE198,0:WAIT198,1:GETA$:A=VAL(A$)
1620 IFA<1ORA>2THEN80
1630 PRINT"[207][203].":IFA=1THENV1=1:GOTO80
1640 IFOP(3)<>12THENPRINT"[206]ON-FUNCTIONAL.":GOTO80
1650 V5=1:V2=1:V4=M+3:GOTO80
1660 OP(3)=12:A$="[212]GF TNBKK CFUJDF BOOBQFMSKZ EJST B GPKF":GOSUB880
1670 A$="JM SGF JMTSQVNFMS APBQC.  [215]JSG DBQF ZPV":GOSUB880
1680 A$="JMTFQS SGF CFUJDF.  [212]GF KJEFAPBS GVNT":GOSUB880
1690 A$="XJSG FMFQHZ.":GOSUB880:GOTO80
1700 A$="[193]T ZPV FMSFQ, SGF KJEFAPBS TFBKT BMC":GOSUB880
1710 A$="TKPXKZ KJEST BXBZ EQPN SGF TGJO.  [217]PV":GOSUB880
1720 A$="GBUF NBCF HPPC ZPVQ FTDBOF.":GOSUB880
1730 A$="[195]PMHQBSVKBSJPMT EQPN [193]MSGPMZ [205]BQP,":GOSUB880
1740 A$="OQPHQBNNFQ.  [203]FFO BCUFMSVQF HBNJMH!":GOSUB880:PRINT:GOTO60000
1750 A$="[196]PM'S ZPV SGJML SGBS ZPV GBUF SBLFM":GOSUB880
1760 A$="KPMH FMPVHG?  [212]GF TGJO GBT TVCCFMKZ":GOSUB880
1770 A$="AQPLFM VO, FWOFKKJMH ZPV JMSP SGF":GOSUB880
1780 A$="UBDVVN PE TOBDF.  [217]PV GBUF CJFC.":GOSUB880:GOTO800
1800 PRINT"[211]OMETHING IS IN THERE!":RETURN
1810 A$="[217]PV EJMC TPNFSGJMH!":V3=1:RETURN
50000 W$="":C=0:PRINT">[146][157]";:IFLIMIT=0THENLIMIT=80
50010 GETA$:IFA$="[145]"ORA$=""ORA$="[157]"ORA$=""ORA$=""ORA$="[147]"ORA$=""THEN50010
50020 AS=ASC(A$):IFAS=13ORAS=141ORAS=20THEN50070
50030 IFPEEK(653)=2ORPEEK(653)=4THEN50010
50040 IFC=LIMIT AND(AS<>20ANDAS<>13ANDAS<>141)THEN50010
50050 IFAS=34OR(AS>=133ANDAS<=140)OR(AS>=1ANDAS<=31)THEN50010
50060 C=C+1:W$=W$+A$:PRINTA$">[146][157]";:GOTO50010
50070 IFAS=20ANDW$<>""THENW$=LEFT$(W$,LEN(W$)-1):PRINT"[157]<[146] [157][157]";:C=C-1:GOTO50010
50075 IFAS=13ANDW$=""THEN50010
50080 IFAS=20ANDW$=""THEN50010
50090 IFAS=13THENPRINT" ":LW=LEN(W$):V=VAL(W$):FL$=LEFT$(W$,1):LL$=RIGHT$(W$,1)
50100 LIMIT=0:AM$=W$:RETURN
60000 FORT=1TO2000:NEXT
60005 OPEN15,8,15,"R0:HELLO CONNECT=HELLO CONNECT":INPUT#15,ER:CLOSE15
60010 IF ER<>63 THEN PRINT"[147]":END
60020 A$="HELLO CONNECT":Q$=CHR$(34):POKE53281,7:POKE53280,7:PRINT"[147]"
60030 PRINT"[158]LOAD"Q$A$Q$",8"
60040 PRINT"RUN":POKE631,13:POKE632,13:POKE198,2:END
61000 POKE214,15:PRINT:PRINT"  [155][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][152]"
61130 FORI=1TO3:PRINT"                                      ":NEXT
61150 PRINT"        [208]UBLISHED ON [204][207][193][196][211][212][193][210] #59     "
61160 PRINT"      sUBSCRIPTIONS 1-800-831-2694    "
61170 PRINT"     changing[160]this[160]notice[160]is[160]illegal  "
61180 PRINT"                                      "
61190 PRINT"  [151][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185]"
61200 AU$="[204][201][198][197][194][207][193][212]":POKE214,17:PRINT:PRINTSPC(20-LEN(AU$)/2)"[152]"AU$
61210 AU$="[194]Y [193]NTHONY [205]ARO  ([195]) 1989":POKE214,18:PRINT
61220 PRINTSPC(20-LEN(AU$)/2)"[152]"AU$""
61230 PRINT""TAB(12)"[159][204] [201] [198] [197] [194] [207] [193] [212]"
61235 PRINTTAB(8)"[154][193] [215]ATERLOGGED [193]DVENTURE"
61240 QQ=QQ+1:GETA$:IFA$=""ANDQQ<200THEN61240
61250 PRINT"[147]":RETURN