1 REM TO PUT YOUR OWN IMAGES IN THIS          VIEWER:
2 REM 1) CREATE A SEQ FILE WITH THE              NUMBER OF IMAGES, FOLLOWED BY
3 REM    "IMAGE NAME,AURTHUR" <CR>.
4 REM     SEQ FILE SHOULD BE NAMED                    "PS.IMAGE.NAMES"
5 REM 2) IF THE SAME PERSON CREATED THE          PREVIOUS IMAGE, PUT AN (*).
6 REM 3) IF YOUR USING EDSTAR, LEAVE             ONE BLANK LINE AT THE BEGIN-
7 REM    NING OF THE FILE.
8 :
9 :
10 POKE53280,2:POKE53281,.:POKE650,128
12 IFX=.THENPRINTCHR$(142)"[147][153]    WELCOME TO THE PRINT SHOP VIEWER"
15 IFX=.THENX=1:LOAD"BLOAD.O",8,1
20 POKE56,120:CLR:POKE2,1
25 SYS828,50759,"TEXT/DOT/WIPE.O"
30 SYS828,51456,"UNPACKER"
35 SYS828,32768,"IMLOADSC6.O"
39 :
40 GOSUB1500:REM DEFINE STRINGS & VARS
50 GOSUB1000:REM READ NAMES OF IMAGES
55 GOSUB2000:REM DISPLAY NAMES FOR VIEW
60 GOSUB2500:REM MOVE HIGHLIGHT AND                      SELECT IMAGES
65 RI=CS+(CP-1)*28:TF=.:FL=.
66 IX=6:IY=6:NL=25:IFNB=3THENIX=13:IY=7:NL=20
70 IFA$="[133]"THENGOSUB3000:SYS51459:GOTO60
75 IFA$="[134]"THENGOSUB5000:SYS51459:GOTO60
80 IFA$="[135]"THENCP=CP+1:IFCP>NPTHENCP=1
81 IFA$="[135]"THENGOSUB2040:IFNP>1THENCS=1
82 IFA$="[135]"THEN60
85 IFA$="[136]"THENGOSUB60000:GOSUB2100:GOTO60
90 DI=RI:GOSUB4000:GOTO60
990 STOP
999 :
1000 OPEN3,8,3,"PS.IMAGE.NAMES":CO=.:NP=1
1005 INPUT#3,NB:REM    BLOCK SIZE                              OF  IMAGES
1007 INPUT#3,NI:REM   NUMBER OF IMAGES
1008 EX=.:IFNI/2<>INT(NI/2)THENNI=NI+1:EX=1
1010 DIM IM$(NI),BY$(NI),ME$(NI)
1020 FORA=1TONI
1025 IFBY$(A)="*"THENBY$(A)=BY$(A-1)
1030 INPUT#3,IM$(A),BY$(A):ME$(A)=IM$(A):CO=CO+1
1040 IFBY$(A)="*"THENBY$(A)=BY$(A-1)
1050 NI(NP)=NI(NP)+1:IFCO=28THENCO=.:NP=NP+1
1060 B=LEN(ME$(A)):IFB<>16THENME$(A)=ME$(A)+LEFT$(SP$,16-B)
1070 NEXT:CLOSE3
1080 IF(EX)THENIM$(NI)="[150]-NOT SELECTABLE-":ME$(NI)=IM$(NI)
1090 RETURN
1100 :
1500 TP$="[213][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][201]"
1510 SI$="[221]                                      [221]"
1520 DI$="[171][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][179]"
1530 BO$="[202][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][203]"
1540 BT$="[202][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][203][157][148][192]"
1550 SP$="                "
1560 CS=1    :REM CURRENT SELECTION
1570 JO=56320:REM JOYSTICK PORT 2
1580 CP=1    :REM CURRENT PAGE
1990 RETURN
1999 :
2000 PRINT"[147][153][146]"TP$SI$SI$DI$;
2010 FORA=1TO14:PRINTSI$;:NEXT
2020 PRINTDI$SI$SI$SI$SI$SI$BT$;
2030 FORA=217TO242:POKEA,PEEK(A)OR128:NEXT
2040 PRINT"[146]        [158]PRINT SHOP VIEWER V2"
2050 PRINT"[150]BY A. GARDNER, J. WEILER, & M. MAYNARD"
2060 PRINT"";
2070 MI=INT(NI(CP)/2):REM MIDDLE IMAGE
2080 IF(NP>1)AND(CP<>NP)THENMI=14
2085 SI=(CP-1)*28:REM STARTING IMAGE                          FOR CURRENT PAGE
2090 FORA=SI+1TOSI+MI:PRINTTAB(1)"][154]"ME$(A)"[  ][154]"ME$(A+MI)"[":NEXT
2093 IFSI+14=SI+MITHEN2100
2096 FORA=SI+13TOSI+MISTEP-1:PRINT"                                      ":NEXT
2100 PRINT"[154]NUMBER OF PAGES:"NP;
2110 PRINTTAB(23)"[154]CURRENT PAGE:"CP
2120 PRINT"F1 [154]- AUTO MODE"
2130 PRINT"F3 [154]- QUICK LOOK       [158]CRSR KEYS MOVE "
2140 PRINT"F5 [154]- NEXT PAGE          [158]HIGHLIGHT"
2150 PRINT"F7 [154]- QUIT           [158]RETURN SELECTS IT."
2160 RETURN
2500 B=CS:IFB>MITHENB=B-MI
2510 PRINT"";:FORA=1TOB:PRINT:NEXT
2520 PRINTTAB(2);:IFCS>MITHENPRINTTAB(19)"->";
2530 PRINT""ME$(SI+CS);:POKE198,.
2535 IFCS<MI+1THENPRINT"[146]<-";
2540 GETA$:GOSUB2700:IFA$=""THEN2540
2543 IF(A$=CHR$(13))AND(IM$(SI+CS)="[150]-NOT SELECTABLE-")THEN2540
2545 IF(A$=CHR$(13))OR(A$="[133]")OR(A$="[134]")OR(A$="[135]")OR(A$="[136]")THENRETURN
2550 B=CS:IFB>MITHENB=B-MI
2560 PRINT"";:FORA=1TOB:PRINT:NEXT
2570 PRINTTAB(2);:IFCS>MITHENPRINTTAB(19)"  ";
2580 PRINT"[154]"ME$(SI+CS);
2585 IFCS<MI+1THENPRINT"  ";
2590 IFA$=""THENCS=CS+1:IFCS>NI(CP)THENCS=NI(CP)
2600 IFA$="[145]"THENCS=CS-1:IFCS<1THENCS=1
2610 IFA$=""THENCS=CS+MI:IFCS>NI(CP)THENCS=CS-MI*2
2620 IFA$="[157]"THENCS=CS-MI:IFCS<1THENCS=CS+MI*2
2640 GOTO2500
2700 IF(PEEK(JO)AND16)=.THENA$=CHR$(13):RETURN
2710 A=(PEEK(JO)AND15):IFA=15THENRETURN
2720 IFA=14THENA$="[145]"
2730 IFA=07THENA$=""
2740 IFA=13THENA$=""
2750 IFA=11THENA$="[157]"
2760 RETURN
2990 REM DISPLAY THE IMAGES STARTING AT          RI (WHICH IS WHERE THE HIGH-
2991 REM LIGHT IS CURRENTLY AT) AND              ENDING WITH THE LAST IMAGE
3000 FORDI=RITONI:TF=1
3005 IFIM$(DI)="[150]-NOT SELECTABLE-"THEN3030
3012 GOSUB4000:REM PLOT PS IMAGE
3020 POKE249,224:POKE250,204:SYS50765:IFA$="Q"ORA$="[209]"THENRETURN
3025 FL=1
3030 NEXT:IFRI=1THENRETURN:REM IF RI=1       WE STARTED AT THE BEGINNING
3035 REM DISPLAY THE IMAGES STARTING             AT 1 AND ENDING AT RI - 1
3040 FORDI=1TORI-1:TF=1
3045 IFIM$(DI)="[150]-NOT SELECTABLE-"THEN3080
3060 GOSUB4000:REM PLOT PS IMAGE
3070 POKE249,224:POKE250,204:SYS50765:IFA$="Q"ORA$="[209]"THENRETURN
3075 FL=1
3080 NEXT:RETURN
4000 IFFL=.THENPOKE249,224:POKE250,204:SYS51459:SYS50765
4007 N$=IM$(DI):POKE53270,200:SYS50759,N$,(160-LEN(N$)*8/2),.
4008 N$="CREATED BY":SYS50759,N$,(160-LEN(N$)*8/2),8
4009 N$=BY$(DI):SYS50759,N$,(160-LEN(N$)*8/2),16
4010 :
4020 POKE53270,200
4030 SYS32768,IM$(DI),NB,57344,60328
4040 :
4060 SYS50759,"PRESS A KEY",112,172:IFTF=1THENSYS50759,"[Q TO QUIT]",112,180
4062 POKE198,.
4065 GETA$:GOSUB2700:IFA$=""THEN4065
4070 IFTF=.THENSYS51459
4080 RETURN
5000 PX=.:PY=2:TF=1:POKE249,224:POKE250,204:SYS51459:SYS50765:POKE53270,200
5010 GOSUB7000
5050 FORX=1TONI-EX
5060 POKE53270,200:SYS32768,IM$(X),NB,57344,57344+PX*8+PY*320
5070 PX=PX+IX:IFPX>33THENPX=.:PY=PY+IY
5080 GETA$:IFA$="Q"ORA$="[209]"THENRETURN
5090 FL=.:IFPX=.ANDPY=23THENGOSUB6000:IFFL=1THENRETURN
5100 NEXT:FL=1:SYSTE,"[PRESS A KEY]",118,188
5110 POKE198,.:WAIT198,1:RETURN
5120 :
6000 SYSTE,"[PRESS A KEY]",118,190
6010 POKE198,.:WAIT198,1:GETA$:POKE198,.:IFA$="Q"ORA$="[209]"THENFL=1:RETURN
6020 POKE249,224:POKE250,204:SYS50765
6030 GOSUB7000:PX=.:PY=2:RETURN
7000 TE=50759:SYSTE,"PRINT SHOP IS A TRADEMARK OF BRODERBUND",.,.
7010 REM  SYSTE,"TRADEMARK",244,56
7020 REM  SYSTE,"OF",276,64:SYSTE,"BRODERBUND",244,72
7030 SYSTE,"SOFTWARE  -----------  PRESS Q TO QUIT.",.,8
7040 RETURN
60000 PRINT"[146]";
60010 FORA=1TO2:PRINT"                                      ":NEXT
60020 PRINT"[154] ARE YOU SURE YOU WANT TO QUIT? (Y[154]/N[154])":POKE198,.
60030 FORA=1TO2:PRINT"                                      ":NEXT
60040 A=PEEK(203):IFA<>25ANDA<>39THEN60040
60050 IFA=39THENRETURN
60060 OPEN15,8,15,"R0:HELLO CONNECT=HELLO CONNECT":INPUT#15,ER:CLOSE15
60070 IFER<>63THENPRINT"";:POKE198,.:END
60080 LOAD"HELLO CONNECT",8