10 S=65520:F=54272
20 POKE783,PEEK(783)AND254
30 POKE53280,14:POKE53281,1:PRINTCHR$(14):PRINTCHR$(8):DIMQU$(60),RE$(60)
39 :
40 GOSUB10000:REM *** TITLE PAGE ***
49 :
50 GOSUB11000:REM *** INSTRUCTIONS ***
59 :
60 GOSUB4000:REM *** READ TEXT FILE ***
69 :
70 GOSUB1100:REM *** SCRAMBLE QUERY AND REPSONSE ***
79 :
80 GOSUB3000:REM *** FORMAT SCREEN ***
89 :
90 GOSUB1200:REM *** GET QUERY AND RESPONSE ***
99 :
100 Q$=QU$:V=5:H=1:LF=38:GOSUB1000
109 :
110 V=13:H=4:PP=0:PR=0:GOSUB2100:REM *** KEYBOARD INPUT ***
119 :
120 IFFLAG=1THENPOKE781,13:POKE782,4:SYSS:PRINTRE$:GOSUB970
130 IFFLAG=1THENSC=0:POKE781,21:POKE782,9:SYSS:PRINT"[206]O POINTS FOR THIS ONE![146]"
135 FLAG=0
139 :
140 HS=HS+SC:POKE781,19:POKE782,10-LEN(STR$(HS)):SYSS:PRINTHS:SC=0
149 :
150 POKE781,23:POKE782,5:SYSS:PRINT"[196]O YOU WANT TO CONTINUE (Y/N)? "
160 POKE198,0:WAIT198,1:GETKEY$
170 IFKEY$="Y"ORKEY$="[217]"THEN80
180 IFKEY$="N"ORKEY$="[206]"THEN200
190 GOTO150
200 POKE781,23:POKE782,0:SYSS
205 PRINT"[196]O YOU WANT TO SELECT ANOTHER CATEGORY":PRINT"(Y/N)?";
210 POKE198,0:WAIT198,1:GETKEY$
220 IFKEY$="Y"ORKEY$="[217]"THEN60
230 IFKEY$="N"ORKEY$="[206]"THEN3200
240 GOTO200
900 STOP
957 :
958 REM *** WRONG LETTER SOUND      ***
959 :
960 POKEF+24,15:POKEF+6,240:POKEF+4,17
961 FORX1=25TO1STEP-4:POKEF+1,26-X1:NEXTX1:POKEF+4,32:POKEF+4,16:RETURN
967 :
968 REM *** WRONG ANSWER SOUND      ***
969 :
970 POKEF+24,24:POKEF+6,240:POKEF+4,17
971 FORA=1TO4:FORX1=16TO62STEP4:POKEF+1,77-X1:NEXTX1:NEXTA:POKEF+4,32
972 POKEF+4,16:RETURN
977 :
978 REM *** RIGHT ANSWER SOUND      ***
979 :
980 POKEF+24,15:POKEF+6,240:POKEF+4,17
981 FORA=1TO4:FORX1=1TO25:POKEF+1,80-X1:NEXTX1:NEXTA:POKEF+4,32:POKEF+4,16:RETURN
987 :
988 REM *** LETTER SOUND            ***
989 :
990 POKEF+1,14:POKEF+5,3:POKEF+6,240:POKEF+24,15:POKEF+4,17
991 FORD=3TO40STEP15:POKEF+1,D:POKEF+4,17:NEXTD:POKEF+4,32:RETURN
997 :
998 REM *** FORMAT STATEMENTS      ***
999 :
1000 IFLEN(Q$)>LFTHEN1020
1010 POKE781,V:POKE782,H:SYSS:PRINTQ$:RETURN
1020 YF=0:XF=LF
1030 IFMID$(Q$,XF,1)=CHR$(32)THENPOKE781,V:POKE782,H:SYSS
1040 IFMID$(Q$,XF,1)=CHR$(32)THENPRINTLEFT$(Q$,XF-1):V=V+1:GOTO1060
1050 XF=XF-1:GOTO1030
1060 YF=XF+LF:IFYF>LEN(Q$)THENYF=LEN(Q$)-XF
1070 IFYF<=LFTHENPOKE781,V:POKE782,H:SYSS:PRINTRIGHT$(Q$,YF):RETURN
1080 IFMID$(Q$,YF,1)=CHR$(32)THENPOKE781,V:POKE782,H:SYSS
1090 IFMID$(Q$,YF,1)=CHR$(32)THENPRINTMID$(Q$,XF+1,YF-XF):XF=YF:V=V+1:GOTO1060
1095 YF=YF-1:GOTO1080
1097 :
1098 REM *** SCRAMBLE QUERY/RESPONSE ***
1099 :
1100 FORX=1TONU:A%=(RND(1)*NU)+1
1105 T1$=QU$(X):QU$(X)=QU$(A%):QU$(A%)=T1$
1110 T2$=RE$(X):RE$(X)=RE$(A%):RE$(A%)=T2$:NEXT:Z9=0
1120 RETURN
1197 :
1198 REM *** GET QUERY/RESPONSE    ***
1199 :
1200 Z9=Z9+1:IFZ9>NUTHEN1220
1210 QU$=QU$(Z9):RE$=RE$(Z9):RETURN
1220 PRINTCHR$(147):PRINT"[207]NE MOMENT, PLEASE, WHILE [201] GET SOME"
1230 PRINT"MORE QUESTIONS......."
1240 GOSUB1100:GOSUB3000:GOTO1200
2097 :
2098 REM *** KEYBOARD INPUT        ***
2099 :
2100 FORX=1TOLEN(RE$):TI$="000000"
2110 GETKEY$:GOSUB2200:IFSC<=0THENFLAG=1:X=LEN(RE$):GOTO2150
2111 IFKEY$=""THEN2110
2115 IFKEY$=CHR$(133)THENFLAG=1:X=LEN(RE$):GOTO2150
2116 IFKEY$>CHR$(192)THENT$=CHR$(ASC(KEY$)-128):GOTO2118
2117 T$=KEY$
2118 M$=MID$(RE$,X,1):IFM$>CHR$(128)THENM$=CHR$(ASC(M$)-128)
2120 IFT$=M$THENGOSUB2220:GOTO2150
2140 PP=PP+1:GOSUB960:GOTO2110
2150 NEXT
2155 IFFLAG=0THENPOKE781,12:POKE782,24:SYSS:PRINT"[129] [210][201][199][200][212]! [146]":GOSUB980
2160 RETURN
2197 :
2198 REM *** TIMER/SCORE ROUTINE    ***
2199 :
2200 IFTI$<>"000000"THENPR=PR+1:TI$="000000"
2205 SC=100-PP-PR
2210 POKE781,10:POKE782,38-LEN(STR$(SC)):SYSS:PRINTSC:RETURN
2217 :
2218 REM *** PRINT KEY              ***
2219 :
2220 POKE781,V:POKE782,H:SYSS:PRINTKEY$:GOSUB990:H=H+1:RETURN
2997 :
2998 REM *** FORMAT SCREEN          ***
2999 :
3000 PRINTCHR$(147):POKE781,1:POKE782,0:SYSS
3010 FORX=1TO120:PRINT"*";:NEXT
3020 PRINT"":FORX=1TO80:PRINT"*";:NEXT
3030 PRINT"":FORX=1TO80:PRINT"*";:NEXT
3040 POKE781,2:POKE782,15:SYSS:PRINT" [210][197][195][207][204][204][197][195][212][160][146]"
3050 POKE781,10:POKE782,20:SYSS:PRINT"[213][206][201][212][160][211][195][207][210][197] >>>[146]"
3060 POKE781,11:POKE782,0:SYSS:PRINT"[212][200][197][160][210][197][211][208][207][206][211][197][160][201][211]:[146]"
3070 POKE781,13:POKE782,0:SYSS:PRINT">>>[146]"
3080 POKE781,18:POKE782,0:SYSS:PRINT"[199][193][205][197][160][211][195][207][210][197][146]"
3090 POKE781,18:POKE782,18:SYSS:PRINT"[208]RESS <[198]1>[146] FOR ANSWER"
3100 :
3110 POKE781,19:POKE782,10-LEN(STR$(HS)):SYSS:PRINTHS:SC=0
3120 RETURN
3197 :
3198 REM *** END GAME               ***
3199 :
3200 PRINTCHR$(147)
3210 PRINT"[217]OUR FINAL SCORE WAS "HS:FLAG=0
3219 :
3220 OPEN15,8,15:OPEN4,8,4,"0:R.HIGH SCORE,SEQ,READ"
3230 FORX=0TO9:INPUT#4,H$(X,0):INPUT#4,H$(X,1):NEXT:CLOSE4:CLOSE15
3239 :
3240 IFHS<VAL(H$(9,1))THENFLAG=1
3249 :
3250 IFFLAG=1THENPRINT"[217]OUR SCORE WAS NOT HIGH ENOUGH TO BE"
3260 IFFLAG=1THENPRINT"INCLUDED IN MY HIGH SCORE LIST."
3270 IFFLAG=1THENPRINT"[194]ETTER LUCK NEXT TIME!":FLAG=0:GOTO3510
3279 :
3280 PRINT:PRINT"[217]OUR SCORE WAS VERY GOOD!  [197]NTER YOUR"
3290 PRINT"INITIALS AND [201] WILL INCLUDE IT IN MY"
3300 PRINT"HIGH SCORE LIST!"
3309 :
3310 PRINT:PRINT
3320 INPUT"[197]NTER YOUR INITIALS";IT$
3330 PRINT:PRINT"[207]NE MOMENT, PLEASE....."
3340 IFIT$=""THENIT$="[193][193][193]"
3350 IFLEN(IT$)>3THENIT$=LEFT$(IT$,3)
3360 H$(9,0)=IT$:H$(9,1)=RIGHT$(STR$(HS),LEN(STR$(HS))-1)
3369 :
3370 FORI=0TO8:FORJ=I+1TO9:IFVAL(H$(I,1))>=VAL(H$(J,1))THEN3400
3380 K$=H$(I,1):H$(I,1)=H$(J,1):H$(J,1)=K$
3390 K$=H$(I,0):H$(I,0)=H$(J,0):H$(J,0)=K$
3400 NEXTJ:NEXTI
3409 :
3410 OPEN15,8,15,"I0":PRINT#15,"S0:R.HIGH SCORE"
3420 OPEN4,8,4,"0:R.HIGH SCORE,SEQ,WRITE"
3430 FORX=0TO9:PRINT#4,H$(X,0):PRINT#4,H$(X,1):NEXT
3440 CLOSE4:CLOSE15
3449 :
3450 POKE781,23:POKE782,1:SYSS:PRINT"[208]RESS ([211][208][193][195][197] [194][193][210]> TO CONTINUE.";
3460 POKE198,0:WAIT198,1:GETKEY$
3469 :
3470 PRINTCHR$(147):PRINT"[200]IGH SCORES FOR [210][197][195][207][204][204][197][195][212] ARE:"
3480 PRINT:FORX=0TO9:PRINTH$(X,0);TAB(15-LEN(H$(X,1)));H$(X,1):PRINT:NEXT
3489 :
3490 POKE781,23:POKE782,1:SYSS:PRINT"[208]RESS <[211][208][193][195][197] [194][193][210]> TO CONTINUE.";
3500 POKE198,0:WAIT198,1:GETKEY$
3509 :
3510 PRINTCHR$(147):PRINT:PRINT:PRINT"[196]OES SOMEONE ELSE WANT TO TRY [210][197][195][207][204][204][197][195][212] (Y/N)?[160]";
3520 POKE198,0:WAIT198,1:GETKEY$
3530 IFKEY$="Y"ORKEY$="[217]"THENSC=0:HS=0:GOTO60
3540 IFKEY$="N"ORKEY$="[206]"THEN3560
3550 GOTO3520
3559 :
3560 PRINT"[147]"
3562 PRINT:PRINT:PRINT:PRINT"[212]HANKS FOR PLAYING [210][197][195][207][204][204][197][195][212]!"
3569 :
3570 GOTO63000  :REM *** END ***
3997 :
3998 REM *** READ TEXT FILE        ***
3999 :
4000 PRINTCHR$(147)
4010 PRINT"[215]HICH FILE WOULD YOU LIKE ME TO GET?"
4020 POKE781,5:POKE782,5:SYSS:PRINT"0.  [197]XIT PROGRAM"
4030 POKE781,7:POKE782,5:SYSS:PRINT"1.  [210][197][195][207][204][204][197][195][212] WRITTEN WORD"
4040 POKE781,9:POKE782,5:SYSS:PRINT"2.  [210][197][195][207][204][204][197][195][212] TV SHOWS"
4050 POKE781,11:POKE782,5:SYSS:PRINT"3.  [210][197][195][207][204][204][197][195][212] LITERARY"
4060 POKE781,14:POKE782,1:SYSS:PRINT"[215]HICH ONE (0-3) -[160]";
4070 POKE198,0:WAIT198,1:GETKEY$:PRINTKEY$
4075 IFKEY$="0"THEN3200
4080 IFKEY$="1"THENFI$="R.WRITTEN WORD":GOTO4120
4090 IFKEY$="2"THENFI$="R.TV SHOWS":GOTO4120
4100 IFKEY$="3"THENFI$="R.LITERARY":GOTO4120
4110 GOTO4060
4120 PRINT:PRINT:PRINT"[207]NE MOMENT, PLEASE, WHILE [201] GET THE     INFORMATION...."
4122 OPEN15,8,15
4125 OPEN4,8,4,"0:"+FI$+",SEQ,READ"
4130 INPUT#4,NU
4140 FORX=1TONU:INPUT#4,QU$(X):INPUT#4,RE$(X):NEXT
4150 CLOSE4:CLOSE15
4160 RETURN
9997 :
9998 REM *** TITLE PAGE            ***
9999 :
10000 PRINTCHR$(147)
10010 PRINTTAB(12)"*#*#*#*#*#*#*#*"
10020 PRINTTAB(12)"#             #"
10030 PRINTTAB(12)"*             *"
10040 PRINTTAB(12)"#  [210][197][195][207][204][204][197][195][212]  #"
10050 PRINTTAB(12)"*             *"
10060 PRINTTAB(12)"#             #"
10070 PRINTTAB(12)"*#*#*#*#*#*#*#*"
10080 PRINT:PRINT:PRINTTAB(9)"[193] [199]AME OF [210]EMEMBERING"
10090 PRINT"";TAB(19)"BY"
10100 PRINT"";TAB(13)"[196]ONNA [203]. [215]OODY"
10110 RETURN
10997 :
10998 REM *** INSTRUCTIONS          ***
10999 :
11000 POKE781,23:POKE782,5:SYSS:PRINT"[196]O YOU WANT INSTRUCTIONS (Y/N)?";
11010 POKE198,0:WAIT198,1:GETKEY$
11020 IFKEY$="N"ORKEY$="[206]"THEN11520
11030 IFKEY$="Y"ORKEY$="[217]"THEN11050
11040 GOTO11000
11050 PRINTCHR$(147)
11060 PRINT:PRINT"  [200]OW WELL DO YOU REMEMBER?  [206]OT JUST"
11070 PRINT:PRINT"THE IMPORTANT THINGS, BUT ALSO THE"
11080 PRINT:PRINT"LITTLE, FUN THINGS?  [204]IKE WHO STARRED"
11090 PRINT:PRINT"IN [195][193][211][193][194][204][193][206][195][193]?  [212]HIS GAME WILL GIVE"
11100 PRINT:PRINT"YOU A CHANCE TO SEE JUST HOW MUCH YOU"
11110 PRINT:PRINT"DO REMEMBER!"
11120 PRINT:PRINT"  [201] WILL GIVE YOU A QUESTION OR"
11130 PRINT:PRINT"STATEMENT TO ANSWER.  [193]LL YOU HAVE TO"
11140 PRINT:PRINT"DO IS TYPE IN THE CORRECT RESPONSE."
11150 PRINT:PRINT"[211]OUND EASY?  [212]HERE ARE A FEW CATCHES!"
11160 POKE781,23:POKE782,5:SYSS:PRINT"[208]RESS <[211][208][193][195][197] [194][193][210]> TO CONTINUE.";
11170 POKE198,0:WAIT198,1:GETKEY$:PRINTCHR$(147)
11180 PRINT:PRINT"  [201] WON'T LET YOU ENTER ANY LETTERS (OR"
11190 PRINT:PRINT"SPACES!) THAT AREN'T IN THE CORRECT"
11200 PRINT:PRINT"PLACE IN THE RESPONSE!  [198]OR EACH WRONG"
11210 PRINT:PRINT"LETTER YOU TRY TO ENTER, [201] WILL TAKE"
11220 PRINT:PRINT"A POINT OFF YOUR SCORE!  [212]HE CLOCK IS"
11230 PRINT:PRINT"ALSO COUNTING DOWN FROM 100, SO EACH"
11240 PRINT:PRINT"SECOND YOU DELAY TAKES ANOTHER POINT"
11250 PRINT:PRINT"AWAY FROM YOUR SCORE!  [211]O YOU HAVE TO"
11260 PRINT:PRINT"BE FAST AND ACCURATE WHEN YOU ANSWER!"
11270 POKE781,23:POKE782,5:SYSS:PRINT"[208]RESS <[211][208][193][195][197] [194][193][210]> TO CONTINUE.";
11280 POKE198,0:WAIT198,1:GETKEY$:PRINTCHR$(147)
11290 PRINT:PRINT"  [217]OU CAN GIVE UP AT ANY TIME BY"
11300 PRINT:PRINT"PRESSING THE [198]1 KEY.  [201]F YOU DO, YOU"
11310 PRINT:PRINT"WILL GET TO SEE THE ANSWER, BUT YOU"
11320 PRINT:PRINT"WON'T GET ANY POINTS FOR THE RESPONSE."
11330 PRINT:PRINT"  [193]S AN INCENTIVE TO DO BETTER, THE TOP"
11340 PRINT:PRINT"10 HIGH SCORES ARE SAVED TO DISK."
11350 PRINT:PRINT"  [217]OU WILL HAVE A CHOICE OF THREE"
11360 PRINT:PRINT"DIFFERENT SETS OF [210][197][195][207][204][204][197][195][212] QUESTIONS"
11370 PRINT:PRINT"TO USE.  [202]UST ENTER THE NUMBER OF THE"
11380 PRINT:PRINT"FILE YOU WANT AND [201] WILL GET IT FOR"
11390 POKE781,23:POKE782,5:SYSS:PRINT"[208]RESS <[211][208][193][195][197] [194][193][210]> TO CONTINUE.";
11400 POKE198,0:WAIT198,1:GETKEY$:PRINTCHR$(147)
11410 PRINT:PRINT"YOU.  [201] WILL ALSO RANDOMLY PICK"
11420 PRINT:PRINT"QUESTIONS FROM THE FILE, SO EACH TIME"
11430 PRINT:PRINT"YOU PLAY THE QUESTIONS WILL BE"
11440 PRINT:PRINT"DIFFERENT."
11450 REM      PRINT:PRINT"  ([217]OU CAN ALSO CREATE YOUR OWN FILES"
11460 REM      PRINT:PRINT"BY USING THE PROGRAM CALLED [210][197][195][207][204][204][197][195][212]"
11470 REM      PRINT:PRINT"[198][201][204][197][160][195][210][197][193][212][207][210].)"
11480 PRINT:PRINT"  [199]ET READY!  [204]ET'S SEE HOW MANY THINGS"
11490 PRINT:PRINT"YOU CAN [210][197][195][207][204][204][197][195][212]!"
11500 POKE781,23:POKE782,5:SYSS:PRINT"[208]RESS <[211][208][193][195][197] [194][193][210]> TO CONTINUE.";
11510 POKE198,0:WAIT198,1:GETKEY$:PRINTCHR$(147)
11520 RETURN
63000 POKE646,PEEK(53281)
63002 PRINT"LOAD"CHR$(34)"HELLO"CHR$(34)",8":PRINT"RUN"
63004 POKE631,13:POKE632,13:POKE198,2:END