Activate 方法

激活活页夹中的稿件。

语法

object.Activate

object

必须的。将被激活的 Section 对象。

说明

几个稿件能同时被选择，但其中只有一个稿件是被激活的。如果被激活的稿件具有隐藏属性，它将变为可见。

使用 SelectedSectionNames 属性返回或设置所选择的稿件名。


Activate 方法示例

本示例创建一个新的活页夹，增添一个 Microsoft Excel 工作簿和一个工作文档，并且激活第一个稿件。

Set newBinder = CreateObject("Office.Binder")

newBinder.Visible = True

newBinder.Sections.Add Type:="Excel.Sheet"

newBinder.Sections.Add Type:="Word.Document"

newBinder.Sections(1).Activate


Active Section 属性

返回一个 Section 对象 代表了活页夹中被激活的稿件。如果活页夹中不包含可见稿件，将会产生一个错误。只读。

说明

要使一个稿件被激活，可使用 Activate 方法。


ActiveSection 属性示例

如果第一个稿件的类型是 Excel.Sheet.5 ，本示例打开活页夹 Binder1.obd 并创建第一个稿件的备份。新的稿件将被插入到最后一个稿件的后面。

Set newBinder = GetObject("Binder1.obd", "Office.Binder")

newBinder.Visible = True

newBinder.Sections(1).Activate

If ActiveSection.Type = "Excel.Sheet.5" Then

newBinder.ActiveSection.Copy

End If


Add 方法

在活页夹中创建一个新的稿件，返回一个 Section 对象，这个对象代表新的稿件。添加一个稿件可以依靠创建一个新的对象或向已经存在的文件中插入一个稿件来完成。

语法

object.Add(type, fileName, before, after)

object

必须的。Sections 对象。

type

可选的。创建的稿件类型必须为以下之一 ，Excel.Chart， Excel.Sheet， Word.Document， PowerPoint.Show， 或 PowerPoint.Slide. 如果 type 被省略， 必须指明 fileName 。

fileName

可选的。文件的完整路径和文件名包含所要添加的稿件，如果 fileName 被省略，必须指明 type 。

before

可选的。新的稿件添加到指定稿件之前。如果指定了 after ，就不能指定 before 。

after

可选的。新的稿件添加到指定稿件之后。如果指定了 before ，就不能指定 after 。

说明

在 type 和 fileName 之间必须指定一个。指定 type 名不必包含版本号，版本号由 Type 属性返回。

如果省略 before 和 after，新稿件将被添加到活页夹中最后一个稿件的后面。


Add 方法示例

本示例在 Binder1.obd 中第一个稿件之前添加一个新的 Word 文档。

Set newBinder = GetObject("Binder1.obd", "Office.Binder")

newBinder.Visible = True

With newBinder.Sections.Add(Type:="Word.Document", before:=1)

    .Name = "Totals"

End With


Copy 方法

把稿件复制到活页夹中其他的地方。返回新的 Section 对象。

语法

object.Copy(before, after)

object

必须的。Section 对象。

before

可选的。这个稿件将被复制到当前稿件的前面。如果指定了 after，就不能指定 before。

after

可选的。这个稿件将被复制到当前稿件的后面。如果指定了 before，就不能指定 after。

说明

如果省略 before 和 after，复制的稿件将被插入到活页夹中最后一个稿件的后面。


Copy 方法示例

本示例判断 Binder1.obd 中的活动稿件类型是否为 Excel.Sheet.5。 如果是，本示例将此稿件复制到稿件 "Document."之后。

Set newBinder = GetObject("Binder1.obd", "Office.Binder")

newBinder.Visible = True

If newBinder.ActiveSection.Type = "Excel.Sheet.5" Then

newBinder.ActiveSection.Copy after:="Document"

End If


Count 属性

返回 Sections 集合对象的序号。只读。

说明

所有的稿件，不管是可见的还是隐藏的，都有序号。


Count 属性示例

本示例显示 Binder1.obd 中的稿件数。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

sectionNumber = myBinder.Sections.Count

binderName = myBinder.Name

Set myBinder = Nothing

MsgBox "There are " & sectionNumber & " sections in " _

& binderName


Delete 方法

删除 Section 对象。

语法

object.Delete

object

必须的。Section 对象。


Delete 方法示例

本示例删除 Binder2.obd 中的第三个稿件。

Set myBinder = GetObject("Binder2.obd", "Office.Binder")

myBinder.Visible = True

myBinder.Sections(3).Delete


Index 属性

使用 Sections 集合对象返回 Section 对象的索引号。只读。

说明

所有的稿件，不管是可见的还是隐藏的，都包含在索引计数之列。

使用 Move 方法改变稿件的顺序。


Index 属性 示例

本示例判断活动稿件是否为 Binder1.obd 中的第一个稿件，如果是，本示例将把第一个稿件移动到第三个稿件之后。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

myBinder.Visible = True

If myBinder.ActiveSection.Index = 1 Then

myBinder.ActiveSection.Move after:=3

End If


Item 属性

从 Sections 集合对象返回 Section 对象。只读。

语法

object.Item(index)

object

要求 Sections 对象。

index

要求稿件编号或稿件名。

说明

因为 Item 属性 是 Sections 集合对象的默认属性，以下说明是相同的。

myBinder.Sections.Item(3)

myBinder.Sections(3)


Item 属性 示例

本示例显示 Binder1.obd 中第三个稿件的名字。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

sectionName = myBinder.Sections.Item(3).Name

Set myBinder = Nothing

MsgBox sectionName


LeftPane 属性

如果活页夹窗口的左窗格是可见的，为 True 。左边的窗格也称为活页夹窗格，其中包含了活页夹中所有稿件的图标。只读。


LeftPane 属性示例

本示例创建一个新的活页夹并使它可见。接着添加一个类型为 Excel.Sheet 的稿件，隐藏活页夹方格，并以 Binder1.obd 名保存活页夹。

Set newBinder = CreateObject("Office.Binder")

newBinder.Visible = True

With newBinder

.Sections.Add Type:="Excel.Sheet"

.LeftPane = False

.SaveAs "Binder1.obd"

End With


Move 方法

把稿件移动到活页夹其他的地方。

语法

object.Move(before, after)

object

必须的。Section 对象。

before

可选的。这个稿件将被移动到当前稿件的前面，如果指定了 after，就不能指定 before。

after

可选的。这个稿件将被移动到当前稿件的后面，如果指定了 before，就不能指定 after。

说明

如果省略 before 和 after，这个稿件将被移动到活页夹中最后一个稿件的后面。


Move 方法示例

本示例判断 Binder1 中的活动稿件是否在第一个稿件之后，如果是，本示例将活动稿件移动到活页夹中第一个稿件之前。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

myBinder.Visble = True

If myBinder.ActiveSection.Index <> 1 Then

myBinder.ActiveSection.Move before:=1

End If


Name 属性

返回或设置 Binder 或 Section 对象名，如下例所示。只读。

对象	名称
Binder	活页夹文件名，并不包含磁盘路径。只读。
Section	稿件名，如活页夹方格中的图标显示。只读。


Name 属性示例

本示例把 Binder1.obd 中的活动稿件命名为 "Budget 95"。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

mBinder.Visible = True

myBinder.ActiveSection.Name = "Budget 95"


Object 属性

返回与这个稿件相关联的 OLE 自动对象名。只读。

说明

使用此属性能够存取稿件的内容。（例如， Microsoft Excel 工作表中的单元格 A1 的值。）


Object 属性 示例

本示例显示稿件 "Revenue 96." 中单元格 "GrandTotal" 的值。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

myBinder.Visible = True

total = myBinder.Sections("Revenue 96").Object.Range("GrandTotal")

MsgBox "The grand total for 1996 is " & total


Parent 属性

返回指定对象的父对象。只读。


Parent 属性 示例

本示例提示用户一个活页夹已经打开，接着增加一个类型为 Excel.Sheet 的稿件并在工作图表的 A1 网格中插入活页夹路径。

obd = InputBox("Specify the binder to open")

Set myBinder = GetObject(obd, "Office.Binder")

myBinder.Visible = True

Set newSection = myBinder.Sections.Add(type:="Excel.Sheet")

newSection.Object.Range("A1").Value = newSection.Parent.Path


Path 属性

返回完整的路径名（作为串），不包含活页夹名。只读。


Path 属性 示例

本示例显示 Binder1.obd. 完整的路径名。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

MsgBox myBinder.Path & myBinder.Name

Set myBinder = Nothing


PrintOut 方法

打印活页夹中每一个稿件，一类稿件，或是某一个稿件。

语法 1

object.PrintOut(what, numbering, firstPage, sections, fileName, printerName, driverName, noPrinting)

语法 2

object.PrintOut

object

必须的。Binder 对象 （语法 1） 或 Section 对象（语法 2）。

what

必须的。活页夹中被打印的稿件。为以下之一：bindPrintActiveSection, bindPrintVisibleSections, bindPrintSelectedSections, 或 bindPrintSectionSubset。

numbering

可选的。页码图，为 bindConsecutivePages（默认）或 bindRestartEachSection。

firstPage

可选的。 页码的起始号，如果默认，则为1。

sections

可选的。如果 what 是 bindPrintSectionSubset, 被打印的稿件索引为一维数组。

fileName

可选的。文件名，在此处打印方向将被改变。

printerName

可选的。 打印机名，如果省略，将使用默认的打印机。

driverName

可选的。 打印机驱动程序名，如果省略，将使用默认的打印机驱动程序。

noPrinting

可选的。如果是 True， printerName 和 driverName 被设置成不完成打印，如果 False 或省略，打印完成。

说明

使用 语法 1 和对 sections 参数指定索引号，可以打印单一稿件，或使用其中的一种打印方法，稿件的类型由对象模式提供（通过　Object 属性存取）。


PrintOut 方法示例

本示例打印 Binder1.obd. 中所有可见的稿件。第一页的编号为10。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

myBinder.PrintOut what:=bindPrintVisibleSections, _

numbering:=bindConsecutivePages, firstPage:=10

Set myBinder = Nothing

本示例打印 Binder4.obd 中第一个、第二个稿件和稿件名为"Expense Report"的稿件。

Set myBinder = GetObject("Binder4.obd", "Office.Binder")

myBinder.PrintOut what:=bindPrintSectionSubset, _

sections:=Array(1, 2, "Expense Report")

Set myBinder = Nothing


Save 方法

保存对指定活页夹的所有修改。

语法

object.Save

object

必须的。Binder 对象。

说明

如果使用 Save 保存活页夹，将会产生一个错误。第一次保存新的活页夹，应使用 SaveAs 方法。


Save 方法示例

本示例在 Binder1.obd 中添加一个类型为 Excel.Sheet 的稿件，然后保存活页夹。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

With myBinder

    .Visible = True

    .Sections.Add Type:="Excel.Sheet"

    .Save

End With


SaveAs 方法

保存对活页夹或各稿件的修改。如果活页夹被保存，返回 True 。如果活页夹没有被保存，返回False 。如果活页夹是不可见的，将回产生一个错误。

语法 1

object.SaveAs(fileName, saveOption)

语法 2

object.SaveAs(fileName)

object

必须的。为 Binder 对象 （语法 1） 或 Section 对象（语法 2）。

fileName

对 Section 是必须有, 对 Binder 是可选。用一个串说明要保存的文件名，可以包含 完整的路径，如果不包含，文件将保存在默认的文件夹之中。

saveOption

可选的。 指定保存活页夹时的选项，如下表所示。

值	说明
bindFailIfFileExists	如果 fileName 存在，将会产生一个错误。fileName 要求使用默认值。
bindOverwriteExisting	如果 fileName 存在。SaveAs 覆盖它。fileName 必须指明。
bindDisplayDialog	显示 Save As 对话框，fileName 是可选的。如果用户没有保存而关闭对话窗，SaveAs 将返回 False。
说明

稿件作为一个唯一的文件被保存时，并不删除活页夹中对应的稿件。如果要从活页夹中删除一个稿件，使用 Delete 方法。


SaveAs 方法示例

本示例判断 Binder1.obd 中的第一个稿件的类型是否为 Excel.Sheet.5 ，如果是， 本示例 将以工作簿 Book1.xls 保存它。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

If myBinder.Sections(1).Type = "Excel.Sheet.5" Then

myBinder.Sections(1).SaveAs "MyBook1.xls"

End If

Set myBinder = Nothing

本示例创建一个新的活页夹，并使它可见，接着提示用户以 Binder1.obd 名保存它。

Set newBinder = CreateObject("Office.Binder")

newBinder.Visible = True

newBinder.SaveAs fileName:="Binder1.obd", _

saveOption:=bindDisplayDialog


Sections 属性

返回 Sections 集合对象，它代表一个活页夹中所有的稿件。只读。

说明

本属性返回完整的 Sections 集合。用 Item 属性，通过指定索引或名称，可返回集合中的某一成员（一个 Section 对象）。

Item 属性是 Sections 集合对象的默认属性。以下语句是等效的。

myBinder.Sections.Item(3)

myBinder.Sections(3)


Sections 属性 示例

本示例显示 Binder1.obd. 中的 Microsoft Excel 稿件编号 。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

wk = 0

For Each s In myBinder.Sections

If s.Type = "Excel.Sheet.5" Then

wk = wk + 1

End If

Next

MsgBox "There are " & wk & " Microsoft Excel sections in this binder."

Set myBinder = Nothing

本示例显示 Binder1.obd. 中第三个稿件的名字，同时显示稿件 "Financial Analysis."的位置。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

MsgBox myBinder.Sections(3).Name

MsgBox myBinder.Sections("Financial Analysis").Index

Set myBinder = Nothing


SelectedSectionNames 属性

返回或设置所选稿件名的序列。只读。

说明

当设置 SelectedSectionNames 属性时， 序列中的第一个稿件变为活动稿件。如果序列中包含了不存在的稿件时，将会产生一个错误。


SelectedSectionNames 属性示例

本示例 选择 Binder1.obd 中的头三个稿件。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

myBinder.Visible = True

Dim s(1 to 3) As String

For x = 1 To 3

s(x) = myBinder.Sections(x).Name

Next

myBinder.SelectedSectionNames = s


Type 属性

返回一个串，包含 Section 对象的 OLE 名。只读。

说明

OLE 名用 appName.objectType.versionNumber 指定（例如， "Word.Document.6"）。 有关活页夹稿件更详细的信息请参阅 Add 方法。


Type 属性示例

本示例显示 Binder1.obd. 中第一个稿件的类型。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

theType = myBinder.Sections(1).Type

Set myBinder = Nothing

MsgBox theType


Visible 属性

如果是 True，活页夹或稿件是可见的。只读。

说明

当 OLE 自动打开一个Binder 对象时， Visible 属性 是 False. 为使活页夹可见，设置Visible 属性为 True。

隐藏的稿件包含在Sections 集合对象的计数之中。


Visible 属性示例

本示例打开 Binder1.obd 并使它可见。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

myBinder.Visible = True


Section 对象

代表活页夹中的稿件。

Accessors

Section 对象是Sections 集合的成员。Sections 集合包含活页夹中所有的Section 对象。用 Add 方法可以创建新的对象并添加到集合中。

要存取集合中单个成员，可使用 Sections 对象的 Item 属性，以稿件的索引号或名称作为参数。Item 属性是 Sections 集合对象的默认属性，下面的语句是等效的。

myBinder.Sections.Item(3)

myBinder.Sections(3)

索引号代表稿件在活页夹窗格中的次序。Sections(1)是第一个稿件，Sections(Sections.Count)是最后一个。激活稿件不会改变其序号。所有的稿件都有其序号，不论其是否出于隐藏状态。下面的示例激活指定活页夹中的稿件 1。

myBinder.Sections(1).Activate

说明

Name 属性返回和设置活页夹名称。下面的示例显示 Binder1.obd 中稿件 1 的名称。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

theName = myBinder.Sections(1).Name

Set myBinder = Nothing

MsgBox theName

用 SaveAs 方法可以把稿件的备份保存到另一个文件中。下面的示例把 Binder1.obd 中的第一个稿件保存到一个新的 Microsoft Excel 工作薄中。.

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

If myBinder.Sections(1).Type = "Excel.Sheet.5" Then

myBinder.Sections(1).SaveAs "MyBook3.xls"

End If

本示例激活活页夹 "Annual Report." 中名叫 "Sumsales" 的稿件。

Set myBinder = GetObject("C:\reports\Annual Report.obd", "Office.Binder")

myBinder.Visible = True

myBinder.Sections("Sumsales").Activate


Sections 集合对象

活页夹中所有 Section 对象的集合。Sections 包含活页夹中所有的稿件，而不论其是否隐藏。

Accessors

用 Add 方法可以创建新的稿件，或把已有的文件作为稿件添加进去。下面的示例在活页夹中添加一个新的、空的 Microsoft Excel 工作薄。

Set myBinder = CreateObject("Office.Binder")

myBinder.Sections.Add Type:="Excel.Sheet"

下面的示例打开已有的活页夹，并把文件 Array.xls 作为一个稿件添加进去。

Set myBinder = GetObject("Binder1.obd", "Office.Binder")

myBinder.Visible = True

myBinder.Sections.Add fileName:="MyBook1.xls"

使用 Sections 属性可以同时存取整个集合。下面的示例显示 Binder1.obd 中的稿件数。

Set myBinder = GetObject("binder1.obd", "Office.Binder")

MsgBox "there are " & myBinder.Sections.Count & _

    " sections in this binder"

Set myBinder = Nothing

要存取集合中的单个成员，可使用 Sections 对象的 Item 属性。用索引号和名称作为参数。Item 属性是 Sections 集合对象的默认属性，下面的语句是等效的。

myBinder.Sections.Item(3)

myBinder.Sections(3)


Binder 对象

代表 Microsoft Office 活页夹文件。在 Visual Basic 中，活页夹作为一个 OLE 自动对象打开。

Accessors

用CreateObject 函数创建新的活页夹。下面的示例创建一个新的活页夹，使其可见，然后保存为 Mybind.obd。

Set myBinder = CreateObject("Office.Binder")

myBinder.Visible = True

myBinder.SaveAs filename := "Mybind.obd"

用 Open 方法或 GetObject 函数打开已有的活页夹。下面的示例打开上一个活页夹，并使其可见。

Set myBinder = GetObject("Mybind.obd", "Office.Binder")

myBinder.Visible = True

说明

活页夹创建或打开后是隐藏的。把 Visible 属性设置成 True 以便显示活页夹。


Open 方法

Opens 打开现有的活页夹，或者用模板创建新的活页夹。

语法

object.Open(fileName, openAsTemplate)

object

必须的。Binder 对象。

fileName

必须的。字符串指定要打开的文件名。

openAsTemplate

可选的。如果是 True，文件作为基于指定活页夹模板的新活页夹打开。如果是 False 或忽略，文件作为活页夹文件打开。

说明

打开现有活页夹更好的方法是用 GetObject 函数。

必须在 CreateObject 之后立即使用 Open 方法，否则会产生错误。


Open 方法示例

本示例打开 Binder2.obd ，并在该活页夹第一个稿件之前添加一个新的 Word 文档。

Set myBinder = CreateObject("Office.Binder")

With myBinder

    .Open "Binder1.obd"

    .Sections.Add Type:="Word.Document", before:=1

    .Visible = True

End With


Update 方法

保存对稿件的修改。

语法

object.Update

object

必须的。要更新的 Section 对象。

说明

用方法确保对活页夹的修改已保存。详细内容，请参阅示例。


Update 方法示例

这个示例创建一个新的活页夹，在其中添加一个新的 Microsoft Excel 工作表，在工作表中放置一个值，然后保存修改。如果不使用 Update 方法，工作表的修改将丢失，新的稿件对象将设置成 Nothing。

Set newBinder = CreateObject("Office.Binder")

Set newSection = newBinder.Sections.Add(Type:="Excel.Sheet")

newSection.Object.Range("a1").Value = 3.14159

newSection.Update

Set newSection = Nothing


BuiltinDocumentProperties 属性

返回代表指定活页夹的所有内置文档属性的 DocumentProperties 集合对象。只读。

要使用这个属性，必须用“工具”菜单中的“应用”命令，建立对 Microsoft Office 95 Object Library 中对象的引用。

说明

这个属性所有的内部文档属性。要返回集合（DocumentProperty 对象）中单个成员，可使用 Item 方法，以属性的名称或数字索引来存取。要浏览内置属性名称的列表，请参阅 Item 方法。

Item 方法是 DocumentProperties 集合对象默认的方法，下面的语句是等效的。

BuiltinDocumentProperties.Item(1)

BuiltinDocumentProperties(1)

用 CustomDocumentProperties 属性可以返回自定义的文档属性的集合。


BuiltinDocumentProperties 属性示例

本示例显示 Binder1.obd 的作者名。

Set nb = GetObject("binder1.obd", "office.binder")

MsgBox nb.BuiltinDocumentProperties("Author").Value

Set nb = Nothing


 CustomDocumentProperties 属性

返回代表指定活页夹的所有自定义属性的 DocumentProperties 集合对象。只读。

要使用这个属性，必须用“工具”菜单中的“应用”命令，建立对 Microsoft Office 95 Object Library 中对象的引用。

说明

这个属性返回自定义文档属性的集合。要返回集合（DocumentProperty 对象）中单个成员，可使用 Item 方法，以属性的名称或数字索引来存取。

Item 方法是 DocumentProperties 集合对象默认的方法，下面的语句是等效的。

CustomDocumentProperties.Item("Complete")

CustomDocumentProperties("Complete")

用 BuiltinDocumentProperties 属性可以返回内置的文档属性的集合。


CustomDocumentProperties Property 示例

本示例在 Binder1.obd 中添加自定义属性，然后保存这个活页夹。

Set nb = GetObject("binder1.obd", "office.binder")

nb.CustomDocumentProperties.Add Name:="complete", _

LinkToContent:=False, Type:=offPropertyTypeBoolean, Value:=False

nb.Save

Set nb = Nothing