Tips&Tricks I trucchi del mestiere

 

Come validare un indirizzo e-mail con le Regular Expression

Un tip dedicato al riconoscimento della corretta sintassi di un indirizzo e-mail. Il tutto si basa su di una funzione legata all'uso delle "Regular Expression" (molto familiari ai masticatori del C, del Perl, ecc.) che riducono lo script a poche righe di codice.
Tip fornito dal Sig. M.Luciani

 
<%
Function IsMail(sEmail) 
  Dim objRegExp
  Set objRegExp = New RegExp
  objRegExp.Pattern = "^[a-z._-]+\@[a-z._-]+\.[a-z]{2,4}$"
  objRegExp.IgnoreCase = True 
  IsMail = objRegExp.Test(sEmail)
End Function 

Dim strEmail

strEmail = "webmaster@byluciani.com"

If IsMail(strEmail) Then
  Response.Write strEmail & _
                 " Φ un indirizzo email sintatticamente corretto"
Else
  Response.Write strEmail & _
                 " NON Φ un indirizzo email sintatticamente corretto"
End If
%>

Email a Go Go
Il tip proposto consente di spedire molto velocemente email; la parte di codice allegata funziona sia rinominato in .vbs che in moduli di access, macro di excel, pagine ASP. PerchΦ l'esempio funzioni occorre modificare l'indirizzo del server web e gli indirizzi di destinazione. Nell'esempio viene spedita via mail una pagina web, comprensiva di immagini, hyperlink ecc. E' molto veloce, consente di cambiare destinatario e spedire la stessa mail senza riconfigurare nulla. Il tip funziona in qualsiasi ambiente di scripting microsoft (vbs, asp, vba, vb). Ideale per mailing list. Con un server smtp locale, con un PIII a 800 mhz si possono passare le 10 mail al secondo.
Tip fornito dal sig. M.Piccinini 

'Definizioni per CDO
dim cdoSendUsingMethod, cdoSendUsingPort,cdoSMTPServer,cdoSMTPServerPort,cdoSMTPAuthenticate,cdoAnonymous,cdoSuppressNone
cdoSendUsingMethod = "http://schemas.microsoft.com/cdo/configuration/sendusing"
cdoSendUsingPort = 2
cdoSMTPServer = "http://schemas.microsoft.com/cdo/configuration/smtpserver"
cdoSMTPServerPort = "http://schemas.microsoft.com/cdo/configuration/smtpserverport"
cdoSMTPAuthenticate = "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"
cdoAnonymous = 0
cdoSuppressNone = 0

' invio una mail di prova
Dim oConf , oMail , oFlds , oAtt 

Set oMail = CreateObject("CDO.Message")
Set oConf = CreateObject("CDO.Configuration")
Set oFlds = oConf.Fields
oFlds(cdoSendUsingMethod) = cdoSendUsingPort
oFlds(cdoSMTPServer) = "mioServerSmtp"
oFlds(cdoSMTPServerPort) = 25
oFlds(cdoSMTPAuthenticate) = cdoAnonymous
oFlds.Update
Set oMail.Configuration = oConf

oMail.From = "MioMailer <io@mioprovider.it>"
oMail.Subject  = "Prova CDO"
oMail.CreateMHTMLBody "http://www.itportal.it", cdoSuppressNone

oMail.To = "Indirizzo1@provider1.it"
oMail.Send 

oMail.To = "Indirizzo2@provider2.it"
oMail.Send 

' etc etc etc

set oConf = Nothing
set oflds = Nothing
set oMail = Nothing