Push Commands
--------------------------------------------------------------------------------


#xcommand @ <nRow>, <nCol> BUTTON [ <oBtn> PROMPT ] <cCaption> ;
             [ SIZE <nWidth>, <nHeight> ] ;
             [ ACTION <uAction> ] ;
             [ <default: DEFAULT> ] ;
             [ <of:OF, WINDOW, DIALOG> <oWnd> ] ;
             [ <help:HELP, HELPID, HELP ID> <nHelpId> ] ;
             [ FONT <oFont> ] ;
             [ <pixel: PIXEL> ] ;
             [ <design: DESIGN> ] ;
             [ MESSAGE <cMsg> ] ;
             [ <update: UPDATE> ] ;
             [ WHEN <WhenFunc> ] ;
             [ VALID <uValid> ] ;
             [ <lCancel: CANCEL> ] ;
      => ;
         [ <oBtn> := ] TButton():New( <nRow>, <nCol>, <cCaption>, <oWnd>,;
            <{uAction}>, <nWidth>, <nHeight>, <nHelpId>, <oFont>, <.default.>,;
            <.pixel.>, <.design.>, <cMsg>, <.update.>, <{WhenFunc}>,;
            <{uValid}>, <.lCancel.> )


#xcommand REDEFINE BUTTON [ <oBtn> ] ;
             [ ID <nId> <of:OF, WINDOW, DIALOG> <oDlg> ] ;
             [ ACTION <uAction,...> ] ;
             [ <help:HELP, HELPID, HELP ID> <nHelpId> ] ;
             [ MESSAGE <cMsg> ] ;
             [ <update: UPDATE> ] ;
             [ WHEN <WhenFunc> ] ;
             [ VALID <uValid> ] ;
             [ PROMPT <cPrompt> ] ;
             [ <lCancel: CANCEL> ] ;
       => ;
          [ <oBtn> := ] TButton():ReDefine( <nId>, [\{||<uAction>\}], <oDlg>,;
             <nHelpId>, <cMsg>, <.update.>, <{WhenFunc}>, <{uValid}>,;
             <cPrompt>, <.lCancel.> )


 <nRow>, <nCol>  The coordinates of the Button. They mimic text mode coordinates.

 <oBtn>          A reference to the Button Object.

 <oBar>          A reference to the Button

 <cCaption>      The label of the Button.

 <cBpFile1>      The file name of the bitmap as a Picture Button.
 <cBmpFile2>     When a second bitmap is provided it is displayed as the
                 Button in a depressed state.

 <nHelpId>       The help topic identifier of the Button.

 <oWnd>          The container window of the Button.

 <uAction>       The action to be performed when the Button is pressed.

 <oFont>         A reference to the Font Object to use with the Button.

 <nWidth>,       The dimensions of the Button.
 <nHeigth>

 <cResName1>     The bitmap resource to display as a Picture Button.
 <cResName2>     When a second bitmap resource is provided it is displayed
                 as the Button in a depressed state.

 <cMsg>          The associated message of this control

 <WhenFunc>      It is an expression to evaluate indicating if the control is
                 or not enable.

 <nId>           The numeric resource identifier of the Control.

 CLAUSES

 DEFAULT         For default PushButtons: Automatically executes when
                 the user press Enter, even from other controls.

                 Use this clause only when building the Button from
                 source code. When using resources, this clause must
                 be specifies from the resource editor.

 !seealso: TButton.eho:"TButton"