Visual Basic VBX Controls Support  

   Creating a VBX from   @ <nRow>, <nCol> VBX [<oVbx>] ;
   source code              [ OF <oWnd> ] ;
   (using a VBX on a        [ SIZE <nWidth>, <nHeight> ] ;
    window)                 [ FILE | FILENAME | DISK <cVbxFile> ] ;
                            [ CLASS <cVbxClass> ] ;
                            [ ON <cClause1> <uAction1> ;
                            [ ON <cClauseN> <uActionN> ] ]

   Warning: Some VBXs controls need some specific initialization data,
   and may not work properly using them on windows. In those cases,
   use them only in DialogBoxes using REDEFINE VBX ...

   Creating a VBX from   REDEFINE VBX [<oControl>] ;
   resources                [ ID <nId> ] ;
   (using a VBX on a        [ OF <oDlg> ] ;
    dialog box)             [ COLOR <nClrFore> [,<nClrBack>] ] ;
                            [ ON <cClause1> <uAction1> ;
                            [ ON <cClauseN> <uActionN> ] ]

<nRow>, <nCol>            The screen coordinates

<oVbx>                    A reference to the oVbx control object

<nWidth>, <nHeight>       The dimensions of the oVbx control

<cVbxFile>                The filename of the .VBX file

<cVbxClass>               Optional VBX class name specified by the manufacturer

<cClause>                 Any event name specified by the VBX manufacturer
<uAction>                 Any action to execute on that event

<nId>                     The oVbx control ID from inside DialogBoxes

<oDlg>                    A reference to the DialogBox object container

<nClrFore>, <nClrBack>    Colors of the oVbx from DialogBoxes


#xtranslate _PARM_BLOCK_10_( <uAction> ) => ;
            \{ |bp1,bp2,bp3,bp4,bp5,bp6,bp7,bp8,bp9,bp10| <uAction> \}

#xcommand @ <nRow>, <nCol> VBX [<oVbx>] ;
             [ OF <oWnd> ] ;
             [ SIZE <nWidth>, <nHeight> ] ;
             [ <file: FILE, FILENAME, DISK> <cVbxFile> ] ;
             [ CLASS <cVbxClass> ] ;
             [ ON <cClause1> <uAction1> ;
             [ ON <cClauseN> <uActionN> ] ] ;
             [ WHEN <uWhen> ] ;
             [ VALID <uValid> ] ;
             [ <lPixel: PIXEL> ] ;
             [ <lDesign: DESIGN> ] ;
       => ;
          [ <oVbx> := ] TVbControl():New( <nRow>, <nCol>, <nWidth>, <nHeight>,;
             <oWnd>, <cVbxFile>, <cVbxClass>, ;
             \{ [ <(cClause1)>, _PARM_BLOCK_10_( <uAction1> ) ] ;
              [,<(cClauseN)>, _PARM_BLOCK_10_( <uActionN> ) ] ;
             \}, [<{uWhen}>], [<{uValid}>], <.lPixel.>, <.lDesign.> )


#xcommand REDEFINE VBX [<oControl>] ;
             [ ID <nId> ] ;
             [ OF <oDlg> ] ;
             [ COLOR <nClrFore> [,<nClrBack>] ] ;
             [ ON <cClause1> <uAction1> ;
             [ ON <cClauseN> <uActionN> ] ] ;
       => ;
          [ <oControl> := ] TVbControl():ReDefine( <nId>, <oDlg>,;
             <nClrFore>, <nClrBack>, ;
             \{ [ <(cClause1)>, _PARM_BLOCK_10_( <uAction1> ) ] ;
              [,<(cClauseN)>, _PARM_BLOCK_10_( <uActionN> ) ] ;
             \} )