ScrollBar Controls Commands
--------------------------------------------------------------------------------

 Creating a ScrollBar        @ <nRow>, <nCol> SCROLLBAR [<oSbr>] ;
 from source code              [ HORIZONTAL | VERTICAL ] ;
                               [ RANGE <nMin>, <nMax> ] ;
                               [ PAGESTEP <nPgStep> ] ;
                               [ SIZE <nWidth>, <nHeight> ] ;
                               [ UP | ON UP <uUpAction> ] ;
                               [ DOWN | ON DOWN <uDownAction> ] ;
                               [ PAGEUP | ON PAGEUP <uPgUpAction> ] ;
                               [ PAGEDOWN | ON PAGEDOWN <uPgDownAction> ] ;
                               [ ON THUMBPOS <uPos> ] ;
                               [ PIXEL ] ;
                               [ OF | WINDOW | DIALOG <oDlg> ]


#xcommand @ <nRow>, <nCol> SCROLLBAR [ <oSbr> ] ;
             [ <h: HORIZONTAL> ] ;
             [ <v: VERTICAL> ] ;
             [ RANGE <nMin>, <nMax> ] ;
             [ PAGESTEP <nPgStep> ] ;
             [ SIZE <nWidth>, <nHeight> ] ;
             [ <up:UP, ON UP> <uUpAction> ] ;
             [ <dn:DOWN, ON DOWN> <uDownAction> ] ;
             [ <pgup:PAGEUP, ON PAGEUP> <uPgUpAction> ] ;
             [ <pgdn:PAGEDOWN, ON PAGEDOWN> <uPgDownAction> ] ;
             [ <pos: ON THUMBPOS> <uPos> ] ;
             [ <pixel: PIXEL> ] ;
             [ <color: COLOR,COLORS> <nClrText> [,<nClrBack>] ] ;
             [ OF <oWnd> ] ;
             [ MESSAGE <cMsg> ] ;
             [ <update: UPDATE> ] ;
             [ WHEN <uWhen> ] ;
             [ VALID <uValid> ] ;
             [ <lDesign: DESIGN> ] ;
       => ;
          [ <oSbr> := ] TScrollBar():New( <nRow>, <nCol>, <nMin>, <nMax>, <nPgStep>,;
             (.not.<.h.>) [.or. <.v.> ], <oWnd>, <nWidth>, <nHeight> ,;
             [<{uUpAction}>], [<{uDownAction}>], [<{uPgUpAction}>], ;
             [<{uPgDownAction}>], [\{|nPos| <uPos> \}], [<.pixel.>],;
             <nClrText>, <nClrBack>, <cMsg>, <.update.>, <{uWhen}>, <{uValid}>,;
             <.lDesign.> )

// for 'non-true ScrollBars' ( when using WS_VSCROLL or WS_HSCROLL styles )
#xcommand DEFINE SCROLLBAR [ <oSbr> ] ;
             [ <h: HORIZONTAL> ] ;
             [ <v: VERTICAL> ] ;
             [ RANGE <nMin>, <nMax> ] ;
             [ PAGESTEP <nPgStep> ] ;
             [ <up:UP, ON UP> <uUpAction> ] ;
             [ <dn:DOWN, ON DOWN> <uDownAction> ] ;
             [ <pgup:PAGEUP, ON PAGEUP> <uPgUpAction> ] ;
             [ <pgdn:PAGEDOWN, ON PAGEDOWN> <uPgDownAction> ] ;
             [ <pos: ON THUMBPOS> <uPos> ] ;
             [ <color: COLOR,COLORS> <nClrText> [,<nClrBack>] ] ;
             [ <of: OF, WINDOW, DIALOG> <oWnd> ] ;
             [ MESSAGE <cMsg> ] ;
             [ <update: UPDATE> ] ;
             [ WHEN <uWhen> ] ;
             [ VALID <uValid> ] ;
       => ;
             [ <oSbr> := ] TScrollBar():WinNew( <nMin>, <nMax>, <nPgStep>, ;
             (.not.<.h.>) [.or. <.v.> ], <oWnd>, [<{uUpAction}>],;
             [<{uDownAction}>], [<{uPgUpAction}>], ;
             [<{uPgDownAction}>], [\{|nPos| <uPos> \}],;
             <nClrText>, <nClrBack>, <cMsg>, <.update.>, <{uWhen}>, <{uValid}> )



 Creating a ScrollBar        REDEFINE SCROLLBAR [ <oSbr> ] ;
 from resources                [ ID <nID> ] ;
                               [ RANGE <nMin>, <nMax> ] ;
                               [ PAGESTEP <nPgStep> ] ;
                               [ UP | ON UP <uUpAction> ] ;
                               [ DOWN | ON DOWN <uDownAction> ] ;
                               [ PAGEUP | ON PAGEUP <uPgUpAction> ] ;
                               [ PAGEDOWN | ON PAGEDOWN <uPgDownAction> ] ;
                               [ ON THUMBPOS <uPos> ] ;
                               [ OF | WINDOW | DIALOG <oDlg> ]

#xcommand REDEFINE SCROLLBAR [ <oSbr> ] ;
             [ ID <nID>  ] ;
             [ RANGE <nMin>, <nMax> ] ;
             [ PAGESTEP <nPgStep> ] ;
             [ <up:UP, ON UP, ON LEFT> <uUpAction> ] ;
             [ <dn:DOWN, ON DOWN, ON RIGHT> <uDownAction> ] ;
             [ <pgup:PAGEUP, ON PAGEUP> <uPgUpAction> ] ;
             [ <pgdn:PAGEDOWN, ON PAGEDOWN> <uPgDownAction> ] ;
             [ <pos: ON THUMBPOS> <uPos> ] ;
             [ <color: COLOR,COLORS> <nClrText> [,<nClrBack>] ] ;
             [ OF <oDlg> ] ;
             [ MESSAGE <cMsg> ] ;
             [ <update: UPDATE> ] ;
             [ WHEN <uWhen> ] ;
             [ VALID <uValid> ] ;
       => ;
          [ <oSbr> := ] TScrollBar():Redefine( <nID>, <nMin>, <nMax>, <nPgStep>,;
            <oDlg>, [<{uUpAction}>], [<{uDownAction}>], [<{uPgUpAction}>], ;
            [<{uPgDownAction}>], [\{|nPos| <uPos> \}], <nClrText>,;
            <nClrBack>, <cMsg>, <.update.>, <{uWhen}>, <{uValid}> )




 <nRow>, <nCol>  The coordinates of the ScrollBar.
                 We simulate Text coordinates.

 <oSbr>          A reference to the ScrollBar Object.

 <oDlg>          The container window of the ScrollBar.

 <nMin>, <nMax>  The range of values to be represented by the scrollbar.

 <nPgStep>       The increment of value when PageUp or PageDown is
                 selected on the Scrollbar. That is, when clicking
                 between the thumb and the top arrow or when clicking
                 between the thumb and the bottom arrow.

 <nWidth>        The dimensions in pixels of the ScrollBar.
 <nHeight>

 <uUpAction>     An action to be performed when going up is selected on
                 the scrollbar. That is, when clicking on the top arrow or
                 when pressing the key K_UP.

 <uDownAction>   An action to be performed when going down is selected on
                 the scrollbar. That is, when clicking on the bottom arrow or
                 when pressing the key K_DOWN.

 <uPgUpAction>   An action to be performed when page up is selected on
                 the scrollbar. That is, when clicking between the thumb
                 and the top arrow.

 <uPgDownAction> An action to be performed when page down is selected on
                 the scrollbar. That is, when clicking between the thumb
                 and the bottom arrow.

 <uPos>          An action to be performed when the thumb is moved by the
                 user and left on a different position. The new position
                 is automatically provided as nPos value.

 <nId>           The numeric resource identifier of the Control.

 CLAUSES

 HORIZONTAL      To use a horizontal or vertical scrollbar. Only useful
 VERTICAL        when creating from source code.

 PIXEL           To use pixel coordinates instead of Text coordinates.

 !seealso: TScrlBar.eho:TScrollBar Headers.eho:FiveWin.ch