GET Commands
--------------------------------------------------------------------------------

                             @ <nRow>, <nCol> GET [ <oGet> VAR <uVar> ] ;
 For editing Memos              [ OF | WINDOW | DIALOG <oWnd> ] ;
                                [ MULTILINE | MEMO | TEXT ] ;
                                [ COLOR   <cColor> ] ;
                                [ SIZE <nWidth>, <nHeight> ] ;
                                [ FONT <oFont> ] ;
                                [ DESIGN ] ;
                                [ CURSOR <oCursor> ] ;
                                [ PIXEL ] ;
                                [ MESSAGE <cMsg> ] ;
                                [ UPDATE ] ;
                                [ WHEN <WhenFunc> ] ;
                                [ CENTER | CENTERED ] ;
                                [ RIGHT ] ;
                                [ ON CHANGE <uChange> ] ;

#command @ <nRow>, <nCol> GET [ <oGet> VAR ] <uVar> ;
            [ <dlg: OF, WINDOW, DIALOG> <oWnd> ] ;
            [ <memo: MULTILINE, MEMO, TEXT> ] ;
            [ <color:COLOR,COLORS> <nClrFore> [,<nClrBack>] ] ;
            [ SIZE <nWidth>, <nHeight> ] ;
            [ FONT <oFont> ] ;
            [ <hscroll: HSCROLL> ] ;
            [ CURSOR <oCursor> ] ;
            [ <pixel: PIXEL> ] ;
            [ MESSAGE <cMsg> ] ;
            [ <update: UPDATE> ] ;
            [ WHEN <uWhen> ] ;
            [ <lCenter: CENTER, CENTERED> ] ;
            [ <lRight: RIGHT> ] ;
            [ <readonly: READONLY, NO MODIFY> ] ;
            [ VALID <uValid> ] ;
            [ ON CHANGE <uChange> ] ;
            [ <lDesign: DESIGN> ] ;
       => ;
          [ <oGet> := ] TMultiGet():New( <nRow>, <nCol>, bSETGET(<uVar>),;
             [<oWnd>], <nWidth>, <nHeight>, <oFont>, <.hscroll.>,;
             <nClrFore>, <nClrBack>, <oCursor>, <.pixel.>,;
             <cMsg>, <.update.>, <{uWhen}>, <.lCenter.>,;
             <.lRight.>, <.readonly.>, <{uValid}>,;
             [\{|nKey, nFlags, Self| <uChange>\}], <.lDesign.> )


 For editing Memos           REDEFINE GET [ <oGet> VAR ] <uVar> ;
                               [ MULTILINE | MEMO | TEXT ] ;
                               [ ID <nId> ] ;
                               [ OF | WINDOW | DIALOG <oWnd> ] ;
                               [ HELPID | HELP ID <nHelpId> ] ;
                               [ COLOR | COLORS <nClrFore> [,<nClrBack>] ] ;
                               [ FONT <oFont> ] ;
                               [ CURSOR <oCursor> ] ;
                               [ MESSAGE <cMsg> ] ;
                               [ UPDATE ] ;
                               [ WHEN <WhenFunc> ] ;
                               [ READONLY | NO MODIFY> ] ;

#xcommand REDEFINE GET [ <oGet> VAR ] <uVar> ;
             [ <memo: MULTILINE, MEMO, TEXT> ] ;
             [ ID <nId> ] ;
             [ <dlg: OF, WINDOW, DIALOG> <oDlg> ] ;
             [ <help:HELPID, HELP ID> <nHelpId> ] ;
             [ <color: COLOR,COLORS> <nClrFore> [,<nClrBack>] ] ;
             [ FONT <oFont> ] ;
             [ CURSOR <oCursor> ] ;
             [ MESSAGE <cMsg> ] ;
             [ <update: UPDATE> ] ;
             [ WHEN <uWhen> ] ;
             [ <readonly: READONLY, NO MODIFY> ] ;
             [ VALID <uValid> ] ;
             [ ON CHANGE <uChange> ] ;
       => ;
          [ <oGet> := ] TMultiGet():ReDefine( <nId>, bSETGET(<uVar>),;
             <oDlg>, <nHelpId>, <nClrFore>, <nClrBack>, <oFont>, <oCursor>,;
             <cMsg>, <.update.>, <{uWhen}>, <.readonly.>, <{uValid}>,;
             [\{|nKey, nFlags, Self| <uChange>\}] )



 <nRow>, <nCol>  The coordinates of the GET. We simulate Text coordinates.

 <oGet>          A reference to the GET Object.

 <uVar>          The variable which the GET Object is manipulating.

 <oWnd>          The container window of the GET.

 <cPict>         Typical xBase PICTURE clause.

 <ValidFunc>     Validating expression or function. The same as in MsDos.

 <WhenFunc>      When Clause. Not available yet!

 <cColor>        The color of the GET. Not available yet!

 <nWidth>,       The dimensions in pixels of the GET.
 <nHeight>

 <oFont>         A reference to the Font Object to be used with the GET.

 <oCursor>       A reference to the Cursor Object to display over this control.

 <cMsg>          The associated message of this control.

 <nId>           The numeric resource identifier of the Control.

 <nHelpId>       Help topic identifier for GETs from resources.

 <nClrFore>      Foreground color as a RGB number, or as a xBase string
 <nClrBack>      Background color as a RGB number

 <uChange>       An action to be performed when the Get changes.

 CLAUSES

 MULTILINE       To use a multiple lines GET control to allow memo
 MEMO            editing.
 TEXT

 UPDATE          This control may be updated from TDialog:Update() METHOD

 CENTER          If the GET contains has to appear centered

 RIGHT           If the GET contents have to appear right justified.
                 Important: In order to right justify a GET from a DialogBox,
                 it has to be defined at the resource as MultiLine and
                 right Justified and has to use the default font!

 PIXEL           To use pixel coordinates instead of Text coordinates.

 DESIGN          Allows the user to move and resize with the mouse

 READ ONLY       Disables editing in this control.
 NO MODIFY

 !seealso: TGet.eho:TGet TMGet.eho:TMultiGet Headers.eho:FiveWin.ch